jeremy.emf

; -!- emf -!-

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Miscelanneous Settings
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

!if &or &seq $platform "dos" &seq $platform "win32"
    set-variable $home "c:/Users/Jeremy"
!endif

set-variable $mode-line "%s%r%u%k %b %l:%c - %h:%m (%e) %f"
set-variable $cursor-blink 250
set-variable $file-ignore "~ ./ .8 .o .a .exe"
set-variable $kept-version 10
set-variable $indent-width 4
set-variable $tab-width 8

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Additional file hooks
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

add-file-hook ".go" fhook-go

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Line handling
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

-1 global-mode "lf"

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Helper Methods
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Complete what the two above lines have in common from the current cursor
; position.
;

define-macro complete-similar
    ; #l0 is the starting column
    ; #l1 is 2 lines back
    ; #l2 is 1 line back
    ; #l3 is the current length (mid string is taken from #l0 to #l3)
    ; #l4 is the maximum length we should attempt (shorter len of #l1 and #l2)

    set-variable #l0 $window-acol

    2 backward-line
    set-variable #l1 @wl
    forward-line
    set-variable #l2 @wl
    forward-line

    set-variable #l4 &len #l1
    !if &less &len #l2 #l4
        set-variable #l4 &len #l2
    !endif

    set-variable #l3 1

    !while &and &less &add #l0 &inc #l3 1 #l4 &sequal &mid #l1 #l0 #l3 &mid #l2 #l0 #l3
        ; Loop while line 1 and line 2 strings are the same bound by #l0 and #l3
        ; Each iteration #l3 is incremented by 1
    !done

    ; If we have reached the end of the string, do not deincrement by one which is
    ; typically the failing condition from the above loop
    !if &not &equal &add #l0 #l3 #l4
        set-variable #l3 &sub #l3 1
    !endif

    insert-string &mid #l1 #l0 #l3
!emacro

; Align all subsequent lines containing #l0 to column #l1
define-macro align-char
    set-variable .TheChar   #p0
    set-variable .TheColumn #p1

*nextline
    forward-line

    !if &or &xsequal @wl "^[ \t]*$" &xsequal @wl "^[ \t]*//.*$"
        !goto nextline
    !endif

    !if &not &xsequal @wl &cat &cat ".*" .TheChar ".*"
        !goto finish
    !endif

    beginning-of-line
    !while &not &sin @wc .TheChar
        forward-char
    !done

    !if &equal .TheColumn $window-acol
        !goto nextline
    !endif

    !if &less $window-acol .TheColumn
        !while &less $window-acol .TheColumn
            insert-space
        !done
        !goto nextline
    !endif

    !if &great $window-acol .TheColumn
        !while &great $window-acol .TheColumn
            backward-char
            !if &not &seq @wc " "
                !bell
                !abort
            !endif
            1 forward-delete-char
        !done
        !goto nextline
    !endif

*finish
    ml-write "Finished"
    !return
!emacro

; Align all subsequent lines containing the character under the cursor to the
; cursors position
define-macro align-current-char
    set-variable #l0 @wc
    set-variable #l1 $window-acol

    align-char
!emacro

; Pad to column #l0 with spaces
define-macro pad-to-x
    !while &less $window-acol #p0
        insert-space
    !done
!emacro

; Prompt the user for what column to pad to with spaces
define-macro pad
    set-variable #l0 @ml "To Column"
    pad-to-x
!emacro

; Macro to delete the whitespace, or if on a word all of the word until the
; next word is reached.
0 define-macro super-delete
    set-variable #l0 0
    !while &not &sin @wc " \t\n"
        forward-char
        set-variable #l0 &add #l0 1
    !done
    !repeat
        !force forward-char
        !if $status
            set-variable #l0 &add #l0 1
        !endif
    !until &or &seq @wc "" &not &sin @wc " \t\n"
    #l0 backward-delete-char
    !return
!emacro

; Macro to backspace the whitespace, or if on a word all of the word until the
; previous word is reached.
0 define-macro super-backspace
    set-variable #l0 -1
    set-variable #l1 0
    !repeat
        !force backward-char
        !if $status
            set-variable #l0 &add #l0 1
            !if &sin @wc " \t\n"
                set-variable #l1 1
            !endif
        !else
            set-variable #l1 1
        !endif
    !until #l1
    !repeat
        !force backward-char
        !if $status
            set-variable #l0 &add #l0 1
        !else
            &add #l0 1 forward-delete-char
            !return
        !endif
    !until &not &sin @wc " \t\n"
    forward-char
    #l0 forward-delete-char
    !return
!emacro

define-macro spotless
    -1 clean
!emacro

; Go to the first non-blank character on the current line. If already there,
; go to column 1
define-macro smart-home
    set-variable #l0 $window-acol

    beginning-of-line

    !while &sin @wc " \t"
        !force forward-char
    !done

    !if &equal $window-acol #l0
        beginning-of-line
    !end
!emacro

; Delete from the current position to the character give via the user prompt
define-macro forward-delete-to
    ml-write "Delete to: "

    set-variable #l0 @cgk

    !if &seq #l0 "C-g"
        ml-write "Cancelled"
    !else
        !while &not &seq @wc #l0
            forward-delete-char
        !done
    !end
!emacro

; Delete from the current position to the character given via the user prompt
define-macro backward-delete-to
    ml-write "Backward delete to: "

    set-variable #l0 @cgk

    !if &seq #l0 "C-g"
        ml-write "Cancelled"
    !else
        backward-char

        !while &not &seq @wc #l0
            forward-delete-char
            backward-char
        !done
    !end
!emacro

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Task Timer
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; #l0 should contain the value to convert to seconds. #l0 will contain the
; result
define-macro time-to-seconds
    set-variable #p0 &add &mid #p0 16 2 &mul 60 &add &mid #p0 14 2 &mul 60 &mid #p0 12 2
!emacro

; #l0 and #l1 should contain the start -> end time. #l0 will have the human
; time difference.
define-macro human-time-diff
    set-variable #l0 &sub #p1 #p0 ; difference in seconds
    set-variable #l1 0            ; day count
    set-variable #l2 0            ; hour count
    set-variable #l3 0            ; minute count
    set-variable #l4 0            ; second count

    !if &great #l0 86400
        set-variable #l1 &div #l0 86000
        set-variable #l0 &sub #l0 &mul 86000 #l1
    !endif
    !if &great #l0 3600
        set-variable #l2 &div #l0 3600
        set-variable #l0 &sub #l0 &mul 3600 #l2
    !endif
    !if &great #l0 60
        set-variable #l3 &div #l0 60
        set-variable #l0 &sub #l0 &mul 60 #l3
    !endif
    set-variable #l4 #l0

    !if &great #l1 0
        set-variable #p0 &spr "%d day %d hour %d min %d sec" #l1 #l2 #l3 #l4
    !elif &great #l2 0
        set-variable #p0 &spr "%d hour %d min %d sec" #l2 #l3 #l4
    !elif &great #l3 0
        set-variable #p0 &spr "%d min %d sec" #l3 #l4
    !else
        set-variable #p0 &spr "%d sec" #l4
    !endif
!emacro

define-macro timer-begin
    set-variable $timer-started-at $time
!emacro

define-macro timer-status
    set-variable #l0 $time
    time-to-seconds
    set-variable #l1 #l0

    set-variable #l0 $timer-started-at
    time-to-seconds

    human-time-diff

    ml-write &spr "Elapsed time: %s" #l0
!emacro

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; Key Bindings
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

global-bind-key    alarm              "C-c a"
global-bind-key    timer-begin        "C-c b"
global-bind-key    timer-status       "C-c s"
global-bind-key    super-backspace    "C-backspace"
global-bind-key    super-delete       "C-delete"
-1 global-bind-key next-buffer        "A-left"
global-bind-key    next-buffer        "A-right"
global-bind-key    smart-home         "home"
global-bind-key    forward-delete-to  "esc delete"
global-bind-key    backward-delete-to "esc backspace"
global-bind-key    complete-similar   "esc space"