diff --git a/hawaii-shell/PKGBUILD b/hawaii-shell/PKGBUILD
new file mode 100644
index 0000000..83ef45f
--- /dev/null
+++ b/hawaii-shell/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Pier Luigi Fiorini <pierluigi.fiorini@gmail.com>
+
+pkgname=hawaii-shell
+pkgver=0.3.90
+pkgrel=1
+pkgdesc="Hawaii Shell"
+arch=('i686' 'x86_64' 'armv6h' 'armv7h')
+url="https://github.com/hawaii-desktop"
+license=('GPL', 'LGPL')
+depends=('qt5-tools' 'qt5-quickcontrols' 'qt5-graphicaleffects' 'qt5-svg'
+         'greenisland' 'pam' 'libpulse'
+         'kdoctools' 'kdelibs4support' 'krunner' 'kwayland' 'plasma-framework' 'plasma-workspace' 'plasma-nm'
+         'ttf-dejavu' 'ttf-droid')
+optdepends=('weston: nested mode support'
+            'pulseaudio: audio support'
+            'hawaii-icon-themes: icon theme'
+            'hawaii-wallpapers: wallpapers')
+makedepends=('gdb' 'extra-cmake-modules')
+conflicts=('hawaii-shell-git')
+groups=('hawaii')
+options=('debug')
+source=("https://github.com/hawaii-desktop/${pkgname}/archive/v${pkgver}.tar.gz")
+md5sums=('5d7fc54c2757beebeee6ab658ff91313')
+
+prepare() {
+	mkdir -p build
+}
+
+build() {
+	cd build
+	cmake ../${pkgname}-${pkgver} \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DLIB_INSTALL_DIR=lib \
+		-DLIBEXEC_INSTALL_DIR=lib \
+		-DQML_INSTALL_DIR=lib/qt/qml \
+		-DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
+		-DQtWaylandScanner_EXECUTABLE=/usr/lib/qt/bin/qtwaylandscanner \
+		-DCMAKE_BUILD_TYPE=RelWithDebInfo
+	make VERBOSE=1
+}
+
+package() {
+	cd build
+	make DESTDIR="${pkgdir}" install
+}