Browse files

FL-263: portage ~* keyword fix

  • Loading branch information...
1 parent 82cc1eb commit 2cde13b433c3f50923c143653a924d9cf7e7336c @angryvincent angryvincent committed Dec 6, 2012
Showing with 357 additions and 2 deletions.
  1. +2 −2 sys-apps/portage/Manifest
  2. +355 −0 sys-apps/portage/portage-2.3.5-r4.ebuild
View
4 sys-apps/portage/Manifest
@@ -4,6 +4,6 @@ DIST portage-funtoo-2.3.4-r6.tar.gz 950679 SHA256 6012741bb46628c266199737f0d11a
DIST portage-funtoo-2.3.4-r7.tar.gz 951716 SHA256 a6fc45337873ea76fe11f1cbd5a1d46916ac9884dad93be9a6f71cb0f041e9b7 SHA512 61915db961117ead7a2901e0b865568d6e9374cc97e40164df43e576c672272238bd829a6efd1253988f541a7b1a32bf6236bb0d48058d1c68af6d14fc089259 WHIRLPOOL 61d715556d7f5fe8f48f78eda6f4498247469606d3c4c0e0909c7523ba4c9710059e6d6265d3e50e7131c1dca7dbe0f707ceec6347e01f54309c7d569435278f
DIST portage-funtoo-2.3.4-r8.tar.gz 957766 SHA256 36591773b70186cde1d16ecf7fc884d66d3156d5c11cb2d726d08739c6af2611 SHA512 e6ea68d16487866c90c731e01e52c478cc648b1249b809b0466b12a890ecc3d7a9b35330f34994ee0c642d948a0c794837b4298231a12b566ec16cdb7e0ba239 WHIRLPOOL 198f389d662c9f5536f473b696f8b53118ac00f12bad7a8df420d250cd163ed64e83da48b3a6b06dfa5a7d6d68de164759186959c334c480bd21c902418c2c4c
DIST portage-funtoo-2.3.4-r9.tar.gz 957740 SHA256 c94ee590dff497fbf3a97dd1d6bddb90608dfabd778be13e9558bcf193fcc884 SHA512 298bda71cdf09ed903ff46914def2af4f1246c9561ffa935d84d4548d4d2e6fef55da1755f3d40578b402d6211d6a35ee239cdcf530c5197e2b5c016d70dba51 WHIRLPOOL 3971f304dba11624deaeac7495aac10e43912aec1a2c0dcef7fecc60c2fa52e563e0b26f8ada7b5558bb1202d8771b64f84614bd78914e1383765ace6528cc91
-DIST portage-funtoo-2.3.5-r1.tar.gz 988422 RMD160 6e5a4f5947aed1287fa969ac15ecb83d5e493f17 SHA1 5c1c11fb3fc20be815fd5c1541a3a7df88f20b1e SHA256 5206c3b8a03b75745bbf00343db2409246d4524f62d8f497c8c199653cf9e9c1
-DIST portage-funtoo-2.3.5-r2.tar.gz 990061 RMD160 723836ab550a45047958f33395566fab57b7cda5 SHA1 016d09a1b357b54e65311b12fe6fc613c5e656ce SHA256 531985c6a6bf11998332e4a385acdc39791a28cb6016d80798731cd1b6444a92
+DIST portage-funtoo-2.3.5-r2.tar.gz 990061 SHA256 531985c6a6bf11998332e4a385acdc39791a28cb6016d80798731cd1b6444a92 SHA512 bb31b9d86800510a5bc94df24e835c30521435b7e684de1fda9372e5432c0f8b15af5cfb6b72861b6276451f5bf07a451afbfe60ac771676a4091376f63b1642 WHIRLPOOL aba4afe9c8d25857b24e91af7014839f27ddc7be0504a4086eb6b6843038452155bbc048e46c375b901caf6f69744d0439b45f463dee54d386f3d7775f61a5c1
+DIST portage-funtoo-2.3.5-r4.tar.gz 990072 SHA256 0c4e4d71ccad7bde9f79fd20c11d665435ee8b4dd6f44ab8d194854103f47e18 SHA512 00d937b09a934551643502a1c5e68e869dd79972538abf43e913c0ce886f6a9a4a0bcc4974ef9f64e75af771068be28a5e06960770bd25bded7b97d807e3ce41 WHIRLPOOL 4b27c4985c379a5a0b75603e758e8fc3efea09663f29c1668a28abe66fcf77c094afcf959316eb65c07cd3525598d868bc98f913a03230604c7e213f32fcabbe
DIST portage-man-pl-2.1.2.tar.bz2 53893 SHA256 960eaa7c6f3a2af44bdc665266a8e884628a562373cc477d301597ecc5ef961f SHA512 5f5c8dd1559048546633b1e7291ff8c0f5d637595f1a4c98405424b08c30c089fc9359e0214f78fbe358754f20d327794f4692b9b67639585c29b755975ee853 WHIRLPOOL 756e267b84077501d976f46fa448cda5368cd52aeca6ec43d109c81fe8e2364e0cd0f35630d68a4186c70e3b440b7c870b86ac7ef83cc0afa43e10f9f8e1f422
View
355 sys-apps/portage/portage-2.3.5-r4.ebuild
@@ -0,0 +1,355 @@
+# Distributed under the terms of the GNU General Public License v2
+
+# Require EAPI 2 since we now require at least python-2.6 (for python 3
+# syntax support) which also requires EAPI 2.
+EAPI=3
+inherit eutils python
+
+DESCRIPTION="Portage is the package management and distribution system for Gentoo"
+HOMEPAGE="http://www.gentoo.org/proj/en/portage/index.xml"
+LICENSE="GPL-2"
+KEYWORDS="*"
+SLOT="0"
+IUSE="build doc epydoc +ipc linguas_pl pypy1_9 python2 python3 selinux xattr"
+GITHUB_REPO="portage-funtoo"
+GITHUB_USER="funtoo"
+GITHUB_TAG="funtoo-${PVR}"
+RESTRICT="mirror"
+
+# Import of the io module in python-2.6 raises ImportError for the
+# thread module if threading is disabled.
+python_dep_ssl="python3? ( =dev-lang/python-3*[ssl] )
+ !pypy1_9? ( !python2? ( !python3? (
+ || ( >=dev-lang/python-2.7[ssl] dev-lang/python:2.6[threads,ssl] )
+ ) ) )
+ pypy1_9? ( !python2? ( !python3? ( dev-python/pypy:1.9[bzip2,ssl] ) ) )
+ python2? ( !python3? ( || ( dev-lang/python:2.7[ssl] dev-lang/python:2.6[ssl,threads] ) ) )"
+python_dep="${python_dep_ssl//\[ssl\]}"
+python_dep="${python_dep//,ssl}"
+python_dep="${python_dep//ssl,}"
+
+# The pysqlite blocker is for bug #282760.
+DEPEND="${python_dep}
+ >=sys-apps/sed-4.0.5 sys-devel/patch
+ doc? ( app-text/xmlto ~app-text/docbook-xml-dtd-4.4 )
+ epydoc? ( >=dev-python/epydoc-2.0 !<=dev-python/pysqlite-2.4.1 )"
+# Require sandbox-2.2 for bug #288863.
+# For xattr, we can spawn getfattr and setfattr from sys-apps/attr, but that's
+# quite slow, so it's not considered in the dependencies as an alternative to
+# to python-3.3 / pyxattr. Also, xattr support is only tested with Linux, so
+# for now, don't pull in xattr deps for other kernels.
+# For whirlpool hash, require python[ssl] or python-mhash (bug #425046).
+RDEPEND="${python_dep}
+ !build? ( >=sys-apps/sed-4.0.5
+ >=app-shells/bash-3.2_p17
+ >=app-admin/eselect-1.2
+ || ( ${python_dep_ssl} dev-python/python-mhash )
+ )
+ elibc_FreeBSD? ( sys-freebsd/freebsd-bin )
+ elibc_glibc? ( >=sys-apps/sandbox-2.2 )
+ elibc_uclibc? ( >=sys-apps/sandbox-2.2 )
+ >=app-misc/pax-utils-0.1.17
+ xattr? ( kernel_linux? ( || ( >=dev-lang/python-3.3_pre20110902 dev-python/pyxattr ) ) )
+ selinux? ( || ( >=sys-libs/libselinux-2.0.94[python] <sys-libs/libselinux-2.0.94 ) )
+ !<app-shells/bash-3.2_p17
+ !<app-admin/logrotate-3.8.0"
+PDEPEND="
+ !build? (
+ >=net-misc/rsync-2.6.4
+ userland_GNU? ( >=sys-apps/coreutils-6.4 )
+ )"
+# coreutils-6.4 rdep is for date format in emerge-webrsync #164532
+# NOTE: FEATURES=install-sources requires debugedit and rsync
+
+SRC_ARCHIVES="http://dev.gentoo.org/~zmedico/portage/archives"
+
+prefix_src_archives() {
+ local x y
+ for x in ${@}; do
+ for y in ${SRC_ARCHIVES}; do
+ echo ${y}/${x}
+ done
+ done
+}
+
+PV_PL="2.1.2"
+PATCHVER_PL=""
+SRC_URI="https://www.github.com/${GITHUB_USER}/${GITHUB_REPO}/tarball/${GITHUB_TAG} -> portage-${GITHUB_TAG}.tar.gz
+ linguas_pl? ( mirror://gentoo/${PN}-man-pl-${PV_PL}.tar.bz2
+ $(prefix_src_archives ${PN}-man-pl-${PV_PL}.tar.bz2) )"
+S_PL="${WORKDIR}"/${PN}-${PV_PL}
+
+compatible_python_is_selected() {
+ [[ $("${EPREFIX}/usr/bin/python" -c 'import sys ; sys.stdout.write(sys.hexversion >= 0x2060000 and "good" or "bad")') = good ]]
+}
+
+current_python_has_xattr() {
+ [[ $("${EPREFIX}/usr/bin/python" -c 'import sys ; sys.stdout.write(sys.hexversion >= 0x3030000 and "yes" or "no")') = yes ]] || \
+ "${EPREFIX}/usr/bin/python" -c 'import xattr' 2>/dev/null
+}
+
+pkg_setup() {
+ if use python2 && use python3 ; then
+ ewarn "Both python2 and python3 USE flags are enabled, but only one"
+ ewarn "can be in the shebangs. Using python3."
+ fi
+ if use pypy1_9 && use python3 ; then
+ ewarn "Both pypy1_9 and python3 USE flags are enabled, but only one"
+ ewarn "can be in the shebangs. Using python3."
+ fi
+ if use pypy1_9 && use python2 ; then
+ ewarn "Both pypy1_9 and python2 USE flags are enabled, but only one"
+ ewarn "can be in the shebangs. Using python2"
+ fi
+ if ! use pypy1_9 && ! use python2 && ! use python3 && \
+ ! compatible_python_is_selected ; then
+ ewarn "Attempting to select a compatible default python interpreter"
+ local x success=0
+ for x in /usr/bin/python2.* ; do
+ x=${x#/usr/bin/python2.}
+ if [[ $x -ge 6 ]] 2>/dev/null ; then
+ eselect python set python2.$x
+ if compatible_python_is_selected ; then
+ elog "Default python interpreter is now set to python-2.$x"
+ success=1
+ break
+ fi
+ fi
+ done
+ if [ $success != 1 ] ; then
+ eerror "Unable to select a compatible default python interpreter!"
+ die "This version of portage requires at least python-2.6 to be selected as the default python interpreter (see \`eselect python --help\`)."
+ fi
+ fi
+
+ if use python3; then
+ python_set_active_version 3
+ elif use python2; then
+ python_set_active_version 2
+ elif use pypy1_9; then
+ python_set_active_version 2.7-pypy-1.9
+ fi
+}
+
+src_unpack() {
+ unpack ${A}
+ mv "${WORKDIR}/${GITHUB_USER}-${PN}-funtoo"-??????? "${S}" || die
+}
+
+src_prepare() {
+ if [ -n "${PATCHVER}" ] ; then
+ if [[ -L $S/bin/ebuild-helpers/portageq ]] ; then
+ rm "$S/bin/ebuild-helpers/portageq" \
+ || die "failed to remove portageq helper symlink"
+ fi
+ epatch "${WORKDIR}/${PN}-${PATCHVER}.patch"
+ fi
+ einfo "Setting portage.VERSION to ${PVR} ..."
+ sed -e "s/^VERSION=.*/VERSION=\"${PVR}\"/" -i pym/portage/__init__.py || \
+ die "Failed to patch portage.VERSION"
+ sed -e "1s/VERSION/${PVR}/" -i doc/fragment/version || \
+ die "Failed to patch VERSION in doc/fragment/version"
+ sed -e "1s/VERSION/${PVR}/" -i man/* || \
+ die "Failed to patch VERSION in man page headers"
+
+ if ! use ipc ; then
+ einfo "Disabling ipc..."
+ sed -e "s:_enable_ipc_daemon = True:_enable_ipc_daemon = False:" \
+ -i pym/_emerge/AbstractEbuildProcess.py || \
+ die "failed to patch AbstractEbuildProcess.py"
+ fi
+
+ if use xattr && use kernel_linux ; then
+ einfo "Adding FEATURES=xattr to make.globals ..."
+ echo -e '\nFEATURES="${FEATURES} xattr"' >> cnf/make.globals \
+ || die "failed to append to make.globals"
+ fi
+
+ if use python3; then
+ einfo "Converting shebangs for python3..."
+ python_convert_shebangs -r 3 .
+ elif use python2; then
+ einfo "Converting shebangs for python2..."
+ python_convert_shebangs -r 2 .
+ elif use pypy1_9; then
+ einfo "Converting shebangs for pypy-c1.9..."
+ python_convert_shebangs -r 2.7-pypy-1.9 .
+ fi
+
+ if [[ -n ${EPREFIX} ]] ; then
+ einfo "Setting portage.const.EPREFIX ..."
+ sed -e "s|^\(SANDBOX_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/bin/sandbox\"\)|\\1${EPREFIX}\\2|" \
+ -e "s|^\(FAKEROOT_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/bin/fakeroot\"\)|\\1${EPREFIX}\\2|" \
+ -e "s|^\(BASH_BINARY[[:space:]]*=[[:space:]]*\"\)\(/bin/bash\"\)|\\1${EPREFIX}\\2|" \
+ -e "s|^\(MOVE_BINARY[[:space:]]*=[[:space:]]*\"\)\(/bin/mv\"\)|\\1${EPREFIX}\\2|" \
+ -e "s|^\(PRELINK_BINARY[[:space:]]*=[[:space:]]*\"\)\(/usr/sbin/prelink\"\)|\\1${EPREFIX}\\2|" \
+ -e "s|^\(EPREFIX[[:space:]]*=[[:space:]]*\"\).*|\\1${EPREFIX}\"|" \
+ -i pym/portage/const.py || \
+ die "Failed to patch portage.const.EPREFIX"
+
+ einfo "Prefixing shebangs ..."
+ find . -type f -print0 | \
+ while read -r -d $'\0' ; do
+ local shebang=$(head -n1 "$REPLY")
+ if [[ ${shebang} == "#!"* && ! ${shebang} == "#!${EPREFIX}/"* ]] ; then
+ sed -i -e "1s:.*:#!${EPREFIX}${shebang:2}:" "$REPLY" || \
+ die "sed failed"
+ fi
+ done
+
+ einfo "Adjusting make.globals ..."
+ sed -e 's|^SYNC=.*|SYNC="rsync://rsync.prefix.freens.org/gentoo-portage-prefix"|' \
+ -e "s|^\(PORTDIR=\)\(/usr/portage\)|\\1\"${EPREFIX}\\2\"|" \
+ -e "s|^\(PORTAGE_TMPDIR=\)\(/var/tmp\)|\\1\"${EPREFIX}\\2\"|" \
+ -i cnf/make.globals || die "sed failed"
+
+ einfo "Adding FEATURES=force-prefix to make.globals ..."
+ echo -e '\nFEATURES="${FEATURES} force-prefix"' >> cnf/make.globals \
+ || die "failed to append to make.globals"
+ fi
+
+ echo -e '\nFEATURES="${FEATURES} preserve-libs"' >> cnf/make.globals \
+ || die "failed to append to make.globals"
+
+ cd "${S}/cnf" || die
+ if [ -f "make.conf.${ARCH}".diff ]; then
+ patch make.conf "make.conf.${ARCH}".diff || \
+ die "Failed to patch make.conf.example"
+ else
+ eerror ""
+ eerror "Portage does not have an arch-specific configuration for this arch."
+ eerror "Please notify the arch maintainer about this issue. Using generic."
+ eerror ""
+ fi
+}
+
+src_compile() {
+ if use doc; then
+ emake docbook || die
+ fi
+
+ if use epydoc; then
+ einfo "Generating api docs"
+ emake epydoc || die
+ fi
+}
+
+src_test() {
+ # make files executable, in case they were created by patch
+ find bin -type f | xargs chmod +x
+ emake test || die
+}
+
+src_install() {
+ emake DESTDIR="${D}" \
+ DOCS="NEWS RELEASE-NOTES" \
+ sysconfdir="${EPREFIX}/etc" \
+ prefix="${EPREFIX}/usr" \
+ install || die
+
+ # Use dodoc for compression, since the Makefile doesn't do that.
+ dodoc "${S}"/{NEWS,RELEASE-NOTES} || die
+
+ if use linguas_pl; then
+ doman -i18n=pl "${S_PL}"/man/pl/*.[0-9] || die
+ doman -i18n=pl_PL.UTF-8 "${S_PL}"/man/pl_PL.UTF-8/*.[0-9] || die
+ fi
+
+ # Set PYTHONPATH for portage API consumers. This way we don't have
+ # to rely on patched python having the correct path, since it has
+ # been known to incorrectly add /usr/libx32/portage/pym to sys.path.
+ echo "PYTHONPATH=\"${EPREFIX}/usr/lib/portage/pym\"" > \
+ "${T}/05portage" || die
+ doenvd "${T}/05portage" || die
+
+ exeinto /usr/lib/portage/bin
+ doexe "${FILESDIR}/pygrade.py"
+}
+
+pkg_preinst() {
+ if [[ $ROOT == / ]] ; then
+ # Run some minimal tests as a sanity check.
+ local test_runner=$(find "$ED" -name runTests)
+ if [[ -n $test_runner && -x $test_runner ]] ; then
+ einfo "Running preinst sanity tests..."
+ "$test_runner" || die "preinst sanity tests failed"
+ fi
+ fi
+
+ if use xattr && ! current_python_has_xattr ; then
+ ewarn "For optimal performance in xattr handling, install"
+ ewarn "dev-python/pyxattr, or install >=dev-lang/python-3.3 and"
+ ewarn "enable USE=python3 for $CATEGORY/$PN."
+ fi
+
+ if ! use build && ! has_version dev-python/pycrypto && \
+ ! has_version '>=dev-lang/python-2.6[ssl]' ; then
+ ewarn "If you are an ebuild developer and you plan to commit ebuilds"
+ ewarn "with this system then please install dev-python/pycrypto or"
+ ewarn "enable the ssl USE flag for >=dev-lang/python-2.6 in order"
+ ewarn "to enable RMD160 hash support."
+ ewarn "See bug #198398 for more information."
+ fi
+
+ has_version "<=${CATEGORY}/${PN}-2.2_pre5" \
+ && WORLD_MIGRATION_UPGRADE=true || WORLD_MIGRATION_UPGRADE=false
+
+ # If portage-2.1.6 is installed and the preserved_libs_registry exists,
+ # assume that the NEEDED.ELF.2 files have already been generated.
+ has_version "<=${CATEGORY}/${PN}-2.2_pre7" && \
+ ! ( [ -e "${EROOT}"var/lib/portage/preserved_libs_registry ] && \
+ has_version ">=${CATEGORY}/${PN}-2.1.6_rc" ) \
+ && NEEDED_REBUILD_UPGRADE=true || NEEDED_REBUILD_UPGRADE=false
+}
+
+pkg_postinst() {
+ # Compile all source files recursively. Any orphans
+ # will be identified and removed in postrm.
+ python_mod_optimize /usr/lib/portage/pym
+
+ "${EROOT}usr/lib/portage/bin/pygrade.py"
+
+ if $WORLD_MIGRATION_UPGRADE && \
+ grep -q "^@" "${EROOT}/var/lib/portage/world"; then
+ einfo "moving set references from the worldfile into world_sets"
+ cd "${EROOT}/var/lib/portage/"
+ grep "^@" world >> world_sets
+ sed -i -e '/^@/d' world
+ fi
+
+ if $NEEDED_REBUILD_UPGRADE ; then
+ einfo "rebuilding NEEDED.ELF.2 files"
+ for cpv in "${EROOT}/var/db/pkg"/*/*; do
+ if [ -f "${cpv}/NEEDED" ]; then
+ rm -f "${cpv}/NEEDED.ELF.2"
+ while read line; do
+ filename=${line% *}
+ needed=${line#* }
+ needed=${needed//+/++}
+ needed=${needed//#/##}
+ needed=${needed//%/%%}
+ newline=$(scanelf -BF "%a;%F;%S;%r;${needed}" $filename)
+ newline=${newline// - }
+ echo "${newline:3}" >> "${cpv}/NEEDED.ELF.2"
+ done < "${cpv}/NEEDED"
+ fi
+ done
+ fi
+ # make.conf magick. We rather prefer to have make.conf in one place and set the symlink to
+ # have compatibility
+ if [[ ! -L ${EROOT}etc/make.conf ]]; then
+ if [[ -e ${EROOT}etc/make.conf ]]; then
+ if [[ -e ${EROOT}etc/portage/make.conf ]]; then
+ mv "${EROOT}etc/make.conf" "${EROOT}etc/make.conf.backup"
+ ewarn "Redundant '${EROOT}etc/make.conf' has been renamed to '${EROOT}etc/make.conf.backup'."
+ else
+ mv "${EROOT}etc/make.conf" "${EROOT}etc/portage/make.conf"
+ fi
+ fi
+ ln -s portage/make.conf "${EROOT}etc/make.conf"
+ fi
+}
+
+pkg_postrm() {
+ python_mod_cleanup /usr/lib/portage/pym
+}

0 comments on commit 2cde13b

Please sign in to comment.