dofile

\*Settings ----  
clear all  
set more off  
set varabbrev off  
version 17  
  
  
\*Imports ----  
cd "D:\OneDrive\Documentos\Bristol\Economics (Bsc)\Applied Economics Dissertation\lippmann-replication"  
use "data\raw\gsoep.dta", clear  
//net install cleanplots, from("https://tdmize.github.io/data/cleanplots")  
set scheme cleanplots  
  
  
\*Cleaning ----  
/\*  
edu4 contains some -1 values, which I believe are missing.  
whweek has some negative values, so I will remove them. Same with the incomes.  
  
errand, hwork, ccare, repairs and hobbies all have missing variables.  
Will not remove since not in the regression.  
  
Not all households have two members in the data for a given year, so I remove  
these. Same with homosexual couples.  
 \*/  
keep if whweek >= 0 & incjob1\_mg > 0 & incjob1\_mn > 0 //only dual earner couples here  
drop if missing(hwork) | edu4 == -1 //other vars have missing, but not in regression  
  
//keep only heterosexual couples with both members on the data  
bysort wave cpf\_hid (female): keep if \_N == 2 & female[1] != female[2]  
  
//remove singletons to maintain consistent sample size accross specifications  
bysort pid: drop if \_N == 1  
drop if pid == 2088902  
  
\*Origin  
bysort wave cpf\_hid: drop if loc89[1] != loc89[2] //only single origin couples  
bysort wave cpf\_hid: gen east = (loc89[1] == 1 & loc89[2] == 1)  
  
\*Income  
bysort wave cpf\_hid: egen max\_inc\_mg = max(incjob1\_mg)  
bysort wave cpf\_hid: egen max\_inc\_mn = max(incjob1\_mn)  
  
gen wife\_earns\_more = (female == 1 & incjob1\_mg == max\_inc\_mg) //dummy if wife earns more than husband  
replace wife\_earns\_more = 1 if female == 0 & incjob1\_mg != max\_inc\_mg  
  
\*Income share  
bysort wave cpf\_hid: egen total\_incjob1\_mg = total(incjob1\_mg)  
bysort wave cpf\_hid: egen hhd\_inc = total(incjob1\_mn) //household income uses net  
  
gen female\_income\_share = incjob1\_mn / hhd\_inc if female == 1  
bysort wave cpf\_hid (female): replace female\_income\_share = female\_income\_share[2] if missing(female\_income\_share)  
  
  
\*Figure 2 ----  
graph twoway kdensity female\_income\_share if female == 1 & east == 1, xline(0.5) name(graph1) title(East Germans) xlabel(#10) xtitle(Female Income Share) ytitle(Density)  
graph twoway kdensity female\_income\_share if female == 1 & east == 0, xline(0.5) name(graph2) title(West Germans) xlabel(#10) xtitle(Female Income Share) ytitle(Density)  
  
  
\*Regression ----  
\*Additional dummies  
bysort wave cpf\_hid (female): gen p\_age = cond(female == 0, age[2], age[1]) //partner age  
bysort wave cpf\_hid (female): gen p\_edu4 = cond(female == 0, edu4[2], edu4[1]) //partner education  
bysort wave cpf\_hid (female): gen p\_income = cond(female == 0, incjob1\_mg[2], incjob1\_mg[1]) //partner income  
gen kids = (kidsn\_hh17 != 0)  
  
gen linc = log(incjob1\_mg)  
gen plinc = log(p\_income)  
gen lhhd\_inc = log(hhd\_inc)  
  
\*Housework gap  
bysort wave cpf\_hid: egen couple\_hwork = total(hwork)  
gen hwork\_gap = 2\*hwork - couple\_hwork if female == 1  
bysort wave cpf\_hid (female): replace hwork\_gap = hwork\_gap[2] if missing(hwork\_gap)  
  
\*NOTE: female vs male income share makes no different in all specifications  
  
\*define a string with all controls (this should all instead be in a function, but stata sucks)  
local cross\_sec\_controls female\_income\_share lhhd\_inc linc plinc c.age##c.age c.p\_age##c.p\_age kids i.edu4 i.p\_edu4  
local longitudinal\_controls c.female\_income\_share##c.east lhhd\_inc linc plinc c.age##c.age c.p\_age##c.p\_age kids i.edu4 i.p\_edu4  
  
\*Panel A  
eststo: reghdfe hwork wife\_earns\_more `cross\_sec\_controls' if female == 1 & east == 0, absorb(wavey state) vce(cluster pid) //(1)  
eststo: reghdfe hwork wife\_earns\_more `cross\_sec\_controls' if female == 1 & east == 1, absorb(wavey state) vce(cluster pid) //(2)  
eststo: reghdfe hwork wife\_earns\_more c.wife\_earns\_more#c.east `longitudinal\_controls' if female == 1, absorb(wavey state) vce(cluster pid) //(3)  
  
eststo: reghdfe hwork wife\_earns\_more `cross\_sec\_controls' if female == 1 & east == 0, absorb(wavey state pid) vce(cluster pid) //(4)  
eststo: reghdfe hwork wife\_earns\_more `cross\_sec\_controls' if female == 1 & east == 1, absorb(wavey state pid) vce(cluster pid) //(5)  
eststo: reghdfe hwork wife\_earns\_more c.wife\_earns\_more#c.east `longitudinal\_controls' if female == 1, absorb(wavey state pid) vce(cluster pid) //(6)  
  
esttab using "reports\figures\figure3.rtf", ///  
b(%9.3f) se(%9.3f) star(\* .10 \*\* .05 \*\*\* .01) ///  
mtitles(West East All West East All) coeflabels(wife\_earns\_more WifeEarnsMore c.wife\_earns\_more#c.east WifeEarnsMore×East east East) nonotes ///  
noomitted keep(wife\_earns\_more c.wife\_earns\_more#c.east east) ///  
stats(N, fmt(0 0) label("Observations")) title("Panel A: Women --- Dependent Variable: Housework Time (hours per day)") ///  
replace  
eststo clear  
  
\*Panel B  
local cross\_sec\_controls female\_income\_share lhhd\_inc linc plinc c.age##c.age c.p\_age##c.p\_age kids i.edu4 i.p\_edu4  
local longitudinal\_controls c.female\_income\_share##c.east lhhd\_inc linc plinc c.age##c.age c.p\_age##c.p\_age kids i.edu4 i.p\_edu4  
  
eststo: reghdfe hwork wife\_earns\_more `cross\_sec\_controls' if female == 0 & east == 0, absorb(wavey state) vce(cluster pid) //(1)  
eststo: reghdfe hwork wife\_earns\_more `cross\_sec\_controls' if female == 0 & east == 1, absorb(wavey state) vce(cluster pid) //(2)  
eststo: reghdfe hwork wife\_earns\_more c.wife\_earns\_more#c.east `longitudinal\_controls' if female == 0, absorb(wavey state) vce(cluster pid) //(3)  
  
eststo: reghdfe hwork wife\_earns\_more `cross\_sec\_controls' if female == 0 & east == 0, absorb(wavey state pid) vce(cluster pid) //(4)  
eststo: reghdfe hwork wife\_earns\_more `cross\_sec\_controls' if female == 0 & east == 1, absorb(wavey state pid) vce(cluster pid) //(5)  
eststo: reghdfe hwork wife\_earns\_more c.wife\_earns\_more#c.east `longitudinal\_controls' if female == 0, absorb(wavey state pid) vce(cluster pid) //(6)  
  
esttab using "reports\figures\figure3.rtf", ///  
b(%9.3f) se(%9.3f) star(\* .10 \*\* .05 \*\*\* .01) ///  
nomtitles nonumbers coeflabels(wife\_earns\_more WifeEarnsMore c.wife\_earns\_more#c.east WifeEarnsMore×East east East) nonotes ///  
noomitted keep(wife\_earns\_more c.wife\_earns\_more#c.east east) ///  
stats(N, fmt(0 0) label("Observations")) title("Panel B: Men --- Dependent Variable: Housework Time (hours per day)") ///  
append  
eststo clear  
  
\*Panel C  
eststo: reghdfe hwork\_gap wife\_earns\_more `cross\_sec\_controls' if female == 0 & east == 0, absorb(wavey state) vce(cluster pid) //(1)  
estadd local fe "No"  
estadd scalar individuals = e(N\_clust)  
eststo: reghdfe hwork\_gap wife\_earns\_more `cross\_sec\_controls' if female == 0 & east == 1, absorb(wavey state) vce(cluster pid) //(2)  
estadd local fe "No"  
estadd scalar individuals = e(N\_clust)  
eststo: reghdfe hwork\_gap wife\_earns\_more c.wife\_earns\_more#c.east `longitudinal\_controls' if female == 0, absorb(wavey state) vce(cluster pid) //(3)  
estadd local fe "No"  
estadd scalar individuals = e(N\_clust)  
  
eststo: reghdfe hwork\_gap wife\_earns\_more `cross\_sec\_controls' if female == 0 & east == 0, absorb(wavey state pid) vce(cluster pid) //(4)  
estadd local fe "Yes"  
estadd scalar individuals = e(N\_clust)  
eststo: reghdfe hwork\_gap wife\_earns\_more `cross\_sec\_controls' if female == 0 & east == 1, absorb(wavey state pid) vce(cluster pid) //(5)  
estadd local fe "Yes"  
estadd scalar individuals = e(N\_clust)  
eststo: reghdfe hwork\_gap wife\_earns\_more c.wife\_earns\_more#c.east `longitudinal\_controls' if female == 0, absorb(wavey state pid) vce(cluster pid) //(6)  
gen used = e(sample)  
estadd local fe "Yes"  
estadd scalar individuals = e(N\_clust)  
  
esttab using "reports\figures\figure3.rtf", ///  
b(%9.3f) se(%9.3f) star(\* .10 \*\* .05 \*\*\* .01) ///  
nomtitles nonumbers coeflabels(wife\_earns\_more WifeEarnsMore c.wife\_earns\_more#c.east WifeEarnsMore×East east East) ///  
noomitted keep(wife\_earns\_more c.wife\_earns\_more#c.east east) ///  
stats(N individuals fe, fmt(0 0) label("Observations" "Individuals" "Individual fixed effects")) title("Panel C: Couple --- Dependent Variable: Housework Time Gap (Woman's - Man's)") ///  
append