48 changes: 48 additions & 0 deletions flang/test/HLFIR/extents-of-shape-of.f90
View file
Original file line number Diff line number Diff line change
@@ -0,0 +1,48 @@
! RUN: bbc -emit-fir -hlfir %s -o - | FileCheck --check-prefix CHECK-ALL --check-prefix CHECK-HLFIR %s
! RUN: bbc -emit-fir -hlfir %s -o - | fir-opt --lower-hlfir-intrinsics | fir-opt --bufferize-hlfir | fir-opt --convert-hlfir-to-fir | FileCheck --check-prefix CHECK-ALL --check-prefix CHECK-FIR %s
subroutine foo(a, b)
real :: a(:, :), b(:, :)
interface
elemental subroutine elem_sub(x)
real, intent(in) :: x
end subroutine
end interface
call elem_sub(matmul(a, b))
end subroutine
! CHECK-ALL-LABEL: func.func @_QPfoo
! CHECK-ALL: %[[A_ARG:.*]]: !fir.box<!fir.array<?x?xf32>> {fir.bindc_name = "a"}
! CHECK-ALL: %[[B_ARG:.*]]: !fir.box<!fir.array<?x?xf32>> {fir.bindc_name = "b"}

! CHECK-HLFIR-DAG: %[[A_VAR:.*]]:2 = hlfir.declare %[[A_ARG]]
! CHECK-HLFIR-DAG: %[[B_VAR:.*]]:2 = hlfir.declare %[[B_ARG]]
! CHECK-HLFIR-NEXT: %[[MUL:.*]] = hlfir.matmul %[[A_VAR]]#0 %[[B_VAR]]#0
! CHECK-HLFIR-NEXT: %[[SHAPE:.*]] = hlfir.shape_of %[[MUL]] : (!hlfir.expr<?x?xf32>) -> !fir.shape<2>
! CHECK-HLFIR-NEXT: %[[EXT0:.*]] = hlfir.get_extent %[[SHAPE]] {dim = 0 : index} : (!fir.shape<2>) -> index
! CHECK-HLFIR-NEXT: %[[EXT1:.*]] = hlfir.get_extent %[[SHAPE]] {dim = 1 : index} : (!fir.shape<2>) -> index
! CHECK-HLFIR-NEXT: %[[C1:.*]] = arith.constant 1 : index
! CHECK-HLFIR-NEXT: fir.do_loop %[[ARG2:.*]] = %[[C1]] to %[[EXT1]] step %[[C1]] {
! CHECK-HLFIR-NEXT: fir.do_loop %[[ARG3:.*]] = %[[C1]] to %[[EXT0]] step %[[C1]] {
! CHECK-HLFIR-NEXT: %[[ELE:.*]] = hlfir.apply %[[MUL]], %[[ARG3]], %[[ARG2]] : (!hlfir.expr<?x?xf32>, index, index) -> f32
! CHECK-HLFIR-NEXT: %[[ASSOC:.*]]:3 = hlfir.associate %[[ELE]] {uniq_name = "adapt.valuebyref"} : (f32) -> (!fir.ref<f32>, !fir.ref<f32>, i1)
! CHECK-HLFIR-NEXT: fir.call
! CHECK-HLFIR-NEXT: hlfir.end_associate
! CHECK-HLFIR-NEXT: }
! CHECK-HLFIR-NEXT: }
! CHECK-HLFIR-NEXT: hlfir.destroy %[[MUL]]

! ...
! CHECK-FIR: fir.call @_FortranAMatmul
! CHECK-FIR-NEXT: %[[MUL:.*]] = fir.load %[[MUL_BOX:.*]] : !fir.ref<!fir.box<!fir.heap<!fir.array<?x?xf32>>>>
! CHECK-FIR-NEXT: %[[C0:.*]] = arith.constant 0 : index
! CHECK-FIR-NEXT: %[[DIMS0:.*]]:3 = fir.box_dims %[[MUL]], %[[C0]]
! CHECK-FIR-NEXT: %[[C1:.*]] = arith.constant 1 : index
! CHECK-FIR-NEXT: %[[DIMS1:.*]]:3 = fir.box_dims %[[MUL]], %[[C1]]
! ...
! CHECK-FIR: %[[SHAPE:.*]] = fir.shape %[[DIMS0]]#1, %[[DIMS1]]#1
! CHECK-FIR-NEXT: %[[C1_1:.*]] = arith.constant 1 : index
! CHECK-FIR-NEXT: fir.do_loop %[[ARG2:.*]] = %[[C1_1]] to %[[DIMS1]]#1 step %[[C1_1]] {
! CHECK-FIR-NEXT: fir.do_loop %[[ARG3:.*]] = %[[C1_1]] to %[[DIMS0]]#1 step %[[C1_1]] {
! ...

! CHECK-ALL: return
! CHECK-ALL-NEXT: }
16 changes: 16 additions & 0 deletions flang/test/HLFIR/getextent.fir
View file
Original file line number Diff line number Diff line change
@@ -0,0 +1,16 @@
// Test hlfir.get_extent operaiton parse, verify (no errors), and unparse
// RUN: fir-opt %s | fir-opt | FileCheck %s

func.func @getextent(%arg0: !fir.shape<3>) {
%0 = hlfir.get_extent %arg0 {dim = 0 : index} : (!fir.shape<3>) -> index
%1 = hlfir.get_extent %arg0 {dim = 1 : index} : (!fir.shape<3>) -> index
%2 = hlfir.get_extent %arg0 {dim = 2 : index} : (!fir.shape<3>) -> index
return
}
// CHECK-LABEL: func.func @getextent
// CHECK: %[[SHAPE:.*]]: !fir.shape<3>
// CHECK-NEXT: %[[EXT0:.*]] = hlfir.get_extent %[[SHAPE]] {dim = 0 : index} : (!fir.shape<3>) -> index
// CHECK-NEXT: %[[EXT1:.*]] = hlfir.get_extent %[[SHAPE]] {dim = 1 : index} : (!fir.shape<3>) -> index
// CHECK-NEXT: %[[EXT2:.*]] = hlfir.get_extent %[[SHAPE]] {dim = 2 : index} : (!fir.shape<3>) -> index
// CHECK-NEXT: return
// CHECK-NEXT: }
18 changes: 18 additions & 0 deletions flang/test/HLFIR/invalid.fir
View file
Original file line number Diff line number Diff line change
Expand Up @@ -500,3 +500,21 @@ func.func @bad_parent_comp6(%arg0: !fir.box<!fir.array<10x!fir.type<t2{i:i32,j:i
%2 = hlfir.parent_comp %arg0 shape %1 : (!fir.box<!fir.array<10x!fir.type<t2{i:i32,j:i32}>>>, !fir.shape<1>) -> !fir.ref<!fir.array<10x!fir.type<t1{i:i32}>>>
return
}

// -----
func.func @bad_shapeof(%arg0: !hlfir.expr<!fir.char<1,10>>) {
// expected-error@+1 {{'hlfir.shape_of' op cannot get the shape of a shape-less expression}}
%0 = hlfir.shape_of %arg0 : (!hlfir.expr<!fir.char<1,10>>) -> !fir.shape<1>
}

// -----
func.func @bad_shapeof2(%arg0: !hlfir.expr<10xi32>) {
// expected-error@+1 {{'hlfir.shape_of' op result rank and expr rank do not match}}
%0 = hlfir.shape_of %arg0 : (!hlfir.expr<10xi32>) -> !fir.shape<42>
}

// -----
func.func @bad_getextent(%arg0: !fir.shape<1>) {
// expected-error@+1 {{'hlfir.get_extent' op dimension index out of bounds}}
%0 = hlfir.get_extent %arg0 {dim = 1 : index} : (!fir.shape<1>) -> index
}
55 changes: 55 additions & 0 deletions flang/test/HLFIR/shapeof-lowering.fir
View file
Original file line number Diff line number Diff line change
@@ -0,0 +1,55 @@
// Test hlfir.shape_of lowering
// RUN: fir-opt %s -bufferize-hlfir | FileCheck %s

func.func @shapeof_asexpr(%arg0: !fir.box<!fir.heap<!fir.array<?xf32>>>) -> !fir.shape<1> {
%c0 = arith.constant 0 : index
%59:3 = fir.box_dims %arg0, %c0 : (!fir.box<!fir.heap<!fir.array<?xf32>>>, index) -> (index, index, index)
%60 = fir.box_addr %arg0 : (!fir.box<!fir.heap<!fir.array<?xf32>>>) -> !fir.heap<!fir.array<?xf32>>
%61 = fir.shape_shift %59#0, %59#1 : (index, index) -> !fir.shapeshift<1>
%62:2 = hlfir.declare %60(%61) {uniq_name = ".tmp.intrinsic_result"} : (!fir.heap<!fir.array<?xf32>>, !fir.shapeshift<1>) -> (!fir.box<!fir.array<?xf32>>, !fir.heap<!fir.array<?xf32>>)
%true = arith.constant true
%63 = hlfir.as_expr %62#0 move %true : (!fir.box<!fir.array<?xf32>>, i1) -> !hlfir.expr<?xf32>
%64 = hlfir.shape_of %63 : (!hlfir.expr<?xf32>) -> !fir.shape<1>
return %64 : !fir.shape<1>
}
// CHECK-LABEL: @shapeof_asexpr
// CHECK: %[[ARG0:.*]]: !fir.box<!fir.heap<!fir.array<?xf32>>>
// CHECK-NEXT: %[[C0:.*]] = arith.constant 0
// CHECK-NEXT: %[[BOX_DIMS:.*]]:3 = fir.box_dims %[[ARG0]], %[[C0]]
// CHECK-NEXT: %[[BOX_ADDR:.*]] = fir.box_addr %[[ARG0]]
// CHECK-NEXT: %[[SHPE_SHFT:.*]] = fir.shape_shift %[[BOX_DIMS]]#0, %[[BOX_DIMS]]#1
// CHECK-NEXT: %[[VAR:.*]]:2 = hlfir.declare %[[BOX_ADDR]](%[[SHPE_SHFT]])
// CHECK-NEXT: %[[TRUE:.*]] = arith.constant true
// CHECK-NEXT: %[[TUPLE0:.*]] = fir.undefined tuple
// CHECK-NEXT: %[[TUPLE1:.*]] = fir.insert_value %[[TUPLE0]], %[[TRUE]]
// CHECK-NEXT: %[[TUPLE2:.*]] = fir.insert_value %[[TUPLE1]], %[[VAR]]#0
// CHECK-NEXT: %[[SHAPE:.*]] = fir.shape %[[BOX_DIMS]]#1
// CHECK-NEXT: return %[[SHAPE]]

func.func @shapeof_elemental() -> !fir.shape<1> {
%c1 = arith.constant 1 : index
%0 = fir.shape %c1 : (index) -> !fir.shape<1>
%1 = hlfir.elemental %0 : (!fir.shape<1>) -> !hlfir.expr<?xindex> {
^bb0(%arg3: index):
hlfir.yield_element %arg3 : index
}
%2 = hlfir.shape_of %1 : (!hlfir.expr<?xindex>) -> !fir.shape<1>
return %2 : !fir.shape<1>
}
// CHECK-LABEL: @shapeof_elemental
// CHECK: %[[C1:.*]] = arith.constant 1 : index
// CHECK-NEXT: %[[SHAPE:.*]] = fir.shape %[[C1]]
// CHECK: fir.do_loop %{{.*}} = %{{.*}} to %[[C1:.*]]
// CHECK: return %[[SHAPE]]

func.func @shapeof_fallback(%arg0: !hlfir.expr<1x2x3xi32>) -> !fir.shape<3> {
%shape = hlfir.shape_of %arg0 : (!hlfir.expr<1x2x3xi32>) -> !fir.shape<3>
return %shape : !fir.shape<3>
}
// CHECK-LABEL: @shapeof_fallback
// CHECK: %[[EXPR:.*]]: !hlfir.expr<1x2x3xi32>
// CHECK-NEXT: %[[C1:.*]] = arith.constant 1 : index
// CHECK-NEXT: %[[C2:.*]] = arith.constant 2 : index
// CHECK-NEXT: %[[C3:.*]] = arith.constant 3 : index
// CHECK-NEXT: %[[SHAPE:.*]] = fir.shape %[[C1]], %[[C2]], %[[C3]] :
// CHECK-NEXT: return %[[SHAPE]]
29 changes: 29 additions & 0 deletions flang/test/HLFIR/shapeof.fir
View file
Original file line number Diff line number Diff line change
@@ -0,0 +1,29 @@
// Test hlfir.shape_of operation parse, verify (no errors), and unparse
// RUN: fir-opt %s | fir-opt | FileCheck --check-prefix CHECK --check-prefix CHECK-ALL %s

// Test canonicalization
// RUN: fir-opt %s --canonicalize | FileCheck --check-prefix CHECK-CANON --check-prefix CHECK-ALL %s

func.func @shapeof(%arg0: !hlfir.expr<2x2xi32>) -> !fir.shape<2> {
%shape = hlfir.shape_of %arg0 : (!hlfir.expr<2x2xi32>) -> !fir.shape<2>
return %shape : !fir.shape<2>
}
// CHECK-ALL-LABEL: func.func @shapeof
// CHECK-ALL: %[[EXPR:.*]]: !hlfir.expr<2x2xi32>

// CHECK-NEXT: %[[SHAPE:.*]] = hlfir.shape_of %[[EXPR]] : (!hlfir.expr<2x2xi32>) -> !fir.shape<2>

// CHECK-CANON-NEXT: %[[C2:.*]] = arith.constant 2 : index
// CHECK-CANON-NEXT: %[[SHAPE:.*]] = fir.shape %[[C2]], %[[C2]] : (index, index) -> !fir.shape<2>

// CHECK-ALL-NEXT: return %[[SHAPE]]

// no canonicalization of expressions with unknown extents
func.func @shapeof2(%arg0: !hlfir.expr<?x2xi32>) -> !fir.shape<2> {
%shape = hlfir.shape_of %arg0 : (!hlfir.expr<?x2xi32>) -> !fir.shape<2>
return %shape : !fir.shape<2>
}
// CHECK-ALL-LABEL: func.func @shapeof2
// CHECK-ALL: %[[EXPR:.*]]: !hlfir.expr<?x2xi32>
// CHECK-ALL-NEXT: %[[SHAPE:.*]] = hlfir.shape_of %[[EXPR]] : (!hlfir.expr<?x2xi32>) -> !fir.shape<2>
// CHECK-ALL-NEXT: return %[[SHAPE]]