demo: create build scripts for our countdash demo

[shoenig]

We use the education team's "countdash" demo in many places
to showcase Nomad's Consul Connect integration. This change
adds a Dockerfile for each of counter-dashboard and
counter-api that can be used to build artifacts to publish
to Nomad's Docker Hub organization.

The recent "0.0.3" release of the countdash demo includes
changes we want in order to demo task group service checks.

[shoenig]

Goal is to get something like this job into e2e and some of the connect examples

job "cd" {
  datacenters = ["dc1"]

  group "api" {
    network {
      mode = "bridge"

      port "api_healthcheck" {
        to = -1
      }
    }

    service {
      name = "count-api"
      port = "9001"

      connect {
        sidecar_service {}
      }

      check {
        name     = "api-health"
        type     = "http"
        port     = "api_healthcheck"
        path     = "/health"
        interval = "10s"
        timeout  = "3s"
        expose   = true
      }
    }

    task "web" {
      driver = "docker"

      config {
        image = "hashicorpnomad/counter-api:test"
      }
    }
  }

  group "dashboard" {
    network {
      mode = "bridge"

      port "http" {
        static = 9002
        to     = 9002
      }

      port "dashboard_healthcheck" {
        to = -1
      }

      port "dashboard_upstream_healthcheck" {
        to = -1
      }
    }

    service {
      name = "count-dashboard"
      port = "9002"

      connect {
        sidecar_service {
          proxy {
            upstreams {
              destination_name = "count-api"
              local_bind_port  = 8080
            }
          }
        }
      }

      check {
        name     = "dashboard-health"
        type     = "http"
        port     = "dashboard_healthcheck"
        path     = "/health"
        interval = "10s"
        timeout  = "3s"
        expose   = true
      }

      check {
        name     = "dashboard-upstream-health"
        type     = "http"
        port     = "dashboard_upstream_healthcheck"
        path     = "/health/api"
        interval = "10s"
        timeout  = "3s"
        expose   = true
      }
    }

    task "dashboard" {
      driver = "docker"

      env {
        COUNTING_SERVICE_URL = "http://${NOMAD_UPSTREAM_ADDR_count_api}"
      }

      config {
        image = "hashicorpnomad/counter-dashboard:test"
      }
    }
  }
}

[schmichael]

Thanks! I always forget where that demo is located 😬

[github-actions]

I'm going to lock this pull request because it has been closed for 120 days ⏳. This helps our maintainers find and focus on the active contributions.
If you have found a problem that seems related to this change, please open a new issue and complete the issue template so we can capture all the details necessary to investigate further.