Not escaping in macro definition gives confusing error

[ericphanson]

If I define a show-like macro,

macro test_show(obj)
    prnt = :(println("Consider ", $(sprint(Base.show_unquoted, obj))))
	return quote
		with_terminal() do
			$prnt
			println($obj)
		end
	end
end

then it runs into reactivity issues if I use it like

f(x) = 2x

@test_show f(1)

then redefine f. I'm not sure how to describe it clearly, so I've attached a video:

Screen.Recording.2021-04-21.at.18.58.18.mov

You can see that everything gets fixed by re-evaluating the macro definition. By the way, if I actually borrow the full implementation of show,

macro test_show2(exs...)
	blk = Expr(:block)
    for ex in exs
        push!(blk.args, :(println($(sprint(Base.show_unquoted,ex)*" = "),
                                  repr(begin local value = $(esc(ex)) end))))
    end
    isempty(exs) || push!(blk.args, :value)
	
	return quote
		with_terminal() do
			$blk
		end
	end
end

then it works fine even if I use it with functions that I redefine. I'm not really sure what's different in the two-cases.

I'm using Pluto v0.14.2.

[pankgeorg]

This is under active development: #1032 !

[fonsp]

This macro should work already, because it has no hidden definitions or references, right @Pangoraw ? The issue seems to be something else

[fonsp]

@ericphanson Can you try to minimize your example? Are there any errors in the terminal where you launched Pluto?

You showed two similar examples where one works, and the other doesn't. It would be really helpful to us if you would try to narrow down on the difference between the two, and construct a MWE based on that.

[ericphanson]

It seems

macro test_show2(obj)
	:(println($obj))
end

is enough to trigger the reactivity issue. There are no errors in the terminal where I launched Pluto.

[Pangoraw]

This macro should work already, because it has no hidden definitions or references, right @Pangoraw ? The issue seems to be something else

This is not an issue with the Expression explorer because the cell re-executes when the function changes. The problem is with the way julia resolve symbols in macro calls. It does so with regard to the macro's module (only if the macro is in Main.xxx?) and not the caller's module:

In the following example you can replace A with workspace1 and B with workspace2 to see what is happening in Pluto:

julia> module A
           macro x(f)
               :($f)
           end
       end
Main.A

julia> module B
           import ..A.@x # new workspace for new reactive run
           f(x) = 2x
       end
Main.B

julia> @eval B @x f(2)
ERROR: UndefVarError: f not defined
Stacktrace:
 [1] top-level scope at REPL[3]:1
 [2] eval(::Module, ::Any) at ./boot.jl:331
 [3] top-level scope at REPL[3]:1

julia> macroexpand(B, :(@x f(2)))
:(Main.A.f(2))

[ericphanson]

Ah then the difference is probably the escaping with esc in the working one. It seems

macro test_show3(obj)
	:(println($(esc(obj))))
end

works too. So maybe I just wrote a bad macro. (Or is it supposed to work? I guess even the unescaped one would work in the REPL even if it's not super robust).

[Pangoraw]

I had encountered this problem while working on #1032, and the workaround I came up with was removing references to the old Pluto workspace (see Pangoraw@18a4bf8#diff-0cc97f3d6a0f647a05e5f913d416242ecb00f6e67e12004a7204b8846a3fa44cR274)

[fonsp]

@Pangoraw I don't entirely understand this issue, so I'm leaving this to you! Do I understand correctly that this issue is fixed by #1032 ? That's great!