Министерство науки и высшего образования Российской Федерации

федеральное государственное автономное образовательное учреждение высшего образования

«Национальный исследовательский университет ИТМО»

*Факультет Программной инженерии и компьютерной техники*

**Лабораторная работа №6**

Обмен данными с ВУ по прерыванию

Вариант №3132

Группа: P3131

Выполнил: Воронин И.А.

Проверил:

Перцев Тимофей Сергеевич

Санкт-Петербург

2022г

**Задание**

По выданному преподавателем варианту разработать и исследовать работу комплекса программ обмена данными в режиме прерывания программы. Основная программа должна изменять содержимое заданной ячейки памяти (Х), которое должно быть представлено как знаковое число. Область допустимых значений изменения Х должна быть ограничена заданной функцией F(X) и конструктивными особенностями регистра данных ВУ (8-ми битное знаковое представление). Программа обработки прерывания должна выводить на ВУ модифицированное значение Х в соответствии с вариантом задания, а также игнорировать все необрабатываемые прерывания.

1.Основная программа должна уменьшать на 2 содержимое X (ячейки памяти с адресом 02216) в цикле.

2.Обработчик прерывания должен по нажатию кнопки готовности ВУ-1 осуществлять вывод результата вычисления функции F(X)=-3X-2 на данное ВУ, a по нажатию кнопки готовности ВУ-3 изменить знак содержимого РД данного ВУ и записать в Х

3.Если Х оказывается вне ОДЗ при выполнении любой операции по его изменению, то необходимо в Х записать максимальное по ОДЗ число.

**Составленная программа на ассемблере**

ORG 0x0 ;Инициализируем вектора прерываний

V0: WORD $DEFAULT, 0x180

V1: WORD $INT1, 0x180

V2: WORD $DEFAULT, 0x180

V3: WORD $INT3, 0x180

V4: WORD $DEFAULT, 0x180

V5: WORD $DEFAULT, 0x180

V6: WORD $DEFAULT, 0x180

V7: WORD $DEFAULT, 0x180

ORG 0x022

X: WORD 0x002A ;Ячейка содержащая Х

LOW: WORD 0xFFD5 ;Нижняя граница ОДЗ

HIGH: WORD 0x002A ;Верхняя граница ОДЗ

DEFAULT:IRET

START:DI ;Запрет прерываний

CLA

OUT 0x1

OUT 0x5

OUT 0xB

OUT 0xE

OUT 0x12

OUT 0x16

OUT 0x1A

OUT 0x1E

LD #0x9 ;Запрет прерываний всех КВУ кроме 1 и 3,

OUT 0x3 ;MR ВУ-1

LD #0xB

OUT 0x7 ;MR ВУ-3

EI ;Разрешение прерываний

LD X

CYCLE:SUB #0x2 ;В цикле вычитаем 2 из ячейки X

PUSH

CALL CHECK ;Функция проверки ОДЗ

POP

ST X

NOP ;Точка отладки (конец цикла)

JUMP CYCLE

INT1: NOP ;Точка отладки (начало прерывания с ВУ1)

LD X

ASL ;X\*2

ADD X ;X+X

NEG

SUB #0x2

OUT 2 ;Выводим значение F(x) на ВУ-1

NOP ;Точка отладки (конец прерывания с ВУ1)

IRET

INT3: NOP ;Точка отладки (начало прерывания с ВУ3)

IN 6 ;Читаем значение РД с ВУ-3

SXTB ;Расширяем 7 бит

NEG ;Меняем знак

PUSH

CALL CHECK;Проверяем на соответствие ОДЗ

POP

ST X ;Сохраняем в X

NOP ;Точка отладки (конец прерывания с ВУ3)

IRET

CHECK:LD &1

CMP LOW ;Проверка на соответствие нижней границе ОДЗ

BMI NEWX

CMP HIGH ;Проверка на соответствие верхней границе ОДЗ

BPL NEWX

JUMP RETURN

NEWX: LD HIGH ;Загружаем максимальное значение ОДЗ

RETURN: ST &1

RET

**Назначение программы**

Основная программа уменьшает содержимое ячейки Х на 2 в цикле. По прерыванию с ВУ-1 на него выводится значение функции *F(x) =* -3x-2. По прерыванию с ВУ-3, содержимое РД этого ВУ записывается в ячейку Х с изменением знака.

**Область представления исходных данных**

Значение Х: знаковое число

Нижняя граница X (метка LOW): знаковое число

Верхняя граница X (метка HIGH): знаковое число

**ОДЗ**

Так как регистр ВУ содержит 8 бит:

-128 -3x-2 127

-43 x 42

D5 x 2A

**Методика проверки**

**Проверка основной программы:**

1. Заменить точку отладки по адресу 03B (Точка отладки в конце цикла для ассемблера) на команду HLT
2. Запустить программу в режиме «Работа» с адреса 026
3. Дождаться остановки
4. Записать значение на аккумуляторе
5. Продолжить выполнение программы
6. После следующей остановки записать новое значение аккумулятора
7. Сравнить значения, их разность должна быть равна 2.
8. При необходимости, повторять шаги 4-7 пока значение на аккумуляторе не приблизиться к границе ОДЗ
9. Убедиться что при выходе за границу ОДЗ значение автоматически измениться на максимальное по ОДЗ.

**Проверка работы прерывания с ВУ-1:**

1. Заменить точки отладки 03D и 044 (Начало и конец обработки прерывания ВУ-1 для ассемблера) на команду HLT
2. Запустить программу в режиме «Работа» с адреса 026
3. Дождаться остановки
4. Записать значение ячейки Х(022 в памяти)
5. Продолжить выполнение программы
6. После следующей остановки сравнить значение РД ВУ-1 с результатом функции F(x).

**Проверка работы прерывания с ВУ-3:**

1. Заменить точки отладки 046 и 04D (Начало и конец обработки прерывания ВУ-3 для ассемблера) на команду HLT
2. Запустить программу в режиме «Работа» с адреса 026
3. Дождаться остановки
4. Ввести в РД ВУ-3 любое число
5. Нажать готовность ВУ-3
6. Продолжить выполнение программы
7. После следующей остановки сравнить результат ячейки Х (022 в памяти) с введенным в ВУ-3 (знак будет противоположный)