/
hanoidb_backend.erl
174 lines (138 loc) · 5.58 KB
/
hanoidb_backend.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
-module(hanoidb_backend).
-include("include/hanoidb.hrl").
-include("src/hanoidb.hrl").
-type options() :: [ atom() | { atom(), term() } ].
-type kvexp_entry() :: { Key :: key(), Value :: value(), TimeOut :: expiry() }.
-type batch_reader() :: any().
-type batch_writer() :: any().
-type random_reader() :: any().
-export([merge/7]).
%%%=========================================================================
%%% API
%%%=========================================================================
%% batch_reader and batch_writer are used by the merging logic. A batch_reader
%% must return the values in lexicographical order of the binary keys.
-callback open_batch_reader(File :: string(), Options :: options())
-> {ok, batch_reader()} | { error, term() }.
-callback read_next(batch_reader())
-> { [kvexp_entry(), ...], batch_reader()} | 'done'.
-callback close_batch_reader( batch_reader() )
-> ok | {error, term()}.
-callback open_batch_writer(File :: string(), Options :: options())
-> {ok, batch_writer()} | {error, term()}.
-callback write_next( kvexp_entry() , batch_writer() )
-> {ok, batch_writer()} | {error, term()}.
-callback write_count( batch_writer() ) ->
{ok, non_neg_integer()} | {error, term()}.
-callback close_batch_writer( batch_writer() )
-> ok | {error, term()}.
-callback open_random_reader(File :: string(), Options :: options()) ->
{ok, random_reader()} | {error, term()}.
-callback file_name( random_reader() ) ->
{ok, string()} | {error, term()}.
-callback lookup( Key :: key(), random_reader() ) ->
not_found | {ok, value()}.
-callback range_fold( fun( (key(), value(), term()) -> term() ),
Acc0 :: term(),
Reader :: random_reader(),
Range :: #key_range{} ) ->
{limit, term(), LastKey :: binary()} | {ok, term()}.
-callback close_random_reader(random_reader()) ->
ok | {error, term()}.
-spec merge(atom(), string(), string(), string(), integer(), boolean(), list()) -> {ok, integer()}.
merge(Mod,A,B,C, Size, IsLastLevel, Options) ->
{ok, IXA} = Mod:open_batch_reader(A, Options),
{ok, IXB} = Mod:open_batch_reader(B, Options),
{ok, Out} = Mod:open_batch_writer(C, [{size, Size} | Options]),
scan(Mod,IXA, IXB, Out, IsLastLevel, [], [], {0, none}).
terminate(Mod, Out) ->
{ok, Count} = Mod:write_count( Out ),
ok = Mod:close_batch_writer( Out ),
{ok, Count}.
step(S) ->
step(S, 1).
step({N, From}, Steps) ->
{N-Steps, From}.
scan(Mod, IXA, IXB, Out, IsLastLevel, AKVs, BKVs, {N, FromPID}) when N < 1, AKVs =/= [], BKVs =/= [] ->
case FromPID of
none ->
ok;
{PID, Ref} ->
PID ! {Ref, step_done}
end,
receive
{step, From, HowMany} ->
scan(Mod, IXA, IXB, Out, IsLastLevel, AKVs, BKVs, {N+HowMany, From})
end;
scan(Mod, IXA, IXB, Out, IsLastLevel, [], BKVs, Step) ->
case Mod:read_next(IXA) of
{AKVs, IXA2} ->
scan(Mod, IXA2, IXB, Out, IsLastLevel, AKVs, BKVs, Step);
done ->
ok = Mod:close_batch_reader(IXA),
scan_only(Mod, IXB, Out, IsLastLevel, BKVs, Step)
end;
scan(Mod, IXA, IXB, Out, IsLastLevel, AKVs, [], Step) ->
case Mod:read_next(IXB) of
{BKVs, IXB2} ->
scan(Mod, IXA, IXB2, Out, IsLastLevel, AKVs, BKVs, Step);
done ->
ok = Mod:close_batch_reader(IXB),
scan_only(Mod, IXA, Out, IsLastLevel, AKVs, Step)
end;
scan(Mod, IXA, IXB, Out, IsLastLevel, [{Key1,_,_}=Entry|AT], [{Key2,_,_}|_]=BKVs, Step)
when Key1 < Key2 ->
case Entry of
{_, ?TOMBSTONE, _} when IsLastLevel ->
scan(Mod, IXA, IXB, Out, true, AT, BKVs, step(Step));
_ ->
{ok, Out3} = Mod:write_next( Entry, Out ),
scan(Mod, IXA, IXB, Out3, IsLastLevel, AT, BKVs, step(Step))
end;
scan(Mod, IXA, IXB, Out, IsLastLevel, [{Key1,_,_}|_]=AKVs, [{Key2,_,_}=Entry|BT], Step)
when Key1 > Key2 ->
case Entry of
{_, ?TOMBSTONE, _} when IsLastLevel ->
scan(Mod, IXA, IXB, Out, true, AKVs, BT, step(Step));
_ ->
{ok, Out3} = Mod:write_next( Entry, Out ),
scan(Mod, IXA, IXB, Out3, IsLastLevel, AKVs, BT, step(Step))
end;
scan(Mod, IXA, IXB, Out, IsLastLevel, [_|AT], [Entry|BT], Step) ->
case Entry of
{_, ?TOMBSTONE, _} when IsLastLevel ->
scan(Mod, IXA, IXB, Out, true, AT, BT, step(Step));
_ ->
{ok, Out3} = Mod:write_next( Entry, Out ),
scan(Mod, IXA, IXB, Out3, IsLastLevel, AT, BT, step(Step, 2))
end.
scan_only(Mod, IX, Out, IsLastLevel, KVs, {N, FromPID}) when N < 1, KVs =/= [] ->
case FromPID of
none ->
ok;
{PID, Ref} ->
PID ! {Ref, step_done}
end,
receive
{step, From, HowMany} ->
scan_only(Mod, IX, Out, IsLastLevel, KVs, {N+HowMany, From})
end;
scan_only(Mod, IX, Out, IsLastLevel, [], {_, FromPID}=Step) ->
case Mod:read_next(IX) of
{KVs, IX2} ->
scan_only(Mod, IX2, Out, IsLastLevel, KVs, Step);
done ->
case FromPID of
none ->
ok;
{PID, Ref} ->
PID ! {Ref, step_done}
end,
ok = Mod:close_batch_reader(IX),
terminate(Mod, Out)
end;
scan_only(Mod, IX, Out, true, [{_,?TOMBSTONE,_}|Rest], Step) ->
scan_only(Mod, IX, Out, true, Rest, step(Step));
scan_only(Mod, IX, Out, IsLastLevel, [Entry|Rest], Step) ->
{ok, Out3} = Mod:write_next( Entry, Out ),
scan_only(Mod, IX, Out3, IsLastLevel, Rest, step(Step)).