**抄底---突破箱体(主图叠加、源码、说明、无未来、通达信）**

http://www2.55188.com/viewthread.php?tid=5080464&highlight=

思路决定胜败  
可以叠加在任意主图里  
这个指标非常简单 就几句 为我原创 我自己也一直在使用 3年前我在 地主会 的专贴里有发布过  
现重新在指标区发布   
目前很多箱体的设计 画法 都是以前期高点 大阳 收盘价划线 所谓突破前高  
这个箱体的设计不一样 以大阴开盘价划线 那么主力所有的洗盘 挖坑 上升前的下蹲 等动作  
都能监控到 股价不回来就算了 一旦回来 必然突破箱顶   
箱体的研究源于抄底 呵呵 我认为短线暴利  
一个就是抄底 一个就是追强  
那么研究抄底 你首先要解决那里是底? 总跌幅20%?30%?50%?缩量? 放量?怎么定义这些?  
我的研究成果就是箱体 我不管他怎么跌 只要是 涨停板 突破就认为它是一个短底   
你也可以把它定义为其它大阳

{箱体}

DF:=(C-REF(C,1))/REF(C,1)\*100<-5;

AA:=BARSLAST(DF);

突破箱体:=CROSS(C,REF(C,AA));

箱顶:DRAWLINE(DF,O,REF(DF,1),REF(O,1),1),COLORMAGENTA LINETHICK2;

箱底:LLV(MIN(L,REF(L,AA)),AA),COLORCYAN,LINETHICK2;

DRAWTEXT(ISLASTBAR,箱顶,' 箱顶');

{如果不喜欢输出 箱底 可以在箱底:= 冒号后插入等号}

选股指标很简单的关键有3点  
1.突破箱体K线的涨幅  
2.回调几天后在突破箱体  
3.在箱体内横盘在突破  
4.做为买点时 注意假突破  
要确定这些参数你需要看历史做统计啊

http://www.55188.com/blog.php?tid=5080464&page=10

突破箱顶选股公式源码  
DF:=(C-REF(C,1))/REF(C,1)\*100<-5;  
AA:=BARSLAST(DF);  
突破箱体:=CROSS(C,REF(C,AA));  
箱顶:=DRAWLINE(DF,O,REF(DF,1),REF(O,1),1);  
箱底:=LLV(MIN(L,REF(L,AA)),AA);  
XG:CROSS(C,箱顶);  
  
回调箱顶选股源码  
DF:=(C-REF(C,1))/REF(C,1)\*100<-5;  
AA:=BARSLAST(DF);  
突破箱体:=CROSS(C,REF(C,AA));  
箱顶:=DRAWLINE(DF,O,REF(DF,1),REF(O,1),1);  
箱底:=LLV(MIN(L,REF(L,AA)),AA);  
XG:CROSS(箱顶,L);