Floating Windows Support From Neovim

[Piping]

Hi @junegunn

Neovim patch from @bfredl has a working version of floating windows implementation now.

Is it possible to add a split direction like float and then open fzf inside floating windows.

Here is a reference

[junegunn]

You can pass an arbitrary command as window option.

function! Foo()
  tabnew
  " or whatever
endfunction

call fzf#run({'window': 'call Foo()'})

See https://github.com/junegunn/fzf/blob/master/README-VIM.md#fzfrun for details.

[Piping]

@junegunn Thanks a bunch

[Piping]

function! Foo()
     if exists('*nvim_open_float_win')
         let b = nvim_create_buf(v:false)
         call nvim_buf_set_option(b, "buftype", "nofile")
         call nvim_buf_set_lines(b,0,-1,v:true,["test"])
         let opts = {'x':100, 'y':5, 'anchor': 'NE'}
         let w =  nvim_open_float_win(b,v:false,60,20,opts)
         hi Floating guibg=#000000
         call setwinvar(w, '&winhl', 'Normal:Floating')
         call setwinvar(w, '&number', 0)
     endif
 endfunction
 call fzf#run({'window': 'call Foo()'})

I tried the following script, but fzf windows is not opened inside the floating windows, any idea?

How does fzf window option locate the window?

[junegunn]

It opens in the "current" window where your cursor is positioned.

[bfredl]

@Piping change v:false to v:true in the open float call.

[Piping]

@bfredl Thanks!

This is what I got!

@junegunn
Awesome.

Although if I adjust the gui terminal size, the nvim crashed.

nvim: ../src/nvim/ui_compositor.c:226: compose_line: Assertion `until <= default_grid.Columns' failed.

@bfredl

[kassio]

I got a nice result with the following:

let g:fzf_layout = { 'window': 'call FloatingFZF()' }
function! FloatingFZF()
  let buf = nvim_create_buf(v:false, v:true)
  call setbufvar(buf, '&signcolumn', 'no')

  let winheight = winheight(0)
  let winwidth = winwidth(0)

  let width = float2nr(winwidth-(winwidth*2/10))

  let opts = {
        \ 'relative': 'editor',
        \ 'row': &lines - 3,
        \ 'col': float2nr((winwidth-width)/2),
        \ 'width': width,
        \ 'height': &lines - 3
        \ }

  call nvim_open_win(buf, v:true, opts)
endfunction

I was trying to achieve a different visual with the "input" in the top and the list of files in a top-down layout, but with the current fzf customization tools I didn't find a way to do it.

[kassio]

little change to keep the floating window centralized horizontally, regardless of any vertical splits.

function! FloatingFZF()
  let buf = nvim_create_buf(v:false, v:true)
  call setbufvar(buf, '&signcolumn', 'no')

  let width = float2nr(&columns - (&columns * 2 / 10))
  let height = &lines - 3
  let y = &lines - 3
  let x = float2nr((&columns - width) / 2)

  let opts = {
        \ 'relative': 'editor',
        \ 'row': y,
        \ 'col': x,
        \ 'width': width,
        \ 'height': height
        \ }

  call nvim_open_win(buf, v:true, opts)
endfunction