Programação em Lógica com Restrições

Geração e Resolução de um puzzle “Tic Tac Logic” em Prolog

FEUP-PLOG, Turma 3MIEIC06, Grupo TicTacLogic\_3

André Sousa Lago ([up201303313@fe.up.pt](mailto:up201303313@fe.up.pt))

Gustavo Rocha da Silva (up201304143@fe.up.pt)

Universidade do Porto, 2015/2016

**Abstract.** Resolução do problema de decisão inerente à geração e solução um puzzle “Tic Tac Logic” utilizando programação em lógica com restrições em SICStus Prolog da forma mais eficiente possível, evitando *backtracking* e instanciação de variáveis antes do seu *labeling*. Foi elaborado um conjunto de predicados para o SICStus Prolog que permite a resolução do problema enunciado, bem como a visualização da sua complexidade temporal e do impacto das opções de *labeling*.

1. Introdução

Este projeto foi proposto no âmbito da unidade curricular “Programação em Lógica” do 3º ano do Mestrado Integrado em Engenharia Informática e Computação da Faculdade de Engenharia da Universidade do Porto, com o objetivo de construir um programa em Programação em Lógica com Restrições para a resolução de problemas de decisão combinatória ou de otimização sugeridos.

Neste caso, o problema em análise trata-se de um problema de decisão combinatória inerente ao puzzle lógico “*Tic Tac Logic*”. Tratando-se de um puzzle de tabuleiro, o nosso programa consiste num conjunto de predicados de *SICStus Prolog* que permite a geração e solução de puzzles “*Tic Tac Logic*” com altura e largura variáveis e independentes, bem como a visualização dos estados iniciais, intermédios e finais dos tabuleiros e da variação da complexidade temporal da execução em função das dimensões do tabuleiro.

Assim, neste relatório, será feita uma descrição do problema em análise, ou seja, as regras do “*Tic Tac Logic*”. De seguida, será apresentada a abordagem aplicada à resolução do problema no que diz respeito a variáveis de decisão, restrições, função de avaliação e estratégia de pesquisa. Seguir-se-á a demonstração da visualização da solução bem como os resultados obtidos. Por fim, serão discutidas as conclusões atingidas com a realização do projeto, terminando com a bibliografia e os anexos existentes.

1. Descrição do Problema

O problema do “*Tic Tac Logic*” apresenta algumas semelhanças com o tradicional “jogo do galo” no que diz respeito ao tabuleiro e possibilidades de jogo. O problema consiste num puzzle que se constrói sobre um tabuleiro retangular com *N* células de largura e *M* células de altura. Cada célula deve ser preenchida com uma de duas possibilidades, ‘*X*’ ou ‘*O*’. O estado inicial do tabuleiro pode ser vazio ou com algumas células preenchidas com uma das duas possibilidades referidas. Assim, o tabuleiro deve ser preenchido de tal forma que se verifiquem as seguintes condições:

1. Numa mesma linha ou coluna não devem haver mais do que duas posições com ‘*X*’ ou ‘*O*’ consecutivas.
2. Para cada linha e coluna o número de posições com ‘*X*’ deve ser igual ao número de posições com ‘*O*’.
3. Cada linha e cada coluna devem ser únicas.
4. Abordagem para solução do puzzle

A abordagem ao problema em questão consistiu na determinação das variáveis de decisão, restrições e estratégia de pesquisa que permitem a solução eficiente do puzzle “*Tic Tac Logic*”.

* 1. Variáveis de Decisão

As variáveis de decisão correspondem às células do tabuleiro de jogo. Assim, dado um tabuleiro *N*\**M*, a lista de variáveis de decisão corresponde à ordenação linear de todas as células do tabuleiro, linha a linha. Para a representação em Prolog do tabuleiro utiliza-se uma lista de listas, sendo que cada uma das listas “internas” representa uma linha do tabuleiro, sendo por sua vez composta pelas células do tabuleiro. Assim, o jogo deve ser representado por uma lista composta por *M* listas de comprimento *N*. Por sua vez, cada célula é representada por um número de 0 a 2, que representa uma célula vazia (0), uma célula com ‘*X’* (1) ou uma célula com '*O’* (2). Uma vez que o tabuleiro se deve encontrar totalmente preenchido no final da resolução do puzzle, o domínio das variáveis presente nessa lista será [1, 2].

* 1. Restrições

Como foi descrito na secção 2 deste artigo, a resolução do puzzle é limitada por três restrições. A sua implementação em *SICStus Prolog* foi a seguinte:

### Restrição 1 – células iguais consecutivas

Para garantir o cumprimento desta restrição foi utilizado o predicado “*no\_more\_than\_two\_consecutives(+Board)*”. Este predicado sucede se em nenhuma das linhas do tabuleiro fornecido ocorrer o mesmo símbolo (*X* ou *O*) mais do que duas vezes seguidas. Contudo, isso não garante o cumprimento da restrição nas colunas do tabuleiro. Para isso, é efetuada a transposição do tabuleiro inicial com recurso ao predicado “*transpose(+OriginalMatrix, -TransposedMatrix)*”, que transpõe a matrix fornecida, fornecendo-se o seu resultado ao predicado “*no\_more\_than\_two\_consecutives*” para analisar o cumprimento da restrição.

### Restrição 2 – igual número de posições com *X* e *O*

Uma vez mais, para facilitar a validação desta restrição, pode ser utilizada a técnica de transposição referida no parágrafo anterior uma vez que dessa forma, a verificação linha a linha e coluna a coluna é igual.

Assim, utiliza-se o predicado “*same\_number(+List, +NumOccurrances, +Element1, +Element2)*” tanto no tabuleiro original como no tabuleiro transposto para garantir que em cada linha e coluna o número de posições com *X* e com *O* é igual.

### Restrição 3 – linhas e colunas únicas

Também na verificação desta restrição foi utilizada a técnica de transposição já referida pelos motivos mencionados na secção anterior.

Deste modo, é aplicado o predicado “*all\_different\_lists(+ListOfLists)*” que sucede apenas se todas as listas em “*ListOfLists*” forem distintas umas das outras. O predicado é aplicado com o tabuleiro original e o tabuleiro transposto para, assim, garantir a unicidade de cada linha (em relação às restantes linhas) e de cada coluna (em relação às restantes colunas).

* 1. Estratégia de Pesquisa

Para solucionar um tabuleiro foi desenvolvido o predicado “*solver(+Board, +Width, +Height, +LabelingParams)*” que permite alterar os parâmetros de “*labeling*”. Neste predicado, se a variável “*Board*” não estiver instanciada, o predicado coloca nela um tabuleiro vazio. Se, porém, se pretender que o predicado resolva um tabuleiro parcialmente preenchido, as posições vazias deste não devem estar instanciadas. Para a solução de um tabuleiro já existente não são necessários parâmetros de “*labeling*” pois as opções por defeito permitem uma resolução eficiente do problema.

Contudo, quando se pretende gerar um tabuleiro de jogo a partir de um tabuleiro vazio, é necessário garantir que o “*labeling*” faz uma escolha aleatória das variáveis para evitar que o tabuleiro gerado seja sempre igual de umas vezes para as outras. Neste caso, o “*labeling*” deve ter ativada a opção “*variable(sel)*” que torna o predicado “*sel(+Variables, -Selected, -Rest)*” responsável por escolher a variável seguinte a instanciar. Neste caso, o predicado “*sel*” faz uma escolha aleatória das variáveis disponíveis.

1. Abordagem para geração do puzzle

A geração eficiente de um puzzle de jogo válido traduz-se em problemas diferentes daqueles que são inerentes à solução de um puzzle. Contudo, um algoritmo de solução eficiente é essencial para uma geração não só eficiente como válida. Por outras palavras, sem um algoritmo de solução de um puzzle seria impossível de garantir que o tabuleiro gerado fosse válido sem possuir tabuleiros pré-definidos.

Foram implementados dois algoritmos de geração distintos uma vez que cada um apresenta as suas vantagens e desvantagens:

* 1. Geração com garantia de uma e só uma solução possível

O primeiro algoritmo, implementado pelo predicado “*generate\_board\_slow(-Board, +Width, +Height)*”, usa uma técnica de geração menos eficiente mas que garante que existe apenas uma solução possível tabuleiro gerado. Esta técnica consiste nos seguintes passos:

1. Criação de um tabuleiro válido com recurso ao predicado “*solver*”, utilizando como opção de “*labeling*” o predicado “*variable(sel)*” de forma a tornar aleatório o tabuleiro gerado.
2. Construção de uma lista com todas as posições preenchidas to tabuleiro (“*board\_nonempty\_coords(+Board, +Width, +Height, -NonEmpty)*”).
3. Seleção aleatória de uma posição (“*-Coords, +NonEmpty, -Rest*”).
4. Se a remoção da posição escolhida mantiver a restrição de apenas existir uma solução possível para o tabuleiro resultante, a posição é removida e retorna-se ao passo 2 (“*board\_remove\_pieces\_aux*”);
5. Em caso contrário, faz-se uma nova escolha aleatória no resto da lista obtida em 2
6. No caso de não haver nenhuma posição a remover que garanta a restrição referida, termina-se a execução do predicado, sendo retornado o tabuleiro gerado.
   1. Geração com número definido de peças preenchidas

Este algoritmo, implementado pelo predicado “*generate\_board\_fast(-Board, +Width, +Height)*”, revelou ser bastante mais rápido do que o anterior, mas tem uma desvantagem no que diz respeito ao número de soluções possíveis para o tabuleiro gerado. Enquanto o outro algoritmo garante que apenas há uma solução possível, este não garante esta restrição, sendo precisamente essa a causa do aumento da velocidade de execução. É, assim, impossível dizer se este algoritmo é melhor ou pior do que o anterior pois isso dependeria do contexto de aplicação.

A técnica obstante deste algoritmo é a seguinte:

1. Geração de um tabuleiro válido com recurso ao predicado “*solver*”, utilizando como opção de “*labeling*” o predicado “*variable(sel)*” de forma a tornar aleatório o tabuleiro gerado.
2. Sendo “*Size*” o número total de posições do tabuleiro gerado, remoção sucessiva de posições preenchidas aleatórias até que o número total de posições preenchidas no tabuleiro seja igual a *Size/7.*
3. Visualização da Solução

A visualização do tabuleiro em modo de texto é feita com recurso aos predicados implementados no ficheiro “*visualization.pl*”.

De uma forma geral, o predicado “*print\_board(+Board)*” imprime o tabuleiro de forma a ser percetível a organização das células. Para isso, desenha “linhas” que limitam as células do tabuleiro e coloca em cada célula um caractere representativo do valor dessa célula.

Para fazer a conversão dos valores das células para texto, o predicado “*piece\_to\_ascii(+Piece, -Char)*” determina o caractere correspondente a “*Piece*”. Se “*Piece*” for uma variável ou tiver o valor zero, o caractere correspondente é o espaço (célula vazia). Por sua vez, “1” corresponde ao caractere ‘*X*’ e “2” ao caractere “*O*”.

O predicado “*print\_board*” faz uso dos predicados “*print\_separating\_line(+Size)*” e “*print\_line(+Line)*” que fazem, respetivamente, a impressão de uma linha constituída por caracteres ‘-‘ que separa as linhas do tabuleiro e a impressão da linha em si do tabuleiro, separando as diferentes células por linhas verticais (‘|’).

Um exemplo de tabuleiro seria o seguinte:

---------------------------------

| | X | | | | O | | |

---------------------------------

| O | X | | | | | | |

---------------------------------

| | | O | | O | O | | |

---------------------------------

| O | | | | | | | X |

---------------------------------

| | X | | | X | | | |

---------------------------------

| | X | | | | | | |

---------------------------------

| | | | | O | | | O |

---------------------------------

| | | O | | | | | |

---------------------------------

1. Resultados

A implementação realizada pode ser usada tanto para a geração como para a solução de um tabuleiro. Assim, é importante perceber o desempenho das técnicas usadas para ambas as situações, discutindo as suas vantagens e desvantagens.

* 1. Geração de tabuleiros

Como foi referido na secção 4, foram utilizados dois algoritmos para geração de tabuleiro: um que garante a existência de apenas uma solução possível (nesta secção referido como “*slow*”; outro que garante que o tabuleiro gerado contém um número de peças proporcional ao tamanho do tabuleiro em si (nesta secção referido como “*fast*”). Para analisar o desempenho de ambos os algoritmos foram realizadas 10 execuções para tabuleiros de tamanho “6x6”, “8x8” e “10x10” cujos tempos de execução foram medidos com recurso ao predicado “*statistics*” do SICStus Prolog. Os resultados obtidos serão discutidos com base nos gráficos apresentados abaixo.

**Fig. 1.** Médias e desvios padrão dos tempos de execução dos algoritmos “*fast*” e “*slow*” no curso de 10 execuções

Através do gráfico presente na figura 1 é possível perceber que para tabuleiros pequenos (“6x6”) a diferença entre os dois algoritmos é quase inexistente. Contudo, com aumentos ligeiros no tamanho (“8x8”) a diferença torna-se bastante mais percetível, embora seja relativamente pequena. O grande impacto da melhor eficiência do algoritmo “*fast*” faz-se notar particularmente no tabuleiro “10x10” onde, embora o tabuleiro por si só não seja demasiado grande, o algoritmo “*slow*” demora em média 12 vezes mais do que o “*fast*”.

Para além disso, é ainda percetível outro efeito do aumento do tamanho do tabuleiro. Em ambos os algoritmos aumenta, de forma semelhante ao tempo médio, o desvio dos tempos de execução obtidos, o que se traduz numa maior irregularidade nos valores observados. Ou seja, por exemplo, para um tabuleiro “10x10”, é igualmente provável que o algoritmo “*slow*” demore 2 ou 22 segundos (aproximadamente).

**Fig. 2.** Médias dos tempos de execução de ambos os algoritmos de geração ao longo de 10 execuções

Pelo gráfico da figura 2 é visível a evolução do tempo de execução de ambos os algoritmos em função do tamanho do tabuleiro. Para aumentos ligeiros do tamanho do tabuleiro, o algoritmo “*slow*” apresenta aumentos muito mais significativos do que no algoritmo “*fast*”, mostrando uma evolução aparentemente exponencial face a uma evolução mais linear do outro algoritmo.

É importante salientar que não foram acrescentados os dados sobre tempos de execução dos algoritmos para tabuleiros ainda maiores (por exemplo “12x12”) uma vez que não acrescentariam mais informação àquela que foi apresentada e porque dificultaria a visualização dos resultados nos gráficos por questões de escala.

Apesar da clara desvantagem do algoritmo “*slow*” para tamanhos de tabuleiros superiores a “8x8”, deve-se notar a sua vantagem em termos de qualidade da solução. Dependendo do contexto a que o tabuleiro seria aplicado, a garantia de apenas existir uma solução pode traduzir-se numa grande vantagem. Assim, de uma forma geral, tendo em conta o tempo de execução e a qualidade da solução, o algoritmo “*slow*” é melhor para tabuleiros pequenos (no máximo “8x8”), mas nos restantes tabuleiros “*fast*” é superior tendo em conta a sua rapidez.

* 1. Solução de tabuleiros

No que diz respeito à solução de tabuleiros, foi feita uma comparação dos tempos de execução do predicado “*solver*” ao longo de 10 execuções, para os tamanhos “8x8”, “10x10”, “12x12” e “14x14”. Para além disso, foi testada a diferença de se colocar a opção “*enum*” na tentativa de melhorar os resultados obtidos.

**Fig. 3.** Tempo médio de execução do predicado “*solver*” com e sem a opção “*enum*”, ao longo de 10 execuções para tamanhos variáveis

Pelos dados da figura 3 é possível estabelecer conclusões quanto ao comportamento do predicado “*solver*” para tamanhos diferentes de tabuleiros, bem como a diferença causada pela opção “*enum*”.

Em primeiro lugar, o predicado é extremamente rápido para tabuleiros pequenos (no máximo “12x12”) uma vez que consegue resolvê-los em menos de 0,25 segundos. Para além disso, a resolução é praticamente instantânea para tabuleiros menores que 10x10. Contudo, o crescimento mostra-se exponencial em função do tamanho do tabuleiro a resolver, justificando o crescimento elevado para o tabuleiro “14x14”. Assim, para tabuleiros ainda maiores a resolução poderia durar desde alguns minutos a várias horas.

Por fim, foi observado que a presença de “*enum*” causou um pequeno aumento no tempo de execução do predicado “*solver*”, pelo que não será benéfica para acelerar a solução de tabuleiros.

1. Conclusões e Trabalho Futuro

Os resultados obtidos para a geração de um tabuleiro de jogo permitem concluir que a utilização do algoritmo implementado em “*generate\_board\_fast*” é vantajosa para tabuleiros de tamanho “10x10” ou maior. Contudo, para tabuleiros de dimensão menor o algoritmo implementado por “*generate\_board\_slow*” será preferível para serem obtidas soluções de maior qualidade.

No que diz respeito à solução de tabuleiros, o algoritmo implementado mostrou-se especialmente eficiente para tabuleiros de dimensão inferior ou igual a “12x12”. Para tabuleiros maiores o desempenho do algoritmo não é o desejável para situações em que o cálculo necessite de rapidez ou de várias execuções seguidas.

Bibliografia

1. Conceptis Ltd.: Conceptis Puzzles, Tic-Tac-Logic, <http://www.conceptispuzzles.com/index.aspx?uri=puzzle/tic-tac-logic> (página consultada pela última vez a 08/12/2015 pelas 10:30)

Anexos

* Ficheiro “visualization.pl”, responsável pela implementação dos predicados de visualização de tabuleiros:

piece\_to\_ascii(**P**, ' ') **:-** var(P), !**.**

piece\_to\_ascii(*0*, ' ')**.**

piece\_to\_ascii(*1*, 'X')**.**

piece\_to\_ascii(*2*, 'O')**.**

print\_board([**Line**]) **:-**

print\_line(Line),

length(Line, **Size**),

print\_separating\_line(Size)**.**

print\_board([**Line1**, **Line2** |**Rest**]) **:-**

print\_line(Line1),

print\_board([Line2 | Rest])**.**

print\_board([])**.**

print\_line(**Line**) **:-**

length(Line, **Size**),

print\_separating\_line(Size),

print\_line\_cells(Line)**.**

print\_separating\_line(**Size**) **:-**

Size > *0*, !,

print\_separating\_line\_aux,

**S1** is Size - *1*,

print\_separating\_line(S1)**.**

print\_separating\_line(*0*) **:-** write('-'), nl**.**

print\_separating\_line\_aux **:-** write('----')**.**

print\_line\_cells([**Cell**|**Rest**]) **:-**

write('|'),

print\_cell(Cell),

print\_line\_cells(Rest)**.**

print\_line\_cells([]) **:-** write('|'), nl**.**

print\_cell(**Cell**) **:-**

piece\_to\_ascii(Cell, **P**),

write(' '), write(P), write(' ')**.**

write\_time(**T**) **:-** T > *1000*,

**S** is T/*1000*,

write(S), write('s')**.**

write\_time(**T**) **:-** write(T), write('ms')**.**

* Ficheiro “tictaclogic.pl”, responsável pela implementação dos predicados de geração e solução de tabuleiros:

**:-** use\_module(library(clpfd))**.**

**:-** use\_module(library(random))**.**

**:-** use\_module(library(system))**.**

**:-** use\_module(library(lists))**.**

**:-** now(**Timestamp**),

setrand(Timestamp)**.**

**:-** ensure\_loaded('visualization.pl')**.**

cross(*1*)**.**

circle(*2*)**.**

tictaclogic(**Width**, **Height**, **BoardGenerator**) **:-**

**Mw** is Width mod *2*,

Mw = *0*, *% Width must be even*

**Mh** is Height mod *2*,

Mh = *0*, *% Height must be even*

write('Generating board...'), nl,

**G** =.. [BoardGenerator, **B**, Width, Height],

statistics(walltime, [**InitTime**|\_]),

G,

statistics(walltime, [**GenTime**|\_]),

**Delta1** is GenTime - InitTime,

write('Board to be solved: '), nl, print\_board(B), nl,

write('Board generated in '), write\_time(Delta1), nl,

statistics(walltime, [**InitTime2**|\_]),

solver(B, Width, Height, [enum]),

statistics(walltime, [**SolveTime**|\_]),

write('Solution: '), nl, print\_board(B),

**Delta2** is SolveTime-InitTime2,

write('Board solved in '), write\_time(Delta2), nl**.**

generate\_board\_fast(**B**, **Width**, **Height**) **:-**

solver(**B1**, Width, Height, [variable(sel), enum]),

**Size** is Width \* Height,

**N** is Size - (Size div *7*),

board\_nonempty\_coords(B1, Width, Height, **NonEmpty**),

generate\_board\_fast\_aux(B1, B, Width, Height, NonEmpty, \_, N)**.**

generate\_board\_fast\_aux(**B**, B, \_, \_, \_, \_, *0*) **:-** !**.**

generate\_board\_fast\_aux(**B**, **NewBoard**, **Width**, **Height**, **NonEmpty**, **NonEmptyNew**, **N**) **:-**

print\_board(B),

random\_select(**Coords**, NonEmpty, **NonEmpty1**),

board\_remove\_piece(B, Coords, **B1**),

**N1** is N - *1*,

generate\_board\_fast\_aux(B1, NewBoard, Width, Height, NonEmpty1, NonEmptyNew, N1)**.**

generate\_board\_slow(**B**, **Width**, **Height**) **:-**

solver(**B1**, Width, Height, [variable(sel)]),

board\_remove\_pieces(B1, Width, Height, B)**.**

board\_remove\_pieces(**B**, **Width**, **Height**, **Result**) **:-**

print\_board(B),

board\_nonempty\_coords(B, Width, Height, **NonEmpty**),

random\_select(**Coords**, NonEmpty, **Rest**),

board\_remove\_piece(B, Coords, **B1**),

board\_copy(B1, **B2**),

findall(B2, solver(B2, Width, Height, []), **L**),

board\_remove\_pieces\_aux(B, B1, L, Width, Height, Rest, Result)**.**

board\_remove\_pieces\_aux(\_, **B1**, **L**, **Width**, **Height**, \_, **Result**) **:-**

length(L, *1*), !,

board\_remove\_pieces(B1, Width, Height, Result)**.**

board\_remove\_pieces\_aux(**B**, \_, \_, \_, \_, [], B) **:-** !**.**

board\_remove\_pieces\_aux(**B**, \_, \_, **Width**, **Height**, **NonEmpty**, **Result**) **:-**

random\_select(**Coords**, NonEmpty, **Rest**),

board\_remove\_piece(B, Coords, **B1**),

board\_copy(B1, **B2**),

findall(B2, solver(B2, Width, Height, []), **L**),

board\_remove\_pieces\_aux\_aux(B, B1, L, Width, Height, Rest, Result)**.**

board\_remove\_pieces\_aux\_aux(\_, **B1**, **L**, **Width**, **Height**, \_, **Result**) **:-**

length(L, *1*), !,

board\_remove\_pieces(B1, Width, Height, Result)**.**

board\_remove\_pieces\_aux\_aux(**B**, **B1**, **L**, **Width**, **Height**, [\_ | **T**], **Result**) **:-** board\_remove\_pieces\_aux(B, B1, L, Width, Height, T, Result)**.**

*%replace(+N, +X, +L1, -L2)*

*% Replaces the Nth member of L1 by X and instanciates L2 to the result.*

replace(**N**, **X**, **L1**, **L2**) **:-**

length(**L3**, N),

append(L3, [\_ | **T**], L1),

append(L3, [X | T], L2)**.**

board\_xy(**Board**, [**X**, **Y**], **Cell**) **:-**

nth0(Y, Board, **Line**),

nth0(X, Line, Cell)**.**

board\_copy([], []) **:-** !**.**

board\_copy([**H1** | **T1**], [**H2** | **T2**]) **:-**

board\_copy\_aux(H1, H2),

board\_copy(T1, T2)**.**

board\_copy\_aux([], []) **:-** !**.**

board\_copy\_aux([**H1** | **T1**], [\_ | **T2**]) **:-**

var(H1), !,

board\_copy\_aux(T1, T2)**.**

board\_copy\_aux([**H1** | **T1**], [H1 | **T2**]) **:-** board\_copy\_aux(T1, T2)**.**

board\_nonempty\_coords(**Board**, **Width**, **Height**, **NonEmpty**) **:-** board\_nonempty\_coords\_aux(Board, NonEmpty, Width, Height, [*0*, *0*])**.**

board\_nonempty\_coords\_aux([], \_, \_, **Height**, [*0*, Height])**.**

board\_nonempty\_coords\_aux([**Bh** | **Bt**], **NonEmpty**, **Width**, **Height**, [*0*, **Y**]) **:-**

board\_nonempty\_coords\_aux\_aux(Bh, **NonEmpty1**, Width, Height, [*0*, Y]),

append(NonEmpty1, **NonEmpty2**, NonEmpty),

**Y1** is Y + *1*,

board\_nonempty\_coords\_aux(Bt, NonEmpty2, Width, Height, [*0*, Y1])**.**

board\_nonempty\_coords\_aux\_aux([], [], **Width**, \_, [Width, \_]) **:-** !**.**

board\_nonempty\_coords\_aux\_aux([**Rh** | **Rt**], [[**X**, **Y**] | **Et**], **Width**, **Height**, [X, Y]) **:-**

nonvar(Rh), !,

**X1** is X + *1*,

board\_nonempty\_coords\_aux\_aux(Rt, Et, Width, Height, [X1, Y])**.**

board\_nonempty\_coords\_aux\_aux([\_ | **Rt**], **NonEmpty**, **Width**, **Height**, [**X**, **Y**]) **:-**

**X1** is X + *1*,

board\_nonempty\_coords\_aux\_aux(Rt, NonEmpty, Width, Height, [X1, Y])**.**

board\_random\_coords(**Width**, **Height**, [**X**, **Y**]) **:-**

**Total\_size** is Width \* Height,

random(*0*, Total\_size, **R**),

**Div** is R div Width,

**Mod** is R mod Width,

X = Div,

Y = Mod**.**

board\_remove\_piece(**Board**, [**X**, **Y**], **New\_board**) **:-**

nth0(Y, Board, **Line**),

replace(X, \_, Line, **New\_line**),

replace(Y, New\_line, Board, New\_board)**.**

solver(**B**, **Width**, **Height**, **LabelingParams**) **:-**

empty\_board(B, Width, Height),

list\_board\_vars(B, **L**),

domain(L, *1*, *2*),

*% Restrictions*

**Nw** is Width div *2*,

**Nh** is Height div *2*,

transpose(B, **B1**),

cross(**X**),

circle(**O**),

no\_more\_than\_two\_consecutive(B),

no\_more\_than\_two\_consecutive(B1),

same\_number(B, Nw, X, O),

same\_number(B1, Nh, X, O),

all\_different\_lists(B),

all\_different\_lists(B1),

*% Labeling*

labeling(LabelingParams, L)**.**

same\_number([], \_, \_, \_)**.**

same\_number([**H** | **T**], **N**, **X**, **O**) **:-**

global\_cardinality(H, [X-N, O-N]),

same\_number(T, N, X, O)**.**

all\_different\_lists([])**.**

all\_different\_lists([**H** | **T**]) **:-**

all\_different\_lists(H, T),

all\_different\_lists(T)**.**

all\_different\_lists(\_, [])**.**

all\_different\_lists(**L**, [**H** | **T**]) **:-**

different\_lists(L, H, **Bs**),

sum(Bs, #\=, *0*),

all\_different\_lists(L, T)**.**

different\_lists([], [], [])**.**

different\_lists([**L1h** | **L1t**], [**L2h** | **L2t**], [**B** | **Bs**]) **:-**

(L1h #\= L2h) #<=> B,

different\_lists(L1t, L2t, Bs)**.**

empty\_board([], \_, *0*) **:-** !**.**

empty\_board([**H** | **T**], **Width**, **Height**) **:-**

length(H, Width),

**Height1** is Height - *1*,

empty\_board(T, Width, Height1)**.**

list\_board\_vars([], [])**.**

list\_board\_vars([**Bh** | **Bt**], **L**) **:-**

append(Bh, **L1**, L),

list\_board\_vars(Bt, L1)**.**

no\_more\_than\_two\_consecutive([])**.**

no\_more\_than\_two\_consecutive([**H** | **T**]) **:-**

no\_more\_than\_two\_consecutive\_aux(H),

no\_more\_than\_two\_consecutive(T)**.**

no\_more\_than\_two\_consecutive\_aux([\_, \_])**.**

no\_more\_than\_two\_consecutive\_aux([**H**, **H2**, **H3** | **T**]) **:-**

H #\= H2 #\/ H #\= H3,

no\_more\_than\_two\_consecutive\_aux([H2, H3 | T])**.**

sel(**Vars**, **Selected**, **Rest**) **:-** random\_select(Selected, Vars, Rest), var(Selected)**.**

test\_board2(**B**, *6*, *6*) **:-**

cross(**X**),

circle(**O**),

B = [[\_, \_, \_, \_, \_, \_],

[X, \_, \_, \_, \_, X],

[\_, \_, \_, X, \_, \_],

[O, \_, \_, X, \_, \_],

[\_, O, \_, \_, \_, \_],

[\_, O, \_, \_, X, \_]]**.**

test\_board(**B**, *6*, *6*) **:-**

cross(**X**),

circle(**O**),

B = [[\_, \_, X, \_, \_, \_],

[\_, \_, X, \_, \_, \_],

[X, \_, \_, \_, \_, X],

[\_, \_, O, \_, \_, \_],

[\_, X, \_, \_, \_, X],

[O, \_, \_, \_, O, \_]]**.**

test\_board(**B**, *8*, *8*) **:-**

cross(**X**),

circle(**O**),

B = [[\_, \_, \_, X, \_, X, \_, \_],

[\_, X, \_, \_, \_, \_, \_, \_],

[\_, \_, \_, \_, X, X, \_, X],

[\_, \_, O, \_, \_, \_, O, \_],

[X, \_, \_, \_, X, \_, \_, \_],

[\_, \_, \_, O, \_, \_, X, X],

[\_, X, \_, \_, \_, \_, \_, \_],

[\_, \_, O, \_, \_, \_, O, \_]]**.**

test\_board(**B**, *10*, *10*) **:-**

cross(**X**),

circle(**O**),

B = [[\_, \_, X, \_, \_, \_, \_, X, \_, \_],

[\_, \_, \_, \_, \_, \_, \_, \_, X, \_],

[\_, O, \_, \_, \_, \_, \_, \_, \_, \_],

[\_, \_, \_, \_, \_, \_, O, \_, O, \_],

[\_, O, X, \_, \_, \_, \_, \_, \_, \_],

[\_, \_, \_, \_, \_, \_, \_, \_, \_, \_],

[\_, \_, \_, \_, O, \_, \_, \_, \_, \_],

[\_, \_, \_, \_, \_, \_, \_, \_, \_, \_],

[\_, \_, \_, \_, \_, \_, \_, \_, \_, \_],

[\_, \_, \_, \_, O, \_, \_, \_, \_, \_]]**.**