Switching Gradle build scripts to a modern plugins DSL. Also moving common parts to the root build script.

Author: jacekbilski

app/build.gradle

@@ -1,10 +1,6 @@
-plugins {
-  id "org.springframework.boot"
-}
+apply plugin: "org.springframework.boot"
 
 group = "com.webcalc"
-version = "0.0.1-SNAPSHOT"
-sourceCompatibility = 11
 
 dependencies {
   implementation(project(":calculator"))
@@ -13,18 +9,11 @@ dependencies {
   implementation("org.springframework.boot:spring-boot-starter-security")
   testImplementation("org.springframework.boot:spring-boot-starter-test") {
     exclude group: "junit", module: "junit"
+    exclude group: "org.junit.vintage", module: "junit-vintage-engine"
   }
   testImplementation("io.rest-assured:rest-assured")
   testImplementation("org.junit.jupiter:junit-jupiter-api")
   testImplementation("org.junit.jupiter:junit-jupiter-params")
   testRuntime("org.junit.jupiter:junit-jupiter-engine")
   testImplementation("org.assertj:assertj-core")
 }
-
-test {
-  useJUnitPlatform()
-
-  testLogging {
-    events "passed", "skipped", "failed"
-  }
-}

billing/build.gradle

@@ -1,24 +1,7 @@
-version = "0.0.1-SNAPSHOT"
-sourceCompatibility = 11
-
-dependencyManagement {
-  imports {
-    mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
-  }
-}
-
 dependencies {
   implementation(project(":calculator"))
   testImplementation("org.junit.jupiter:junit-jupiter-api")
   testImplementation("org.junit.jupiter:junit-jupiter-params")
   testRuntime("org.junit.jupiter:junit-jupiter-engine")
   testImplementation("org.assertj:assertj-core")
 }
-
-test {
-  useJUnitPlatform()
-
-  testLogging {
-    events "passed", "skipped", "failed"
-  }
-}

build.gradle

@@ -1,20 +1,31 @@
-buildscript {
-  ext {
-    springBootVersion = "2.1.4.RELEASE"
-  }
-  repositories {
-    mavenCentral()
-  }
-  dependencies {
-    classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
-  }
+plugins {
+  id "java"
+  id "io.spring.dependency-management" version "1.0.9.RELEASE"
+  id 'org.springframework.boot' version '2.3.1.RELEASE' apply false
 }
 
 allprojects {
   apply plugin: "java"
-  apply plugin: "io.spring.dependency-management"
+  apply plugin: 'io.spring.dependency-management'
+
+  version = "0.0.1-SNAPSHOT"
+  sourceCompatibility = 11
+
+  dependencyManagement {
+    imports {
+      mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
+    }
+  }
 
   repositories {
     mavenCentral()
   }
+
+  test {
+    useJUnitPlatform()
+
+    testLogging {
+      events "passed", "skipped", "failed"
+    }
+  }
 }

calculator/build.gradle

@@ -1,23 +1,6 @@
-version = "0.0.1-SNAPSHOT"
-sourceCompatibility = 11
-
-dependencyManagement {
-  imports {
-    mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
-  }
-}
-
 dependencies {
   testImplementation("org.junit.jupiter:junit-jupiter-api")
   testImplementation("org.junit.jupiter:junit-jupiter-params")
   testRuntime("org.junit.jupiter:junit-jupiter-engine")
   testImplementation("org.assertj:assertj-core")
 }
-
-test {
-  useJUnitPlatform()
-
-  testLogging {
-    events "passed", "skipped", "failed"
-  }
-}