

****

**微机接口课程设计报告**

**彩灯控制器**

**院（系）： 计算机学院**

**专业班级： 计算机1302**

**学 号： 3130602050**

**学生姓名： 曾 彪**

# 一、实验要求


有8盏彩灯，4个开关作为输入，控制4种闪烁方式。当没有开关闭合时，4种花型依次轮流闪烁，每种花型闪烁时间持续2分钟，每盏灯点亮的时间为1秒。只有某一个开关闭合时，对应的花型连续不断的闪烁。设计实现该功能的电路，并编写完整的代码。

# 二、实验原理


## 2.1 设计思路、原理

使用8254每秒输出一个脉冲，这个输出的脉冲接到8259中断的一个IRQ，使得每秒钟产生一个中断，在中断服务程序里，先读取此时的开关状态，根据开关的不同状态执行不同的操作，8个小灯的亮灭可以通过8255的A端口输出的数据来控制，其中每一位控制一个小灯，8255的B端口接开关，开关的状态通过B端口读入， 中断服务程序里判断开关的值，如果是只有一个开关的值是1，则通过查表输出一个这种样式的一个键码值，然后下一次就查表的位置往后移一个。如果开关没有键的值是1，则各种样式交替闪烁，在这种情况下，有一个变量1记录当前应该闪烁的是哪种样式，还有一个变量2用来记录当前样式闪烁了的次数，当当前样式闪烁了120次之后，变量2的值清零，变量1的值往后挪一个，这样就可以控制彩灯根据开关的不同状态闪烁了。

## 2.2 硬件原理图



如上图，左边为8255芯片，芯片的A端口接8个小灯，从A端口送出数据则点亮对应的小灯，通过8255的B端口可以读开关的状态，S1控制闪烁的暂停与开始，S4~S8控制5个不同的闪烁样式。



如上图，最左边的是8254芯片，通过计数器0和计数器1的组合可以产生1HZ的脉冲，脉冲的输出接8259的IRQ0，图中中间的是8259芯片，右边的是8086

# 三、软件模块

## 1.主程序里的相关初始化

初始化完毕后通过一条跳转到原地的指令JMP $来等待中断信号的到来一旦有中断请求信号，并且允许中断，则转去执行中断服务程序，执行结束后又返回主程序等待中断请求。



## 2.中断服务程序

在中断服务程序中，先读取开关的状态，如果开关S1是1，则直接退出中断程序，保持8个小灯的状态不变，以此表示暂停，S1的值为0则表示开始，则继续判断其他开关的状态，如果只有一个开关的值是1，则跳转到对应的样式的代码部分，否则根据变量SwitchCount的值跳转，跳转处的这一部分代码会再次判断开关的值，如果是确实是由只有一个开关为1跳转到此处的，则直接查表，把数据通过A端口送到小灯，否则把变量ShanShuoCount的值加1，表示又闪了1秒，如果ShanshuoCount的值到120了，则清零，并把SwitchCount的值往后挪一个，然后查表、输出。最后发送EOI命令，结束本次中断。



# 四、调试过程

## 1.硬件端口、线的检查

在接线前，要对每根线进行测试，看线有没有问题，可以把线的一端接小灯，另一端接地，如果小灯亮了，说明线没有问题。

在调试的时候也要确保端口是能用的，否则整个程序也不能工作，可以把端口与八段数码管端口相连，送入一个数据，看数码管的值有没有变化，从而检查端口有没有问题。

## 2.8254的调试

8254的调试可以把脉冲输出out1接到一个小灯上，如果小灯能够每秒钟闪一下，则表示8254的初始化和硬件都没有问题。

## 3.中断的调试

在调试中断时，可以把中断模块8259的IRQ0接到实验箱左下角的脉冲信号那里，通过手动按键可以产生一个脉冲。调试时可以在中断服务程序的开始部分设一个断点，当程序在主程序里等待中断时，全速运行的同时按下按键，产生一个脉冲， 如果程序执行到中断程序里停下来了，则说明能进入中断，进入中断后，同样可以通过带断点全速，看程序的执行结果是不是和期望的一样。

## 4.程序的最后调试

当程序编写好了，各个部分也没问题了之后，还要进行总体的测试，看彩灯的闪烁有没有受开关的控制，闪烁的稳定稳定等，如果有问题，还要重新对代码进行修改，优化。

# 五、实验体会

在这次课程设计中，我充分地体会到了计算机世界的奇妙之处，通过对各个部件的巧妙结合运用，最终组合成了彩灯控制器。

最初在选这个题目的时候犹豫了很久，最终选择了做彩灯的，因为相对而言对这个题目比较感兴趣，这样做起实验来也会比较有动力，第一节课的时候首先画了一下原理图，然后就是写代码了，这个实验比较简单，不过也要充分考虑到各种情况，好在我的硬件比较给力，都没什么问题，调试起来也比较顺利，不会的地方也可以问问老师，问题就迎刃而解了。这个实验用到的基本上都是平时实验的知识，再加上一些代码的编写，只要平时实验认真做，也就不难了。

在程序的设计过程中，同时也能够不断的学习和进步，我相信这将为我今后的学习工作打下坚实的基础，这对我来说也是一次丰富的收获。

# 六、程序清单

.486p

stackp equ 1400h

CODE SEGMENT USE16

ASSUME DS:CODE,ES:CODE,CS:CODE

ORG 03000H

BEG: JMP START

IFSWITCH DB 0 ;是否是交替模式，不可改

SHANSHUOCOUNT DB 0 ;轮流闪烁时间计数0-120，不可改

SWITCHCOUNT DB 1 ;交替模式中当前的样式，不可改

ORDERNO DB 0 ;每各样式中的当前次序，不可改

ShanShuoLimit DB 120 ;交替闪烁的情况下每种样式最多闪烁次数，可改

;8255片选连CS-4时：

PORT1 EQU 203H ;A

PORT2 EQU 207H ;B

PORT3 EQU 20BH ;C

PORT4 EQU 20FH ;CTRL

;

PORT8254A EQU 300H

PORT8254B EQU 304H

PORT8254C EQU 308H

PORT8254D EQU 30CH

WAY1 DB 0,18H,24H,42H,81H ;样式1 ，18H即00011000B,1表示对应的二极管点亮 00011000->00100100->01000010->10000001->00011000....

WAY2 DB 0,81H,42H,24H,18H,24H,42H ;样式2 10000001->01000010->00100100->00011000->00100100->01000010->10000001...

WAY3 DB 0,00H,80H,0C0H,0E0H,0F0H,0F8H,0FCH,0FEH,0FFH ;样式3 00000000->10000000->11000000->11100000->11110000->11111000->11111100->11111110->11111111->00000000...

WAY4 DB 0,01H,02H,04H,08H,10H,20H,40H,80H,40H,20H,10H,08H,04H,02H ;样式4 00000001->00000010->00000100->00001000->00010000->00100000->01000000->10000000->01000000->00100000->00010000->00001000->00000100->00000010->00000001...

WAY5 DB 0,5AH,0A5H ;样式5 01011010->10100101->01011010....

WayCount DB 5 ;样式的数量

PORTJI EQU 3A8H ;8259A奇地址

PORTOU EQU 3A0H ;8259A偶地址

START:

CLI ;关中断

mov ax,CODE

mov ds,ax ;装载数据段

MOV AX,0

MOV ES,AX ;附加段，中断向量表段基地址0000H

mov ss,ax

mov sp,stackp ;设置堆栈段

MOV AL,10000010B

MOV DX,PORT4 ;8255初始化 A端口输入，B端口输出

OUT DX,AL

MOV BX,40H\*4

MOV AX,OFFSET INTPROC

MOV ES:[BX],AX ;设置中断向量

MOV AX,SEG INTPROC

MOV ES:[BX+2],AX

MOV AL,00010011B

MOV DX,PORTOU ;ICW1

OUT DX,AL

MOV AL,01000000B

MOV DX,PORTJI ;ICW2

OUT DX,AL

MOV AL,00000001B ;ICW4

OUT DX,AL

MOV AL,11111110B ;中断屏蔽字,OCW1

OUT DX,AL

; clk0接47kHz时每1秒产生一个脉冲

;计数器0初始化：

MOV AL,37H

MOV DX,PORT8254D

OUT DX,AL

MOV AX,470H

MOV DX,PORT8254A

OUT DX,AL

MOV AL,AH

OUT DX,AL

;计数器1初始化：

MOV AL,77H

MOV DX,PORT8254D

OUT DX,AL

MOV AX,100H

MOV DX,PORT8254B

OUT DX,AL

MOV AL,AH

OUT DX,AL

STI

WT:

JMP WT

INTPROC PROC

PUSH DX

PUSH AX

PUSH BX

STI

MOV DX,PORT2 ;读开关状态

IN AL,DX

TEST AL,80H ;暂停闪烁的开关，实验开始前就把这个所对应的键弹起（值为1）否则不会闪烁，0的时候（按下）暂停

JNZ EXIT2

AND AL,1FH ;无视剩余的3个开关的状态

CMP AL,01H

JE CASE1

CMP AL,02H

JE CASE2 ;后五个开关如同时只有一个开关弹起则按相应的样式闪烁（实验设备上是按下是0，弹起是1）

CMP AL,04H ;其余情况交替闪烁，每种闪120下

JE CASE3

CMP AL,08H

JE CASE4

CMP AL,10H

JE CASE5

;CASE0，交替闪烁的情况:

CMP IFSWITCH,0 ;IFSWTICH=1表示当前正在交替闪烁，

JNE NEXT0 ;IFSWTICH=0表示刚从某种样式单独闪烁的状态切换到交替闪烁的状态（比如说刚才是只有一个开关弹起，现在没有开关弹起）

MOV IFSWITCH,1 通过IFSWITCH的值是0还是1可以知道是不是交替刚开始，如果是0，表示交替状态刚开始，需要对下面的三个变量初始化

MOV SWITCHCOUNT,1 ;先从第一种样式开始闪烁

MOV SHANSHUOCOUNT,0 ;当前样式闪烁次数初始化

MOV ORDERNO,0

NEXT0:CMP SWITCHCOUNT,01H

JE CASE1

CMP SWITCHCOUNT,02H

JE CASE2 ;切到相应的样式

CMP SWITCHCOUNT,03H

JE CASE3

CMP SWITCHCOUNT,04H

JE CASE4

CMP SWITCHCOUNT,05H

JE CASE5

CASE1:

MOV DL,01H ;对应的按键值

MOV DH,4 ;样式1每个循环中包含的键码数

LEA BX,WAY1

CALL CasePro

JMP EXIT1

CASE2:

MOV DL,02H ;对应的按键值

MOV DH,6 ;样式2每个循环中包含的键码数

LEA BX,WAY2

CALL CasePro

JMP EXIT1

CASE3:

MOV DL,04H ;对应的按键值

MOV DH,9 ;样式3每个循环中包含的键码数

LEA BX,WAY3

CALL CasePro

JMP EXIT1

CASE4:

MOV DL,08H ;对应的按键值

MOV DH,14 ;样式4每个循环中包含的键码数

LEA BX,WAY4

CALL CasePro

JMP EXIT1

CASE5:

MOV DL,10H ;对应的按键值

MOV DH,12 ;样式5每个循环中包含的键码数

LEA BX,WAY5

CALL CasePro

JMP EXIT1

EXIT1:

MOV DX,PORT1

OUT DX,AL ;从端口A送出数据，让小灯们亮

EXIT2:

CLI

MOV DX,PORTOU

MOV AL,20H ;发送EOI命令

OUT DX,AL

POP BX

POP AX

POP DX

IRET

INTPROC ENDP

CasePro PROC

;参数说明：

;AL：当前按键值

;DL：当前样式对应的按键值

;DH：当前样式每个循环中包含的键码数

;BX：所查表格的首地址

;SHANSHUOCOUNT：当前样式闪烁次数

;SWITCHCOUNT ：当前样式序号

;ORDERNO ：当前样式的键码序号

;ShanShuoLimit ：交替闪烁的情况下每种样式最多闪烁次数

;WayCount :样式的数量

CMP AL,DL ;再次确认是多样式交替闪还是单样式，AL=1说明是单样式

JE NEXT11

INC SHANSHUOCOUNT ;闪烁次数+1

MOV AH, ShanShuoLimit

CMP SHANSHUOCOUNT,AH ;ShanShuoLimit 120是交替闪烁的情况下每种样式最多闪烁次数

JNE NEXT12 ;不足120次

MOV SHANSHUOCOUNT,0

INC SWITCHCOUNT ;当前样式已经闪了120次，准备切到下一样式

MOV AH, WayCount

CMP SWITCHCOUNT,AH ;WayCount 5是样式的数量

JBE NEXT12

MOV SWITCHCOUNT,1 ;转样式1

JMP NEXT12

NEXT11:

MOV IFSWITCH,0

NEXT12:

INC ORDERNO

CMP ORDERNO,DH

JNG NEXT13

MOV ORDERNO,1

NEXT13:

;LEA BX,WAY1

MOV AL,ORDERNO

XLAT

NOT AL ;对al每一位取反，因为二极管是0点亮

RET

CasePro ENDP

CODE ENDS

END beg