Left Factored Grammar

-----------------------------

1. program → **program id (** identifier\_list **);** program1

1.1 program1 → declarations program1\_1

**|** subprogram\_declarations compound\_statement **.**

**|** compound\_statement **.**

1.1.1 program1\_1 → subprogram\_declarations compound\_statement **. |** compound\_statement **.**

2. identifier\_list → **id** identifier\_list1

2.1 identifier\_list1 → **, id** identifier\_list1 **| epsilon**

3. declarations → **var id :** type **;** declarations1

3.1 declarations1 → **var id :** type **;** declarations1 | **epsilon**

4. type → standard\_type | **array [ num .. num ] of** standard\_type

5. standard\_type → **integer | real**

6. subprogram\_declarations → subprogram\_declaration **;** subprogram\_declarations1

6.1 subprogram\_declarations1 → subprogram\_declaration **;** subprogram\_declarations1 | **epsilon**

7. subprogram\_declaration → subprogram\_head subprogram\_declaration1

7.1 subprogram\_declaration1 →declarations subprogram\_declaration1\_1

| subprogram\_declarations compound\_statement

| compound\_statement

7.1.1 subprogram\_declaration1\_1 → subprogram\_declarations compound\_statement | compound\_statement

8. subprogram\_head → **function id** subprogram\_head1

8.1 subprogram\_head1 → **(** parameter\_list **)** **:** standard\_type **; |** **:** standard\_type **;**

9. parameter\_list → **id** : type parameter\_list1

9.1 parameter\_list1 → **; id** **:** type parameter\_list1 | **epsilon**

10. compound\_statement →**begin** compound\_statement1

10.1 compound\_statement1 → statement\_list **end | end**

11. statement\_list → statement statement\_list1

11.1 statement\_list1 = **;** statement statement\_list1 | **epsilon**

12. statement → variable **assignop** expression

| compound\_statement

| **if** expression **then** statement statement1

| **while** expression **do** statement

12.1 statement1 →**else** statement | **epsilon**

13. variable → **id** variable1

13.1 variable1 → **[** expression **]**  | **epsilon**

14. expression\_list →expression expression\_list1

14.1 expression\_list1 → **,** expression | **epsilon**

15. expression → simple\_expression expression1

15.1 expression1 →**relop** simple\_expression | **epsilon**

16. simple\_expression → term simple\_expression1 | sign term simple\_expression1

16.1 simple\_expression1 → **addop** term simple\_expression1 | **epsilon**

17. term → factor term1

17.1 term1 → **multop** factor term1 | **epsilon**

18. factor → **id** factor1 **| num** | **(** expression **)** | **not** factor

18.1 factor1 → **(** expression\_list **) |** variable1

19. sign → **+** | **-**