Kai Wen Tsai

CS152

861261944

Phase 2 Parser

**Program:**

Program -> Function | Function Program | epsilon

**Function:**

Function -> FUNCTION ident SEMICOLON BEGIN\_PARAMS Declaration\_Block END\_PARAMS BEGIN\_LOCALS Declaration\_Block END\_LOCALS BEGIN\_BODY Statement\_Block END\_BODY

**Declaration\_Block:**

Declaration\_Block -> Declaration SEMICOLON | Declaration SEMICOLON Declaration\_Block | epsilon

**Statement\_Block:**

Statement\_Block -> Statement SEMICOLON | Statement SEMICOLON Statement\_Block

**Declaration:**

Declaration -> ident COMMA Declaration | ident COLON Array\_Block INTEGER

**Array\_Block:**

Array\_Block -> ARRAY L\_SQUARE\_BRACKET number R\_SQUARE\_BRACKET OF | epsilon

**Statement:**

Statement -> Statement\_Var | Statement\_If | Statement\_While | Statement\_Do | Statement\_For | Statement\_Read | Statement\_Write | Statement\_Continue | Statement\_Return

**Statement\_Var:**

Statement\_Var -> Var ASSIGN Expression

**Statement\_If:**

Statement\_If -> IF Bool\_Exp THEN If\_Statement\_Block ENDIF

**If\_Statement\_Block:**

If\_Statement\_Block -> Statement SEMICOLON | Statement SEMICOLON If\_Statement\_Block | Statement SEMICOLON ELSE Statement\_Block

**Statement\_While:**

Statement\_While -> WHILE Bool\_Exp BEGINLOOP Statement\_Block ENDLOOP

**Statement\_Do:**

Statement\_Do -> DO BEGINLOOP Statement\_Block ENDLOOP WHILE Bool\_Exp

**Statement\_For:**

Statement\_For -> FOR Var ASSIGN number SEMICOLON Bool\_Exp SEMICOLON Var ASSIGN Expression BEGINLOOP Statement\_Block ENDLOOP

**Statement\_Read:**

Statement\_Read -> READ Var\_Block

**Var\_Block:**

Var\_Block -> Var COMMA | Var

**Statement\_Write:**

Statement\_Write -> WRITE Var\_Block

**Statement\_Continue:**

Statement\_Continue -> CONTINUE

**Statement\_Return:**

Statement\_Return -> RETURN Expression

**Bool\_Exp:**

Bool\_Exp -> Relation\_And\_Exp Or\_Relation\_And\_Exp\_Block

**Or\_Relation\_And\_Exp\_Block:**

Or\_Relation\_And\_Exp\_Block -> OR Relation\_And\_Exp Or\_Relation\_And\_Exp\_Block | epsilon

**Relation\_And\_Exp:**

Relation\_And\_Exp -> Relation\_Exp And\_Relation\_Block

**And\_Relation\_Block:**

And\_Relation\_Block -> AND Relation\_Exp And\_Relation\_Block | epsilon

**Relation\_Exp:**

Relation\_Exp -> NOT Relation\_Cases | Relation\_Cases

**Relation\_Cases:**

Expression Comp Expression | TRUE | FALSE | L\_PAREN Bool\_Exp R\_PAREN

**Comp:**

Comp -> EQ | NEQ | LT | GT | LTE | GTE

**Expression:**

Expression -> Multiplicative\_Exp Multiplicative\_Exp\_Block

**Multiplicative\_Exp\_Block:**

Multiplicative\_Exp\_Block -> ADD Multiplicative\_Exp Multiplicative\_Exp\_Block | SUB Multiplicative\_Exp Multiplicative\_Exp\_Block | epsilon

**Multiplicative\_Exp:**

Multiplicative\_Exp -> Term Term\_Block

**Term\_Block:**

Term\_Block -> MULT Term Term\_Block | DIV Term Term\_Block | MOD Term Term\_Block | epsilon

**Term:**

Term -> SUB Term\_Cases | Term\_Cases | ident L\_PAREN Expression\_Block R\_PAREN

**Expression\_Block:**

Expression\_Block -> Expression | Expression COMMA Expression\_Block | epsilon

**Term\_Cases:**

Term\_Cases -> Var | number | L\_PAREN Expression R\_PAREN

**Var:**

Var -> ident | ident L\_SQUARE\_BRACKET Expression R\_SQUARE\_BRACKET