# 

# 编译原理综合训练实验报告

学院：软件学院

班级：软件21班

学号：2121601003

姓名：李晓萌

2015年7月25日

1. 语言文法的形式化描述(BNF范式)

S ::= <语句组>

语句组 ::= <语句>

语句组 ::= <语句组><语句>

语句 ::= <声明语句>

语句 ::= <执行语句>

**#声明语句**

声明语句 ::= <全局变量定义语句>

声明语句 ::= <函数声明语句>

函数声明语句 ::= <函数头>{<局部语句组或空>

函数头 ::= <类型和函数名>(<形式参数列表>)

类型和函数名 ::= <类型>id

形式参数列表 ::= <形式参数>

形式参数列表 ::= <形式参数列表>com<形式参数>

形式参数列表 ::=

形式参数 ::= <类型>id

局部语句组或空 ::= <局部语句组>}

局部语句组或空 ::= }

局部语句组 ::= <局部语句>

局部语句组 ::= <局部语句组><局部语句>

局部语句 ::= <局部变量定义语句>

局部语句 ::= <执行语句>

局部语句 ::= <return语句>

return语句 ::= return<值>semi

局部变量定义语句 ::= <局部声明部分>semi

局部声明部分 ::= <类型><局部声明元>

局部声明部分 ::= <局部声明部分>com<局部声明元>

局部声明元 ::= id

局部声明元 ::= <局部数组参数表>]

局部数组参数表 ::= <局部数组参数表>com number

局部数组参数表 ::= id [ number

**#全局变量定义部分**

全局变量定义语句 ::= <全局声明部分>semi

全局声明部分 ::= <全局声明部分>com<全局声明元>

全局声明部分 ::= <类型><全局声明元>

全局声明元 ::= <全局数组参数表>]

全局声明元 ::= id

全局数组参数表 ::= <全局数组参数表>com number

全局数组参数表 ::= id [ number

**#执行语句部分**

执行语句 ::= <控制语句>

执行语句 ::= <求值语句>

控制语句 ::= <if语句>

控制语句 ::= <while语句>

if语句 ::= <没有else的if语句>

if语句 ::= <没有else的if语句><else子句>

没有else的if语句 ::= <if语句头>{<执行语句组或空>

if语句头 ::= if(<布尔表达式>)

else子句 ::= <else字符串>{<执行语句组或空>

else字符串 ::= else

while语句 ::= <while语句头>{<执行语句组或空>

while语句头 ::= <while字符串> ( <布尔表达式> )

while字符串 ::= while

执行语句组或空 ::= <执行语句组> }

执行语句组或空 ::= }

执行语句组 ::= <执行语句>

执行语句组 ::= <执行语句组><执行语句>

**#表达式部分**

布尔表达式 ::= <与或值>

与或值 ::= <与前缀><非值>

与或值 ::= <非值>

与或值 ::= <或前缀><非值>

与前缀 ::= <与或值> and

或前缀 ::= <与或值> or

非值 ::= not <元布尔值>

非值 ::= <元布尔值>

元布尔值 ::= <值><关系运算符><值>

元布尔值 ::= ( <布尔表达式> )

元布尔值 ::= true

元布尔值 ::= false

**#关系运算符部分**

关系运算符 ::= <

关系运算符 ::= >

关系运算符 ::= >=

关系运算符 ::= ==

关系运算符 ::= <=

关系运算符 ::= <>

**#求值语句部分**

求值语句 ::= <值>semi

值 ::= <左值> ass <加值>

值 ::= <加值>

加值 ::= <加值>-<乘积值>

加值 ::= <加值>+<乘积值>

加值 ::= <乘积值>

乘积值 ::= <乘积值>\*<自增值>

乘积值 ::= <自增值> 自增值 ::= <元值> 自增值 ::= ++<左值> 自增值 ::= <左值>++ 元值 ::= <左值> 元值 ::= number

元值 ::= (<值>)

元值 ::= <函数调用>

左值 ::= <数组访问参数表>]

左值 ::= id

数组访问参数表 ::= id [ <数组访问参数>

数组访问参数表 ::= <数组访问参数表> com <数组访问参数>

数组访问参数 ::= <值>

函数调用 ::= id ( <实参列表> )

实参列表 ::= <实参> 实参列表 ::= <实参列表> com <实参>

实参列表 ::=

实参 ::= <值>

**#类型定义部分**

类型 ::= bool

类型 ::= int

类型 ::= char

类型 ::= real

1. 单词种别定义
2. 关键算法的文字解释

编译器的总框架

主要函数介绍

1. 程序
2. 测试样例(输入 & 输出)
3. 实验总结

问题:常量的保存?

单词种别的定义?

Input4:应该是分号报错?

Input2:出错辣;

Input6:函数返回值不能赋给变量(✿◡‿◡);C:\Users\lxm\AppData\Local\Temp\SGPicFaceTpBq\4524\01DE9FC1.gif;