# User Case2 SPARQL EXAMPLES

**(February 2016, version prepared by Geiza M. Hamazaki da Silva and Livia Ruback, Tecgraf Institute/PUC-Rio)**

This document describes the process used to test the EDRC UC2 with answering real SPARQL queries. To enhance that goal, some parts of the EDRC UC2 files (https://github.com/dpricetq/iso15926) were adapted and it is available at the directory edrc\_usecase\_2 - changed by TecGraf.

Section 1 explains the changes to make to run the SPARQL queries examples. Section 2 shows the local graphs created to store the different parts of the information. Sections 3 brings the SPARQL queries together with its results.

## **1. Changes on the EDRC UC2 files:**

* Fixed inconsistence problems related to the templates pointed out on the sections “Problems identified”, document Report EDRC Use Case 2.pdf:
* Prefix of the pca endpoint changed

from @prefix pcardl: http://posccaesar.org/rdl/

to @prefix pcardl: <http:/ /data.posccaesar.org/rdl/>

* Prefix of the tpl endpoint changed

from @prefix tpl: <http://data.posccaesar.org/tpl/>

to @prefix tpl: <http://localhost:8089/tpl/>

## **2. Graphs created:**

|  |  |  |
| --- | --- | --- |
| **Prefix** | **Taken from file** | **Notes** |
| http://localhost:8089/tecgraph | local graph (stores the pressure equipment request for quote and the response) |  |
| http://localhost:8089/tpl | iso15926-master\standards\pca\ data.posccaesar.org\_tpl.rdf | <http://data.posccaesar.org/tpl/>  endpoint **not** available |
| http://localhost:8089/rdlExtension | iso15926-master\edrc\_usecase\_2/ EDRC\_UC2\_RDL\_Extension\_tec.ttl |  |
| http://localhost:8089/emerson | iso15926-master\edrc\_usecase\_2/  Emerson\_Catalogue.rdf |  |

**3. SPARQL queries executed:**

**3.1) Who the element that the Request For Quotes refer about?**

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

prefix tpl: <http://localhost:8089/tpl/>

prefix pcardl: <http://data.posccaesar.org/rdl/>

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select distinct ?templateInstance ?label ?subClassOfLabel

where {

# Relations from ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation template

?templateInstance rdf:type tpl:ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation.

?templateInstance tpl:hasDefined ?element.

?templateInstance tpl:hasDefinition ?aux.

?aux rdf:type pcardl:R-a3107083-c97f-458d-aa24-d3785a0a1835. # item of a Request For Quotation

?element rdfs:label ?label.

?element rdfs:subClassOf ?subClassOf.

# accessing the posccaesar endpoint to get the label of the cost resource

SERVICE <http://data.posccaesar.org/rdl/> {

?subClassOf rdfs:label ?subClassOfLabel.

}

}




Figure 1: Result of the Request For Quotation query

**3.2) What are the parts of the Pressure Equipment?**

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

prefix tpl: <http://localhost:8089/tpl/>

prefix pcardl: <http://data.posccaesar.org/rdl/>

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select distinct ?rfqItem ?labelEquipment ?subClassOfLabel ?partSubClassOfLabel

where {

# Relations from ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation template

?templateInstance rdf:type tpl:ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation.

?templateInstance tpl:hasDefinition ?rfqItem.

?rfqItem rdf:type pcardl:R-a3107083-c97f-458d-aa24-d3785a0a1835.

?templateInstance tpl:hasDefined ?equipment.

?equipment rdfs:label ?labelEquipment.

?equipment rdfs:subClassOf ?subClassOf.

# accessing the posccaesar endpoint to get the label of the equipment resource

SERVICE <http://data.posccaesar.org/rdl/> {

?subClassOf rdfs:label ?subClassOfLabel.

}

# Relations from ClassOfAssemblyDefinition template

?templateInstance2 tpl:hasClassOfWhole ?equipment.

?templateInstance2 rdf:type tpl:ClassOfAssemblyDefinition.

?templateInstance2 tpl:hasClassOfPart ?part.

?part rdfs:subClassOf ?partSubClassOf.

# accessing the posccaesar endpoint to get the label of the part

SERVICE <http://data.posccaesar.org/rdl/> {

?partSubClassOf rdfs:label ?partSubClassOfLabel.

}

}




Figure 2: Result of the Pressure Equipment parts

**3.3) What are the Calibration Ranges for the Pressure Equipment ordered?**

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

prefix tpl: <http://localhost:8089/tpl/>

prefix pcardl: <http://data.posccaesar.org/rdl/>

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select distinct ?rfqItem ?labelEquipment ?subClassOfLabel ?subClassOfscale ?lowerBound ?upperBound

where {

# Relations from ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation template

?templateInstance rdf:type tpl:ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation.

?templateInstance tpl:hasDefinition ?rfqItem.

?rfqItem rdf:type pcardl:R-a3107083-c97f-458d-aa24-d3785a0a1835.

?templateInstance tpl:hasDefined ?equipment.

?equipment rdfs:label ?labelEquipment.

?equipment rdfs:subClassOf ?subClassOf.

# accessing the posccaesar endpoint to get the label of the equipment resource

SERVICE <http://data.posccaesar.org/rdl/> {

?subClassOf rdfs:label ?subClassOfLabel.

}

# Relations from ClassOfIndividualHasIndirectPropertyWithBoundingValues template

?templateInstance2 rdf:type tpl:ClassOfIndividualHasIndirectPropertyWithBoundingValues.

?templateInstance2 tpl:hasPossessorType ?equipment.

?templateInstance2 tpl:hasScale ?scale.

# accessing the posccaesar endpoint to get the label of the scale

SERVICE <http://data.posccaesar.org/rdl/> {

?scale rdfs:label ?subClassOfscale.

}

?templateInstance2 tpl:valLowerBound ?lowerBound.

?templateInstance2 tpl:valUpperBound ?upperBound.

}




Figure 3 Result of the pressure equipment calibration ranges

**3.4) What are the Normal Operating Pressure and Normal Operating Temperature of the Pressure Transmitter requested?**

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

prefix tpl: <http://localhost:8089/tpl/>

prefix pcardl: <http://data.posccaesar.org/rdl/>

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select distinct ?rfqItem ?labelEquipment ?subClassOfLabel ?tempValue ?pressValue

where {

# Relations from ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation template

?templateInstance rdf:type tpl:ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation.

?templateInstance tpl:hasDefinition ?rfqItem.

?rfqItem rdf:type pcardl:R-a3107083-c97f-458d-aa24-d3785a0a1835.

?templateInstance tpl:hasDefined ?equipment.

?equipment rdfs:label ?labelEquipment.

?equipment rdfs:subClassOf ?subClassOf.

# accessing the posccaesar endpoint to get the label of the equipment resource

SERVICE <http://data.posccaesar.org/rdl/> {

?subClassOf rdfs:label ?subClassOfLabel.

}

# Relations from ClassOfContainmentDefinition template

?templateInstance2 rdf:type tpl:ClassOfContainmentDefinition.

?templateInstance2 tpl:hasClassOfContainer ?equipment.

?templateInstance2 tpl:hasClassOfContained ?stream.

# Relations from ClassOfIndividualHasIndirectPropertyWithValue template

?templateInstance3 rdf:type tpl:ClassOfIndividualHasIndirectPropertyWithValue.

?templateInstance3 tpl:hasPossessorType ?stream.

?templateInstance3 tpl:hasScale pcardl:RDS1322684.

# ensures that ?templateInstance3 has the DEGREE CELSIUS scale, i.e., it is a temperature

?templateInstance3 tpl:valPropertyValue ?tempValue.

?templateInstance4 rdf:type tpl:ClassOfIndividualHasIndirectPropertyWithValue.

?templateInstance4 tpl:hasPossessorType ?stream.

?templateInstance4 tpl:hasScale pcardl:RDS1348874.

# ensures that ?templateInstance4 has the BAR GAUGE scale, i.e., it is a pressure

?templateInstance4 tpl:valPropertyValue ?pressValue.

}




Figure 4: Result for the normal operating pressure and the normal operating temperature requested

Notes:

The SPARQL query result shows 2 instances for the TestData1 (that contains only one request for quote at the pressure\_transmitter\_rfq\_1.ttl file and its response). These 2 instances have different pressure values (19.2 and 10), i.e., the same request for quotation element have different values of pressure in the two files (request and reply).

On the other side, we can see more 10 instances for to the TestData10 (that contains 10 requests for quotes at the pressure\_transmitter\_rfq\_10.ttl file and its response). The pressure and temperature values for all instances match on the request and the reply files.

**3.5) Response of the RFQ:**

**“What are the cost (currency, cost type and value) of the equipment ordered?”**

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

prefix tpl: <http://localhost:8089/tpl/>

prefix pcardl: <http://data.posccaesar.org/rdl/>

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select ?labelEquipment ?currencyLabel ?productName ?productClassLabel ?costTypeLabel ?value

FROM <http://localhost:8089/tecgraph> # local graph with the 4 pressure transmitter ttl files

FROM <http://localhost:8089/emerson> # local graph copied from edrc\_usecase\_2/Emerson\_Catalogue.rdf

FROM <http://localhost:8089/rdlExtension> # local graph copied from edrc\_usecase\_2/EDRC\_UC2\_RDL\_Extension.ttl

where {

# Relations from ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation template

?templateInstance rdf:type tpl:ClassifiedDefinitionOfClassOfIndividualWithInformationRepresentation.

?templateInstance tpl:hasDefinition ?item.

?item rdf:type pcardl:R-bd9e51e1-7182-421d-887e-e5cb37e34653.

?templateInstance tpl:hasDefined ?equipment.

?equipment rdfs:label ?labelEquipment.

# Relations from ProductClassFulfilsClassOfFunctionPlace template

?productClassInstance tpl:hasFunctionPlaceClass ?element.

?productClassInstance rdf:type tpl:ProductClassFulfilsClassOfFunctionPlace.

?productClassInstance tpl:hasProductClass ?product.

?product rdfs:label ?productName.

?product rdf:type ?productClass.

?productClass rdfs:label ?productClassLabel.

# Relations from ClassOfIndividualHasMonetaryValue template

?monetaryValueInstance tpl:hasPossessorType ?product.

?monetaryValueInstance rdf:type tpl:ClassOfIndividualHasMonetaryValue.

?monetaryValueInstance tpl:hasCurrency ?currency.

# the currencyLabel is stored on the emerson local graph

?currency rdfs:label ?currencyLabel.

?monetaryValueInstance tpl:hasCostType ?costType.

# accessing the posccaesar endpoint to get the label of the cost resource

SERVICE <http://data.posccaesar.org/rdl/> {

?costType rdfs:label ?costTypeLabel.

}

?monetaryValueInstance tpl:valPropertyValue ?value.

}




Figure 5: Result for the query about the cost of the equipment ordered