**/\*EXAMPLE OF HOW TO ADD AN EXTRA MATCHING VARIABLE, ‘ETHNIC’.\*/**

DATA population; /\*Example of population dataset\*/

input uniqueid gender $ age ethnic $ casecontrol; /\*gender and ethnic are defined as categorical variables by the following $\*/

cards;

1 f 26 1 1

2 m 27 1 1

3 m 30 2 0

4 f 25 2 0

5 m 29 1 0

6 f 26 1 1

7 f 28 2 0

8 f 28 1 0

9 m 25 1 1

10 m 26 2 0

11 f 30 3 0

12 m 29 2 0

13 f 27 1 0

14 m 27 3 0

15 f 26 1 1

16 f 25 2 0

17 f 29 1 0

18 f 30 3 0

19 m 26 1 0

20 m 26 2 1

21 f 30 2 0

22 m 25 3 0

23 m 27 1 0

24 m 28 1 1

;

run;

%LET agerange = 5; /\*For this example, we have chosen the age range to be 5. Controls can therefore be up to 5 years younger or older than the case\*/

%LET ratio = 3; /\*We have chosen to match 3 controls for each case\*/

DATA cases controls;

SET population;

IF casecontrol = 1 THEN OUTPUT cases;

ELSE OUTPUT controls;

RUN;

PROC FREQ NOPRINT DATA=cases;

TABLES age\*gender\*ethnic/OUT=caseout; /\*Since we want ‘ethnic’ to be a matching variable, we need to add it here\*/

RUN;

%MACRO sample(v\_age, v\_gender, v\_count,v\_ethnic); /\*Here, ethnic is also added\*/

DATA qualify1;

SET controls;

WHERE (&v\_age-&agerange <= age <= &v\_age+&agerange)

AND

(gender = "&v\_gender")

AND

(ethnic = "&v\_ethnic"); /\*You will also need to add your extra variable to this step.\*/

case\_age = &v\_age;

case\_gender = "&v\_gender";

case\_ethnic = "&v\_ethnic"; /\* You will also need to add your extra variable to this step.\*/

SEED = RANUNI(0);

PROC SORT;

BY SEED;

DATA qualify2;

SET qualify1 NOBS=totobs;

IF \_N\_ <= &v\_count\*&ratio;

IF &v\_count\*&ratio <= totobs THEN tag = 'yes';

ELSE tag = 'no';

PROC APPEND BASE=matches DATA=qualify2 force; /\*new data set matches will contain the matched controls\*/

PROC SORT DATA=qualify2 OUT=temp1 (KEEP=uniqueid);

BY uniqueid;

PROC SORT DATA=controls OUT=temp2;

BY uniqueid;

DATA controls; /\*the dataset controls is updated so that the controls already matched are removed and can not be matched again\*/

MERGE temp1(IN=in1) temp2(IN=in2);

BY uniqueid;

IF in2 AND NOT in1;

%MEND sample;

DATA \_NULL\_;

SET caseout;

CALL EXECUTE ('%sample('||age||','||gender||','||count||','||ethnic||')'); /\* You will also need to add your extra variable to this step.\*/

RUN;

/\*The next part is for testing if any of the cases have not received the wanted amount of controls\*/

PROC FREQ NOPRINT DATA=matches;

TABLES case\_age\*case\_gender\*case\_ethnic/OUT=con\_out; /\* You will also need to add your extra variable to this step.\*/

PROC SORT DATA = caseout(RENAME=

(age=case\_age gender=case\_gender count=case\_cnt ethnic=case\_ethnic)); /\* You will also need to add your extra variable to this step.\*/

BY case\_age case\_gender case\_ethnic; /\* You will also need to add your extra variable to this step.\*/

PROC SORT DATA = con\_out (RENAME= (count=con\_cnt));

BY case\_age case\_gender case\_ethnic; /\* You will also need to add your extra variable to this step.\*/

DATA final (DROP=percent);

MERGE caseout con\_out;

BY case\_age case\_gender case\_ethnic; /\* You will also need to add your extra variable to this step.\*/

con\_need = case\_cnt\*&ratio;

IF con\_cnt = . THEN con\_cnt = 0;

diff = con\_cnt-con\_need;

PROC PRINT DATA = final; /\*creates a table showing what characterizes the cases who have not received enough matches and how many matches they are missing\*/

WHERE diff < 0;

TITLE 'Insufficient Matches';

RUN;

**RESULT**

| **Obs** | **case\_age** | **case\_gender** | **case\_ethnic** | **case\_cnt** | **con\_cnt** | **con\_need** | **diff** |
| --- | --- | --- | --- | --- | --- | --- | --- |
| **2** | 26 | f | 1 | 3 | 3 | 9 | -6 |
| **4** | 27 | m | 1 | 1 | 0 | 3 | -3 |
| **5** | 28 | m | 1 | 1 | 0 | 3 | -3 |

**LOG**

Please see the file titled ‘Log extra’