国外经典策略库

**（1）基于ADX及EMA的交易系统**

/\*策略说明:基于ADX及EMA进行判断

系统要素:

1. 计算30根k线最高价和最低价的EMA价差

2. 计算12根k线的ADX

入场条件:

满足上根K线的收盘价收于EMA30之上,且ADX向上的条件 在EntryBarBAR内该条件成立

当前价小于等于SellSetup,做空,当条件满足超过EntryBarBAR后,取消入场

当前价大于等于BuySetup,做多,当条件满足超过EntryBarBAR后,取消入场

出场条件:

多：当前价格下破30根K线最高价的EMA

空：当前价格上穿30根K线最低价的EMA

**\*/**

参数：

N: 1 100 14 DMI的N值

M: 1 30 6 ADX均线周期 ,DMI的M值

AVGLEN: 10 50 30 最高最低价的EMA周期数

ENTRYBAR: 1 5 2 保持BuySetup触发BAR数

TR:=SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),N);//收盘价与最低价做差，最高价与前一周期收盘价做差，最低价与前一周期收盘价作差，在上述三个数据中取绝对值最大者，对该最大值做N周期累加求和。。

HD:=HIGH-REF(HIGH,1);//最高价与前一周期最高价做差

LD:=REF(LOW,1)-LOW;//前一周期最低价与最低价做差

DMP:=SUM(IFELSE(HD>0 && HD>LD,HD,0),N);//如果HD>0并且HD>LD,取HD否则取0,对取值做N周期累加求和。

DMM:=SUM(IFELSE(LD>0 && LD>HD,LD,0),N);//如果LD>0并且LD>HD,取LD否则取0,对取值做N周期累加求和。

PDI:DMP\*100/TR;

MDI:DMM\*100/TR;

ADX:MA(ABS(MDI-PDI)/(MDI+PDI)\*100,M);//MDI与PDI差的绝对值与(MDI+PDI)\*100做比值，取该比值的M个周期均值。

ADXR:(ADX+REF(ADX,M))/2;

UPPERMA:=EMA(HIGH,AVGLEN);//计算30根K线最高价的EMA

LOWERMA:=EMA(LOW,AVGLEN);//计算30根K线最低价的EMA

CHANSPREAD:=(UPPERMA-LOWERMA)/2;//通过EMA计算出噪音通道宽度

BUYSETUP:=C>UPPERMA&&ADX>REF(ADX,1);//当ADX向上且当前价大于30根K线最高价的EMA满足买入准备条件

BUYTARGET:=C+CHANSPREAD;//满足买入准备条件时,用前BAR价格计算出多头触发价

MROBS:=BARSLAST(BUYSETUP);//上次满足买入准备条件距离当前BAR的数目

MROBS<=ENTRYBAR&&BKVOL=0&&SKVOL=0&&BARPOS>100&&H>BUYTARGET&&VOL>0,BK;//系统入场

SETSIGPRICETYPE(BK,MAX(OPEN,REF(BUYTARGET,1)));

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=UPPERMA-MINPRICE,SP;//系统出场

SETSIGPRICETYPE(SP,MIN(OPEN,REF(UPPERMA,1)-MINPRICE));

SELLSETUP:=C<LOWERMA&&ADX>REF(ADX,1);//当ADX向上且当前价下于30根K线最低价的EMA满足卖出准备条件

SELLTARGET:=C-CHANSPREAD;//满足卖出准备条件时,用前BAR价格计算出空头触发价

MROSS:=BARSLAST(SELLSETUP);//上次满足卖出准备条件距离当前BAR的数目

MROSS<=ENTRYBAR&&BKVOL=0&&SKVOL=0&&BARPOS>100&&LOW<=SELLTARGET&&VOL>0,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(SELLTARGET,1)));

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>=LOWERMA+MINPRICE,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(LOWERMA,1)+MINPRICE));

AUTOFILTER;

**（2）基于平移的高低点均值通道与K线中值突破的系统**

/\*策略说明:基于平移的高点和低点均线通道与K线中值突破进行判断

系统要素:

1. Range Leader是个当前K线的中点在之前K线的最高点上, 且当前K线的振幅大于之前K线的振幅的K线

2. 计算高点和低点的移动平均线

入场条件:

1、上根K线为RangeLead，并且上一根收盘价大于N周期前高点的MA，当前无多仓，则开多仓

2、上根K线为RangeLead，并且上一根收盘价小于N周期前低点的MA，当前无空仓，则开空仓

出场条件:

1. 开仓后，5个K线内用中轨止损，5个K线后用外轨止损

\*/

参数：

ABSDISP: 1 10 5 高低点均线前移周期

AVGLEN: 1 50 20 高低点均线计算周期

EXITBAR: 1 10 5 止损周期参数，该周期以前中轨止损，以后外轨止损

RANGE1:=HIGH-LOW;

UPPERAVG:=MA(REF(HIGH,ABSDISP),AVGLEN); // 计算N周期前高点的MA，N=参数ABSDISP

LOWERAVG:=MA(REF(LOW,ABSDISP),AVGLEN); // 计算N周期前低点的MA，N=参数ABSDISP

MEDIANPRICE:=(HIGH + LOW)\*0.5;// 计算K线中点

EXITAVG:=MA(REF(MEDIANPRICE,ABSDISP),AVGLEN); // 计算N周期前K线中点的MA，N=参数ABSDISP

RANGELEADB:=MEDIANPRICE>REF(H,1)&&RANGE1>REF(RANGE1,1); //当K线中点大于前一根K线高点并且振幅〉上一根振幅时，RANGELEADB返回1

// 系统入场

BKVOL=0&&SKVOL=0&&REF(RANGELEADB,1)=1&&REF(C,1)>REF(UPPERAVG,1),BK;//上根K线RANGELEADB返回1，并且上一根收盘价大于N周期前高点的MA，当前无多仓，则开多仓

SETSIGPRICETYPE(BK,OPEN);

BKVOL=0&&SKVOL=0&&REF(RANGELEADB,1)=1&&REF(C,1)<REF(LOWERAVG,1),SK;//上根K线RANGELEADS返回1，并且上一根收盘价小于N周期前低点的MA，当前无空仓，则开空仓

SETSIGPRICETYPE(SK,OPEN);

// 系统出场

BKVOL>0&&BARSBK>0&&BARSBK<=EXITBAR&&LOW<EXITAVG,SP;//开仓后N根K线内用中轨止损，N根K线后用上轨止损，N=参数EXITBAR

SETSIGPRICETYPE(SP,MIN(OPEN,EXITAVG));

BKVOL>0&&BARSBK>0&&BARSBK>EXITBAR&&LOW<=UPPERAVG-MINPRICE,SP;

//SETSIGPRICETYPE(SP,MIN(OPEN,UPPERAVG-MINPRICE));

SKVOL>0&&BARSSK>0&&BARSSK<=EXITBAR&&H>=EXITAVG,BP;//开仓后N根K线内用中轨止损，N根K线后用上轨止损，N=参数EXITBAR

SETSIGPRICETYPE(BP,MAX(OPEN,EXITAVG));

SKVOL>0&&BARSSK>0&&BARSSK>EXITBAR&&HIGH>=LOWERAVG+MINPRICE,BP;

//SETSIGPRICETYPE(BP,MAX(OPEN,LOWERAVG+MINPRICE));

AUTOFILTER;

**（3）基于平移布林通道的系统**

/\*策略说明:基于平移的boll通道突破系统

系统要素:

1. 平移的boll通道

入场条件:

1、关键价格突破通道上轨，则开多仓

2、关键价格突破通道下轨，则开空仓

出场条件:

1、关键价格突破通道上轨，则平空仓

2、关键价格突破通道下轨，则平多仓

**\*/**

参数：

SDLEN：1 20 12 boll标准差周期参数

AVGLEN：1 10 3 boll均线周期参数

SDEV：1 10 2 boll通道倍数参数

DISP：1 20 16 boll平移参数

//平移BOLL通道计算

AVGVAL:=MA(C,AVGLEN);

SDMULT:=STD(C,SDLEN)\*SDEV;

DISPTOP:=REF(AVGVAL,DISP)+SDMULT;

DISPBOTTOM:=REF(AVGVAL,DISP)-SDMULT;

//系统入场

BKVOL=0&&SKVOL=0&&HIGH>=REF(DISPTOP,1),BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(DISPTOP,1)));

BKVOL=0&&SKVOL=0&&LOW<=REF(DISPBOTTOM,1),SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(DISPBOTTOM,1)));

//系统出场

BKVOL>0&&BARSBK>0&&LOW<=REF(DISPBOTTOM,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(DISPBOTTOM,1)));

SKVOL>0&&BARSSK>0&&HIGH>=REF(DISPTOP,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(DISPTOP,1)));

AUTOFILTER;

**（4）基于置换均线的二次穿越突破系统**

/\*策略说明:本策略是基于置换均线的二次穿越突破系统

系统要素:

1. 将移动平均K线向后平移一定BAR数即为置换均线

2. 相隔一定BAR数的收盘价二次穿越置换均线

3. 二次穿越完成时那根BAR的高点（或低点）作为突破进场价

4. 完成二次穿越的一定BAR数内突破

入场条件:

1. 有效期内价格向上突破设定进场价做多

2. 有效期内价格向下突破设定进场价做空

出场条件:

1. 价格反向穿越均线后止损

2. 基于N根K线的高低点的跟踪止损

**\*/**

参数：

AVGLENGTH：1 10 5 均线周期

AVGDISPLACE：1 10 5 置换均线向后平移Bar数

VALIDBARS2：1 10 5 开仓先决条件之二（上穿后再下穿）条件值保持有效的BAR数

VALIDBARS1：1 10 5 开仓先决条件之一（收盘价上穿DMA均线）条件值保持有效的BAR数

VALIDBARS3：1 10 5 开仓先决条件（上穿再下穿再上穿）条件值保持有效的BAR数

TRAILSBARS：1 10 5 多少根BAR的最低价作为跟踪止损价

// 计算置换均线

MA1:=MA(CLOSE,AVGLENGTH);

DMA1:=REF(MA1,AVGDISPLACE);

// 判断收盘价是否穿越置换均线

CONCROSSOVER:=CROSSUP(CLOSE,DMA1);

CONCROSSUNDER:=CROSSDOWN(CLOSE,DMA1);

// 计算最近的一次下穿发生的BAR离当前BAR的根数

BARSLASTCRSUND:=BARSLAST(CONCROSSUNDER=1);

// 计算最近的两次上穿发生的BAR离当前BAR的根数

BARSSECCRSOVR:=BARSLAST(CONCROSSOVER=1);

BARSFSTCRSOVR:=BARSSECCRSOVR+REF(BARSLAST(CONCROSSOVER=1),BARSSECCRSOVR);

//计算最近的一次上穿发生的BAR离当前BAR的根数

BARSLASTCRSOVR:=BARSLAST(CONCROSSOVER=1);

//计算最近的两次下穿发生的BAR离当前BAR的根数

BARSSECCRSUND:=BARSLAST(CONCROSSUNDER=1);

BARSFSTCRSUND:=BARSSECCRSUND+REF(BARSLAST(CONCROSSUNDER=1),BARSSECCRSUND);

// 设置开仓标志

TJ:=CONCROSSOVER&&(BARSLASTCRSUND-BARSSECCRSOVR)<=VALIDBARS2&&BARSFSTCRSOVR-BARSLASTCRSUND<=VALIDBARS1;

ENTRYPOINT:=HIGH+MINPRICE;

TJ1:=CONCROSSUNDER&&(BARSLASTCRSOVR-BARSSECCRSUND)<=VALIDBARS2&&BARSFSTCRSUND-BARSLASTCRSOVR<=VALIDBARS1;

ENTRYPOINT1:=LOW-MINPRICE;

//开仓

TJ&&BKVOL=0&&SKVOL=0&&0<=VALIDBARS3&&HIGH>=ENTRYPOINT&&VOL>0,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,ENTRYPOINT));

TJ1&&BKVOL=0&&SKVOL=0&&0<=VALIDBARS3&&LOW<=ENTRYPOINT1&&VOL>0,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,ENTRYPOINT1));

// 止损价格计算

REVERSALPRICE:=REF(DMA1,1)-MINPRICE;

TRAILSTOPPRICE:=LLV(REF(LOW,1),TRAILSBARS);

REVERSALPRICE1:=REF(DMA1,1)+MINPRICE;

TRAILSTOPPRICE1:=HHV(REF(H,1),TRAILSBARS);

// 平仓

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=MAX(REVERSALPRICE,TRAILSTOPPRICE),SP;

SETSIGPRICETYPE(SP,MIN(OPEN, MAX(REVERSALPRICE,TRAILSTOPPRICE)));

SKVOL>0&&BARSSK>0&&VOL>0&&H>=MIN(REVERSALPRICE1,TRAILSTOPPRICE1),BP;

SETSIGPRICETYPE(BP,MIN(REVERSALPRICE1,TRAILSTOPPRICE1));

AUTOFILTER;

**（5）基于均线和形态的高低点突破系统多**

/\*策略说明:本策略是基于均线和K线形态的高低点突破系统

系统要素:

1. 根据价格与快速均线和慢速均线的关系来判断大的趋势，价格在上为多头趋势，在下为空头趋势

2. 根据2根K线收盘位置构成的形态来判断小趋势，第一根收盘靠近低点第二根收盘靠近高点为上涨趋势，否则为下跌趋势

3. 最近2根K线的高低点形成的通道

入场条件:

1. 大趋势为多头趋势，且K线形态也为多头趋势时，突破通道高点做多

2. 大趋势为空头趋势，且K线形态也为空头趋势时，突破通道低点做空

出场条件:

1. 开多以开仓BAR的最近N根BAR的低点作为止损价

开空以开仓BAR的最近N根BAR的高点作为止损价

2. 盈利超过止损额的一定倍数止盈

**\*/**

参数：

FASTLENGTH：1 10 8 快速均线周期

SLOWLENGTH：1 100 40 慢速均线周期

RISKLENGTH：1 10 2 止损通道的周期数

PROFITFACTOR：1 10 2 止盈相对止损的倍数

//计算及输出均线指标

MA\_FAST:=MA(CLOSE,FASTLENGTH);

MA\_SLOW:=MA(CLOSE,SLOWLENGTH);

//每根K线的波动范围

RANGE1:=HIGH-LOW;

//K线形态判断的2个条件

CONDITION1:=CLOSE<=LOW+0.25\*RANGE1;

CONDITION2:=CLOSE>=HIGH-0.25\*RANGE1;

CONDITION11:=CLOSE>=HIGH-0.25\*RANGE1;

CONDITION21:=CLOSE<=LOW+0.25\*RANGE1;

//计算周期的高低点

HH:=HHV(HIGH,2);

LL:=LLV(LOW,RISKLENGTH);

LL1:=LLV(LOW,2);

HH1:=HHV(HIGH,RISKLENGTH);

//开仓

BKVOL=0&&SKVOL=0&&REF(CONDITION1,2)=1&&REF(CONDITION2,1)=1&&REF(C,1)>REF(MA\_FAST,1)&&REF(C,1)>REF(MA\_SLOW,1)&&VOL>0&&HIGH>=REF(HH,1)+MINPRICE,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(HH,1)+MINPRICE));

LONGRISK:=REF(LL,1)-MINPRICE;

BKVOL=0&&SKVOL=0&&REF(CONDITION11,2)=1&&REF(CONDITION21,1)=1&&REF(C,1)<REF(MA\_FAST,1)<REF(MA\_SLOW,1)&&VOL>0&&LOW<REF(LL1,1)-MINPRICE,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(LL1,1)-MINPRICE));

SHORTRISK:=REF(HH1,1)+MINPRICE;

// 平仓

BKVOL>0&&BARSBK>0&&VOL>0&&HIGH>BKPRICE+PROFITFACTOR\*(BKPRICE-LONGRISK),SP;//止盈

SETSIGPRICETYPE(SP,MAX(OPEN,BKPRICE+PROFITFACTOR\*(BKPRICE-LONGRISK)));

BKVOL>0&&BARSBK>0&&VOL>0&&LOW <= LONGRISK,SP;//止损

SETSIGPRICETYPE(SP,MIN(OPEN,LONGRISK));

SKVOL>0&&BARSSK>0&&VOL>0&&LOW<=SKPRICE-PROFITFACTOR\*(SHORTRISK-SKPRICE),BP;// 止盈

SETSIGPRICETYPE(BP,MIN(OPEN,SKPRICE-PROFITFACTOR\*(SHORTRISK-SKPRICE)));

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>=SHORTRISK,BP;//止损

SETSIGPRICETYPE(BP,MAX(OPEN,SHORTRISK));

AUTOFILTER;

**（6）基于MACD判断的交易系统**

/\*策略说明:基于MACD在价格回撤时进行判断的交易系统

系统要素:

多：

1. 用MACD慢线在零轴上判断趋势

2. 在多头趋势中以收盘价和波动率构成入场出场通道

空：

1. 用MACD慢线在零轴下判断趋势

2. 在空头趋势中以收盘价和波动率构成入场出场通道

入场条件:

1. 价格高于MACD慢线上穿零轴的当前价格和波动率组成的通道上轨，做多

2. 价格低于MACD慢线下穿零轴的当前价格和波动率组成的通道下轨，做空

出场条件:

多：

1. macd慢线在零轴下

2. 价格低于MACD慢线上穿零轴的当前价格和波动率组成的通道下轨

3. 价格低于多头趋势形成时的最低价格出场

空：

1. macd慢线在零轴上

2. 价格高于MACD慢线下穿零轴的当前价格和波动率组成的通道上轨

3. 价格高于空头趋势形成时的最高价格出场

**\*/**

参数：

FASTMA：1 10 4 macd短周期值

SLOWMA：1 20 10 macd长周期值

AVGMA：1 20 16 MACD慢线周期值

ATRLEN：1 100 10 atr周期值

EATRPCNT：1 10 1 入场通道波动率过滤数值

XATRPCNT：1 10 1 出场通道波动率过滤数值

MACDLINE:=EMA(CLOSE,FASTMA)-EMA(CLOSE,SLOWMA);//计算MACD快线

SIGNALLINE:=EMA(MACDLINE,AVGMA);//计算MACD慢线

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

AATR:=MA(TRUERANGE,ATRLEN);//计算ATR波动率

ZEROLINE:=0;//零轴

CON1:=CROSSUP(SIGNALLINE,ZEROLINE);//慢线上穿零轴

CON2:=CROSSDOWN(SIGNALLINE,ZEROLINE);//慢线下穿零轴

UPTREND:=IF(CON1||NOT(CON2),1,0);

SIGNALFLAG:=IF(BKVOL>0||NOT(CON1)||NOT(CON2),1,0);

DNTREND:=IF(NOT(CON1)||CON2,1,0);

BUYSETUP:=IF(BKVOL=0||NOT(CON2)||UPTREND=1&&SIGNALFLAG=0,1,0);

CTRENDLOW:=VALUEWHEN((UPTREND=1&&SIGNALFLAG=0)||(UPTREND=1&&MACDLINE<SIGNALLINE&&LOW<LOOP2(CTRENDLOW=NULL,NULL,REF(CTRENDLOW,1))),LOW);// 满足入场条件设定入场价格以及出场价格

UPPERBAND:=VALUEWHEN(REF(BUYSETUP,1)=1&&REF(BUYSETUP,2)=0,REF(C,1)+(EATRPCNT\*REF(AATR,1)));

EXITBAND:=VALUEWHEN(REF(BUYSETUP,1)=1&&REF(BUYSETUP,2)=0,REF(CLOSE,1)-(XATRPCNT\*REF(AATR,1)));

SIGNALFLAG1:=IF(SKVOL>0||NOT(CON1)||NOT(CON2),1,0);

SELLSETUP:=IF(SKVOL=0||NOT(CON1)||DNTREND=1&&SIGNALFLAG1=0,1,0);

CTRENDHIGH:=VALUEWHEN((DNTREND=1&&SIGNALFLAG1=0)||(DNTREND=1&&MACDLINE>SIGNALLINE&&HIGH>LOOP2(CTRENDHIGH=NULL,NULL,REF(CTRENDHIGH,1))),HIGH);// 满足入场条件设定入场价格以及出场价格

LOWERBAND :=VALUEWHEN(REF(SELLSETUP,1)=1&&REF(SELLSETUP,2)=0,REF(CLOSE,1)-(EATRPCNT\*REF(AATR,1)));

EXITBAND1:=VALUEWHEN(REF(SELLSETUP,1)=1&&REF(SELLSETUP,2)=0,REF(CLOSE,1)+(XATRPCNT\*REF(AATR,1)));

//系统入场

REF(BUYSETUP,1)=1&&BKVOL=0&&SKVOL=0&&HIGH>=UPPERBAND,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,UPPERBAND));

REF(SELLSETUP,1)=1&&BKVOL=0&&SKVOL=0&&LOW<=LOWERBAND,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,LOWERBAND));

//系统出场

BKVOL>0&&BARSBK>0&&REF(DNTREND,1)=1,SP;//多头趋势不在时,多头出场

SETSIGPRICETYPE(SP,OPEN);

BKVOL>0&&BARSBK>0&&LOW<=REF(CTRENDLOW,1)-MINPRICE&&REF(CTRENDLOW,1)-MINPRICE>=EXITBAND,SP;//持有多单后低于入场最低价格出场

SKVOL>0&&BARSSK>0&&REF(UPTREND,1)=1,BP;

SETSIGPRICETYPE(BP,OPEN);

SKVOL>0&&BARSSK>0&&H>REF(CTRENDHIGH,1)+MINPRICE&&REF(CTRENDHIGH,1)+MINPRICE<=EXITBAND1,BP;

//SETSIGPRICETYPE(SP,MIN(OPEN,REF(CTRENDLOW,1)-MINPRICE));

//SETSIGPRICETYPE(BP,MAX(OPEN,REF(CTRENDHIGH,1)+MINPRICE));

BKVOL>0&&BARSBK>0&&LOW<=EXITBAND,SP;//持有多单后低于出场价格出场

SKVOL>0&&BARSSK>0&&HIGH>=EXITBAND1,BP;

//SETSIGPRICETYPE(SP,MIN(OPEN,EXITBAND));

//SETSIGPRICETYPE(BP,MAX(OPEN, EXITBAND));

AUTOFILTER;

**（7）四均线交易系统**

/\*策略说明:基于4均线系统进行判断交易

系统要素:

(5和20周期均线),(3和10周期均线)构成的两组不同周期的均线组合

入场条件:

多：

当2组均线均成多头排列时且当前价高于上根BAR最高价入场

空：

当2组均线均成空头排列时且当前价低于上根BAR最低价入场

出场条件:

多：

1 小周期多头均线组合成空头排列

2 两组空头均线分别空头排列且低于上根BAR最低价出场

空：

1 小周期空头均线组合成多头排列

2 两组多头均线分别多头排列且低于上根BAR最高价出场

\*/

参数：

LEFAST：1 10 5 多头入场短均线周期参数

LESLOW：1 100 20 多头入场长均线周期参数

LXFAST： 1 10 3 多头出场短均线周期参数

LXSLOW：1 50 10 多头出场长均线周期参数

SEFAST：1 10 5 空头入场短均线周期参数

SESLOW：1 100 20 空头入场长均线周期参数

SXFAST：1 10 3 空头出场短均线周期参数

SXSLOW：1 100 10 空头出场长均线周期参数

MALEFAST:=MA(CLOSE,LEFAST);//多头入场短均线

MALESLOW:=MA(CLOSE,LESLOW);//多头入场长均线

MALXFAST:=MA(CLOSE,LXFAST);//多头出场短均线

MALXSLOW:=MA(CLOSE,LXSLOW);//多头出场长均线

MASEFAST:=MA(CLOSE,SEFAST);//空头入场短均线

MASESLOW:=MA(CLOSE,SESLOW);//空头入场长均线

MASXFAST:=MA(CLOSE,SXFAST);//空头出场短均线

MASXSLOW:=MA(CLOSE,SXSLOW);//空头出场长均线

//系统入场

BKVOL<=0&&BARPOS>=100&&REF(MALEFAST,1)>REF(MALESLOW,1)&&REF(MALXFAST,1)>REF(MALXSLOW,1)&&HIGH>=REF(HIGH,1)&&VOL>0,BK;//两组均线均成多头排列时且当前价高于上根BAR最高价入场

SETSIGPRICETYPE(BK,MAX(OPEN,REF(H,1)));

SKVOL<=0&&BARPOS>=100&&REF(MASEFAST,1)<REF(MASESLOW,1)&&REF(MASXFAST,1)<REF(MASXSLOW,1)&&LOW<=REF(LOW,1)&&VOL>0,SK;//两组均线均成空头排列时且当前价低于上根BAR最低价入场

SETSIGPRICETYPE(SK,MIN(OPEN,REF(LOW,1)));

//系统出场

BKVOL>0&&BARSBK>0&&VOL>0&&REF(MALXFAST,1)<REF(MALXSLOW,1),SP;

SETSIGPRICETYPE(SP,OPEN);

BKVOL>0&&BARSBK>0&&VOL>0&&REF(MASEFAST,1)<REF(MASESLOW,1)&&REF(MASXFAST,1)<REF(MASXSLOW,1)&&L<REF(L,1),SP;

SKVOL>0&&BARSSK>0&&VOL>0&&REF(MASXFAST,1)>REF(MASXSLOW,1),BP;//小周期空头均线组合成多头排列出场

SETSIGPRICETYPE(BP,OPEN);

SKVOL>0&&BARSSK>0&&VOL>0&&REF(MALEFAST,1)>REF(MALESLOW,1)&&REF(MALXFAST,1)>REF(MALXSLOW,1)&&HIGH>=REF(H,1),BP;//两组均线分别多头排列且高于上根BAR最高价出场

SETSIGPRICETYPE(BP,MAX(OPEN,REF(HIGH,1)));

//SETSIGPRICETYPE(SP,MIN(OPEN,REF(LOW,1)));

AUTOFILTER;

**（8）价格通道突破, 在价格回调时进行判断**

/\*策略说明:

1.计算价格通道

2.收盘价加上ATR的一定倍数作为进场价

入场条件:

多：

1.上一根Bar创新高

2.当前Bar最高价突破上一根Bar收盘价加上ATR的一定倍数

空：

1.上一根Bar创新低

2.当前Bar最低价突破上一根Bar收盘价减去ATR的一定倍数

出场条件:

多：

1.记录多头进场后的跟踪止损价

2.价格向下突破跟踪止损价多头出场

空：

1.记录空头进场后的跟踪止损价

2.价格向上突破跟踪止损价空头出场

\*/

参数：

LENGTH：1 100 10 用于计算ATR和新低价的Bar数

TRIGGER：0 1 0.79 用于计算空头进场价的驱动系数

FIRST：1 10 5 用于计算在进场Bar设置止损价的系数

ACCELER：0 1 0.05 抛物线的加速系数

//初始设置

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

ATR:=MA(TRUERANGE,LENGTH);

CONDITION1:=HIGH>HHV(REF(HIGH,1),LENGTH);

CONDITION2:=LOW<LLV(REF(L,1),LENGTH);

//上一根BAR创新高后且当前BAR最高价突破上一根BAR收盘价加上ATR的一定倍数多头入场

REF(CONDITION1,1)=1&&H>=REF(C,1)+REF(ATR,1)\*TRIGGER&&VOL>0,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(CLOSE,1)+REF(ATR,1)\*TRIGGER));

//上一根BAR创新低后且当前BAR最低价突破上一根BAR收盘价减去ATR的一定倍数空头入场

REF(CONDITION2,1)=1&&L<=REF(C,1)-REF(ATR,1)\*TRIGGER&&VOL>0,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(C,1)-REF(ATR,1)\*TRIGGER));

//记录盈利峰值价和跟踪止损价

STOPATR:=MA(TRUERANGE,3);

AF:=LOOP2(NOT(BKVOL>0&&BARSBK>0&&BKHIGH>REF(BKHIGH,1)&&AF<0.2),IF(BKVOL>0&&BARSBK=NULL,ACCELER,NULL),AF+MIN(ACCELER,0.2-AF));

STOPPRICE:=IF(BKVOL>0&&BARSBK=NULL,LOW-STOPATR\*FIRST,LOOP2(BKVOL>0&&BARSBK>0,STOPPRICE+AF\*(HIGH-STOPPRICE),NULL));

AF1:=LOOP2(NOT(SKVOL>0&&BARSSK>0&&SKLOW<REF(SKLOW,1)&&AF<0.2),IF(SKVOL>0&&BARSSK=NULL,ACCELER,NULL),AF+MIN(ACCELER,0.2-AF));

STOPPRICE1:=IF(SKVOL>0&&BARSSK=NULL,HIGH+STOPATR\*FIRST,LOOP2(SKVOL>0&&BARSSK>0,STOPPRICE-AF1\*(STOPPRICE-LOW),NULL));

//向下突破跟踪止损价多头出场

BKVOL>0&&BARSBK>0&&LOW<=REF(STOPPRICE,1)&&VOL>0,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(STOPPRICE,1)));

//向上突破跟踪止损价空头出场

SKVOL>0&&BARSSK>0&&HIGH>=REF(STOPPRICE1,1)&&VOL>0,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(STOPPRICE1,1)));

AUTOFILTER;

**（9）基于k线建立箱体基于突破进行系统交易**

/\*策略说明:本策略基于k线形成的区域设置进出场价格, 通过价格的上下突破来进行交易或取消做单

系统要素:

k线区域按时间顺序从左向右共由4根k线组成, 最左边的k线标号为3

1. 如果1号k线收盘价高于3号k线最高点, 开始设置做多交易区域, 上轨为3号K线高点, 下轨为标号为1起CancelFlagN根K线的低点

如果标号为0的K线收盘价在上下轨之间, 则做多区域设置成功, 如果收盘价低于下轨则区域设置取消

2. 如果1号k线收盘价低于3号k线最低点, 开始设置做空交易区域, 下轨为3号K线低点, 上轨为标号为1起CancelFlagN根K线的高点

如果标号为0的K线收盘价在上下轨之间, 则做空区域设置成功, 如果收盘价高于上轨则区域设置取消

入场条件:

1. 做多区域设置成功时, 当前k线高于标号为0的K线高点时入场做多

2. 做空区域设置成功时, 当前k线低于标号为0的K线低点时入场做空

出场条件:

1. 基于ATR的保护性止损

2. 基于ATR的盈亏平衡止损

3. 基于ATR的盈利止盈

\*/

参数：

ATRLENGTH：1 100 10 ATR的值

CANCELFLAGN：1 10 5 用于计算取消区域成功设置标志的上下轨的N值

PROTECT：0 1 0.5 保护性止损的ATR乘数

PROFITTARGET：1 10 5 盈利止盈的ATR乘数

BREAK：0 10 3 盈亏平衡止损的ATR乘数

//系统设置

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

ATR:=MA(TRUERANGE,ATRLENGTH);

DOWNLINETEMP:=LLV(LOW,CANCELFLAGN);

UPLINETEMP:=HHV(HIGH,CANCELFLAGN);

//K线区域按时间顺序从左向右共由4根K线组成, 最左边的K线标号为3, 当前K线标号为0

//如果1号K线收盘价高于3号K线最高点, 开始设置做多交易区域, 上轨为3号K线高点, 下轨为从标号为1起CANCELFLAGN根K线的低点

//如果标号为0的K线收盘价在上下轨之间, 则做多区域设置成功, 做多触发价为标号为0的K线高点, 如果之后K线收盘价低于下轨则区域设置取消

//如果1号K线收盘价低于3号K线最低点, 开始设置做空交易区域, 下轨为3号K线低点, 上轨为从标号为1起CANCELFLAGN根K线的高点

//如果标号为0的K线收盘价在上下轨之间, 则做空区域设置成功, 做空触发价为标号为0的K线低点, 如果之后K线收盘价高于下轨则区域设置取消

ENTRYFLAG:=LOOP2(REF(ENTRYFLAG,1)=1&&C<REF(DOWNLINETEMP,1)||ISLASTBK,0,LOOP2(BKVOL<=0&&REF(ENTRYFLAG,1)=0&&REF(C,1)>=REF(H,3)&&C<=REF(H,3)&&C>=REF(DOWNLINETEMP,1),1,0));

UPLINE:=VALUEWHEN(BKVOL<=0&&REF(ENTRYFLAG,1)=0&&REF(C,1)>=REF(H,3),REF(H,3));

DOWNLINE:=VALUEWHEN(BKVOL<=0&&REF(ENTRYFLAG,1)=0&&REF(C,1)>=REF(H,3),REF(DOWNLINETEMP,1));

ENTRYPRICEL:=VALUEWHEN(BKVOL<=0&&REF(ENTRYFLAG,1)=0&&REF(C,1)>=REF(H,3)&&C<=REF(H,3)&&C>=REF(DOWNLINETEMP,1),H);

ENTRYFLAG1:=LOOP2(REF(ENTRYFLAG1,1)=1&&C>REF(UPLINETEMP,1)||ISLASTSK,0,LOOP2(SKVOL<=0&&REF(ENTRYFLAG1,1)=0&&REF(C,1)<=REF(L,3)&&C<=REF(UPLINETEMP,1)&&C>=L,1,0));

UPLINE1:=VALUEWHEN(SKVOL<=0&&REF(ENTRYFLAG1,1)=0&&REF(C,1)<=REF(L,3),REF(UPLINETEMP,1));

DOWNLINE1:=VALUEWHEN(SKVOL<=0&&REF(ENTRYFLAG1,1)=0&&REF(C,1)<=REF(L,3),L);

ENTRYPRICES1:=VALUEWHEN(SKVOL<=0&&REF(ENTRYFLAG1,1)=0&&REF(C,1)<=REF(L,3)&&C<=UPLINE1&&C>=DOWNLINE1,L);

//系统入场

//做多区域设置成功时, 当前K线高于标号为0的K线高点时入场做多

BKVOL<=0&&BARPOS>=ATRLENGTH&&REF(ENTRYFLAG,1)=1&&HIGH>REF(ENTRYPRICEL,1)&&VOL>0,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(ENTRYPRICEL,1)));

//基于ATR的保护性止损

PROTECTSTOPL:=REF(L,1)-PROTECT\*REF(ATR,1);

//基于ATR的盈利止盈

PROFITTARGETSTOPL:=REF(HIGH,1)+PROFITTARGET\*REF(ATR,1);

//做空区域设置成功时, 当前K线低于标号为1的K线低点时入场做多

SKVOL<=0&&BARPOS>=ATRLENGTH&&REF(ENTRYFLAG1,1)=1&&LOW<=REF(ENTRYPRICES1,1)&&VOL>0,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(ENTRYPRICES1,1)));

//基于ATR的保护性止损

PROTECTSTOPS:=REF(HIGH,1)+PROTECT\*REF(ATR,1);

//基于ATR的盈利止盈

PROFITTARGETSTOPS:=REF(LOW,1)-PROFITTARGET\*REF(ATR,1);

//系统出场

//基于ATR的盈亏平衡止损

BREAKEVENSTOPL:=BKPRICE;

TJ1:=REF(BKHIGH,1)>=BREAKEVENSTOPL+BREAK\*REF(ATR,1);

EXITLINEL:=VALUEWHEN(BKVOL>0&&REF(BKVOL,1)>0&&VOL>0,IF(TJ1,BREAKEVENSTOPL,REF(PROTECTSTOPL,1)));

//出场

//基于ATR的盈利止盈

BKVOL>0&&REF(BKVOL,1)>0&&VOL>0&&OPEN>=REF(PROFITTARGETSTOPL,1),SP;

SETSIGPRICETYPE(SP,OPEN);

BKVOL>0&&REF(BKVOL,1)>0&&VOL>0&&L<=EXITLINEL,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,EXITLINEL));

//基于ATR的盈亏平衡止损

BREAKEVENSTOPS:=SKPRICE;

TJ11:=REF(SKLOW,1)<=BREAKEVENSTOPS-BREAK\*REF(ATR,1);

EXITLINES1:=VALUEWHEN(SKVOL>0&&REF(SKVOL,1)>0&&VOL>0,IF(TJ11,BREAKEVENSTOPS,REF(PROTECTSTOPS,1)));//出场线选择

//出场

//基于ATR的盈利止盈

SKVOL>0&&REF(SKVOL,1)>0&&VOL>0&&OPEN<=REF(PROFITTARGETSTOPS,1),BP;

SETSIGPRICETYPE(BP,OPEN);

//基于ATR的保护性止损或盈亏平衡止损

SKVOL>0&&REF(SKVOL,1)>0&&VOL>0&&H>=EXITLINES1,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,EXITLINES1));

AUTOFILTER;

**（10）基于价格区间突破的交易系统**

/\*策略说明:基于通道突破的判断

系统要素:

1. 计算50根k线最高价的区间

2. 计算30根k线最低价的区间

入场条件:

多：

1.价格高于50根K线最高价的区间入场

空：

1.价格低于50根K线最低价的区间入场

出场条件:

多：

1. 当前价格低于30根K线最低价的区间出场

2. 当前价格低于入场价一定ATR波动率幅度出场

空：

1. 当前价格高于30根K线最高价的区间出场

2. 当前价格高于入场价一定ATR波动率幅度出场

\*/

参数：

ATRVAL：1 100 10 波动率参数

LENGTH1：1 100 50 长周期区间参数

LENGTH2：1 100 30 短周期区间参数

IPS：1 10 4 保护止损波动率参数

//系统设置

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

ATR:=MA(TRUERANGE,ATRVAL);//定义ATR

L1:=MAX(LENGTH1,LENGTH2);//出场周期选择较大的区间参数

L2:=MIN(LENGTH1,LENGTH2);//出场周期选择较小的区间参数

UPPERBAND:=HHV(HIGH,L1);//长周期最高价区间

LOWERBAND:=LLV(LOW,L1);//长周期最低价区间

EXITLONG:=LLV(LOW,L2);//短周期最低价区间

EXITSHORT:=HHV(HIGH,L2);//短周期最高价区间

//系统入场

BKVOL=0&&SKVOL=0&&H>=REF(UPPERBAND,1)+MINPRICE&&VOL>0,BK;//价格大于长周期最高价区间入场做多

SETSIGPRICETYPE(BK,MAX(OPEN,REF(UPPERBAND,1)+MINPRICE));

PROTECTSTOPL:=VALUEWHEN(BKVOL=0&&SKVOL=0&&H>=REF(UPPERBAND,1)+MINPRICE&&VOL>0,BKPRICE-IPS\*REF(ATR,1));

BKVOL=0&&SKVOL=0&&LOW<=REF(LOWERBAND,1)-MINPRICE&&VOL>0,SK;//价格低于长周期最低价区间入场做空

SETSIGPRICETYPE(SK,REF(LOWERBAND,1)-MINPRICE);

PROTECTSTOPS:=VALUEWHEN(BKVOL=0&&SKVOL=0&&LOW<=REF(LOWERBAND,1)-MINPRICE&&VOL>0,SKPRICE+IPS\*REF(ATR,1));

//系统出场

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=REF(PROTECTSTOPL,1)&&REF(PROTECTSTOPL,1)>REF(EXITLONG,1),SP;//价格低于入场价以下一定ATR幅度止损

SETSIGPRICETYPE(SP,MIN(OPEN,REF(PROTECTSTOPL,1)));

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=REF(EXITLONG,1)-MINPRICE,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(EXITLONG,1)- MINPRICE));

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>=REF(PROTECTSTOPS,1)&&REF(PROTECTSTOPS,1)<=REF(EXITSHORT,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(PROTECTSTOPS,1)));

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>=REF(EXITSHORT,1)+MINPRICE,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(EXITSHORT,1)+MINPRICE));

AUTOFILTER;

**（11）基于凯特纳通道的交易系统**

/\*策略说明:基于凯特纳通道的交易系统

系统要素:

1. 计算关键价格的凯特纳通道

2. 价格突破凯特纳通道后，设定入场触发单

入场条件:

1、价格突破凯特纳通道后，在当根K线高点之上N倍通道幅度，设定多头触发单，此开仓点将挂单X根k线

2、价格突破凯特纳通道后，在当根K线低点之下N倍通道幅度，设定空头触发单，此开仓点将挂单X根k线

出场条件:

1. 价格下穿轨道中轨时平仓

2. 价格小于N周期低点平仓

\*/

参数：

LENGTH：1 100 10 均线参数

CONSTT：1 5 1.2 通道倍数

CHANPCNT：0 1 0.5 入场参数

STOPN：1 10 4 低点止损参数

BUYN：1 10 5 入场触发条件有效K线周期

SELLN：1 10 5 入场触发条件有效K线周期

//指标计算

PRICE:=CLOSE;//关键价格，可以换成中位价等

AVGVAL:=MA(PRICE,LENGTH); //计算均线 默认10周期

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

AVGRANGE:=MA(TRUERANGE,LENGTH);//计算真实波动均值(ATR) 默认10周期

KCU:=AVGVAL+AVGRANGE\*CONSTT;//计算通道上轨=均线+1.2倍的10周期真实波动值

KCL:=AVGVAL-AVGRANGE\*CONSTT;//计算通道下轨=均线-1.2倍的10周期真实波动值

CHANRNG:=(KCU-KCL)/2;//通道宽度/2

CON:=CROSSUP(PRICE,KCU);// BOOL变量CON，当价格上穿上轨时为真

SETBAR:=VALUEWHEN(CON,HIGH);

COUNTL:=LOOP2(CON,0,REF(COUNTL,1)+1);

HH:=VALUEWHEN(CON,SETBAR+(CHANRNG\*CHANPCNT));// 当CON为真时，计算开仓线HH，COUNTL重置为0

CON1:=CROSSDOWN(PRICE,KCL);//BOOL变量CON,当价格下穿下轨时为真

SETBAR1:=VALUEWHEN(CON1,LOW);

COUNTS:=LOOP2(CON1,0,REF(COUNTS,1)+1);

LL:=VALUEWHEN(CON1,SETBAR1-(CHANRNG\*CHANPCNT));//当CON1为真时，计算开仓线LL，COUNTS重置为0

//系统入场

BKVOL=0&&SKVOL=0&&REF(PRICE,1)>REF(KCU,1)&&COUNTL<=BUYN&&HIGH>=HH,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,HH));

BKVOL=0&&SKVOL=0&&REF(PRICE,1)<REF(KCL,1)&&COUNTS<=SELLN&&LOW<=LL,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,LL));

//系统出场

CON2:=CROSSDOWN(CLOSE,AVGVAL);//BOOL变量CON，当价格下穿轨道中轨时为真

LSTOPLINE:=LLV(REF(LOW,1),STOPN);

BKVOL>0&&BARSBK>0&&REF(CON2,1)=1,SP;//价格下穿轨道中轨时平仓

SETSIGPRICETYPE(SP,OPEN);

BKVOL>0&&BARSBK>0&&LOW<=LSTOPLINE,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,LSTOPLINE));

CON21:=CROSSUP(CLOSE,AVGVAL);// BOOL变量CON，当价格上穿轨道中轨时为真

SSTOPLINE:=HHV(REF(HIGH,1),STOPN);

SKVOL>0&&BARSSK>0&&REF(CON21,1)=1,BP;//价格上穿轨道中轨时平仓

SETSIGPRICETYPE(BP,OPEN);

SKVOL>0&&BARSSK>0&&HIGH>=SSTOPLINE,BP;

SETSIGPRICETYPE(BP,MAX(SSTOPLINE,OPEN));

AUTOFILTER;

**（12）基于均线的阻力线支撑线系统**

/\*策略说明:本策略基于价格与均线建立了一套可变的支撑线阻力线系统, 通过价格与支撑线阻力线的关系进行交易

系统要素:

均线与价格组成的支撑线阻力线系统

1. 当价格死叉均线时, 上根k线的低点为支撑线初始化, 当价格金叉均线时, 上根k线的高点为阻力线初始化

2. 当价格低于均线时不断更新支撑线, 当价格高于均线时不断更新阻力线

3. 当价格金叉均线又死叉均线时记录上根阻力线作为做多的价格线, 当价格死叉均线又金叉均线时记录上根支撑线作为做空的价格线

入场条件:

1. 当价格高于做多的价格线时做多

2. 当价格低于做空的价格线时做空

出场条件:

1. 基于ATR的保护性止损

2. 基于ATR的跟踪止损

\*/

参数：

MALENGTH：1 100 10 均线值

ATRLENGTH：1 5 1.2 ATR的值

PROTECT：0 1 0.5 保护性止损的ATR乘数

TRAIL：1 10 2.5 跟踪止损的ATR乘数

//系统设置

//均线与ATR计算

MA1:=MA(C,MALENGTH);

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

ATR:=MA(TRUERANGE,ATRLENGTH);//定义ATR

//计算入场线

//1.当价格死叉均线时, 上根K线的低点为支撑线初始化, 当价格金叉均线时, 上根K线的高点为阻力线初始化

//2.当价格低于均线时不断更新支撑线, 当价格高于均线时不断更新阻力线

//3.当价格金叉均线又死叉均线时记录上根阻力线作为做多的价格线

CROSSFLAGFORL:=CROSSDOWN(C,MA1);

CROSSFLAGFORS:=CROSSUP(C,MA1);

SUPPORTFLAG:=LOOP2(CROSSFLAGFORL=1,1,LOOP2(CROSSFLAGFORS=1&&REF(SUPPORTFLAG,1)=1,0,1));

RESISTANCEFLAG:=LOOP2(CROSSFLAGFORL=1&&REF(RESISTANCEFLAG,1)=1,0,LOOP2(CROSSFLAGFORS=1,1,0));

RESISTANCELINE:=LOOP2((CROSSFLAGFORS=1&&REF(SUPPORTFLAG,1)=1&&REF(RESISTANCEFLAG,2)=0)||(C>MA1&&HIGH>REF(RESISTANCELINE,1)),HIGH,NULL);

ENTRYPRICEL:=LOOP2(CROSSFLAGFORL=1&&REF(RESISTANCEFLAG,1)=1&&REF(SUPPORTFLAG,2)=0,REF(RESISTANCELINE,1),NULL);

SUPPORTLINE:=LOOP2((CROSSFLAGFORL=1&&REF(RESISTANCEFLAG,1)=1&&REF(SUPPORTFLAG,2)=0)||(C<MA1&&LOW<REF(SUPPORTLINE,1)),LOW,NULL);

//系统入场

//当上根K线的收盘价格金叉多头入场价格线后, 在本根K线开盘价做多

//当上根K线的收盘价格死叉空头入场价格线后, 在本根K线开盘价做空

BKVOL<=0&&REF(ENTRYPRICEL,1)<>0&&REF(ENTRYPRICEL,2)<>0&&REF(C,2)<REF(ENTRYPRICEL,2)&&REF(C,1)>=REF(ENTRYPRICEL,1)&&VOL>0,BK;

SETSIGPRICETYPE(BK,OPEN);

PROTECTSTOPL:=VALUEWHEN(BKVOL<0&&REF(ENTRYPRICEL,1)<>0&&REF(ENTRYPRICEL,2)<>0,REF(L,1)-PROTECT\*REF(ATR,1));//基于ATR的保护性止损

SKVOL<=0&&REF(SKPRICE,1)<>0&&REF(SKPRICE,2)<>0&&REF(C,2)>REF(SKPRICE,2)&&REF(C,1)<=REF(SKPRICE,1)&&VOL>0,SK;

SETSIGPRICETYPE(SK,OPEN);

PROTECTSTOPS:=VALUEWHEN(SKVOL<=0&&REF(SKPRICE,1)<>0&&REF(SKPRICE,2)<>0,REF(HIGH,1)+PROTECT\*REF(ATR,1));//基于ATR的保护性止损

//系统出场

//基于ATR的跟踪止损

TRAILSTOPL:=REF(BKHIGH,1)-TRAIL\*REF(ATR,1);

BKVOL>0&&REF(BKVOL,1)=1&&VOL>0&&L<=REF(PROTECTSTOPL,1)&&REF(PROTECTSTOPL,1)>=TRAILSTOPL,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(PROTECTSTOPL,1)));//基于ATR的保护性止损

BKVOL>0&&REF(BKVOL,1)=1&&VOL>0&&L<=TRAILSTOPL,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,TRAILSTOPL));

TRAILSTOPS:=REF(SKLOW,1)+TRAIL\*REF(ATR,1);

SKVOL>0&&REF(SKVOL,1)>0&&VOL>0&&H>=REF(PROTECTSTOPS,1)&&REF(PROTECTSTOPS,1)<=TRAILSTOPS,BP;//基于ATR的保护性止损

SETSIGPRICETYPE(BP,MAX(OPEN,REF(PROTECTSTOPS,1)));

SKVOL>0&&REF(SKVOL,1)>0&&VOL>0&&H>=TRAILSTOPS,BP;

SETSIGPRICETYPE(BP,MAX(OPEN, TRAILSTOPS));

AUTOFILTER;

**（13）基于均线交叉的通道突破系统**

/\*策略说明:本策略是基于均线交叉与通道突破相结合的交易系统

系统要素:

1. 以快速均线与慢速均线的交叉初步判断趋势

2. 均线交叉后以最近几根K线的高低点加上一定幅度设定为突破通道

3. 均线交叉后一定K线根数内突破通道则趋势有效，否则等待下次趋势

入场条件:

1. 当价格向上突破通道时做多

2. 当价格向下突破通道时做空

出场条件:

1. 趋势反转突破时平仓

2. 基于周期高低点的跟踪止损

再入场条件:

1. 未发生趋势反转

2. 跟踪止损后一定K线根数内突破止损时N根K线的高低点时再进场

\*/

参数：

FASTLEN：1 10 9 快速均线周期数

SLOWLEN：1 100 18 慢速均线周期数

CHLEN：1 100 12 通道突破的周期数

EXTRAPER：1 1000 300 通道突破的幅度(万分比)，如：300 = 3%

TRAILBAR：1 10 8 通道突破的幅度(万分比)，如：300 = 3%

REENTRY：1 100 10 再进场通道突破的周期数

FASTMA:MA(CLOSE,FASTLEN);

SLOWMA:MA(CLOSE,SLOWLEN);

//判断均线是否金叉

CONCROSSOVER:=CROSSUP(FASTMA,SLOWMA);

//判断均线是否死叉

CONCROSSUNDER:=CROSSDOWN(FASTMA,SLOWMA);

//金叉发生时记录最近CHLEN根BAR的高点加上EXTRAPERCENTAGE%作为开多突破价

HH:=IF(COUNT(ISLASTBK,BARPOS)=0,HHV(HIGH,CHLEN),HHV(HIGH,REENTRY));

LENTRYPRICE:=VALUEWHEN(CONCROSSOVER&&BARPOS>=CHLEN-1,HH\*(1+EXTRAPER\*0.0001));

LCOUNT:=IF(CONCROSSOVER&&BARPOS>=CHLEN-1,BARPOS,IF(CROSS(COUNT(ISLASTBK,BARPOS),0.5)||CROSS(ISLASTSP,0.5),-999,NULL));//记录BAR序号以控制只在金叉后CHLEN根BAR内进场否则放弃本次交易

//死叉发生时记录最近CHLEN根BAR的低点减去EXTRAPERCENTAGE%作为开空突破价

LL:=IF(COUNT(ISLASTBK,BARPOS)=0,LLV(LOW,CHLEN),LLV(LOW,REENTRY));

SENTRYPRICE:=VALUEWHEN(CONCROSSUNDER&&BARPOS>=CHLEN-1,LL\*(1-EXTRAPER\*0.0001));

SCOUNT:=IF(CONCROSSUNDER&&BARPOS>=CHLEN-1,BARPOS,IF(CROSS(COUNT(ISLASTSK=1,BARPOS)=1,0.5)||CROSS(ISLASTSP,0.5),-999,NULL));

//开仓

TJ:=BKVOL=0&&SKVOL=0&&BARPOS>LCOUNT&&BARPOS<=LCOUNT+CHLEN&&HIGH>=LENTRYPRICE&&VOL>0;

TJ,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,LENTRYPRICE));

BKVOL=0&&SKVOL=0&&BARPOS>SCOUNT&&BARPOS<=SCOUNT+CHLEN&&LOW<=SENTRYPRICE&&VOL>0,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,SENTRYPRICE));

//死叉发生时记录最近CHLEN根BAR的低点减去EXTRAPERCENTAGE%%作为开空突破价

//金叉发生时记录最近CHLEN根BAR的高点加上EXTRAPERCENTAGE%%作为开多突破价

LL1:=LLV(LOW,CHLEN);

SCOUNT1:=VALUEWHEN(CONCROSSUNDER&&BARPOS>=CHLEN-1,BARPOS);// 记录BAR序号以控制只在死叉后CHLEN根BAR内突破有效

HH1:=HHV(HIGH,CHLEN);

LENTRYPRICE1:=VALUEWHEN(CONCROSSOVER&&BARPOS>=CHLEN-1,HH1\*(1+EXTRAPER\* 0.01));

LCOUNT1:=VALUEWHEN(CONCROSSOVER&&BARPOS>=CHLEN-1,BARPOS);

//反向突破

BARPOS>SCOUNT1&&BARPOS<=SCOUNT1+CHLEN&&LOW<=SENTRYPRICE&&VOL>0&&BKVOL>0,SP;//有持仓则平仓

SETSIGPRICETYPE(SP,MIN(OPEN,SENTRYPRICE));

TJ1:=BARPOS>SCOUNT1&&BARPOS<=SCOUNT1+CHLEN&&LOW<=SENTRYPRICE&&VOL>0&&BKVOL>0;

TRAILSTOPPRICE:=LLV(REF(L,1),TRAILBAR);

REENTRYCOUNT:=IF(TJ1,-999,IF(BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=TRAILSTOPPRICE,BARPOS,NULL));

REENTRYPRICE:=VALUEWHEN(BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=TRAILSTOPPRICE,HH);

BARPOS>LCOUNT1&&BARPOS<=LCOUNT1+CHLEN&&HIGH>=LENTRYPRICE1&&VOL>0&&SKVOL>0,SP;

SETSIGPRICETYPE(SP,MAX(OPEN,LENTRYPRICE1));

TRAILSTOPPRICE1:=HHV(REF(H,1),TRAILBAR);

REENTRYCOUNT1:=IF(BARPOS>LCOUNT&&BARPOS<=LCOUNT+CHLEN&&HIGH>=LENTRYPRICE1&&VOL>0,-999,IF(SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>TRAILSTOPPRICE1,BARPOS,NULL));

//跟踪止损出场

//计算止损位

//触发止损

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=TRAILSTOPPRICE,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,TRAILSTOPPRICE));

BKVOL=0&&SKVOL=0&&BARSSP>0&&BARPOS<=REENTRYCOUNT+15&&VOL>0&&HIGH>=REENTRYPRICE,BK;//跟踪止损后记录BAR序号准备再进场

SETSIGPRICETYPE(BK,MAX(OPEN,REENTRYPRICE));

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>TRAILSTOPPRICE1,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,TRAILSTOPPRICE1));

REENTRYPRICE1:=VALUEWHEN(SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>TRAILSTOPPRICE1,LL);

//出场后在REBAR根BAR内，价格突破再进场突破价进场

BKVOL=0&&SKVOL=0&&BARSSP>0&&BARPOS<=REENTRYCOUNT1+15&&VOL>0&&LOW<=REENTRYPRICE1,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REENTRYPRICE1));

AUTOFILTER;

**（14）基于平移通道的交易系统**

/\*策略说明:本策略基于平移后的高低点通道判断入场条件，结合ATR止损

系统要素:

1. 平移后的高低点通道

2. atr止损

入场条件：

1.当高点上穿平移通道高点时,开多仓

2.当低点下穿平移通道低点时,开空仓

出场条件：

1.ATR跟踪止盈

2.通道止损

**\*/**

参数：

CHANLENGTH：1 100 20 通道计算周期

CHANDELAY：1 100 15 通道平移周期

ATRLENGTH：1 100 10 ATR计算周期

TRAILINGATRS：1 10 3 ATR跟踪止损倍数

//指标计算

UPPERCHAN:=HHV(HIGH,CHANLENGTH);//UPPERCHAN=N周期高点，默认20

LOWERCHAN:=LLV(LOW,CHANLENGTH);//LOWERCHAN=N周期低点，默认20

//系统入场

//价格向上突破CHANDELAY周期前的UPPERCHAN,开多仓

//价格向下突破CHANDELAY周期前的LOWERCHAN，开空仓

CON:=HIGH>=REF(UPPERCHAN,CHANDELAY+1)&&REF(HIGH,1)<REF(UPPERCHAN,CHANDELAY+1);

BKVOL=0&&SKVOL=0&&CON,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(UPPERCHAN,CHANDELAY+1)));

CON1:=LOW<=REF(LOWERCHAN,CHANDELAY+1)&&REF(LOW,1)>REF(LOWERCHAN,CHANDELAY+1);

BKVOL=0&&SKVOL=0&&CON1,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(LOWERCHAN,CHANDELAY+1)));

//系统出场

//ATR跟踪止损,通道止损

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

ATRVAL:=MA(TRUERANGE,ATRLENGTH)\*TRAILINGATRS;

STOPLINE:=VALUEWHEN(BKVOL>0&&BARSBK>0,MAX(REF(BKHIGH,1)-REF(ATRVAL,1),REF(LOWERCHAN,CHANDELAY+1)-MINPRICE));

BKVOL>0&&BARSBK>0&&LOW<=STOPLINE,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,STOPLINE));

STOPLINE1:=VALUEWHEN(SKVOL>0&&BARSSK>0,MIN(REF(SKLOW,1)+REF(ATRVAL,1),REF(UPPERCHAN,CHANDELAY+1)+MINPRICE));

SKVOL>0&&BARSSK>0&&HIGH>=STOPLINE1,SP;

SETSIGPRICETYPE(BP,MAX(OPEN,STOPLINE1));

AUTOFILTER;

**（15）基于用波动加权后的OBV的交易系统**

/\*策略说明:本策略基于用波动加权后的OBV进行判断入场条件，结合高低点突破入场

系统要素:

1. 计算波动加权WOBV,根据WOBV预期均值关系，设定触发条件单

入场条件：

1.当WOBV上穿它的MA时,在当根K线高点建立做多触发单

2.当WOBV下穿它的MA时,在当根K线低点建立做空触发单

出场条件：

1.当WOBV上穿它的MA时,次根K线开盘平空仓

2.当WOBV下穿它的MA时,次根K线开盘平多仓

**\*/**

参数：

AVGLENGTH：1 100 25 计算WOBV的ma周期值

//WOBV指标计算

WOBV:=IFELSE(HIGH-LOW<>0,(((CLOSE-OPEN)/(HIGH-LOW))\*VOL),0);//计算波动加权后的OBVWOBV

SSMA:=MA(WOBV,AVGLENGTH); //计算WOBV的MA

//多空触发条件计算

CON:=CROSSUP(WOBV,SSMA);

CON2:=CROSSDOWN(WOBV,SSMA);

BUYSETUP:=IF(CON2||BKVOL>0,0,IF(CON,1,0));

LEPRICE:=VALUEWHEN(CON,HIGH);

SELLSETUP:=IF(CON||SKVOL>0,0,IF(CON2,1,0));

SEPRICE:=VALUEWHEN(CON2,LOW);

//系统入场

BKVOL=0&&SKVOL=0&&REF(BUYSETUP,1)=1&&HIGH>=REF(LEPRICE,1)+MINPRICE,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(LEPRICE,1)+MINPRICE));

BKVOL=0&&SKVOL=0&&REF(SELLSETUP,1)=1&&LOW<=REF(SEPRICE,1)-MINPRICE,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(SEPRICE,1)-MINPRICE));

//系统出场

BKVOL>1&&BARSBK>0&&REF(CON2,1)=1,SP;

SETSIGPRICETYPE(SP,OPEN);

SKVOL>0&&BARSSK>0&&REF(CON2,1)=1,BP;

SETSIGPRICETYPE(BP,OPEN);

AUTOFILTER;

**（16）基于开收盘价格间的相对关系变化进行判断**

/\*策略说明:本策略计算指数移动平均(10个开盘价和10个收盘价, 然后后者减去前者得到柱状图)，通过柱状图上穿零轴还是下穿零轴来判断上升和下降趋势

系统要素:

1. 10个开盘价的指数移动平均与10个收盘价的指数移动平均之差若上穿零轴定义为上升趋势，上升趋势定义满足后将上穿K线的最高价加上10周期的ATR的一半作为多头入场触发价，同时将上穿K线的最低价减去10周期的ATR的一半作为多头平仓触发价；

2. 10个开盘价的指数移动平均与10个收盘价的指数移动平均之差若下穿零轴定义为下降趋势，下降趋势定义满足后将下穿K线的最低价减去10周期的ATR的一半作为空头入场触发价，同时将下穿K线的最高价加上10周期的ATR的一半作为空头平仓触发价；

入场条件:

1. 10个开盘价的指数移动平均大于10个收盘价的指数移动平均并且向上突破了多头触发价则进场做多；

2. 10个开盘价的指数移动平均小于10个收盘价的指数移动平均并且向下突破了空头触发价则进场做空；

出场条件:

1. 跌破多头平仓触发价或者转为下降趋势多头平仓；

2. 突破空头平仓触发价或者转为上升趋势空头平仓；

\*/

参数：

CLOSELEN：1 100 10 用于计算收盘价指数移动平均的周期

OPENLEN：1 100 10 用于计算开盘价指数移动平均的周期

//条件设置

HISTOGRAM:=EMA(CLOSE,CLOSELEN)-EMA(OPEN,OPENLEN);

CON1:=CROSSUP(HISTOGRAM,0);

CON2:=CROSSDOWN(HISTOGRAM,0);

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

ATR10:=MA(TRUERANGE,10);

//设置多头入场触发价与多头平仓触发价

BUYPRICE:=VALUEWHEN(CON1,HIGH+ATR10\*0.5);

LONGEXITPRICE:=VALUEWHEN(CON1,LOW-ATR10\*0.5);

//设置空头入场触发价与空头平仓触发价

SELLPRICE:=VALUEWHEN(CON2,LOW-ATR10\*0.5);

SHORTEXITPRICE:=VALUEWHEN(CON2,HIGH+ATR10\*0.5);

//满足上升趋势且向上突破触发价则进场做多

REF(HISTOGRAM,1)>0&&VOL>0&&HIGH>=BUYPRICE,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,BUYPRICE));

//满足下降趋势且向下突破触发价则进场做空

REF(HISTOGRAM,1)<0&&VOL>0&&LOW<=SELLPRICE,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,SELLPRICE));

//转为下降趋势多头平仓出场

BKVOL>0&&BARSBK>0&&REF(CON2,1)=1&&VOL>0,SP;

SETSIGPRICETYPE(SP,OPEN);

//转为上升趋势空头平仓出场

SKVOL>0&&BARSSK>0&&REF(CON1,1)=1&&VOL>0,BP;

SETSIGPRICETYPE(BP,OPEN);

//向下突破多头平仓触发价格则多头平仓出场

BKVOL>0&&BARSBK>0&&LOW<=LONGEXITPRICE&&VOL>0,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,LONGEXITPRICE));

//向上突破空头平仓触发价格则空头平仓出场

SKVOL>0&&BARSSK>0&&HIGH>=SHORTEXITPRICE&&VOL>0,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,SHORTEXITPRICE));

AUTOFILTER;

**（17）基于K线加权均值的支撑阻力线突破系统**

/\*策略说明:本策略是基于K线加权均值的支撑阻力线突破系统

系统要素:

1. K线的加权均值 = (最高价+最低价+2\*收盘价)/4

2. 支撑线 = K线加权均值 - ( 最高价 - K线加权均值)

3. 阻力线 = K线加权均值 + ( K线加权均值 - 最低价)

入场条件:

1. 当价格向上突破阻力线做多

2. 当价格向下突破支撑线做空

出场条件:

1. 趋势反转即反向突破时出场

2. 基于ATR的一定倍数的止盈

\*/

参数：

ATRLENGTH：1 100 10 ATR周期

ATRS：1 10 3 几倍ATR止盈

//计算当前K线的加权均值、阻力线和支撑线

WAVGPRICE:=(HIGH+LOW+(CLOSE\*2))/ 4;

RESISTANCE:=(WAVGPRICE\*2)-LOW;

SUPPORT:=(WAVGPRICE\*2)-HIGH;

//计算ATR

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

ATRVAL:=MA(TRUERANGE,ATRLENGTH);

//开仓

BKVOL=0&&SKVOL=0&&HIGH>=REF(RESISTANCE,1)+MINPRICE&&VOL>0,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(RESISTANCE,1)+MINPRICE));

BKVOL=0&&SKVOL=0&&LOW<=REF(SUPPORT,1)-MINPRICE&&VOL>0,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(SUPPORT,1)-MINPRICE));

//开仓时根据开仓BAR的ATR计算止盈价

MYEXITPRICE:=VALUEWHEN(BKVOL>0&&BARSBK=NULL,BKPRICE+ATRVAL\*ATRS);

MYEXITPRICE1:=VALUEWHEN(SKVOL>0&&BARSSK=NULL,SKPRICE-ATRVAL\*ATRS);

//平仓

BKVOL>0&&BARSBK>0&&VOL>0&&HIGH>=MYEXITPRICE,SP;//止盈出场

SETSIGPRICETYPE(SP,MAX(OPEN,MYEXITPRICE));

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=REF(SUPPORT,1)-MINPRICE,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(SUPPORT,1)-MINPRICE));//反向突破止损出场

SKVOL>0&&BARSSK>0&&VOL>0&&LOW<=MYEXITPRICE1,BP;//止盈出场

SETSIGPRICETYPE(BP,MIN(OPEN,MYEXITPRICE1));

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>=REF(RESISTANCE,1)+MINPRICE,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(RESISTANCE,1)+MINPRICE));//反向突破止损出场

AUTOFILTER;

**（18）基于价格与均线的相关差进行判断**

/\*策略说明:

1.系统将当前价格和MA之差定义为DRD

2.计算RDV: N天DRD的加和除以DRD绝对值的加和

入场条件:

1.设置ETLong为入市阈值，如果RDV>ETLong,则入场做多

2.设置ETShort为入市阈值，如果RDV<ETShort,则入场做空

出场条件:

1.如果RDV下穿0, 多头平仓

2.如果RDV上穿0, 空头平仓

**\*/**

参数：

RMALEN：1 100 15

ETLONG：1 10 5 //设置做多参数

ETSHORT：-10 0 -5 //设置做空参数

//初始设置

RMA:=MA(CLOSE,RMALEN);

DRD:=CLOSE-RMA;

NDV:=SUM(DRD,RMALEN);

TDV:=SUM(ABS(DRD),RMALEN);

RDV:=VALUEWHEN(TDV>0,100\*NDV/TDV);

//多头开仓

BKVOL=0&&SKVOL=0&&REF(RDV,1)>ETLONG&&VOL>0,BK;

SETSIGPRICETYPE(BK,OPEN);

//空头开仓

SKVOL=0&&BKVOL=0&&REF(RDV,1)<ETSHORT&&VOL>0,SK;

SETSIGPRICETYPE(SK,OPEN);

//多头平仓

BKVOL>0&&BARSBK>0&&REF(RDV,1)<0&&VOL>0,SP;

SETSIGPRICETYPE(SP,OPEN);

//空头平仓

SKVOL>0&&BARSSK>0&&REF(RDV,1)>0&&VOL>0,BP;

SETSIGPRICETYPE(BP,OPEN);

AUTOFILTER;

**（19）基于商品价差的通道突破系统**

需要同时对两个合约进行开平仓，同时需要互相读取两个合约的持仓情况，无法改写。

**（20）基于市场强弱和动量的通道突破系统**

/\*策略说明:本策略是基于市场强弱指标和动量的通道突破系统

系统要素:

1. 根据N根K线的收盘价相对前一根K线的涨跌计算出市场强弱指标

2. 最近9根K线的动量变化趋势

3. 最近N根K线的高低点形成的通道

入场条件:

1. 市场强弱指标为多头，且市场动量由空转多时，突破通道高点做多

2. 市场强弱指标为空头，且市场动量由多转空时，突破通道低点做空

出场条件:

1. 开多以开仓BAR的最近N根BAR的低点作为止损价

开空以开仓BAR的最近N根BAR的高点作为止损价

2. 盈利超过止损额的一定倍数止盈

3. 出现反向信号止损

\*/

参数：

LENGTH：1 10 5 强弱指标和通道计算的周期值

STOP\_LEN：1 10 5 止损通道的周期值

PROFITFACTOR：0 10 3 止盈相对止损的倍数

ENTRYS：0 100 95 强弱指标的进场值

//计算市场强弱指标

CLOSECHANGE:=CLOSE-REF(CLOSE,1);

UPCLOSES1:=LOOP2(BARPOS=1,0,LOOP2(CLOSECHANGE>0,REF(UPCLOSES1,1)+1,0));

UPCLOSES:=IF(UPCLOSES1<=LENGTH,UPCLOSES1,0);//收盘价上涨计入涨幅累计

DNCLOSES1:=LOOP2(BARPOS=1,0,LOOP2(CLOSECHANGE<=0,REF(DNCLOSES1,1)+1,0));

DNCLOSES:=IF(DNCLOSES1<=LENGTH,DNCLOSES1,0);//否则计入跌幅累计

//计算周期内涨跌

SUMCHANGE:=SUM(CLOSECHANGE,LENGTH);

//周期内上涨，计算上涨强度，0-100之间

//周期内下跌，计算下跌强度，0-100之间

MARKETSTRENGTH:=IF(SUMCHANGE>=0,SUMCHANGE/UPCLOSES\*100,SUMCHANGE/ABS(DNCLOSES)\*100);

//计算动量

MOMENTUM1:=CLOSE-REF(CLOSE,4);

MOMENTUM2:=REF(CLOSE,4)-REF(CLOSE,8);

//计算周期高低点，开仓突破用

HH:=HHV(HIGH,LENGTH);

LL1:=LLV(LOW,LENGTH);

//计算周期低点，开仓后止损用

LL2:=LLV(LOW,STOP\_LEN);

//开仓

BKVOL=0&&SKVOL=0&&REF(MARKETSTRENGTH,1)>=ENTRYS&&REF(MOMENTUM1,1)>=0&&REF(MOMENTUM2,1)<0&&H>=REF(HH,1)&&VOL>0,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(HH,1)));

//记录开仓BAR的周期低点作为止损位

STOPLOSS:=VALUEWHEN(BKVOL=0&&SKVOL=0&&REF(MARKETSTRENGTH,1)>=ENTRYS&&REF(MOMENTUM1,1)>=0&&REF(MOMENTUM2,1)<0&&H>=REF(HH,1)&&VOL>0,LL2);

//根据止损位计算止盈位

PROFITTARGET:=BKPRICE+(BKPRICE-STOPLOSS)\*PROFITFACTOR;

//平仓

BKVOL>1&&BARSBK>0&&VOL>0&&HIGH>=PROFITTARGET,SP;

SETSIGPRICETYPE(SP,MAX(OPEN,PROFITTARGET));

BKVOL>1&&BARSBK>0&&VOL>0&&LOW<=STOPLOSS,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,STOPLOSS));

BKVOL>1&&BARSBK>0&&VOL>0&&REF(MARKETSTRENGTH,1)<=-1\*ENTRYS&&REF(MOMENTUM1,1)<0&&REF(MOMENTUM2,1)>=0&&LOW<=REF(LL1,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(LL1,1)));

//计算周期高低点，开仓突破用

HH1:=HHV(H,LENGTH);

LL:=LLV(L,LENGTH);

//计算周期高点，开仓后止损用

HH2:=HHV(H,STOP\_LEN);

//开仓

BKVOL=0&&SKVOL=0&&REF(MARKETSTRENGTH,1)<=-1\*ENTRYS&&REF(MOMENTUM1,1)<=0&&REF(MOMENTUM2,1)>0&&L<=REF(LL,1)&&VOL>0,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(LL,1)));

//记录开仓BAR的周期低点作为止损位

STOPLOSS1:=VALUEWHEN(BKVOL=0&&SKVOL=0&&REF(MARKETSTRENGTH,1)<=-1\*ENTRYS&&REF(MOMENTUM1,1)<=0&&REF(MOMENTUM2,1)>0&&L<=REF(LL,1)&&VOL>0,HH2);

//根据止损位计算止盈位

PROFITTARGET1:=SKPRICE-(STOPLOSS1-SKPRICE)\*PROFITFACTOR;

//平仓

SKVOL>1&&BARSSK>0&&VOL>0&&LOW<=PROFITTARGET1,BP;

SETSIGPRICETYPE(BP,MIN(OPEN,PROFITTARGET1));

SKVOL>1&&BARSSK>0&&VOL>0&&HIGH>=STOPLOSS1,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,STOPLOSS1));

SKVOL>1&&BARSSK>0&&VOL>0&&REF(MARKETSTRENGTH,1)>=ENTRYS&&REF(MOMENTUM1,1)>0&&REF(MOMENTUM2,1)<=0&&H>=REF(HH1,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(HH1,1)));

AUTOFILTER;

**（21）基于均线与动能的交易系统**

/\*策略说明:本策略基于均线与均线间的动能变化建立的交易系统

系统要素:

1. 1根长期均线进行趋势判断

2. 2根较短均线值之差揭示的动能变化为交易提供基础

入场条件:

1. 当价格高于长期均线且动能相对之前变强时做多

2. 当价格低于长期均线且动能相对之前变弱时做空

出场条件:

1. 当动能减弱时, 价格低于ExitStopN根K线低点多头平仓

2. 当动能增强时, 价格高于ExitStopN根K线高点空头平仓

\*/

参数：

TRENDMAL：1 100 50 显示趋势的均线值

EXITSTOPN：1 10 3 求高低点的bar数值

SLOWLENGTH：0 100 20 动能计算中的慢均线值

FASTLENGTH：0 100 50 动能计算中的快均线值

//系统设置

//计算趋势线和均线动能

TRENDMA:=MA(C,TRENDMAL);

PRICEOSCI:=MA(C,FASTLENGTH)-MA(C,SLOWLENGTH);

//系统入场

//当上根K线的收盘价格高于TRENDMA线, 如果上根K线的动能相对于上上根为增强且动能仍未负, 则在本根K线开盘价做多

//当上根K线的收盘价格低于TRENDMA线, 如果上根K线的动能相对于上上根为减弱且动能仍为正, 则在本根K线开盘价做空

BKVOL<=0&&REF(TRENDMA,1)<>0&&REF(C,1)>REF(TRENDMA,1)&&REF(PRICEOSCI,1)<=0&&REF(PRICEOSCI,1)>REF(PRICEOSCI,2)&&VOL>0,BK;

SETSIGPRICETYPE(BK,OPEN);

SKVOL<=0&&REF(TRENDMA,1)<>0&&REF(C,1)<REF(TRENDMA,1)&&REF(PRICEOSCI,1)>=0&&REF(PRICEOSCI,1)>REF(PRICEOSCI,2)&&VOL>0,SK;

SETSIGPRICETYPE(SK,OPEN);

//系统出场

//当均线动能减弱时, 如果价格跌穿过去EXITSTOPN根K线的低点后平仓

//当均线动能增强时, 如果价格上穿过去EXITSTOPN根K线的高点后平仓

EXITL:=LLV(L,EXITSTOPN);

BKVOL>0&&REF(BKVOL,1)=1&&REF(PRICEOSCI,1)<REF(PRICEOSCI,2)&&LOW<=REF(EXITL,1)&&VOL>0,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(EXITL,1)));

EXITS:=HHV(H,EXITSTOPN);

SKVOL>0&&REF(SKVOL,1)=1&&REF(PRICEOSCI,1)<REF(PRICEOSCI,2)&&H>=REF(EXITS,1)&&VOL>0,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(EXITS,1)));

AUTOFILTER;

**（22）基于指数移动平均线组进行判断**

/\*策略说明:

1.计算三条指数移动平均线(Avg1, Avg2 , Avg3)；

2.通过指数移动平均线的组合来判断趋势

入场条件:

1.当Avg1向上穿过Avg2并且Avg2大于Avg3时，在下一根k线开盘处买入

2.当Avg1向下穿过Avg2并且Avg2小于Avg3时，在下一根k线开盘处卖出

出场条件:

1.Avg1下穿Avg2多头出场

2.跟踪止损

\*/

参数：

AVGLEN1：1 100 6

AVGLEN2：1 100 12

AVGLEN3：1 100 28

RLENGTH：1 100 4

//初始设置

AVG1:=EMA(CLOSE,AVGLEN1);

AVG2:=EMA(CLOSE,AVGLEN2);

AVG3:=EMA(CLOSE,AVGLEN3);

RANGE1:=HIGH-LOW;//定义K线幅度

//AVG1向上穿过AVG2为买入条件之一

BUYCON1:=CROSSUP(AVG1,AVG2);

//AVG1向下穿过AVG2为卖出条件之一

SELLCON1:=CROSSDOWN(AVG1,AVG2);

//BUYCON1满足且AVG2大于AVG3时，做多

REF(BUYCON1,1)=1&&REF(AVG2,1)>REF(AVG3,1)&&VOL>0,BK;

SETSIGPRICETYPE(BK,OPEN);

//SELLCON1满足且AVG2小于AVG3时，做空

REF(SELLCON1,1)&&REF(AVG2,1)<REF(AVG3,1)&&VOL>0,SK;

SETSIGPRICETYPE(SK,OPEN);

//AVG1小于AVG2多头出场

BKVOL>0&&BARSBK>0&&REF(AVG1,1)<REF(AVG2,1)&&VOL>0,SP;

//AVG1大于AVG2空头出场

SKVOL>0&&BARSSK>0&&REF(AVG1,1)>REF(AVG2,1)&&VOL>0,BP;

SETSIGPRICETYPE(BP,OPEN);

//设置跟踪止损价

RANGEL:=MA(RANGE1,RLENGTH);

LONGSTOPPRICE:=LOOP2(BKVOL>0&&BARSBK=NULL,LOW-RANGEL,LOOP2(BKVOL>0&&BARSBK>0,LONGSTOPPRICE+(LOW-LONGSTOPPRICE)\*0.25,NULL));

BKVOL>0&&BARSBK>0&&LOW<=REF(LONGSTOPPRICE,1)&&VOL>0,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(LONGSTOPPRICE,1)));

//空头进场后记录跟踪止损价

RANGES:=MA(RANGE1,RLENGTH);

SHORTSTOPPRICE:=LOOP2(SKVOL>0&&BARSSK=NULL,HIGH+RANGES,LOOP2(SKVOL>0&&BARSSK>0,SHORTSTOPPRICE-(SHORTSTOPPRICE-HIGH)/3,NULL));

//向上突破跟踪止损价空头出场

SKVOL>0&&BARSSK>0&&HIGH>=REF(SHORTSTOPPRICE,1)&&VOL>0,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(SHORTSTOPPRICE,1)));

AUTOFILTER;

**（23）基于初始交易范围突破的思想来建立系统**

/\* 策略说明:

用特定时间周期内的最高价位和最低价位计算交易范围，然后计算真实的波动范围和周期内的ATR对比，如果

当前k线的波动范围比n\*交易范围的值大，并且真实波动范围比ATR大，这就满足了前两个系统挂单的条件

入场条件:

1.7周期区间“空隙”之和 >7周期区间高度的2倍

当前的k线比交易范围的最高值大, 而且如果当前k线的中间价格高于之前一根k线的最高值

做多

2.7周期区间“空隙”之和 >7周期区间高度的2倍

当前的k线比交易范围的最低值小, 而且如果当前k线的中间价格低于之前一根k线的最低值

做空

出场条件:

1.初始止损

2.跟踪止损（盈利峰值价回落ATR的一定倍数）

3.收盘价创7周期低点，且K线中点低于前K线最低价多头出场

3.收盘价创7周期高点，且K线中点高于前K线最高价空头出场

\*/

参数：

RANGELEN：1 100 7

ATRLEN：1 100 2

RNGPCNT：1 1000 200

//初始设置

RANGEH:=HHV(REF(H,1),RANGELEN);

RANGEL:=LLV(REF(L,1),RANGELEN);

TRANGE:=RANGEH-RANGEL;

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

ATR:=MA(TRUERANGE,ATRLEN);

ATRMA:=MA(TRUERANGE,RANGELEN);

VALUE2:=LOOP2(BARPOS=1,0,REF(VALUE2,1));

VALUE1:=IF(VALUE2<=7,VALUE2,0);

NOTRADES:=LOOP2(REF(H,VALUE1)<=RANGEH,REF(NOTRADES,1)+(RANGEH-REF(HIGH,VALUE1)),LOOP2(REF(LOW,VALUE1)>=RANGEL,REF(NOTRADES,1)+(REF(LOW,VALUE1)-RANGEL),0));

CONDITION1:=NOTRADES>=TRANGE\*(RNGPCNT\*0.01);//7周期区间“空隙”之和 >7周期区间高度的2倍

CONDITION2:=TRUERANGE>REF(ATRMA,1);//当根K线ATR>前根7周期均值

CONDITION3:=CLOSE>RANGEH&&(HIGH+LOW)\*0.5>REF(HIGH,1); //收盘价创7周期高点，且K线中点高于前K线最高价

CONDITION4:=CLOSE<RANGEL&&(HIGH+LOW)\*0.5<REF(LOW,1);//收盘价创7周期低点，且K线中点低于前K线最低价

//多头入场

REF(CONDITION1,1)=1&&REF(CONDITION2,1)=1&&REF(CONDITION3,1)&&BKVOL=0&&SKVOL=0&&VOL>0,BK;

SETSIGPRICETYPE(BK,OPEN);

LONGRISK:=VALUEWHEN(REF(CONDITION1,1)=1&&REF(CONDITION2,1)=1&&REF(CONDITION3,1)&&BKVOL=0&&SKVOL=0&&VOL>0,RANGEL);//记录初始止损价

LONGHIGH:=LOOP2(REF(CONDITION1,1)=1&&REF(CONDITION2,1)=1&&REF(CONDITION3,1)&&BKVOL=0&&SKVOL=0&&VOL>0,HIGH,LOOP2(BKVOL>0&&BARSBK>0,MAX(LONGHIGH,HIGH),NULL));//记录跟踪止盈价

//多头出场

BKVOL>0&&BARSBK>0&&VOL>0&&REF(CONDITION4,1)=1,SP;//收盘价创7周期低点，且K线中点低于前K线最低价多头出场

SETSIGPRICETYPE(SP,OPEN);

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=LONGRISK,SP;//跌破初始止损价多头出场

SETSIGPRICETYPE(SP,MIN(OPEN,LONGRISK));

BKVOL>0&&BARSBK>0&&VOL>0&&LOW<=REF(LONGHIGH,1)-(ATR\*REF(ATR,1)),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(LONGHIGH,1)-(ATR\*REF(ATR,1))));

//空头入场

REF(CONDITION1,1)=1&&REF(CONDITION2,1)=1&&REF(CONDITION4,1)&&BKVOL=0&&SKVOL=0&&VOL>0,SK;

SETSIGPRICETYPE(SK,OPEN);

SHORTRISK:=VALUEWHEN(REF(CONDITION1,1)=1&&REF(CONDITION2,1)=1&&REF(CONDITION4,1)&&BKVOL=0&&SKVOL=0&&VOL>0,RANGEH);//记录初始止损价

SHORTLOW:=LOOP2(REF(CONDITION1,1)=1&&REF(CONDITION2,1)=1&&REF(CONDITION4,1)&&BKVOL=0&&SKVOL=0&&VOL>0,LOW,LOOP2(SKVOL>0&&BARSSK>0,MIN(SHORTLOW,LOW),NULL));//记录跟踪止盈价

//空头出场

SKVOL>0&&BARSSK>0&&VOL>0&&REF(CONDITION3,1)=1,BP;//收盘价创7周期高点且K线中点高于前K线最高价空头出场

SETSIGPRICETYPE(BP,OPEN);

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>=SHORTRISK,BP;//突破初始止损价空头出场

SETSIGPRICETYPE(BP,MAX(OPEN,SHORTRISK));

SKVOL>0&&BARSSK>0&&VOL>0&&HIGH>=REF(SHORTLOW,1)+(ATR\*REF(ATR,1)),BP;//盈利峰值价回落ATR一定倍数空头出场

SETSIGPRICETYPE(BP,MAX(OPEN,REF(SHORTLOW,1)+(ATR\*REF(ATR,1))));

AUTOFILTER;

**（24）基于DMI中ADX的震荡交易系统**

/\* 策略说明:

本策略基于DMI指标中的ADX指数判断行情是否为震荡, 然后通过k线形态进行逆势交易的系统

系统要素:

1. DMI指标中的ADX指数

2. ConsecBars根阴线(收盘低于前根即可)或ConsecBars根阳线(收盘高于前根即可)

入场条件:

当ADX指数低于25且低于ADXLowThanBefore天前的值时

1. 如果出现连续ConsecBars根阴线(收盘低于前根即可), 则在下根k线开盘做多

2. 如果出现连续ConsecBars根阳线(收盘高于前根即可), 则在下根k线开盘做空

出场条件:

1. 基于ATR的保护性止损

2. 入场ProactiveStopBars根K线后的主动性平仓

\*/

参数：

DMI\_N：1 100 14 //DMI的N值

DMI\_M：1 100 6 //DMI的M值，本策略中用不到

ATRLENGTH：1 100 10 //ATB值

CONSECBARS：1 10 3 //入场条件中连续阳线或阴线的个数

ADXLEVEL：1 100 25 //ADX低于此值时被认为行情处于震荡中

ADXL：1 10 3 //入场条件中ADX需要弱于之前值的天数

//系统设置

//DMI指标计算, 最终将输出ADX指标

SF:=1/DMI\_N;

TRUEHIGH:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE:=IF(ISLASTBAR,H-L,TRUEHIGH-TRUELOW);

TRVALUE:=TRUERANGE;

UPPERMOVE:=VALUEWHEN(BARPOS=DMI\_N||BARPOS>DMI\_N,H-REF(H,1));

LOWERMOVE:=VALUEWHEN(BARPOS=DMI\_N||BARPOS>DMI\_N,REF(L,1)-L);

PLUSDM:=LOOP2(((BARPOS=DMI\_N)||(BARPOS>DMI\_N))&&UPPERMOVE>LOWERMOVE&&UPPERMOVE>0,UPPERMOVE,LOOP2((BARPOS=DMI\_N)||(BARPOS>DMI\_N),O,NULL));

MINUSDM:=LOOP2(((BARPOS=DMI\_N)||(BARPOS>DMI\_N))&&LOWERMOVE>UPPERMOVE&&LOWERMOVE>0,LOWERMOVE,LOOP2((BARPOS=DMI\_N)||(BARPOS>DMI\_N),O,NULL));

SUMPLUSDM:=SUM(PLUSDM,DMI\_N);

SUMMINUSDM:=SUM(MINUSDM,DMI\_N);

SUMTR:=SUM(REF(TRVALUE,1),DMI\_N);

AVGPLUSDM:=LOOP2(BARPOS=DMI\_N,SUMPLUSDM/DMI\_N,LOOP2(BARPOS>DMI\_N,REF(AVGPLUSDM,1)+SF\*(PLUSDM-REF(AVGPLUSDM,1)),NULL));

AVGMINUSDM:=LOOP2(BARPOS=DMI\_N,SUMMINUSDM/DMI\_N,LOOP2(BARPOS>DMI\_N,REF(AVGMINUSDM,1)+SF\*(MINUSDM-REF(AVGMINUSDM,1)),NULL));

SVOLTY:=LOOP2(BARPOS=DMI\_N,SUMTR/DMI\_N,LOOP2(BARPOS>DMI\_N,REF(SVOLTY,1)+SF\*(TRVALUE-REF(SVOLTY,1)),NULL));

ODMIPLUS:=VALUEWHEN(BARPOS>=DMI\_N,IF(SVOLTY>0,100\*AVGPLUSDM/SVOLTY,0));

ODMIMINUS:=VALUEWHEN(BARPOS>=DMI\_N,IF(SVOLTY>0,100\*AVGMINUSDM/SVOLTY,0));

DIVISOR:=ODMIPLUS+ODMIMINUS;

SDMI:=IF(DIVISOR>0,100\*ABS(ODMIPLUS-ODMIMINUS)/DIVISOR,0);

CUMM:=SUM(SDMI,BARPOS);

SADX:=LOOP2(BARPOS>0&&BARPOS<=DMI\_N,CUMM/BARPOS,REF(SADX,1)+SF\*(SDMI-REF(SADX,1)));

OADXR:=LOOP2(BARPOS>0&&BARPOS<=DMI\_N,(SADX+REF(SADX,BARPOS-1))\*0.5,(SADX+REF(SADX,DMI\_M-1))\*0.5);

OVOLTY:=VALUEWHEN(BARPOS>DMI\_N,SVOLTY);

ODMI:=VALUEWHEN(BARPOS>DMI\_N,SDMI);

OADX:=VALUEWHEN(BARPOS>DMI\_N,SADX);

//ATR计算

TRUEHIGH1:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW1:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE1:=IF(ISLASTBAR,H-L,TRUEHIGH1-TRUELOW1);

ATR:=MA(TRUERANGE1,ATRLENGTH);

//系统入场

//当ADX指数低于25且低于ADXLOWTHANBEFORE天前的值时, 如果出现连续CONSECBARS根阴线(收盘低于前根即可), 则在下根K线开盘做多

CONSECBARSCOUNT1:=COUNT(CLOSE<REF(CLOSE,1),3);

BKVOL<=0&&BARPOS>DMI\_N&&REF(OADX,1)<ADXLEVEL&&REF(OADX,1)<REF(OADX,ADXL+1)&&REF(CONSECBARSCOUNT1,1)=3&&VOL>0,BK;

SETSIGPRICETYPE(BK,OPEN);

//基于ATR的保护性止损

PROTECTSTOPL:=REF(LOW,1)-0.5\*REF(ATR,1);

//系统出场

//入场PROACTIVESTOPBARS根K线后的主动性平仓

BKVOL>0&&REF(BKVOL,1)=1&&VOL>0&&BARSBK>=10,SP;

SETSIGPRICETYPE(SP,OPEN);

//基于ATR的保护性止损

BKVOL>0&&REF(BKVOL,1)=1&&VOL>0&&L<=REF(PROTECTSTOPL,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(PROTECTSTOPL,1)));

//系统入场

//当ADX指数低于25且低于ADXLOWTHANBEFORE天前的值时, 如果出现连续CONSECBARS根阳线(收盘高于前根即可), 则在下根K线开盘做空

CONSECBARSCOUNT2:=COUNT(CLOSE>REF(CLOSE,1),3);

SKVOL<=0&&BARPOS>DMI\_N&&REF(OADX,1)<ADXLEVEL&&REF(OADX,1)<REF(OADX,ADXL+1)&&REF(CONSECBARSCOUNT2,1)=3&&VOL>0,SK;

SETSIGPRICETYPE(SK,OPEN);

//基于ATR的保护性止损

PROTECTSTOPS:=REF(H,1)+0.5\*REF(ATR,1);

//系统出场

//入场PROACTIVESTOPBARS根K线后的主动性平仓

SKVOL>0&&REF(SKVOL,1)=1&&VOL>0&&BARSSK>=10,BP;

SETSIGPRICETYPE(BP,OPEN);

//基于ATR的保护性止损

SKVOL>0&&REF(SKVOL,1)=1&&VOL>0&&H>=REF(PROTECTSTOPS,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(PROTECTSTOPS,1)));

AUTOFILTER;

**（25）基于收盘价与之前k线高低进行打分的交易系统**

/\* 策略说明:

本策略基于当前收盘价与之前k线的高低进行打分, 并通过打分的均值与对应的收盘价均值进行交易

系统要素:

1. 当当前收盘价格大于之前LookBack根K线内某一根k线的收盘价时记+1分, 否则记-1分, 加总这些分数以获得当前K线的得分

2. 对k线的打分计算一条均线

3. 对k线的收盘计算一条均线

入场条件:

1. 当价格高于收盘价均线, 且打分也高于打分均线时的入场做多

2. 当价格低于收盘价均线, 且打分也低于打分均线时的入场做空

出场条件:

1. 基于ATR的保护性止损

2. 基于ATR的跟踪止损

3. 基于ATR的盈亏平衡止损

\*/

参数：

LOOKBACK：1 100 10 //用于给当前K线打分的回溯根数

MALENGTH：1 100 18 //均线值

ATRLENGTH：1 100 10 //ATR的值

PROTECTS：0 1 0.5 //保护性止损的ATR乘数

TRAILS：1 10 3 //跟踪止损的ATR乘数

BREAKE：1 10 5 //盈亏平衡止损的ATR乘数

//系统设置

//K线打分-当当前收盘价格大于之前LOOKBACK根K线内某一根K线的收盘价时记+1分, 否则记-1分, 加总这些分数以获得当前K线的得分

TEMP1:=C>REF(C,1)+C>REF(C,2)+C>REF(C,3)+C>REF(C,4)+C>REF(C,5)+C>REF(C,6)+C>REF(C,7)+C>REF(C,8)+C>REF(C,9)+C>REF(C,10);

TEMP:=TEMP1-(10-TEMP1);

TRENDSCORE:=TEMP;

//均线和ATR计算

MA1:=MA(C,MALENGTH);

TRENDSCOREMA:=MA(TRENDSCORE,MALENGTH);

TRUEHIGH1:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW1:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE1:=IF(ISLASTBAR,H-L,TRUEHIGH1-TRUELOW1);

ATR:=MA(TRUERANGE1,ATRLENGTH);

//系统入场

//当价格高于收盘价均线, 且打分也高于打分均线时的入场做多

BKVOL<=0&&REF(MA1,1)<>0&&REF(C,1)>=REF(MA1,1)&&REF(TRENDSCORE,1)>=REF(TRENDSCOREMA,1)&&VOL>0,BK;

SETSIGPRICETYPE(BK,OPEN);

//基于ATR的保护性止损

PROTECTSTOPL:=REF(LOW,1)-PROTECTS\*REF(ATR,1);

//系统出场

//基于ATR的跟踪止损

TRAILSTOPL:=REF(BKHIGH,1)-TRAILS\*REF(ATR,1);

//基于ATR的盈亏平衡止损

BREAKEVENSTOPL:=BKPRICE;

//出场线选择

TJ1:=BKVOL>0&&REF(BKVOL,1)=1&&REF(BKHIGH,1)>=BREAKEVENSTOPL+BREAKE\*REF(ATR,1)&&TRAILSTOPL>=BREAKEVENSTOPL;

TJ2:=BKVOL>0&&REF(BKVOL,1)=1&&REF(BKHIGH,1)>=BREAKEVENSTOPL+BREAKE\*REF(ATR,1)&&NOT(TRAILSTOPL>=BREAKEVENSTOPL);

TJ3:=BKVOL>0&&REF(BKVOL,1)=1&&NOT(REF(BKHIGH,1)>=BREAKEVENSTOPL+BREAKE\*REF(ATR,1))&&TRAILSTOPL>=REF(PROTECTSTOPL,1);

TJ4:=BKVOL>0&&REF(BKVOL,1)=1&&NOT(REF(BKHIGH,1)>=BREAKEVENSTOPL+BREAKE\*REF(ATR,1))&&NOT(TRAILSTOPL>=REF(PROTECTSTOPL,1));

EXITLINEL:=LOOP2(TJ1||TJ3,TRAILSTOPL,LOOP2(TJ2,BREAKEVENSTOPL,LOOP2(TJ4,REF(PROTECTSTOPL,1),NULL)));

//出场

L<=EXITLINEL&&VOL>0,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,EXITLINEL));

//系统入场

//当价格低于收盘价均线, 且打分也低于打分均线时的入场做空

SKVOL<=0&&REF(MA1,1)<>0&&REF(C,1)<=REF(MA1,1)&&REF(TRENDSCORE,1)<=REF(TRENDSCOREMA,1)&&VOL>0,SK;

SETSIGPRICETYPE(SK,OPEN);

//基于ATR的保护性止损

PROTECTSTOPS:=REF(H,1)+PROTECTS\*REF(ATR,1);

//系统出场

//基于ATR的跟踪止损

TRAILSTOPS:=REF(SKLOW,1)+TRAILS\*REF(ATR,1);

//基于ATR的盈亏平衡止损

BREAKEVENSTOPS:=SKPRICE;

//出场线选择

TJ11:=SKVOL>0&&REF(SKVOL,1)=1&&REF(SKLOW,1)<=BREAKEVENSTOPS-BREAKE\*REF(ATR,1)&&TRAILSTOPS <= BREAKEVENSTOPS;

TJ22:=SKVOL>0&&REF(SKVOL,1)=1&&REF(SKLOW,1)>=BREAKEVENSTOPS-BREAKE\*REF(ATR,1)&&NOT(TRAILSTOPS <= BREAKEVENSTOPS);

TJ33:=SKVOL>0&&REF(SKVOL,1)=1&&NOT(REF(SKLOW,1)<=BREAKEVENSTOPS-BREAKE\*REF(ATR,1))&&TRAILS<=REF(PROTECTSTOPS,1);

TJ44:=BKVOL>0&&REF(BKVOL,1)=1&&NOT(REF(SKLOW,1)<=BREAKEVENSTOPS-BREAKE\*REF(ATR,1))&&NOT(TRAILS<=REF(PROTECTSTOPS,1));

EXITLINES:=LOOP2(TJ11||TJ33,TRAILSTOPS,LOOP2(TJ22,BREAKEVENSTOPS,LOOP2(TJ44,REF(PROTECTS,1),NULL)));

//出场

H>=EXITLINES&&VOL>0,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,EXITLINES));

AUTOFILTER;

**（26）成交量加权动量交易系统**

/ \*策略说明:

基于动量系统, 通过交易量加权进行判断

系统要素:

1. 用UWM上穿零轴判断多头趋势
2. 用UWM下穿零轴判断空头趋势

多头入场条件:

1. 价格高于UWM上穿零轴时价格通道,且在SetupLen的BAR数目内,做多

多头出场条件:

1. 空头势多单出场

空头入场条件:

1. 价格低于UWM下穿零轴时价格通道,在SetupLen的BAR数目内,做空

空头出场条件:

1. 多头势空单出场

\*/

参数：

MOMLEN：1 100 5 //UWM参数

AVGLEN：1 100 20 //UWM参数

ATRLEN：1 100 5 //ATR参数

ATRPCNT：0 1 0.5 //入场价格波动率参数

SETUPLEN：1 10 5 //条件持续有效K线数

MOMVALUE:=C-REF(C,MOMLEN);

VWM:=EMA(VOL\*MOMVALUE,AVGLEN);//定义UWM

TRUEHIGH1:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW1:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE1:=IF(ISLASTBAR,H-L,TRUEHIGH1-TRUELOW1);

AATR:=MA(TRUERANGE1,ATRLEN);//ATR

BULLSETUP:=CROSSUP(VWM,0);//UWM上穿零轴定义多头势

BEARSETUP:=CROSSDOWN(VWM,0);//UWM下穿零轴定义空头势

LSETUP:=LOOP2(BARPOS=1||BULLSETUP,0,REF(LSETUP,1)+1);//多头势开始计数并记录当前价格

LEPRICE:=VALUEWHEN(BULLSETUP,C);

SSETUP:=LOOP2(BARPOS=1||BEARSETUP,0,REF(SSETUP,1)+1);//空头势开始计数并记录当前价格

SEPRICE:=VALUEWHEN(BEARSETUP,C);

//系统入场

//当多头势满足并且在SETUPLEN的BAR数目内,当价格达到入场价格后,做多

BARPOS>AVGLEN&&BKVOL=0&&SKVOL=0&&HIGH>=REF(LEPRICE,1)+(ATRPCNT\*REF(AATR,1))&&REF(LSETUP,1)<=SETUPLEN&&LSETUP>=1&&VOL>0,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(LEPRICE,1)+(ATRPCNT\*REF(AATR,1))));

//系统出场

BKVOL>0&&BARSBK>0&&VOL>0&&REF(BEARSETUP,1)=1,SP;

SETSIGPRICETYPE(SP,OPEN);

//系统入场

//当空头势满足并且在SETUPLEN的BAR数目内,当价格达到入场价格后,做空

BARPOS>AVGLEN&&BKVOL=0&&SKVOL=0&&L<=REF(SEPRICE,1)-(ATRPCNT\*REF(AATR,1))&&REF(SSETUP,1)<=SETUPLEN&&SSETUP>=1&&VOL>0,SK;

SETSIGPRICETYPE(BK,MIN(OPEN,REF(SEPRICE,1)-(ATRPCNT\*REF(AATR,1))));

AUTOFILTER;

**（27）布林强盗**

/\*

策略说明:

基于布林通道的突破系统

系统要素:

1、基于收盘价计算而来的布林通道

2、基于收盘价计算而来的进场过滤器

3、自适应出场均线

入场条件:

1、满足过滤条件，并且价格上破布林通道上轨，开多单

2、满足过滤条件，并且价格下破布林通道下轨，开空单

出场条件:

1、持有多单时，自适应出场均线低于布林通道上轨，并且价格下破自适应出场均线，平多单

2、持有空单时，自适应出场均线高于布林通道下轨，并且价格上破自适应出场均线，平空单

\*/

参数：

BOLLINGERL：1 100 50 //布林通道参数

OFFSET：1 5 1.25 //布林通道参数

ROCCALCL：1 100 30 //过滤器参数

LIQLENGTH：1 100 50 //自适应出场均线参数

//布林通道中轨

MIDLINE:MA(CLOSE,BOLLINGERL);

BAND:=STD(CLOSE,BOLLINGERL);

//布林通道上轨

UPBAND:MIDLINE+OFFSET\*BAND;

//布林通道下轨

DNBAND:MIDLINE-OFFSET\*BAND;

//进场过滤器

ROCCALC:=CLOSE-REF(CLOSE,ROCCALCL-1);

//满足过滤条件，并且价格突破布林通道上轨，开多单

BKVOL<=0&&REF(ROCCALC,1)>0&&HIGH>=REF(UPBAND,1),BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(UPBAND,1)));

//自适应出场均线

LIQDAYS1:=LOOP2(BKVOL=0,LIQLENGTH,MAX((REF(LIQDAYS1,1)-1),10));

LIQPOINT1:MA(CLOSE,LIQDAYS1);

//持有多单时，自适应出场均线低于布林通道上轨，并且价格下破自适应出场均线，平多单

BKVOL>0&&BARSBK>=1&&REF(LIQPOINT1,1)<REF(UPBAND,1)&&LOW<=REF(LIQPOINT1,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(LIQPOINT1,1)));

//满足过滤条件，并且价格突破布林通道下轨，开空单

SKVOL<=0&&REF(ROCCALC,1)<0&&L<=REF(DNBAND,1),SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(DNBAND,1)));

//自适应出场均线

LIQDAYS2:=LOOP2(SKVOL=0,LIQLENGTH,MAX((REF(LIQDAYS2,1)-1),10));

LIQPOINT2:=MA(CLOSE,LIQDAYS2);

//持有空单时，自适应出场均线高于布林通道下轨，并且价格上破自适应出场均线，平空单

SKVOL>0&&BARSSK>=1&&REF(LIQPOINT2,1)>REF(DNBAND,1)&&H>=REF(LIQPOINT2,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(LIQPOINT2,1)));

AUTOFILTER;

**（28）动态突破**

/\*

策略说明:

基于自适应的布林通道与自适应的唐奇安通道的突破系统

系统要素:

1、自适应布林通道

2、自适应唐奇安通道

3、自适应出场均线

入场条件:

1、昨日价格大于布林通道上轨，并且当日周期价格大于唐奇安通道上轨，开多单

2、昨日价格小于布林通道下轨，并且当日周期价格小于唐奇安通道下轨，开空单

出场条件:

1、持有多单时，价格小于自适应出场均线，平多单

2、持有空单时，价格大于自适应出场均线，平空单

\*/

参数：

BOLBANDTRIG：1 10 2 //布林通道参数

CEILINGAMT：1 100 60 //自适应参数的上限

FLOORAMT：1 100 20 //自适应参数的下限

//当日市场波动

TODAYVOLATILITY:=STD(CLOSE,30);

//昨日市场波动

YESTERDAYVOLATILITY:=REF(TODAYVOLATILITY,1);

//市场波动的变动率

DELTAVOLATILITY:=(TODAYVOLATILITY-YESTERDAYVOLATILITY)/TODAYVOLATILITY;

//计算自适应参数

LOOKBACKDAYS1:=LOOP2(BARPOS=1,20,REF(LOOKBACKDAYS1,1)\*(1+DELTAVOLATILITY));

LOOKBACKDAYS2:=ROUND(LOOKBACKDAYS1,0);

LOOKBACKDAYS3:=MIN(LOOKBACKDAYS2,CEILINGAMT);

LOOKBACKDAYS:=MAX(LOOKBACKDAYS3,FLOORAMT);

//自适应布林通道中轨

MIDLINE:=MA(CLOSE,LOOKBACKDAYS);

BAND:=STD(CLOSE,LOOKBACKDAYS);

//自适应布林通道上轨

UPBAND:=MIDLINE+BOLBANDTRIG\*BAND;

//自适应布林通道下轨

DNBAND:=MIDLINE-BOLBANDTRIG\*BAND;

//自适应唐奇安通道上轨

BUYPOINT:=LLV(HIGH,LOOKBACKDAYS);

//自适应唐奇安通道下轨

SELLPOINT:=LLV(LOW,LOOKBACKDAYS);

//自适应出场均线

LIQPOINT:=MIDLINE;

//昨日价格大于布林通道上轨，并且当日价格大于唐奇安通道上轨，开多单

BKVOL<=0&&REF(C,1)>REF(UPBAND,1)&&H>=REF(BUYPOINT,1),BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(BUYPOINT,1)));

//持有多单时，昨日价格小于布林通道下轨，并且当日价格小于唐奇安通道下轨，平多单

BKVOL>0&&REF(C,1)<REF(DNBAND,1)&&LOW<=REF(SELLPOINT,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(SELLPOINT,1)));

//持有多单时，价格小于自适应出场均线，平多单

BKVOL>0&&BARSBK>=1&&LOW<=REF(LIQPOINT,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(LIQPOINT,1)));

//持有空单时，昨日价格大于布林通道上轨，并且当日价格大于唐奇安通道上轨，平空单

SKVOL<=0&&REF(C,1)>REF(UPBAND,1)&&H>=REF(BUYPOINT,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(BUYPOINT,1)));

//昨日价格小于布林通道下轨，并且当日价格小于唐奇安通道下轨，开空单

SKVOL>0&&REF(CLOSE,1)<REF(DNBAND,1)&&LOW<=REF(SELLPOINT,1),SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(SELLPOINT,1)));

//持有空单时，价格大于自适应出场均线，平空单

SKVOL>0&&BARSSK>=1&&HIGH>=REF(LIQPOINT,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(LIQPOINT,1)));

AUTOFILTER;

**（29）幽灵交易者**

/\*

策略说明:

模拟交易产生一次亏损后才启动真实下单交易。

系统要素:

1、两条指数平均线

2、RSI指标

3、唐奇安通道

入场条件:

1、模拟交易产生一次亏损、短期均线在长期均线之上、RSI低于超买值、创新高，则开多单

2、模拟交易产生一次亏损、短期均线在长期均线之下、RSI高于超卖值、创新低，则开空单

出场条件:

1、持有多单时小于唐奇安通道下轨，平多单

2、持有空单时大于唐奇安通道上轨，平空单

\*/

参数：

FASTLENGTH：1 10 9 //短期指数平均线参数

SLOWLENGTH：1 100 19 //长期指数平均线参数

LENGTH：1 100 9 //RSI参数

OVERBOUGHT：1 100 30 //超买

OVERSOLD：1 100 30 //超卖

//短期指数平均线

AVGVALUE1:=EMA(CLOSE,FASTLENGTH);

//长期指数平均线参数

AVGVALUE2:=EMA(CLOSE,SLOWLENGTH);

//计算RSI

SF:=1/LENGTH;

CHANGE:=CLOSE-REF(CLOSE,1);

NETCHGAVG:=LOOP2(BARPOS<=LENGTH-1,(CLOSE-REF(CLOSE,LENGTH))/LENGTH,REF(NETCHGAVG,1)+SF\*(CHANGE-REF(NETCHGAVG,1)));

TOTCHGAVG:=LOOP2(BARPOS<=LENGTH-1,MA(ABS(CLOSE-REF(CLOSE,1)),LENGTH),REF(TOTCHGAVG,1)+SF\*(ABS(CHANGE)-REF(TOTCHGAVG,1)));

CHGRATIO:=LOOP2(TOTCHGAVG<>0,NETCHGAVG/TOTCHGAVG,0);

RSIVALUE:=50\*(CHGRATIO+1);

//唐奇安通道上轨

EXITHIBAND:=HHV(HIGH,20);

//唐奇安通道下轨

EXITLOBAND:=LLV(LOW,20);

//持有多单时下破唐奇安通道下轨，平多单

MYPOSITION1:=IF(ISLASTSP=1,0,IF(ISLASTBK=1,1,NULL));

MYPOSITION1=1&&REF(MYPOSITION1,1)=1&&LOW<=REF(EXITLOBAND,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(EXITLOBAND,1)));

MYENTRYPRICE1:=MIN(OPEN,REF(EXITLOBAND,1));

MYPROFIT1:=REFSIG\_PRICE(SP,1)-MYENTRYPRICE1;

//模拟交易产生一次亏损、短期均线在长期均线之上、RSI低于超买值、创新高，则开多单

MYPOSITION1=0&&REF(MYPOSITION1,1)=0&&REF(AVGVALUE1,1)>REF(AVGVALUE2,1)&&REF(RSIVALUE,1)<OVERBOUGHT&&HIGH>=REF(HIGH,1)&&MYPROFIT1<0,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(HIGH,1)));

//持有空单时大于唐奇安通道上轨，平空单

MYPOSITION2:=IF(ISLASTBP=1,0,IF(ISLASTSK=1,-1,NULL));

MYPOSITION2=-1&&REF(MYPOSITION2,1)=-1&&H>=REF(EXITHIBAND,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(EXITHIBAND,1)));

MYEXITPRICE2:=MAX(OPEN,REF(EXITHIBAND,1));

MYPROFIT2:=MYEXITPRICE2-SKPRICE;

//模拟交易产生一次亏损、短期均线在长期均线之下、RSI高于超卖值、创新低，则开空单

MYPOSITION2=0&&REF(MYPOSITION2,1)=0&&REF(AVGVALUE1,1)>REF(AVGVALUE2,1)&&REF(RSIVALUE,1)>OVERSOLD&&L<=REF(L,1)&&MYPROFIT2<0,SK;

SETSIGPRICETYPE(SK, MIN(OPEN,REF(LOW,1)));

AUTOFILTER;

**（30）金肯特纳**

/\*

策略说明:

基于肯特纳通道的突破系统

系统要素:

1、基于最高价、最低价、收盘价三者平均值计算而来的三价均线

2、基于三价均线加减真实波幅计算而来的通道上下轨

多头入场条件:

1、三价均线向上，并且价格上破通道上轨，开多单

2、三价均线向下，并且价格下破通道下轨，开空单

多头出场条件:

1、持有多单时，价格下破三价均线，平多单

2、持有空单时，价格上破三价均线，平空单

空头入场条件:

1、三价均线向上，并且价格上破通道上轨，开多单

2、三价均线向下，并且价格下破通道下轨，开空单

空头出场条件:

1、持有多单时，价格下破三价均线，平多单

2、持有空单时，价格上破三价均线，平空单

\*/

参数：

AVGLENGTH：1 100 40 //三价均线参数

ATRLENGTH：1 100 40 //真实波幅参数

//三价均线

MOVAVGVAL:=MA((HIGH+LOW+CLOSE)/3,AVGLENGTH);

//通道上轨

TRUEHIGH1:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW1:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE1:=IF(ISLASTBAR,H-L,TRUEHIGH1-TRUELOW1);

UPBAND:=MA(TRUERANGE1,ATRLENGTH);

DNBAND:=MA(TRUERANGE1,ATRLENGTH);

//出场条件

LIQUIDPOINT:=MOVAVGVAL;

//三价均线向上，并且价格上破通道上轨，开多单

BKVOL<=0&&REF(MOVAVGVAL,1)>REF(MOVAVGVAL,1)&&H>REF(UPBAND,1),BK;

SETSIGPRICETYPE(BK,MAX(OPEN,REF(UPBAND,1)));

//持有多单时，价格下破三价均线，平多单

BKVOL>0&&BARSBK>=1&&LOW<=REF(LIQUIDPOINT,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(LIQUIDPOINT,1)));

//三价均线向下，并且价格下破通道下轨，开空单

SKVOL<=0&&REF(MOVAVGVAL,1)<REF(MOVAVGVAL,1)&&L<=REF(DNBAND,1),SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(DNBAND,1)));

//持有空单时，价格上破三价均线，平空单

SKVOL>0&&BARSSK>=1&&H>=REF(LIQUIDPOINT,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(LIQUIDPOINT,1)));

AUTOFILTER;

**（31）恒温器**

/\*

策略说明:

通过计算市场的潮汐指数，把市场划分为震荡和趋势两种走势；震荡市中

采用开盘区间突破进场；趋势市中采用布林通道突破进场。

系统要素:

1、潮汐指数

2、关键价格

3、布林通道

4、真实波幅

5、出场均线

入场条件:

1、震荡市中采用开盘区间突破进场

2、趋势市中采用布林通道突破进场

出场条件:

1、震荡市时进场单的出场为反手信号和ATR保护性止损

2、趋势市时进场单的出场为反手信号和均线出场

\*/

参数：

ATRLENGTH：1 100 10 //真实波幅参数

SWINGPRCNT1：0 1 0.5 //震荡市开仓参数

SWINGPRCNT2：0 1 0.75 //震荡市开仓参数

BOLLI：1 100 50 //布林通道参数

NUMSTDDEVS：1 100 2 //布林通道参数

SWINGT：1 100 20 //潮汐指数小于此值为震荡市，否则为趋势市

//计算潮汐指数用以区分震荡市与趋势市

CMIVAL:=ABS(CLOSE-REF(CLOSE,29))/(HHV(HIGH,30)-LLV(LOW,30))\*100;

TRENDLOKBUY:=MA(LOW,3);

TRENDLOKSELL:=MA(HIGH,3);

//关键价格

KEYOFDAY:=(HIGH+LOW+CLOSE)/3;

//震荡市中收盘价大于关键价格为宜卖市，否则为宜买市

BUYEASIERDAY:=IF(CLOSE<=REF(KEYOFDAY,1),1,0);

SELLEASIERDAY:=IF(CLOSE>REF(KEYOFDAY,1),1,0);

//计算震荡市的进场价格

TRUEHIGH1:=IF(HIGH>REF(C,1),HIGH,REF(C,1));

TRUELOW1:=IF(LOW<=REF(C,1),LOW,REF(C,1));

TRUERANGE1:=IF(ISLASTBAR,H-L,TRUEHIGH1-TRUELOW1);

MYATR:=MA(TRUERANGE1,ATRLENGTH);

SWINGBUYPT1:=IF(BUYEASIERDAY=1,OPEN+SWINGPRCNT1\*REF(MYATR,1),IF(SELLEASIERDAY=1,OPEN+SWINGPRCNT2\*REF(MYATR,1),NULL));

SWINGSELLPT1:=IF(BUYEASIERDAY=1,OPEN-SWINGPRCNT2\*REF(MYATR,1),IF(SELLEASIERDAY=1,OPEN-SWINGPRCNT1\*REF(MYATR,1),NULL));

SWINGBUYPT:=MAX(SWINGBUYPT1,REF(TRENDLOKBUY,1));

SWINGSELLPT:=MIN(SWINGSELLPT1,REF(TRENDLOKSELL,1));

//计算趋势市的进场价格

MIDLINE:=MA(CLOSE,BOLLI);

BAND:=STD(CLOSE,BOLLI);

UPBAND:=MIDLINE+NUMSTDDEVS\*BAND;

DNBAND:=MIDLINE-NUMSTDDEVS\*BAND;

TRENDBUYPT:=UPBAND;

TRENDSELLPT:=DNBAND;

SWINGPROTSTOP:=3\*MYATR;// 震荡市时进场单的出场触发价格

TRENDPROTSTOP:=MA(CLOSE,50);// 趋势市时进场单的出场触发价格

//震荡市

SWINGENTRY1:=IF(ISLASTBK=1,1,IF(ISLASTSP=1,0,NULL));

REF(CMIVAL,1)<SWINGT&&BKVOL<=0&&H>=SWINGBUYPT,BK;

SETSIGPRICETYPE(BK,MAX(OPEN,SWINGBUYPT));

REF(CMIVAL,1)<SWINGT&&BKVOL>0&&LOW<=SWINGSELLPT,SP;

SETSIGPRICETYPE(SP,MIN(OPEN,SWINGSELLPT));

//多头趋势市

REF(CMIVAL,1)>=SWINGT&&SWINGENTRY1=1&&BKVOL>0&&BARSBK>=1&&L<=(BKPRICE-REF(SWINGPROTSTOP,1)),SP;//震荡市时进场单在趋势市的出场

SETSIGPRICETYPE(SP,MIN(OPEN,BKPRICE-REF(SWINGPROTSTOP,1)));

REF(CMIVAL,1)>=SWINGT&&SWINGENTRY1=0&&BARSSP>=1&&BKVOL<=0&&H>=REF(TRENDBUYPT,1),BK;//趋势市时进场

SETSIGPRICETYPE(BK,MAX(OPEN,REF(TRENDBUYPT,1)));

REF(CMIVAL,1)>=SWINGT&&SWINGENTRY1=0&&BARSSP>=1&&BKVOL>0&&L<=REF(TRENDSELLPT,1),SP;

TRENDENTRY2:=IF(ISLASTBK=1,1,IF(ISLASTSP=1,0,NULL));

//多头趋势市时进场单的出场

BKVOL>0&&BARSBK>=1&&TRENDENTRY2=1&&L<=REF(TRENDPROTSTOP,1),SP;

SETSIGPRICETYPE(SP,MIN(OPEN,REF(TRENDPROTSTOP,1)));

//震荡市

SWINGENTRY3:=IF(ISLASTSK=1,1,IF(ISLASTBP=1,0,NULL));

REF(CMIVAL,1)<SWINGT&&SKVOL<=0&&H>=SWINGBUYPT,BP;

SETSIGPRICETYPE(BP,MAX(OPEN,SWINGBUYPT));

REF(CMIVAL,1)<SWINGT&&SKVOL>0&&LOW<=SWINGSELLPT,SK;

SETSIGPRICETYPE(SK,MIN(OPEN,SWINGSELLPT));

//空头趋势市

REF(CMIVAL,1)>=SWINGT&&SWINGENTRY3=1&&SKVOL>0&&BARSSK>=1&&H>=(SKPRICE+REF(SWINGPROTSTOP,1)),BP;//震荡市时进场单在趋势市的出场

SETSIGPRICETYPE(BP,MAX(OPEN,SKPRICE+REF(SWINGPROTSTOP,1)));

REF(CMIVAL,1)>=SWINGT&&SWINGENTRY3=0&&BARSBP>=1&&SKVOL>0&&H>=REF(TRENDBUYPT,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(TRENDBUYPT,1)));

REF(CMIVAL,1)>=SWINGT&&SWINGENTRY3=0&&BARSBP>=1&&SKVOL<=0&&L<=REF(TRENDSELLPT,1),SK;

SETSIGPRICETYPE(SK,MIN(OPEN,REF(TRENDSELLPT,1)));

TRENDENTRY4:=IF(ISLASTSK=1,1,IF(ISLASTBP=1,0,NULL));

//空头趋势市时进场单的出场

SKVOL>0&&BARSSK>=1&&TRENDENTRY4=1&&H>=REF(TRENDPROTSTOP,1),BP;

SETSIGPRICETYPE(BP,MAX(OPEN,REF(TRENDPROTSTOP,1)));

AUTOFILTER;