**微算機實驗報告**

**姓名：楊哲睿**

**系級：電機10**

**學號：0610780**

**上課時間：4EF、4IJ**



期末專題


**ㄧ、實驗動機：**

現在這個時代，大家走路的時候都在低頭滑手機，實在是很危險，要是走著走著撞到東西就不好了。但要戒掉這個習慣實在是很困難，所以想說來做一個提醒在低頭滑手機的人們快撞到東西的裝置好了，至少能稍微減少一點受傷的機率嘛。


**二、功能：**

* 當有物體靠近（超音波感測的距離少於一公尺）時，LED會用跑馬燈的方式提醒使用者，蜂鳴器也會發出聲響。
* 有一個四個七段顯示器的模組顯示物體與超音波感測器之間的距離（以公分為單位）。
* 不同的距離下，會有不同顏色的跑馬燈，共分為三種顏色：
  + 距離50~99公分時，跑馬燈為綠色
  + 距離20~49公分時，跑馬燈為黃色
  + 距離0~19公分時，跑馬燈為紅色
* 距離障礙物越近，蜂鳴器發出的音調會越高，聲音的頻率範圍從200Hz到2000Hz，每接近（或遠離）物體一公分，音頻約改變18Hz左右。

**三、硬體架構：**



**四、程式流程圖：**



**五、程式碼與註解：**

ORG 0000H

JMP INITIAL

ORG 000BH

JMP TIMER0INTERUPT

ORG 0013H

JMP INT1INTERUPT

ORG 0050H

INITIAL:

MOV 31H, #0FEH ;跑馬燈初始值

MOV A, 31H

MOV P1, A ;跑馬燈輸出

MOV R4, #255 ;控制多久觸發一次Trig及跑馬燈右移

CLR P3.2 ;蜂鳴器輸出

CLR P3.7 ;用來產生半週期為29us的方波

MOV DPTR, #NUMTABLE

SETB IT1 ;Falling edge trigger for interrupt 1

SETB PX1 ;Set INT1 interrupt priority

SETB EA ;Enable all interrupt

SETB EX1 ;Enable INT1 interrupt

SETB ET0 ;Enable Timer/Counter 0 interrupt

CLR TF0 ;TIMER 0 OVERFLOW FLAG

CLR TF1 ;COUNTER 1 OVERFLOW FLAG

MOV TMOD, #11100010B ;Counter 1, Mode 2, enable when INT1 = 1; Timer 0, Mode 2

MOV TH0, #227 ;Timer 0計時29us

MOV TL0, #227

SETB TR0 ;Timer 0開始運作

MOV TH1, #0 ;Counter 1歸0

MOV TL1, #0

SETB TR1 ;Counter 1開始運作

SHOW:

MOV P0, #0FBH ;百位

MOV A, R2

MOVC A, @A+DPTR ;查Table

MOV P2, A

MOV R5, #1

CALL DELAY

MOV P2, #0FFH ;避免殘影

MOV P0, #0FDH ;十位

MOV A, R1

MOVC A, @A+DPTR ;查Table

MOV P2, A

MOV R5, #1

CALL DELAY

MOV P2, #0FFH ;避免殘影

MOV P0, #0FEH ;個位

MOV A, R0

MOVC A, @A+DPTR ;查Table

MOV P2, A

MOV R5, #1

CALL DELAY

MOV P2, #0FFH ;避免殘影

DJNZ R4, SHOW ;顯示255次才(1)觸發Trig一次(2)跑馬燈右移一格

MOV A, 31H

RR A ;跑馬燈右移一格

MOV 31H, A

MOV P1, A

SETB P3.4 ;給超音波模組Trig

MOV R5, #1

CALL DELAY

CLR P3.4

MOV R4, #255

JMP SHOW

TIMER0INTERUPT:

CPL P3.7 ;產生半週期為29us的方波

CLR TF0

CJNE R3, #255, SOUND ;距離超過100就不發出聲音

JMP TIMERRETURN

SOUND:

DJNZ R3, TIMERRETURN

CPL P3.2 ;產生蜂鳴器需要的方波

MOV R3, 30H

TIMERRETURN:

RETI

INT1INTERUPT:

MOV A, TL1

MOV B, #100

DIV AB

MOV R2, A ;百位數

MOV A, B

MOV B, #10

DIV AB

MOV R1, A ;十位數

MOV R0, B ;個位數

CJNE R2, #0, NEXT1

CJNE R1, #5, NEXT2

NEXT2:

JC NEXT3

;50 <= distance < 100, green

SETB P3.1 ;Red light

CLR P3.6 ;Green light

JMP SETSOUND

NEXT3:

CJNE R1, #2, NEXT4

NEXT4:

JC NEXT5

;20 <= distance < 50, yellow(red + green)

CLR P3.1 ;Red light

CLR P3.6 ;Green light

JMP SETSOUND

NEXT5:

;distance < 20, red

CLR P3.1 ;Red light

SETB P3.6 ;Green light

JMP SETSOUND

NEXT1:

SETB P3.1 ;Red light

SETB P3.6 ;Green light

SETSOUND:

MOV A, R1 ;設定音調

MOV B, #10

MUL AB

ADD A, R0

;MOV B, #2

;DIV AB

;ADD A, #17

ADD A, #15

MOV R3, A ;R3跟30H儲存音調的參數

MOV 30H, A ;公式是取距離的後兩位加15

CJNE R2, #0, NEXT6 ;若距離大於100另外設定

JMP INT1RETURN

NEXT6:

MOV R3, #255 ;距離大於100

MOV 30H, #255

INT1RETURN:

CLR TF1 ;Counter歸零

MOV TH1, #0

MOV TL1, #0

RETI

DELAY:

MOV R6, #20

DELAY1:

MOV R7, #30

DELAY2:

DJNZ R7, DELAY2

DJNZ R6, DELAY1

DJNZ R5, DELAY

RET

NUMTABLE:

DB 0C0H ;0

DB 0F9H ;1

DB 0A4H ;2

DB 0B0H ;3

DB 099H ;4

DB 092H ;5

DB 082H ;6

DB 0F8H ;7

DB 080H ;8


DB 090H ;9

END


**六、心得：**

趁著這次期末專題，讓我又把蜂鳴器跟超音波測距的實驗內容再拿出來複習了一次，雖然我的專題跟之前實驗的內容相似，但我覺得要把兩三個不同的實驗結合在一起也是相當有挑戰性的事情。舉例來說，超音波測距的實驗就用掉了一個Timer跟一個Counter，已經沒有多的Timer/Counter可以使用了，但蜂鳴器發出聲音的機制中，也需要使用到Timer，所以在設計這個專題的時候，就要去思考怎麼讓一個Timer能同時滿足這兩個需求，也就是怎麼在不互相干擾的情況下，用同一個Timer完成兩個不同的計時需求。諸如此類的事情在整個專題的製作過程中不斷發生，我想透過專題，是個很好的方式徹底檢視之前所學是否真的有理解，我在這過程中收穫良多。


**七、實品圖：**



整體架構



跑馬燈、蜂鳴器與超音波模組



四個七段顯示器