From 55869f2c5f5b96213db40b3b6d26aeb27b3b1c07 Mon Sep 17 00:00:00 2001
From: Mariusz Pietrzyk <wijet@wijet.pl>
Date: Wed, 24 Jun 2009 12:39:54 +0200
Subject: [PATCH] Added oauth.prf

---
 oauth.prf | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 oauth.prf

diff --git a/oauth.prf b/oauth.prf
new file mode 100644
index 0000000..511721a
--- /dev/null
+++ b/oauth.prf
@@ -0,0 +1,42 @@
+QOAUTH_INCDIR = $$[QT_INSTALL_HEADERS]
+QOAUTH_LIBDIR = $$[QT_INSTALL_LIBS]
+
+QOAUTH_INCDIR ~= s!/qt4!!
+QOAUTH_LIBDIR ~= s!/qt4!!
+
+CONFIG *= qt
+
+# if we are including oauth.prf from the qoauth tree (and not utilizing it as
+# an installed qmake CONFIG feature), then point to the tree.  this allows our
+# qoauth tree apps to build before qoauth itself is installed.
+exists($$PWD/qoauth.pro) {
+    QOAUTH_INCDIR = $$PWD/include
+    QOAUTH_LIBDIR = $$PWD/lib
+}
+
+LINKAGE =
+
+# on mac, if qoauth was built as a framework, link against it
+mac: {
+    framework_dir = $${QOAUTH_LIBDIR}
+    exists($$framework_dir/qoauth.framework) {
+        LIBS += -F$$framework_dir
+        exists($$PWD/qoauth.pro): INCLUDEPATH += $$QOAUTH_INCDIR
+        else: INCLUDEPATH += $$framework_dir/qoauth.framework/Headers
+        LINKAGE = -framework qoauth
+    }
+}
+
+# else, link normally
+isEmpty(LINKAGE) {
+    exists($$PWD/qoauth.pro): INCLUDEPATH += $$QOAUTH_INCDIR
+    else: INCLUDEPATH += $$QOAUTH_INCDIR/QtOAuth
+    LIBS += -L$$QOAUTH_LIBDIR
+    LINKAGE = -lqoauth
+    CONFIG(debug, debug|release) {
+        windows:LINKAGE = -lqoauthd
+        mac:LINKAGE = -lqoauth_debug
+    }
+}
+
+LIBS += $$LINKAGE
\ No newline at end of file