
OFAC #1B解決方案說明

因應Treliant’s OFAC Validation Report Observation #1所指出之問題，為了讓日後可以將OFAC更新之SDN、Consolidated Sanction List中名稱與A.K.A等超過33個字元註1(因為根據SWIFT組織之電文規範，每行電文的長度為35字元，因此加上“1/”的緣故，才會設定為超過33個字元)之的名稱，透過定時自OFAC網站註2自動下載、產生符合PRIME導入之XML格式註3的IWL(Internal Watch List)名單、將名單導入PRIME OFAC Reporter並重新編譯File Image，經過前述的程序，便可將SDN、Consolidated Sanction List中之超過33個字的名稱轉換成“1/名稱”，當電文中包含”1/”時，便可以與IWL中的名單進行比對，以便可以藉此比對與命中包含制裁名稱的電文。(目前經過測試，皆可以將之前PRIME OFAC Reporter無法比對出包含”1/”的電文掃描出來)

上述所說明之”自OFAC網站自動下載”、”產生符合PRIME導入之XML格式的IWL名單”、”將名單導入PRIME OFAC Reporter並重新編譯File Image”等程序，除前述最後之程序係按照目前既有的程序進行外，前述兩項程序係本行根據需求而撰寫程序或程序，底下將對此做一說明。



1. 此下載程序係透過Windows標準之FTP指令設定，所有之下載程序在SDN.FTP的檔案中設定。(下載程序可參考後續說明)
2. 此產生程序係利用Excel VBA註4撰寫而成，因此需要安裝Excel檔案才能執行此一程序(程式邏輯說明請參考後續說明)。因為係透過auto\_open()方式及Application.Quit方式來自動啟動程式與自動結束程式，故不需人工啟動作業。
3. 此部分之程序將按EDC既有的程序進行，不在本份文件說明。

* “自OFAC網站自動下載程序”說明

此下載與處理程序將可分為兩大部分：

1. 藉由定時方式自動啟動下載執行程序(Procedure)

透過Windows標準之schtasks指令(指令使用說明，請自行參閱Microsoft網站說明註5不再贅述)，目前設定內容為：

Schtasks /create /tn “OFAC1B” /tr C:\Users\0049XX\Desktop\OFAC#1B\auto1.bat /sc DAILY /st 20:00

也就是說，每天晚上八點執行auto1.bat的程序

1. 藉由定時方式自動啟動下載執行程序(Procedure)

在auto1.bat中，有兩個步驟：

* + 先切換到準備工作的目錄
  + 執行auto.bat並將執行狀況導出至log.txt中，以便紀錄執行的結果。註6

在auto.bat中，有幾個步驟：

* + 建立準備要自OFAC網站下載名單的目錄，如果目錄既存的話，則刪除該目錄中所有的檔案(這是避免誤用到舊的名單資料)。
  + 在工作目錄中，刪除已將下載的名單(這是避免誤用到舊的名單資料)。註7
  + 檢查SDN.FTP是否存在(因為這個檔案描述所有FTP的程序註8)，如果存在則進行自OFAC網站下載名單的作業。
  + 檢查下載檔案是否完整(必須是六個檔案)，如果不完整的話，則停止後續產生IWL的程序註9。

如果一切執行順利，將下載的名單資料(\*.FF)與產生之XML格式的IWL檔案搬移至名單下載目錄中。

* “產生符合PRIME導入之XML格式的IWL名單”程式說明(請參閱附件四)

此處理程序將可分為兩大部分：

1. 載入名單至Excel中

將下載完成的名單註10先載入Excel的工作表中。

* + 因為SDN.FF與CONS\_ORIM.FF之格式相同，因此採用同一個名單載入程序(LoadSDNTxt)。因為ALT.FF與CONS\_ALT.FF之格式相同，因此採用同一個名單載入(LoadALTTxt)。(程式內容與說明，請參閱附錄中程式列表)

1. 產生符合PRIME XML格式的IWL檔案

在產生IWL檔案時，將分為兩個階段：

* + 從SDN或CONS\_PRIM去尋找每一個超過33個字元的名稱，然後再連結到其AKA名稱，再產生IWL的內容。(GenerateXML程序)
  + 因為有些時候，SDN或CONS\_PRIM中的名稱並沒有超過33個字元，但是其AKA名稱卻超過33個字元，因此先透過ALT或CONS\_ALT先找尋是否有超過33個字元的AKA/FKA/NKA(以下簡稱AKA)且尚未產生IWL的名稱，如果有，則先記錄在ALT或CONS\_ALT中之Ent\_num(也就是unique record identifier/unique listing identifier)，然後再透過這個Ent\_num到SDN或CONS\_PRIM中找到對應的名稱，得到FullName後，再至ALT或CONS\_PRIM中找到所有的AKA紀錄產生IWL內容註11。(GenerateAdditionalXML程序)

註1：因為根據SWIFT組織之電文規範，每行電文的長度為35字元，因此加上”1/”的緣故，才會設定為超過33個字元

註2：OFAC網站為 ofacftp.treas.gov (存放名單之路徑為: fac\_delim與Consolidated\_Sanction list)

註3：請參考(附件一)中PRIME導入之XML格式說明

註4：Excel VBA相關使用方法，請參考<https://docs.microsoft.com/en-us/office/vba/api/overview/excel>及相關連結內容。

註5：https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/schtasks

註6：有關批次程序(Batch)(兩個批次檔如附件二所示)，都為標準之Windows基本指令，如需要了解Windows Command之內容，請自行參閱Microsoft網站說明(<https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/windows-commands>)

註7：標準來說，如果正常執行完畢時，將不會在工作目錄中留存”\*.ff“檔案，因為”\*.ff”檔案會被搬移到名單下載目錄。

註8：在SDN.FTP所描述之FTP程序，請自行參閱<https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/ftp>及相關連結之文件，不再贅述。(SDN.FTP內容可參考(附件三)內容)

註9：產生IWL的程序說明，將在底下說明。

註10：有關SDN內容，參閱OFAC官網上說明。 <https://www.treasury.gov/resource-center/sanctions/SDN-List/Pages/sdn_data.aspx>。本程式將導入Fixed-Width的名單的格式，亦即下載SDN.FF, ALT.FF, ADD.FF(因為本程式係針對超過33個字元的SDN名稱與AKA名稱產生IWL名單，故檔案尚未用到)。有關Consolidated Sanction List內容，請參考OFAC官網上說明。 <https://www.treasury.gov/resource-center/sanctions/SDN-List/Pages/consolidated.aspx>。另外，有關名單內容格式，請參考<https://www.treasury.gov/resource-center/sanctions/SDN-List/Documents/dat_spec.txt>中的說明。

註11：為何在ALT或CONS\_ALT找到資料後，又要至SDN或CONS\_PRIM去找尋對應的資料，這是因為要符合PRIME所提供IWL XML格式的緣故。

附件ㄧ：PRIME導入IWL格式說明

(請加入PRIME的說明文件)

附件二：兩個批次檔的內容

Auto1.bat內容

REM To change the working directory/folder  
cd C:\Users\009374\Desktop\OFAC#1B  
REM To execute the batch procedure and export the status to log.txt  
auto >> log.txt

Auto.bat內容

@echo off  
set myYear=%date:~10,4%  
set myMonth=%date:~4,2%  
set myDay=%date:~7,2%

set mydate=%date%  
set mytime=%time%  
echo .  
echo Starting Time is %mydate%:%mytime%  
echo .

REM To check whether the targeted foler existed or not, if it doesn't then create that folder

if not exist %myYear%%myMonth%%myDay% (  
 echo .  
 echo To Build Daily Folder to each day  
 mkdir %myYear%%myMonth%%myDay%  
 echo .  
) else (  
 echo .  
 echo To delete the contents of folder  
 del /Q .\%myYear%%myMonth%%myDay%\\*.\*  
 echo .  
)  
if exist \*.ff (  
 echo delete \*.ff  
 del /Q \*.ff  
)

REM To check SDN.FTP foler existed or not, if it doesn't then it doesn't start the FTP processes

if not exist sdn.ftp (echo SDN.FTP missed.) else (ftp -i -n -s:sdn.ftp)

REM To check all six files download properly.

set myflag=0  
dir sdn.ff  
if errorlevel 1 (  
 echo SDN.FF file not download  
 set myflag=1  
)  
dir alt.ff  
if errorlevel 1 (  
 echo ALT.FF file not download  
 set myflag=1  
)  
dir add.ff  
if errorlevel 1 (  
 echo ADD.FF file not download  
 set myflag=1  
)  
dir cons\_prim.ff  
if errorlevel 1 (  
 echo CONS\_PRIM.FF file not download  
 set myflag=1  
)  
dir cons\_alt.ff  
if errorlevel 1 (  
 echo CONS\_ALT.FF file not download  
 set myflag=1  
)  
dir cons\_add.ff  
if errorlevel 1 (  
 echo CONS\_ADD.FF file not download  
 set myflag=1  
)

REM If SDN and Consolidated List download not properly, then stop the IWL generated process.  
REM If everything goes well, then move the lists(\*.ff) and XML to another folder to keep.

if %myflag%==1 (  
 echo There is something wrong within SDN Download Process  
) else (  
 "C:\Program Files\Microsoft Office\root\Office16\excel.exe" "C:\Users\009374\Desktop\OFAC#1B\OFAC#1B.xlsm"    
 dir OFAC#1B.XML  
 if errorlevel 1 (  
  echo There is something WRONG during Generate XML process.  
 ) else (  
  move \*.ff .\%myYear%%myMonth%%myDay%  
  move OFAC#1B.XML .\%myYear%%myMonth%%myDay%\%myYear%%myMonth%%myDay%.XML  
 )  
)  
set mydate=%date%  
set mytime=%time%  
echo .  
echo Ending Time is %mydate%:%mytime%  
echo .  
@echo on

附件三：SDN.FTP內容

open  [ofacftp.treas.gov](http://ofacftp.treas.gov)   
user anonymous  
password  
lcd /D "C:\Users\009374\Desktop\OFAC#1B\"  
cd  fac\_delim  
binary  
get sdn.ff  
get add.ff  
get alt.ff  
cd ../consolidated\_list  
get cons\_prim.ff  
get cons\_add.ff  
get cons\_alt.ff  
disconnect  
quit

附件四：各個Excel VBA程序

Sub auto\_open()  
    Dim Filename As String  
    Dim GenfilePath As String  
    Dim SrcfilePath As String  
    Dim startDate As Date, endDate As Date  
          
' Define the working path

    GenfilePath = "C:\Users\009374\Desktop\OFAC#1B\"  
    SrcfilePath = "C:\Users\009374\Desktop\OFAC#1B\"  
      
    Application.ScreenUpdating = False  
    Application.DisplayAlerts = False  
      
' Load the SDN and Consolidated List into Excel

    LoadSDNTxt "SDN", SrcfilePath  
    LoadALTTxt "ALT", SrcfilePath  
    LoadSDNTxt "CONS\_PRIM", SrcfilePath  
    LoadALTTxt "CONS\_ALT", SrcfilePath

' To Generate the IWL following XML format provided by PRIME

    Filename = GenfilePath & "OFAC#1B.xml"  
    Open Filename For Output As #1  
    Print #1, "<parties>"  
      
    GenerateXML "SDN", "ALT"  
    GenerateXML "CONS\_PRIM", "CONS\_ALT"  
    GenerateAdditionalXML "SDN", "ALT"  
    GenerateAdditionalXML "CONS\_PRIM", "CONS\_ALT"  
      
    Print #1, "</parties>"  
    Close #1

    Application.DisplayAlerts = True  
    Application.ScreenUpdating = True  
      
    Application.Quit  
End Sub

Sub LoadSDNTxt(arg1 As String, arg2 As String)  
    Dim InputStr As String  
    Dim i As Integer  
    Dim ent\_num As Integer, SDN\_Name As String, SDN\_Type As String, Program As String, Title As String, Call\_Sign As String  
    Dim Vess\_type As String, Tonnage As String, GRT As String, Vess\_flag As String, Vess\_owner As String, Remarks As String  
      
    On Error Resume Next  
      
' To check the worksheet of SDN/CONS\_PRIM existed or not, if it does then delete the existed worksheet and create a new one. That will avoid to use the wrong data.  
      
    Set sh1 = ThisWorkbook.Worksheets(arg1)  
    If sh1 Is Nothing Then  
        Sheets.Add after:=Sheets(Sheets.Count)  
        Sheets(Sheets.Count).Name = arg1  
    Else  
        Application.DisplayAlerts = False  
        Sheets(arg1).Delete  
        Sheets.Add after:=Sheets(Sheets.Count)  
        Sheets(Sheets.Count).Name = arg1  
    End If  
      
' Start to load the list into the worksheet

    Worksheets(arg1).Select  
    Fn = FreeFile  
    If arg1 = "SDN" Then  
        Open arg2 & "sdn.ff" For Input As #Fn  
    Else  
        Open arg2 & "cons\_prim.ff" For Input As #Fn  
    End If

    i = 1  
    While Not EOF(Fn)  
        Line Input #Fn, InputStr  
        If Len(InputStr) > 0 Then  
            ent\_num = Mid(InputStr, 1, 10)  
            SDN\_Name = Trim(Mid(InputStr, 11, 350))  
            SDN\_Type = Trim(Mid(InputStr, 361, 12))  
            Program = Trim(Mid(InputStr, 373, 200))  
            Title = Trim(Mid(InputStr, 573, 200))  
            Call\_Sign = Trim(Mid(InputStr, 773, 8))  
            Vess\_type = Trim(Mid(InputStr, 781, 25))  
            Tonnage = Trim(Mid(InputStr, 806, 14))  
            GRT = Trim(Mid(InputStr, 820, 8))  
            Vess\_flag = Trim(Mid(InputStr, 828, 40))  
            Vess\_owner = Trim(Mid(InputStr, 868, 150))  
            Remarks = Trim(Mid(InputStr, 1018, 1000))  
          
            Range("A" & i).Value = ent\_num  
            Range("B" & i).Value = SDN\_Name  
            Range("C" & i).Value = SDN\_Type  
            Range("D" & i).Value = Program  
            Range("E" & i).Value = Title  
            Range("F" & i).Value = Call\_Sign  
            Range("G" & i).Value = Vess\_type  
            Range("H" & i).Value = Tonnage  
            Range("I" & i).Value = GRT  
            Range("J" & i).Value = Vess\_flag  
            Range("K" & i).Value = Vess\_owner  
            Range("L" & i).Value = Remarks  
        End If  
        i = i + 1  
    Wend  
    Close #Fn  
End Sub

Sub LoadALTTxt(arg1 As String, arg2 As String)  
    Dim InputStr As String  
    Dim i As Integer  
    Dim ent\_num As Integer, Alt\_num As Integer, Alt\_type As String, Alt\_name As String, Alt\_remarks As String

    On Error Resume Next  
      
' To check the worksheet of ALT/CONS\_ALT existed or not, if it does then delete the existed worksheet and create a new one. That will avoid to use the wrong data.  
      
    Set sh1 = ThisWorkbook.Worksheets(arg1)  
    If sh1 Is Nothing Then  
        Sheets.Add after:=Sheets(Sheets.Count)  
        Sheets(Sheets.Count).Name = arg1  
    Else  
        Application.DisplayAlerts = False  
        Sheets(arg1).Delete  
        Sheets.Add after:=Sheets(Sheets.Count)  
        Sheets(Sheets.Count).Name = arg1  
    End If  
      
' Start to load the list into the worksheet  
      
    Worksheets(arg1).Select  
    Fn = FreeFile  
    If arg1 = "ALT" Then  
        Open arg2 & "alt.ff" For Input As #Fn  
    Else  
        Open arg2 & "cons\_alt.ff" For Input As #Fn  
    End If  
      
    i = 1  
    While Not EOF(Fn)  
        Line Input #Fn, InputStr  
        If Len(InputStr) > 0 Then  
            ent\_num = Mid(InputStr, 1, 10)  
            Alt\_num = Mid(InputStr, 11, 10)  
            Alt\_type = Trim(Mid(InputStr, 21, 8))  
            Alt\_name = Trim(Mid(InputStr, 29, 350))  
            Alt\_remarks = Trim(Mid(InputStr, 379, 200))

            Range("A" & i).Value = ent\_num  
            Range("B" & i).Value = Alt\_num  
            Range("C" & i).Value = Alt\_type  
            Range("D" & i).Value = Alt\_name  
            Range("E" & i).Value = Alt\_remarks  
        End If  
        i = i + 1  
    Wend  
    Close #Fn  
End Sub

Sub GenerateXML(arg1 As String, arg2 As String)  
    Dim entnumStr As Integer, SDNNameStr As String, SDNTypeStr As String, ProgramStr As String, TitleStr As String  
    Dim callsignStr As String, vesstypeStr As String, tonnageStr As String, grtStr As String, vessflagStr As String, vessownerStr As String  
    Dim alttypeStr As String, altnameStr As String, listtypeStr As String  
    Dim procFlag As Boolean, akaFlag As Boolean, firstFlag As Boolean, AltFlag As Boolean  
    Dim SDNCtr As Integer, ALTCtr As Integer, CONSPRIMCtr As Integer, CONSALT As Integer  
    Dim altrowCTR As Integer  
    Dim Altentnum As Integer, Altalttype As String, Altaltname As String  
    Dim Filename As String, contentStr As String  
      
    On Error Resume Next  
      
' To get the number of records of that worksheet.  
      
    procFlag = True  
    Worksheets(arg1).Select  
    For i = 1 To 999999  
        If Range("A" & i) = "" Then Exit For  
    Next i  
    SDNCtr = i - 1  
    Worksheets(arg2).Select  
    For i = 1 To 999999  
        If Range("A" & i) = "" Then Exit For  
    Next i  
    ALTCtr = i - 1  
      
' To get the information from SDN/CONS\_PRIM, if the length of SDN/CONS\_PRIM is more than 33 characters then generate the content of IWL  
      
    altrowCTR = 1  
    For i = 1 To SDNCtr  
        Worksheets(arg1).Select  
        entnumStr = Range("A" & i).Value  
        SDNNameStr = Range("B" & i).Value  
        TitleStr = Trim(Range("E" & i).Value)  
        ProgramStr = Trim(Range("D" & i).Value)  
        SDNTypeStr = Trim(Range("C" & i).Value)  
        callsignStr = Trim(Range("F" & i).Value)  
        vesstypeStr = Trim(Range("G" & i).Value)  
        tonnageStr = Trim(Range("H" & i).Value)  
        grtStr = Trim(Range("I" & i).Value)  
        vessflagStr = Trim(Range("J" & i).Value)  
        vessownerStr = Trim(Range("K" & i).Value)  
        If Len(SDNNameStr) > 33 Then  
            Print #1, "<party>"  
            Print #1, "<info>"  
            Print #1, "<uid>" & entnumStr & "</uid>"  
            Print #1, "<fullname>" & replaceSpecChar(SDNNameStr) & "</fullname>"  
            If TitleStr <> "-0-" Then  
                Print #1, "<title>" & TitleStr & "</title>"  
            End If  
            If SDNTypeStr = "-0-" Then  
                SDNTypeStr = "other"  
            End If  
            Print #1, "<partytype>" & SDNTypeStr & "</partytype>"  
            If callsignStr <> "-0-" Then  
                Print #1, "<callsign>" & callsignStr & "</callsign>"  
            End If  
            If vesstypeStr <> "-0-" Then  
                Print #1, "<vesstype>" & vesstypeStr & "</vesstype>"  
            End If  
            If tonnageStr <> "-0-" Then  
                Print #1, "<tonnage>" & tonnageStr & "</tonnage>"  
            End If  
            If grtStr <> "-0-" Then  
                Print #1, "<grt>" & grtStr & "</grt>"  
            End If  
            If vessflagStr <> "-0-" Then  
                Print #1, "<vessflag>" & vessflagStr & "</vessflag>"  
            End If  
            If vessownerStr <> "-0-" Then  
                Print #1, "<vessowner>" & vesswonerStr & "</vessowner>"  
            End If  
            Print #1, "</info>"  
            Print #1, "<akas>"  
            Print #1, "<aka>"  
            Print #1, "<alttype>a.k.a</alttype>"  
            Altaltname = transformSTR1(SDNNameStr)  
            Print #1, "<altname>" & Altaltname & "</altname>"  
            Print #1, "</aka>"  
            Print #1, "<aka>"  
            Print #1, "<alttype>a.k.a</alttype>"  
            Altaltname = transformSTR2(SDNNameStr)  
            Print #1, "<altname>" & Altaltname & "</altname>"  
            Print #1, "</aka>"

            akaFlag = True  
            If altrowCTR > ALTCtr Then  
                akaFlag = False  
            End If  
              
' The below procedures are generated IWL content of AKA  
' To make the flag("Y") for processed in F column.  
              
            Worksheets(arg2).Select  
            Do While akaFlag  
                Altentnum = Range("A" & altrowCTR).Value  
                If Altentnum = entnumStr Then  
                    Altalttype = Trim(Range("C" & altrowCTR).Value)  
                    Range("F" & altrowCTR).Value = "Y"  
                    If Altalttype = "aka" Then  
                        Altalttype = "a.k.a"  
                    Else  
                        If Altalttype = "fka" Then Altalttype = "f.k.a"  
                        If Altalttype = "nka" Then Altalttype = "n.k.a"  
                    End If  
                    Altaltname = Trim(Range("D" & altrowCTR).Value)  
                    AltFlag = True  
                    Print #1, "<aka>"  
                    Print #1, "<alttype>" & Altalttype & "</alttype>"  
                    Print #1, "<altname>" & replaceSpecChar(Altaltname) & "</altname>"  
                    Print #1, "</aka>"  
                    If Len(Altaltname) > 33 Then  
                        Print #1, "<aka>"  
                        Print #1, "<alttype>a.k.a</alttype>"  
                        Print #1, "<altname>" & transformSTR1(Altaltname) & "</altname>"  
                        Print #1, "</aka>"  
                        Print #1, "<aka>"  
                        Print #1, "<alttype>a.k.a</alttype>"  
                        Print #1, "<altname>" & transformSTR2(Altaltname) & "</altname>"  
                        Print #1, "</aka>"  
                    End If  
                    altrowCTR = altrowCTR + 1  
                Else  
                    If Altentnum > entnumStr Then  
                        akaFlag = False  
                    Else  
                        If altrowCTR > ALTCtr Then  
                            akaFlag = False  
                        Else  
                            altrowCTR = altrowCTR + 1  
                        End If  
                    End If  
                End If  
            Loop  
            Print #1, "</akas>"  
            Print #1, "</party>"  
        End If  
    Next i  
End Sub

Sub GenerateAdditionalXML(arg1 As String, arg2 As String)  
    Dim entnumStr As Integer, SDNNameStr As String, SDNTypeStr As String, ProgramStr As String, TitleStr As String  
    Dim callsignStr As String, vesstypeStr As String, tonnageStr As String, grtStr As String, vessflagStr As String, vessownerStr As String  
    Dim alttypeStr As String, altnameStr As String, listtypeStr As String  
    Dim procFlag As Boolean, akaFlag As Boolean, firstFlag As Boolean, SDNFlag As Boolean, PartyFlag As Boolean  
    Dim SDNCtr As Integer, ALTCtr As Integer, CONSPRIMCtr As Integer, CONSALT As Integer  
    Dim SDNrowCTR As Integer, Tempentnum As String  
    Dim Altentnum As Integer, Altalttype As String, Altaltname As String, AltAlreadyFlag As String  
    Dim Filename As String, contentStr As String  
      
    On Error Resume Next  
      
' To get the number of records of that worksheet.  
      
    Worksheets(arg1).Select  
    For i = 1 To 999999  
        If Range("A" & i) = "" Then Exit For  
    Next i  
    SDNCtr = i - 1  
    Worksheets(arg2).Select  
    For i = 1 To 999999  
        If Range("A" & i) = "" Then Exit For  
    Next i  
    ALTCtr = i - 1  
      
' To get the information from ALT/CONS\_ALT  
' If the length of SDN/CONS\_ALT is more than 33 characters and didn't generate the IWL  
' then look for the record within SDN/CONS\_PRIM.  
' And to generate the IWL  
      
    SDNrowCTR = 1  
    PartyFlag = False  
    For i = 1 To ALTCtr  
        Worksheets(arg2).Select  
        If (Len(Trim(Range("D" & i).Value)) > 33 And Trim(Range("F" & i).Value) = "") Then  
            Tempentnum = Range("A" & i).Value  
                        
            For j = SDNrowCTR To SDNCtr  
                Worksheets(arg1).Select  
                entnumStr = Range("A" & j).Value  
                If entnumStr > Tempentnum Then  
                    SDNrowCTR = j  
                    If (SDNrowCTR - 100) <= 0 Then  
                        SDNrowCTR = 1  
                    Else  
                        SDNrowCTR = SDNrowCTR - 100  
                    End If  
                    Exit For  
                Else  
                    If entnumStr = Tempentnum Then  
                        Worksheets(arg1).Select  
                        PartyFlag = True  
                        SDNNameStr = Trim(Range("B" & j).Value)  
                        TitleStr = Trim(Range("E" & j).Value)  
                        ProgramStr = Trim(Range("D" & j).Value)  
                        SDNTypeStr = Trim(Range("C" & j).Value)  
                        callsignStr = Trim(Range("F" & j).Value)  
                        vesstypeStr = Trim(Range("G" & j).Value)  
                        tonnageStr = Trim(Range("H" & j).Value)  
                        grtStr = Trim(Range("I" & j).Value)  
                        vessflagStr = Trim(Range("J" & j).Value)  
                        vessownerStr = Trim(Range("K" & j).Value)  
                        Print #1, "<party>"  
                        Print #1, "<info>"  
                        Print #1, "<uid>" & entnumStr & "</uid>"  
                        Print #1, "<fullname>" & replaceSpecChar(SDNNameStr) & "</fullname>"  
                        If TitleStr <> "-0-" Then  
                            Print #1, "<title>" & TitleStr & "</title>"  
                        End If  
                        If SDNTypeStr = "-0-" Then  
                            SDNTypeStr = "other"  
                        End If  
                        Print #1, "<partytype>" & SDNTypeStr & "</partytype>"  
                        If callsignStr <> "-0-" Then  
                            Print #1, "<callsign>" & callsignStr & "</callsign>"  
                        End If  
                        If vesstypeStr <> "-0-" Then  
                            Print #1, "<vesstype>" & vesstypeStr & "</vesstype>"  
                        End If  
                        If tonnageStr <> "-0-" Then  
                            Print #1, "<tonnage>" & tonnageStr & "</tonnage>"  
                        End If  
                        If grtStr <> "-0-" Then  
                            Print #1, "<grt>" & grtStr & "</grt>"  
                        End If  
                        If vessflagStr <> "-0-" Then  
                            Print #1, "<vessflag>" & vessflagStr & "</vessflag>"  
                        End If  
                        If vessownerStr <> "-0-" Then  
                            Print #1, "<vessowner>" & vesswonerStr & "</vessowner>"  
                        End If  
                        Print #1, "</info>"  
                        Print #1, "<akas>"  
                        Worksheets(arg2).Select  
                        For k = 1 To ALTCtr  
                            If Range("A" & k).Value > entnumStr Then  
                                Exit For  
                            Else  
                                If Range("A" & k).Value = entnumStr Then  
                                    Altentnum = Range("A" & k).Value  
                                    Altalttype = Trim(Range("C" & k).Value)  
                                    Range("F" & k).Value = "Y"  
                                    If Altalttype = "aka" Then  
                                        Altalttype = "a.k.a"  
                                    Else  
                                        If Altalttype = "fka" Then Altalttype = "f.k.a"  
                                        If Altalttype = "nka" Then Altalttype = "n.k.a"  
                                    End If  
                                    Altaltname = Trim(Range("D" & k).Value)  
                                    Print #1, "<aka>"  
                                    Print #1, "<alttype>" & Altalttype & "</alttype>"  
                                    Print #1, "<altname>" & replaceSpecChar(Altaltname) & "</altname>"  
                                    Print #1, "</aka>"  
                                    If Len(Altaltname) > 33 Then  
                                        Print #1, "<aka>"  
                                        Print #1, "<alttype>a.k.a</alttype>"  
                                        Print #1, "<altname>" & transformSTR1(Altaltname) & "</altname>"  
                                        Print #1, "</aka>"  
                                        Print #1, "<aka>"  
                                        Print #1, "<alttype>a.k.a</alttype>"  
                                        Print #1, "<altname>" & transformSTR2(Altaltname) & "</altname>"  
                                        Print #1, "</aka>"  
                                    End If  
                                End If  
                            End If  
                        Next k  
                        Print #1, "</akas>"  
                    End If  
                End If  
            Next j  
            If PartyFlag Then  
                Print #1, "</party>"  
                PartyFlag = False  
            End If  
        End If  
    Next i  
End Sub

Function transformSTR1(arg1Str As String) As String

' To add "1/" in front of name and truncate the characters after 34  
' To deal with the escape characters in the name

    transformSTR1 = "1/" & Left(arg1Str, 33)  
    transformSTR1 = replaceSpecChar(transformSTR1)  
End Function

Function transformSTR2(arg1Str As String) As String  
    Dim charCTR As Integer  
      
' To add "1/" in front of name for each 33 characters  
' Per the specification from OFAC, the maximum length of name is 350.  
' To deal with the escape characters in the name      
    charCTR = Len(arg1Str)  
    transformSTR2 = "1/"  
    For i = 1 To charCTR  
        transformSTR2 = transformSTR2 & Mid(arg1Str, i, 1)  
        If i = 33 Or i = 66 Or i = 99 Or i = 132 Or i = 165 Or i = 198 Or i = 231 Or i = 264 Or i = 297 Or i = 330 Then  
            transformSTR2 = transformSTR2 & "1/"  
        End If  
    Next i  
    transformSTR2 = replaceSpecChar(transformSTR2)  
End Function

Function replaceSpecChar(arg1 As String) As String  
    Dim lenStr As Integer  
    Dim charStr As String  
      
' This function is focus on dealing with escape character only.  
      
    lenStr = Len(arg1)  
    replaceSpecChar = ""  
    For i = 1 To lenStr  
        charStr = Mid(arg1, i, 1)  
        Select Case charStr  
            Case "<"  
                charStr = "&lt;"  
            Case ">"  
                charStr = "&gt;"  
            Case "&"  
                charStr = "&amp;"  
            Case """"  
                charStr = "&quot;"  
            Case Else  
                charStr = charStr  
        End Select  
        replaceSpecChar = replaceSpecChar + charStr  
    Next  
End Function