**再次加工的阿木资金E 真资金 全资金**

<http://www.55188.com/viewthread.php?tid=8033196&highlight=%D7%CA%BD%F0>

**CAPITAL，返回流通盘大小，单位为手。对于A股得到流通A股，B股得到B股总股本，指数为0 注意：该函数返回常数 基本财务数据函数。 用法: FINANCE(7)取得基本财务数据: 流通A股 注意：该函数返回常数。**

L2\_VOL(N,M)  成交量分档 按:N(0--3):(超大/大/中/小),M(0--3):买入/卖出/主买/主卖四类  
L2\_AMO(N,M) 成交额分档  按:N(0--3):(超大/大/中/小),M(0--3):买入/卖出/主买/主卖四类  
LARGETRDINNUM   逐笔买入大单成交单数,相当于L2\_VOLNUM(0,0),  
L2\_VOLNUM(N,M) 单数分档  按:N(0--1):(超大+大)/(中+小),M(0--1):买/卖二类

 DMA(X，A)　 -- dynamic move average

求X的动态移动平均。A 为动态因子

算法：　若Y=DMA(X，A)则 Y=A\*X+(1-A)\*Y'，其中Y'表示上一周期Y值，A必须小于1。  
例如：　DMA(CLOSE，VOL/CAPITAL)　表示求以换手率作平滑因子的平均价。  
直观理解， 换手率越大，该收盘价对均价影响越大。 这个很好。

{经过大马路123加工过的阿木**资金**E【阿木**资金**E加】，通达信副图}  
A:=LARGEINTRDVOL\*10000/FINANCE(7);  
B:=LARGEOUTTRDVOL\*10000/FINANCE(7);  
A1:=SUM(A,3);  
B1:=SUM(B,3);  
A2:DMA(A1,20);  
B2:DMA(B1,20);  
{DRAWBAND(A2,RGB(255,0,0),B2,RGB(0,30,200));}  
  
H1:HHV(A2,8),COLORMAGENTA;{H1紫色线}  
STICKLINE(A2-H1<0,H1,A2,0,-1);{绿色虚柱线}  
H2:CONST(REF(H1,5)),COLORWHITE,DOTLINE;{前5日H1值横虚线}  
H4:CONST(REF(H1,20)),COLORLIGRAY,DOTLINE;  
DRAWBAND(A2,65,H2,RGB(30,0,150));  
DRAWBAND(A2,255,B2,RGB(0,210,250));  
  
换手率:VOL/CAPITAL\*100,COLORWHITE,NODRAW;  
预换手:IF(CURRBARSCOUNT=1 AND PERIOD=5,换手率\*240/FROMOPEN,DRAWNULL),COLORYELLOW,NODRAW;  
量比:DYNAINFO(17),NODRAW,COLORWHITE;  
日量比:V/REF(MA(V,5),1),NODRAW,COLORWHITE;  
STICKLINE(C>O,0,换手率,3,1)COLORRED;  
STICKLINE(C<O,0,换手率,3,1)COLORGREEN;  
STICKLINE(C=O,0,换手率,3,1)COLORWHITE;  
  
STICKLINE(预换手,0,预换手,3,1)COLORYELLOW{,DOTLINE};  
  
机构:(L2\_VOL(0,0) - L2\_VOL(0,1))\*10000/FINANCE(7),NODRAW,COLORYELLOW;  
大户:(L2\_VOL(1,0) - L2\_VOL(1,1))\*10000/FINANCE(7),NODRAW,COLORRED;  
中户:(L2\_VOL(2,0) - L2\_VOL(2,1))\*10000/FINANCE(7),NODRAW,COLORMAGENTA;  
散户:(L2\_VOL(3,0) - L2\_VOL(3,1))\*10000/FINANCE(7),NODRAW,COLORGRAY;  
主力:机构+大户,NODRAW,COLORYELLOW;  
  
三日主力:SUM(主力,3),COLORYELLOW,LINETHICK3;  
五日主力:SUM(主力,5),COLORRED;  
十日主力:SUM(主力,10),COLORMAGENTA;  
廿日主力:SUM(主力,20),COLORWHITE;  
  
STICKLINE(主力>0,0,主力,2.5,1)COLORYELLOW;  
STICKLINE(主力<0,0,主力,2.5,1)COLORLIBLUE;  
{K:=机构+大户+中户+散户;}  
  
STICKLINE(机构>0,0,2\*(ABS(散户)+ABS(中户)+ABS(大户)+ABS(机构)),1.5,0),COLORYELLOW;  
STICKLINE(机构<0,0,2\*(ABS(散户)+ABS(中户)+ABS(大户)+ABS(机构)),1.5,0),COLORBLUE;  
STICKLINE(大户>0,0,2\*(ABS(散户)+ABS(中户)+ABS(大户)),1.5,0),COLORRED;  
STICKLINE(大户<0,0,2\*(ABS(散户)+ABS(中户)+ABS(大户)),1.5,0),COLORGREEN;  
STICKLINE(中户>0,0,2\*(ABS(散户)+ABS(中户)),1.5,0),COLORMAGENTA;  
STICKLINE(中户<0,0,2\*(ABS(散户)+ABS(中户)),1.5,0),COLORLIGREEN;  
STICKLINE(散户>0,0,2\*散户,1.5,0),COLORGRAY;  
STICKLINE(散户<0,0,2\*ABS(散户),1.5,0),COLORBLUE;  
  
DRAWICON(CROSS(EMA(C,13)-EMA(C,34)>=EMA(EMA(C,13)-EMA(C,34),12),0.5),A2,34);  
DRAWICON(CROSS(EMA(EMA(C,13)-EMA(C,34),12)>EMA(C,13)-EMA(C,34),0.5),A2,35);  
  
DRAWICON(H2<H4 AND CROSS(A2,H2) AND A2>B2,H2,23);  
DRAWICON(H2>H4 AND CROSS(A2,H4) AND A2>B2,H4,23);  
DRAWICON(FILTER(A2=HHV(A2,23),1),A2,1);  
DRAWICON(FILTER(B2=LLV(B2,23),2),B2,2);

图示说明(大马路123）：  
一.实体柱状图：每天各类**资金**仓位变化情况，从上到下为机构、大户、中户、散户。机构买入\_黄色、机构卖出\_蓝色，大户买入\_红色、大户卖出\_绿色，中户买入\_浅红、中户卖出\_浅绿，散户买入\_深灰、散户卖出\_蓝色；  
二.空心柱状图：零轴上方黄色\_主力买入、零轴下方蓝色\_主力卖出；红色空心\_阳线换手率，绿色空心\_阴线换手率，白色空心\_平价换手率，黄色空心\_预换手率；  
三.彩色条带：为3天主力累计和的20天的动态移动平均(A2\_买入，B2\_卖出），红色为A2>B2(净买)，浅蓝为B2>A2(净卖)；  
四.小图标：向上红箭头\_主力计算(A2)23天的最高值，向下绿箭头\_(A2)23天最低值；白底红十字\_主力20天动态移动平均主力净买入；黄底向上大于号\_收盘价计算上穿，浅蓝底向下小于号\_收盘价计算下穿；  
五.紫色折线为H1（8日内A2最高值），绿色虚柱线为H1>A2时，H1与A2的连线；白色横虚线为前5日的H1值，蓝色带为A2与此值之间的色带；淡灰色横虚线为H4（前20天的H1值），不是经常能显示；  
六.曲线：黄色粗线为3天主力和，红色线为5天主力和，浅红色为10天主力和，白色线为20天主力和。  
  
公式说明(阿木林原说明)：  
一、本公式是由主力**资金**的净流入或净流出纯加减而来，是根据主力**资金**的实际进出和进出的量来判别的，不是根据大盘或股价的涨跌或什么均线或其他指标来判断的；  
二、本人一贯对通达信软件上面反映的主力**资金**净流入（主动）比较感冒，故而主力**资金**净流入指标原理和判别公式用的是：主力**资金**净流入（包括负流入——即净流出，下同）=主力**资金**主动流入+主力**资金**被动流入；  
三、公式研判的说明：  
（1）.主力**资金**流入（或流出）带：1.**资金**带的粗细反映主力**资金**的流入或流出的多少；2.蓝色带：反映主力**资金**的净流出和股价下跌或回调的趋势，红色带：反映主力**资金**的净流入和股价上行的趋势；  
    3.坐标反映成交量的增减，特别是主力**资金**净流入或净流出的增减；  
（2）成交量柱体，分别由颜色来反映参与者的构成以及是买入或是卖出的操盘行为：1.机构买入用红色反映，卖出行为用深蓝反映；2.大户（私募）买入行为为洋红色，卖出行为为绿色；3.中户买入用淡红，卖出用淡绿；4，散户买入用淡灰，卖出用蓝色。  
     成交量柱体的黄框，代表主力**资金**的绝对净流入量；成交量柱体的篮框，代表主力**资金**的绝对净流出量。  
    
       设计本公式的想法是，用一个附图来体现主力**资金**运作的整个过程和股价涨跌趋势之间的关系，细细体验一下主力**资金**进出场的拐点以及股价的拐点关系，包括吸筹、吸盘、拉升、打压、出货的整个运作过程。{原文链接：[url]http://www.55188.com/thread-5995179-1-1.html