
Ampel-

Steuerung

mit Arduino



Manuel Haag

April 2020

# Einleitung

In diesem Projekt bauen wir eine Ampelanlage bestehend aus:

* einer Ampel für Autos
* einer Ampel für Fussgänger mit Knopf
* einer Steuerung mit Arduino

Die Anlage läuft selbständig mit einer 9V Batterie.

## Funktionsweise der Ampel

Beim Start (oder nach RESET) blinken beide Ampeln orange.

Sobald der Knopf bei der Fussgängerampel gedrückt wird, schalten zuerst beide Ampeln auf Rot, danach folgt die Grünphase (10 Sekunden) für Fussgänger.

Danach stellt die Fussgängerampel auf Rot und die Autos bekommen grün (zeitlich unbeschränkt).

Bei erneutem Drücken des Knopfes erfolgt wieder eine Grünphase für die Fussgänger.

Die Grünphase für Autos dauert jedoch mindestens 10 Sekunden (falls der Knopf zu früh gedrückt wird).

# Bauteile

## Stromversorgung

Die Ampel wird mit einer 9V Batterie betrieben und über einen Stecker mit Kabel am Arduino angeschlossen.

ACHTUNG: die Batterie darf nicht verkehrt angeschlossen werden, sonst könnte die Steuerung kaputt gehen!

Beim Anschliessen des Steckers an die Batterie immer darauf achten, dass die Polung stimmt!  
Die beiden abisolierten Kabelenden (rot und schwarz) dürfen sich nicht berühren, sonst gibt es einen Kurzschluss und das Kabel wird heiss oder beginnt zu schmelzen!

Rot = Pluspol  
Schwarz = Minuspol




Aufgaben:

1. Schliesse die Batterie an ein Messgerät (Voltmeter) an und überprüfe, wieviel Spannung (Volt) die Batterie noch hat. Wenn die Batterie neu ist, sollte sie etwas mehr als 9V anzeigen.
2. Was passiert, wenn du Plus und Minus vertauschst?


***Tipp: Spannungen bis etwa 50 Volt sind ungefährlich. Über 50 Volt ist gefährlich und*** ***darf nicht berührt werden! Die Steckdose hat 230V und ist somit lebensgefährlich!***

## LED

Leuchtdioden (Englisch: Light Emitting Diode – *LED*) sind kleine Lämpchen. Es gibt sie in verschiedenen Grössen und Farben. Wir verwenden Gelb, Rot und Grün.




Die LEDs funktionieren nur, wenn Plus und Minus richtig angeschlossen sind. Den Minuspol erkennt man am kürzeren Bein und an der flachen Seite der LED:




Damit die LEDs nicht kaputt gehen, braucht es vor jeder LED einen Schutzwiderstand.

## Widerstand

Widerstände «bremsen» den Stromfluss. Es gibt schwache und starke Widerstände. Der Wert des Widerstands ist mit Farbringen gekennzeichnet und heisst «Ohm».  
Beim Widerstand spielt es keine Rolle, wie man ihn anschliesst (Plus/Minus).



Widerstände können zum Beispiel dazu dienen, LEDs vor zu hohen Strömen zu schützen.  
Für unsere Ampel braucht es vor jeder LED einen kleinen Widerstand von 220 Ohm. Dieser hat die Farbcodierung ROT-ROT-BRAUN:




Aufgaben:

1. Löte einen 560 Ohm Widerstand (Farbcode GRÜN-BLAU-BRAUN) an ein Bein einer LED.
2. Schliesse die LED mit dem Vorwiderstand an die 9V Batterie an, so dass sie leuchtet.
3. Was passiert, wenn du Plus und Minus vertauschst?

## Taster Knopf

Ein Taster ist ein kleiner Schalter, welcher den Stromkreis schliesst, solange er gedrückt wird.  
Damit kann man der Ampelsteuerung mitteilen, dass jemand über den Fussgängerstreifen gehen will.

Wir verwenden diesen Taster mit eingebautem LED-Lämpchen, welches aufleuchtet, wenn der Knopf gedrückt wurde.



Aufgaben:


1. Finde mithilfe eines «Durchgangspiepsers» heraus, welche Anschlussbeine zum Taster gehören und welche zur LED.
2. Mache eine kleine Zeichnung mit den Anschlüssen für später.

## Arduino

Der Arduino ist ein kleiner Computer. Er besteht aus einem Mikrocontroller, den man programmieren kann. Wir werden ihn so programmieren, dass er die LEDs der Ampel aufleuchten lässt und die Ampel genau so funktioniert, wie wir es möchten.  
Er hat mehrere Anschlüsse für Ein- und Ausgänge. An den Ausgängen werden die LEDs angeschlossen, an einem Eingang der Taster.

Der Arduino benötigt eine Stromversorgung (9V Batterie) und kann mit dem RESET-Knopf jederzeit neu gestartet werden.

Zusätzlich hat es auf dem Arduino eine kleine grüne LED, welche nützlich ist, wenn man schnell etwas Testen will.



9V Batterie

**Arduino**

RESET-Knopf

Mikrocontroller  
(programmierbar)

Ein- oder Ausgänge

kleine LED

# Programmierung des Arduino


## Programmierung über FTDI-Kabel

Der Arduino wird über einen normalen PC oder Laptop mit einem speziellen FTDI Kabel über USB programmiert. Das Programm bleibt auf dem Arduino gespeichert, auch wenn man die Batterie abhängt. Wenn er einmal programmiert ist, läuft der Arduino selbständig (ohne PC). Jedesmal, wenn man am Programm etwas ändern will, muss man den Arduino neu programmieren.

Für die Programmierung benötigt man eine Entwicklungsumgebung auf dem PC namens Arduino IDE. Diese kann hier downgeloadet werden:

<https://www.arduino.cc/en/Main/Software>

Unter Tools – Board muss «Arduino Pro or Pro Mini” ausgewählt werden




## Erstes Testprogramm «Blink»

Zu Beginn schreiben wir ein erstes kleines Programm, welches die kleine grüne LED auf dem Arduino blinken lässt.





Aufgaben:

1. Verbinde den Arduino mit dem FTDI-Kabel über USB mit dem PC genau wie abgebildet. Stecke vorher die Batterie ab, falls es eine hat.

1. Öffne das Blink Demo Programm unter File 🡪 Examples 🡪 01.Basics 🡪 Blink



1. Übertrage das Programm «Blink» auf den Arduino indem du auf «Upload» klickst.

Zur Übertragung des Programms auf den Arduino (Upload)

1. Das Programm «Blink» startet automatisch nach erfolgreichem Upload.  
   Beobachte, ob die grüne LED im Sekundentakt blinkt. Du kannst den Arduino auch vom FTDI-Kabel abhängen und stattdessen mit Batterie betreiben.
2. Verändere die Werte von delay(1000) auf Zeile 34 und 36.  
   Gib zum Beispiel delay(100) oder delay(3000) ein.  
   Übertrage das veränderte Programm erneut auf den Arduino.  
   Was passiert?

***Tipp: 1 Sekunde = 1000 Millisekunden (Tausendstelsekunden)***

## Programm für die Ampelsteuerung

Nun ist es Zeit, das richtige Ampelprogramm auf den Arduino zu laden.

Der Quellcode ist hier zu finden: <https://github.com/helijunky/Ampel>

Übertrage das Programm wie zuvor mit dem FTDI-Kabel.

/\*

Ampelsteuerung mit Arduino

Manuel Haag

März 2020

Funktionsweise

--------------

Beim Start (oder nach RESET) blinken beide Ampeln orange.

Sobald der Knopf bei der Fussgängerampel gedrückt wird, schalten zuerst

beide Ampeln auf Rot, danach folgt die Grünphase für Fussgänger

(10 Sekunden).

Danach stellt die Fussgängerampel auf Rot und die Autos bekommen grün

(zeitlich unbeschränkt).

Bei erneutem Drücken des Knopfes erfolgt wieder eine Grünphase für die

Fussgänger. Die Grünphase für Autos dauert jedoch mindestens 10 Sekunden

(falls der Knopf zu früh gedrückt wird).

\*/

// Definition der Namen für Ein- und Ausgänge am Arduino

#define LED\_AUTO\_ROT 9              // Ausgang 9 für Auto Rot

#define LED\_AUTO\_GELB 8             // Ausgang 8 für Auto Gelb

#define LED\_AUTO\_GRUEN 7            // Ausgang 7 für Auto Grün

#define LED\_FUSSG\_ROT 6             // Ausgang 6 für Fussgänger Rot

#define LED\_FUSSG\_GELB 5            // Ausgang 5 für Fussgänger Gelb

#define LED\_FUSSG\_GRUEN 4           // Ausgang 4 für Fussgänger Grün

#define LED\_KNOPF 3                 // Ausgang 3 für LED in Knopf

#define KNOPF 2                     // Eingang 2 für Knopf

// Variablen

bool blinken = true;                // true:  Blinken eingeschaltet

                                   // false: Blinken ausgeschaltet

volatile bool gedrueckt;            // true:  Knopf wurde gedrückt

                                   // false: Knopf nicht gedrückt

// die setup Funktion wird beim Start einmal ausgeführt

void setup() {

 // alle LEDs werden als Ausgang definiert

 pinMode(LED\_BUILTIN, OUTPUT);

 pinMode(LED\_AUTO\_ROT, OUTPUT);

 pinMode(LED\_AUTO\_GELB, OUTPUT);

 pinMode(LED\_AUTO\_GRUEN, OUTPUT);

 pinMode(LED\_FUSSG\_ROT, OUTPUT);

 pinMode(LED\_FUSSG\_GELB, OUTPUT);

 pinMode(LED\_FUSSG\_GRUEN, OUTPUT);

 pinMode(LED\_KNOPF, OUTPUT);

 // der Knopf wird als Eingang definiert

 pinMode(KNOPF, INPUT\_PULLUP);

 // sobald der Knopf gedrückt wird, wird die Funktion "druecken" aufgerufen

 // (Interrupt-Funktion)

 attachInterrupt(digitalPinToInterrupt(KNOPF), druecken, FALLING);

 // zum Testen werden alle LEDs kurz eingeschaltet

 digitalWrite(LED\_AUTO\_ROT, HIGH);

 digitalWrite(LED\_AUTO\_GELB, HIGH);

 digitalWrite(LED\_AUTO\_GRUEN, HIGH);

 digitalWrite(LED\_FUSSG\_ROT, HIGH);

 digitalWrite(LED\_FUSSG\_GELB, HIGH);

 digitalWrite(LED\_FUSSG\_GRUEN, HIGH);

 digitalWrite(LED\_KNOPF, HIGH);

 digitalWrite(LED\_BUILTIN, HIGH);

 delay(2000);

 // und wieder ausgeschaltet

 digitalWrite(LED\_AUTO\_ROT, LOW);

 digitalWrite(LED\_AUTO\_GELB, LOW);

 digitalWrite(LED\_AUTO\_GRUEN, LOW);

 digitalWrite(LED\_FUSSG\_ROT, LOW);

 digitalWrite(LED\_FUSSG\_GELB, LOW);

 digitalWrite(LED\_FUSSG\_GRUEN, LOW);

 digitalWrite(LED\_KNOPF, LOW);

 digitalWrite(LED\_BUILTIN, LOW);

 delay(1000);

 gedrueckt = false;  // erster Knopfdruck löschen (Interrupt wird bei jedem Start

                     // einmal ausgeführt)

}

// Interrupt-Funktion wird aufgerufen, sobald der Knopf gedrückt wird

void druecken() {

 if (!gedrueckt) {                      // falls noch nicht gedrückt wurde...

   gedrueckt = true;                   // sich merken, dass Knopf gedrückt wurde

   digitalWrite(LED\_KNOPF, HIGH);      // LED im Knopf einschalten

   digitalWrite(LED\_BUILTIN, HIGH);    // kleine LED auf dem Arduino einschalten

 }

}

// die loop Funktion wird immer wieder ausgeführt

void loop() {

 // Blinken der orangen LEDs

 if (blinken) {                        // wenn Blinken aktiv ist

   digitalWrite(LED\_AUTO\_GELB, HIGH);  // gelbe LED für Auto einschalten

   digitalWrite(LED\_FUSSG\_GELB, HIGH); // gelbe LED für Fussgänger einschalten

   digitalWrite(LED\_BUILTIN, HIGH);    // kleine LED auf dem Arduino einschalten

   delay(700);                         // 700 Millisekunden warten

   digitalWrite(LED\_AUTO\_GELB, LOW);   // gelbe LED für Auto ausschalten

   digitalWrite(LED\_FUSSG\_GELB, LOW);  // gelbe LED für Fussgänger ausschalten

   digitalWrite(LED\_BUILTIN, LOW);     // kleine LED auf dem Arduino ausschalten

   delay(700);                         // 700 Millisekunden warten

 }

 if (gedrueckt) {                      // wenn gedrückt wurde...

   if (blinken) {                      // wenn noch Blinken aktiv ist...

     blinken = false;                  // Blinken ausschalten

     // Fussgänger Ampel auf Orange stellen

     digitalWrite(LED\_FUSSG\_ROT, LOW);

     digitalWrite(LED\_FUSSG\_GELB, HIGH);

     digitalWrite(LED\_FUSSG\_GRUEN, LOW);

   }

   // Auto Ampel auf Orange stellen

   digitalWrite(LED\_AUTO\_ROT, LOW);

   digitalWrite(LED\_AUTO\_GELB, HIGH);

   digitalWrite(LED\_AUTO\_GRUEN, LOW);

   delay(3000);                        // 3 Sekunden warten

   // Auto Ampel auf Rot stellen

   digitalWrite(LED\_AUTO\_ROT, HIGH);

   digitalWrite(LED\_AUTO\_GELB, LOW);

   digitalWrite(LED\_AUTO\_GRUEN, LOW);

   // Fussgänger Ampel auf Rot stellen

   digitalWrite(LED\_FUSSG\_ROT, HIGH);

   digitalWrite(LED\_FUSSG\_GELB, LOW);

   digitalWrite(LED\_FUSSG\_GRUEN, LOW);

   delay(2000);                        // 2 Sekunden warten

   // Fussgänger Ampel auf Grün stellen

   digitalWrite(LED\_FUSSG\_ROT, LOW);

   digitalWrite(LED\_FUSSG\_GELB, LOW);

   digitalWrite(LED\_FUSSG\_GRUEN, HIGH);

   digitalWrite(LED\_KNOPF, LOW);       // LED im Knopf ausschalten

   digitalWrite(LED\_BUILTIN, LOW);     // kleine LED ausschalten

   delay(10000);                       // 10 Sekunden warten

   // Fussgänger Ampel auf Orange stellen

   digitalWrite(LED\_FUSSG\_ROT, LOW);

   digitalWrite(LED\_FUSSG\_GELB, HIGH);

   digitalWrite(LED\_FUSSG\_GRUEN, LOW);

   delay(3000);                        // 3 Sekunden warten

   // Fussgänger Ampel auf Rot stellen

   digitalWrite(LED\_FUSSG\_ROT, HIGH);

   digitalWrite(LED\_FUSSG\_GELB, LOW);

   digitalWrite(LED\_FUSSG\_GRUEN, LOW);

   gedrueckt = false;                  // ab jetzt kann man wieder drücken

   delay(2000);                        // 2 Sekunden warten

   // Auto Ampel auf Rot+Orange stellen

   digitalWrite(LED\_AUTO\_ROT, HIGH);

   digitalWrite(LED\_AUTO\_GELB, HIGH);

   digitalWrite(LED\_AUTO\_GRUEN, LOW);

   delay(2000);                        // 2 Sekunden warten

   // Auto Ampel auf Grün stellen

   digitalWrite(LED\_AUTO\_ROT, LOW);

   digitalWrite(LED\_AUTO\_GELB, LOW);

   digitalWrite(LED\_AUTO\_GRUEN, HIGH);

   delay(10000);                       // 10 Sekunden warten

 }


}

# Bauanleitung

## Schema

Auf dem folgenden Schema siehst du, wie die verschiedenen Teile miteinander über Kabel verbunden werden müssen.

Achtung: Plus (+) und Minus (-) immer beachten!



## Arbeitsschritte

|  |  |
| --- | --- |
|  | Zersäge die Holzleiste in zwei gleich lange Stücke und schleife alle Kanten. Schleife auch die Kanten des Grundbretts. |
|  | Zeichne auf den Holzleisten an, wo du Löcher für die LEDs bohren willst.  Miss den Durchmesser einer LED und suche den passenden Bohrer. Bohre die Löcher (insgesamt 6 Löcher). |
|  | Zeichne auf einer Leiste weitere Löcher für den Drucktaster auf und bohre diese ebenfalls. |
|  | Die Leiste für die Fussgängerampel sollte nun etwa so aussehen.  Die Leiste für die Autoampel hat nur Löcher für die LEDs. |
|  | Lege die LEDs in die Löcher. Unterlege die Leiste mit der Grundplatte, damit die LEDs vorne ein bisschen rausragen. Zuoberst kommt Rot, dann Gelb, dann Grün. Das kürzere Bein (-) muss bei allen LEDs auf der rechten Seite liegen. Klebe die LEDs von hinten mit Heissleim ein. Wiederhole das für die zweite Ampel. |
|  | Knicke die kürzeren Beine (rechts) nach unten und verlöte alle drei Beine mit einem Draht wie auf dem Bild.  Wiederhole das für die zweite Ampel. |
|  | Kürze die Kabel etwa so wie auf dem Bild und ziehe sie durch die richtigen Löcher. Schaue genau, welche Kabel einen Stecker haben.  Die drei schwarzen Kabel werden am Ende zusammengelötet und bilden den Minuspol.  Löte nun am Taster die Kabel an wie auf dem Bild.  Die eingebaute LED braucht einen Vorwiderstand. Löte diesen direkt am Taster an, dort wo der Rote Punkt NICHT ist.  Klebe den Taster vorsichtig mit Heissleim fest. |
|  | Löte ein weiteres langes schwarzes Kabel (für die Autoampel) an den Minuspol und überziehe alle mit einem dicken Schrumpfschlauch.  Nun werden die schwarzen Kabel an den Minuspol der LEDs gelötet.  Anschliessend den Schrumpfschlauch überziehen. |
|  | Löte einen 220 Ohm Vorwiderstand an das längere Bein von jeder der sechs LEDs beider Ampeln.  Bereite drei kurze und drei lange Kabel mit einem Stecker vor zum Anschluss an die LEDs. Stülpe je einen Schrumpfschlauch über die Kabel. Das andere Ende des Widerstands verlötest du mit je einem Kabel. Die kurzen Kabel kommen an die Fussgängerampel, die langen an die Autoampel.  Anschliessend die Schrumpfschläuche so weit wie möglich bis über die Widerstände ziehen. |
| Arduino Pro Mini 328 - 5V / 16MHz - RobotShop | Überziehe das Batteriekabel mit zwei Schrumpfschläuchen.  Löte nun beim Arduino das Batteriekabel an. Plus (rot) kommt an RAW, Minus (schwarz) and GND.  Stecke die 9-polige Steckerleiste von oben in die Löcher 9, 8, 7, 6, 5, 4, 3, 2, GND und verlöte sie von unten.  Schliesse nun alle Stecker in der richtigen Reihenfolge am Arduino an.  Beachte genau das Schema auf Seite 15!  Schliesse die Batterie an und teste, ob alles richtig funktioniert. Am Anfang müssen alle LEDs kurz aufleuchten, auch der Taster. Falls nicht alle LEDs leuchten, musst du nochmals alles kontrollieren. |
|  | Wenn alles richtig funktioniert, schrumpfe alle Schrumpfschläuche mit dem Heissluftföhn fest.  Befestige die Kabel mit Heissleim an der Ampel.  Klebe auch den Arduino an der Fussgängerampel fest wie auf dem Bild.  Mit einem zusätzlichen Kabelbinder kannst du das Batteriekabel mit den anderen Kabeln zusammenbinden. |
|  | Leime beide Ampeln auf die Grundplatte.  Fertig! |