Original production

R1. <Rat23F> ::= <Opt Function Definitions> # <Opt Declaration List> <Statement List> #

R2. <Opt Function Definitions> ::= <Function Definitions> | <Empty>

R3. <Function Definitions> ::= <Function> | <Function> <Function Definitions>

R4. <Function> ::= function <Identifier> ( <Opt Parameter List> ) <Opt Declaration List> <Body>

R5. <Opt Parameter List> ::= <Parameter List> | <Empty>

R6. <Parameter List> ::= <Parameter> | <Parameter> , <Parameter List>

R7. <Parameter> ::= <IDs > <Qualifier>

R8. <Qualifier> ::= integer | bool | real

R9. <Body> ::= { < Statement List> }

R10. <Opt Declaration List> ::= <Declaration List> | <Empty>

R11. <Declaration List> := <Declaration> ; | <Declaration> ; <Declaration List>

R12. <Declaration> ::= <Qualifier > <IDs>

R13. <IDs> ::= <Identifier> | <Identifier>, <IDs>

R14. <Statement List> ::= <Statement> | <Statement> <Statement List>

R15. <Statement> ::= <Compound> | <Assign> | <If> | <Return> | <Print> | <Scan> | <While>

R16. <Compound> ::= { <Statement List> }

R17. <Assign> ::= <Identifier> = <Expression> ;

R18. <If> ::= if ( <Condition> ) <Statement> endif | if ( <Condition> ) <Statement> else <Statement> endif

R19. <Return> ::= ret ; | ret <Expression> ;

R20. <Print> ::= put ( <Expression>);

R21. <Scan> ::= get ( <IDs> );

R22. <While> ::= while ( <Condition> ) <Statement>

R23. <Condition> ::= <Expression> <Relop> <Expression>

R24. <Relop> ::= == | != | > | < | <= | =>

R25. <Expression> ::= <Expression> + <Term> | <Expression> - <Term> | <Term>

R26. <Term> ::= <Term> \* <Factor> | <Term> / <Factor> | <Factor>

R27. <Factor> ::= - <Primary> | <Primary>

R28. <Primary> ::= <Identifier> | <Integer> | <Identifier> ( <IDs> ) | ( <Expression> ) | <Real> | true | false

R29. <Empty> ::= ε

Note: <Identifier>, <Integer>, <Real> are token types as defined in section (1) of the project document on Canvas.

Modified production with left recursion and backtracking removed.

Yellow highlight means the rule was modified. Green highlight means the rule was added.

R1. <Rat23F> ::= <Opt Function Definitions> # <Opt Declaration List> <Statement List> #

R2. <Opt Function Definitions> ::= <Function Definitions> | <Empty>

R3. <Function Definitions> ::= <Function> <Function Definitions Continued>

R4. <Function Definitions Continued> ::= <Empty> | <Function Definitions>

R5. <Function> ::= function <Identifier> ( <Opt Parameter List> ) <Opt Declaration List> <Body>

R6. <Opt Parameter List> ::= <Parameter List> | <Empty>

R7. <Parameter List> ::= <Parameter> <Parameter List Continued>

R8. <Parameter List Continued> ::= <Empty> | ,<Parameter List>

R9. <Parameter> ::= <IDs > <Qualifier>

R10. <Qualifier> ::= integer | bool | real

R11. <Body> ::= { < Statement List> }

R12. <Opt Declaration List> ::= <Declaration List> | <Empty>

R13. <Declaration List> ::= <Declaration> ; <Declaration List Continued>

R14. <Declaration List Continued> ::= <Empty> | <Declaration List>

R15. <Declaration> ::= <Qualifier > <IDs>

R16. <IDs> ::= <Identifier> <IDs Continued>

R17. <IDs Continued> ::= <Empty> | , <IDs>

R18. <Statement List> ::= <Statement> <Statement List Continued>

R19. <Statement List Continued> ::= <Empty> | <Statement List>

R20. <Statement> ::= <Compound> | <Assign> | <If> | <Return> | <Print> | <Scan> | <While>

R21. <Compound> ::= { <Statement List> }

R22. <Assign> ::= <Identifier> = <Expression> ;

R23. <If> ::= if ( <Condition> ) <Statement> <If Continued>

R24. <If Continued> ::= endif | else <Statement> endif

R25. <Return> ::= ret <Return Continued>

R26. <Return Continued> ::= ; | <Expression> ;

R27. <Print> ::= put ( <Expression>);

R28. <Scan> ::= get ( <IDs> );

R29. <While> ::= while ( <Condition> ) <Statement>

R30. <Condition> ::= <Expression> <Relop> <Expression>

R31. <Relop> ::= == | != | > | < | <= | =>

R32. <Expression> ::= <Term> <Expression Prime>

R33. <Expression Prime> ::= <Expression Continued> <Expression Prime> | <Empty>

R34. <Expression Continued> ::= + <Term> | - <Term>

R35. <Term> ::= <Factor> <Term Prime>

R36. <Term Prime> ::= <Term Continued> <Term Prime> | <Empty>

R37. <Term Continued> ::= \* <Factor> | / <Factor>

R38. <Factor> ::= - <Primary> | <Primary>

R39. <Primary> ::= <Identifier> <Primary Continued> | <Integer> | ( <Expression> ) | <Real> | true | false

R40. <Primary Continued> ::= <Empty> | ( <IDs> )

R41. <Empty> ::= ε

Note: <Identifier>, <Integer>, <Real> are token types as defined in section (1) of the project document on Canvas.