Skip to content
Browse files

Initial commit

  • Loading branch information...
0 parents commit bcf4d4409e2d8b57de9e5b363ac2a36f0370b9fb maloi committed
Showing with 477 additions and 0 deletions.
  1. +3 −0 .gitignore
  2. +6 −0 .gitmodules
  3. +3 −0 README
  4. +245 −0 vim/autoload/pathogen.vim
  5. +1 −0 vim/bundle/afterimage
  6. +1 −0 vim/bundle/fugitive
  7. +96 −0 vim/colors/railscasts.vim
  8. +122 −0 vimrc
3 .gitignore
@@ -0,0 +1,3 @@
+*.swp
+*~
+vim/.netrwhist
6 .gitmodules
@@ -0,0 +1,6 @@
+[submodule "vim/bundle/fugitive"]
+ path = vim/bundle/fugitive
+ url = https://github.com/tpope/vim-fugitive.git
+[submodule "vim/bundle/afterimage"]
+ path = vim/bundle/afterimage
+ url = https://github.com/tpope/vim-afterimage.git
3 README
@@ -0,0 +1,3 @@
+git clone http://github.com/maloi/dotfiles.git ~/dotfiles
+ln -s ~/dotfiles/vimrc ~/.vimrc
+ln -s ~/dotfiles/vim ~/.vim
245 vim/autoload/pathogen.vim
@@ -0,0 +1,245 @@
+" pathogen.vim - path option manipulation
+" Maintainer: Tim Pope <http://tpo.pe/>
+" Version: 2.0
+
+" Install in ~/.vim/autoload (or ~\vimfiles\autoload).
+"
+" For management of individually installed plugins in ~/.vim/bundle (or
+" ~\vimfiles\bundle), adding `call pathogen#infect()` to your .vimrc
+" prior to `filetype plugin indent on` is the only other setup necessary.
+"
+" The API is documented inline below. For maximum ease of reading,
+" :set foldmethod=marker
+
+if exists("g:loaded_pathogen") || &cp
+ finish
+endif
+let g:loaded_pathogen = 1
+
+" Point of entry for basic default usage. Give a directory name to invoke
+" pathogen#runtime_append_all_bundles() (defaults to "bundle"), or a full path
+" to invoke pathogen#runtime_prepend_subdirectories(). Afterwards,
+" pathogen#cycle_filetype() is invoked.
+function! pathogen#infect(...) abort " {{{1
+ let source_path = a:0 ? a:1 : 'bundle'
+ if source_path =~# '[\\/]'
+ call pathogen#runtime_prepend_subdirectories(source_path)
+ else
+ call pathogen#runtime_append_all_bundles(source_path)
+ endif
+ call pathogen#cycle_filetype()
+endfunction " }}}1
+
+" Split a path into a list.
+function! pathogen#split(path) abort " {{{1
+ if type(a:path) == type([]) | return a:path | endif
+ let split = split(a:path,'\\\@<!\%(\\\\\)*\zs,')
+ return map(split,'substitute(v:val,''\\\([\\,]\)'',''\1'',"g")')
+endfunction " }}}1
+
+" Convert a list to a path.
+function! pathogen#join(...) abort " {{{1
+ if type(a:1) == type(1) && a:1
+ let i = 1
+ let space = ' '
+ else
+ let i = 0
+ let space = ''
+ endif
+ let path = ""
+ while i < a:0
+ if type(a:000[i]) == type([])
+ let list = a:000[i]
+ let j = 0
+ while j < len(list)
+ let escaped = substitute(list[j],'[,'.space.']\|\\[\,'.space.']\@=','\\&','g')
+ let path .= ',' . escaped
+ let j += 1
+ endwhile
+ else
+ let path .= "," . a:000[i]
+ endif
+ let i += 1
+ endwhile
+ return substitute(path,'^,','','')
+endfunction " }}}1
+
+" Convert a list to a path with escaped spaces for 'path', 'tag', etc.
+function! pathogen#legacyjoin(...) abort " {{{1
+ return call('pathogen#join',[1] + a:000)
+endfunction " }}}1
+
+" Remove duplicates from a list.
+function! pathogen#uniq(list) abort " {{{1
+ let i = 0
+ let seen = {}
+ while i < len(a:list)
+ if (a:list[i] ==# '' && exists('empty')) || has_key(seen,a:list[i])
+ call remove(a:list,i)
+ elseif a:list[i] ==# ''
+ let i += 1
+ let empty = 1
+ else
+ let seen[a:list[i]] = 1
+ let i += 1
+ endif
+ endwhile
+ return a:list
+endfunction " }}}1
+
+" \ on Windows unless shellslash is set, / everywhere else.
+function! pathogen#separator() abort " {{{1
+ return !exists("+shellslash") || &shellslash ? '/' : '\'
+endfunction " }}}1
+
+" Convenience wrapper around glob() which returns a list.
+function! pathogen#glob(pattern) abort " {{{1
+ let files = split(glob(a:pattern),"\n")
+ return map(files,'substitute(v:val,"[".pathogen#separator()."/]$","","")')
+endfunction "}}}1
+
+" Like pathogen#glob(), only limit the results to directories.
+function! pathogen#glob_directories(pattern) abort " {{{1
+ return filter(pathogen#glob(a:pattern),'isdirectory(v:val)')
+endfunction "}}}1
+
+" Turn filetype detection off and back on again if it was already enabled.
+function! pathogen#cycle_filetype() " {{{1
+ if exists('g:did_load_filetypes')
+ filetype off
+ filetype on
+ endif
+endfunction " }}}1
+
+" Checks if a bundle is 'disabled'. A bundle is considered 'disabled' if
+" its 'basename()' is included in g:pathogen_disabled[]' or ends in a tilde.
+function! pathogen#is_disabled(path) " {{{1
+ if a:path =~# '\~$'
+ return 1
+ elseif !exists("g:pathogen_disabled")
+ return 0
+ endif
+ let sep = pathogen#separator()
+ return index(g:pathogen_disabled, strpart(a:path, strridx(a:path, sep)+1)) != -1
+endfunction "}}}1
+
+" Prepend all subdirectories of path to the rtp, and append all 'after'
+" directories in those subdirectories.
+function! pathogen#runtime_prepend_subdirectories(path) " {{{1
+ let sep = pathogen#separator()
+ let before = filter(pathogen#glob_directories(a:path.sep."*"), '!pathogen#is_disabled(v:val)')
+ let after = filter(pathogen#glob_directories(a:path.sep."*".sep."after"), '!pathogen#is_disabled(v:val[0:-7])')
+ let rtp = pathogen#split(&rtp)
+ let path = expand(a:path)
+ call filter(rtp,'v:val[0:strlen(path)-1] !=# path')
+ let &rtp = pathogen#join(pathogen#uniq(before + rtp + after))
+ return &rtp
+endfunction " }}}1
+
+" For each directory in rtp, check for a subdirectory named dir. If it
+" exists, add all subdirectories of that subdirectory to the rtp, immediately
+" after the original directory. If no argument is given, 'bundle' is used.
+" Repeated calls with the same arguments are ignored.
+function! pathogen#runtime_append_all_bundles(...) " {{{1
+ let sep = pathogen#separator()
+ let name = a:0 ? a:1 : 'bundle'
+ if "\n".s:done_bundles =~# "\\M\n".name."\n"
+ return ""
+ endif
+ let s:done_bundles .= name . "\n"
+ let list = []
+ for dir in pathogen#split(&rtp)
+ if dir =~# '\<after$'
+ let list += filter(pathogen#glob_directories(substitute(dir,'after$',name,'').sep.'*[^~]'.sep.'after'), '!pathogen#is_disabled(v:val[0:-7])') + [dir]
+ else
+ let list += [dir] + filter(pathogen#glob_directories(dir.sep.name.sep.'*[^~]'), '!pathogen#is_disabled(v:val)')
+ endif
+ endfor
+ let &rtp = pathogen#join(pathogen#uniq(list))
+ return 1
+endfunction
+
+let s:done_bundles = ''
+" }}}1
+
+" Invoke :helptags on all non-$VIM doc directories in runtimepath.
+function! pathogen#helptags() " {{{1
+ let sep = pathogen#separator()
+ for dir in pathogen#split(&rtp)
+ if (dir.sep)[0 : strlen($VIMRUNTIME)] !=# $VIMRUNTIME.sep && filewritable(dir.sep.'doc') == 2 && !empty(glob(dir.sep.'doc'.sep.'*')) && (!filereadable(dir.sep.'doc'.sep.'tags') || filewritable(dir.sep.'doc'.sep.'tags'))
+ helptags `=dir.'/doc'`
+ endif
+ endfor
+endfunction " }}}1
+
+command! -bar Helptags :call pathogen#helptags()
+
+" Like findfile(), but hardcoded to use the runtimepath.
+function! pathogen#runtime_findfile(file,count) "{{{1
+ let rtp = pathogen#join(1,pathogen#split(&rtp))
+ return fnamemodify(findfile(a:file,rtp,a:count),':p')
+endfunction " }}}1
+
+" Backport of fnameescape().
+function! pathogen#fnameescape(string) " {{{1
+ if exists('*fnameescape')
+ return fnameescape(a:string)
+ elseif a:string ==# '-'
+ return '\-'
+ else
+ return substitute(escape(a:string," \t\n*?[{`$\\%#'\"|!<"),'^[+>]','\\&','')
+ endif
+endfunction " }}}1
+
+function! s:find(count,cmd,file,lcd) " {{{1
+ let rtp = pathogen#join(1,pathogen#split(&runtimepath))
+ let file = pathogen#runtime_findfile(a:file,a:count)
+ if file ==# ''
+ return "echoerr 'E345: Can''t find file \"".a:file."\" in runtimepath'"
+ elseif a:lcd
+ let path = file[0:-strlen(a:file)-2]
+ execute 'lcd `=path`'
+ return a:cmd.' '.pathogen#fnameescape(a:file)
+ else
+ return a:cmd.' '.pathogen#fnameescape(file)
+ endif
+endfunction " }}}1
+
+function! s:Findcomplete(A,L,P) " {{{1
+ let sep = pathogen#separator()
+ let cheats = {
+ \'a': 'autoload',
+ \'d': 'doc',
+ \'f': 'ftplugin',
+ \'i': 'indent',
+ \'p': 'plugin',
+ \'s': 'syntax'}
+ if a:A =~# '^\w[\\/]' && has_key(cheats,a:A[0])
+ let request = cheats[a:A[0]].a:A[1:-1]
+ else
+ let request = a:A
+ endif
+ let pattern = substitute(request,'\'.sep,'*'.sep,'g').'*'
+ let found = {}
+ for path in pathogen#split(&runtimepath)
+ let path = expand(path, ':p')
+ let matches = split(glob(path.sep.pattern),"\n")
+ call map(matches,'isdirectory(v:val) ? v:val.sep : v:val')
+ call map(matches,'expand(v:val, ":p")[strlen(path)+1:-1]')
+ for match in matches
+ let found[match] = 1
+ endfor
+ endfor
+ return sort(keys(found))
+endfunction " }}}1
+
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Ve :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vedit :execute s:find(<count>,'edit<bang>',<q-args>,0)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vopen :execute s:find(<count>,'edit<bang>',<q-args>,1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vsplit :execute s:find(<count>,'split',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vvsplit :execute s:find(<count>,'vsplit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vtabedit :execute s:find(<count>,'tabedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vpedit :execute s:find(<count>,'pedit',<q-args>,<bang>1)
+command! -bar -bang -range=1 -nargs=1 -complete=customlist,s:Findcomplete Vread :execute s:find(<count>,'read',<q-args>,<bang>1)
+
+" vim:set ft=vim ts=8 sw=2 sts=2:
1 vim/bundle/afterimage
@@ -0,0 +1 @@
+Subproject commit 6d5527d2fe337324c4b125a2d3b45e20df16f94d
1 vim/bundle/fugitive
@@ -0,0 +1 @@
+Subproject commit b4b75ef682da3e946c648d3634ade39d0af49aba
96 vim/colors/railscasts.vim
@@ -0,0 +1,96 @@
+" Vim color scheme
+"
+" Name: railscasts.vim
+" Maintainer: Nick Moffitt <nick@zork.net>
+" Last Change: 01 Mar 2008
+" License: WTFPL <http://sam.zoy.org/wtfpl/>
+" Version: 2.1
+"
+" This theme is based on Josh O'Rourke's Vim clone of the railscast
+" textmate theme. The key thing I have done here is supply 256-color
+" terminal equivalents for as many of the colors as possible, and fixed
+" up some of the funny behaviors for editing e-mails and such.
+"
+" To use for gvim:
+" 1: install this file as ~/.vim/colors/railscasts.vim
+" 2: put "colorscheme railscasts" in your .gvimrc
+"
+" If you are using Ubuntu, you can get the benefit of this in your
+" terminals using ordinary vim by taking the following steps:
+"
+" 1: sudo apt-get install ncurses-term
+" 2: put the following in your .vimrc
+" if $COLORTERM == 'gnome-terminal'
+" set term=gnome-256color
+" colorscheme railscasts
+" else
+" colorscheme default
+" endif
+" 3: if you wish to use this with screen, add the following to your .screenrc:
+" attrcolor b ".I"
+" termcapinfo xterm 'Co#256:AB=\E[48;5;%dm:AF=\E[38;5;%dm'
+" defbce "on"
+" term screen-256color-bce
+
+set background=dark
+hi clear
+if exists("syntax_on")
+ syntax reset
+endif
+
+let g:colors_name = "railscasts"
+
+hi link htmlTag xmlTag
+hi link htmlTagName xmlTagName
+hi link htmlEndTag xmlEndTag
+
+highlight Normal guifg=#E6E1DC guibg=#111111
+highlight Cursor guifg=#000000 ctermfg=0 guibg=#FFFFFF ctermbg=15
+highlight CursorLine guibg=#000000 ctermbg=233 cterm=NONE
+
+highlight Comment guifg=#BC9458 ctermfg=180 gui=italic
+highlight Constant guifg=#6D9CBE ctermfg=73
+highlight Define guifg=#CC7833 ctermfg=173
+highlight Error guifg=#FFC66D ctermfg=221 guibg=#990000 ctermbg=88
+highlight Function guifg=#FFC66D ctermfg=221 gui=NONE cterm=NONE
+highlight Identifier guifg=#6D9CBE ctermfg=73 gui=NONE cterm=NONE
+highlight Include guifg=#CC7833 ctermfg=173 gui=NONE cterm=NONE
+highlight PreCondit guifg=#CC7833 ctermfg=173 gui=NONE cterm=NONE
+highlight Keyword guifg=#CC7833 ctermfg=173 cterm=NONE
+highlight LineNr guifg=#2B2B2B ctermfg=159 guibg=#C0C0FF
+highlight Number guifg=#A5C261 ctermfg=107
+highlight PreProc guifg=#E6E1DC ctermfg=103
+highlight Search guifg=NONE ctermfg=NONE guibg=#2b2b2b ctermbg=235 gui=italic cterm=underline
+highlight Statement guifg=#CC7833 ctermfg=173 gui=NONE cterm=NONE
+highlight String guifg=#A5C261 ctermfg=107
+highlight Title guifg=#FFFFFF ctermfg=15
+highlight Type guifg=#DA4939 ctermfg=167 gui=NONE cterm=NONE
+highlight Visual guibg=#5A647E ctermbg=60
+
+highlight DiffAdd guifg=#E6E1DC ctermfg=7 guibg=#519F50 ctermbg=71
+highlight DiffDelete guifg=#E6E1DC ctermfg=7 guibg=#660000 ctermbg=52
+highlight Special guifg=#DA4939 ctermfg=167
+
+highlight pythonBuiltin guifg=#6D9CBE ctermfg=73 gui=NONE cterm=NONE
+highlight rubyBlockParameter guifg=#FFFFFF ctermfg=15
+highlight rubyClass guifg=#FFFFFF ctermfg=15
+highlight rubyConstant guifg=#DA4939 ctermfg=167
+highlight rubyInstanceVariable guifg=#D0D0FF ctermfg=189
+highlight rubyInterpolation guifg=#519F50 ctermfg=107
+highlight rubyLocalVariableOrMethod guifg=#D0D0FF ctermfg=189
+highlight rubyPredefinedConstant guifg=#DA4939 ctermfg=167
+highlight rubyPseudoVariable guifg=#FFC66D ctermfg=221
+highlight rubyStringDelimiter guifg=#A5C261 ctermfg=143
+
+highlight xmlTag guifg=#E8BF6A ctermfg=179
+highlight xmlTagName guifg=#E8BF6A ctermfg=179
+highlight xmlEndTag guifg=#E8BF6A ctermfg=179
+
+highlight mailSubject guifg=#A5C261 ctermfg=107
+highlight mailHeaderKey guifg=#FFC66D ctermfg=221
+highlight mailEmail guifg=#A5C261 ctermfg=107 gui=italic cterm=underline
+
+highlight SpellBad guifg=#D70000 ctermfg=160 ctermbg=NONE cterm=underline
+highlight SpellRare guifg=#D75F87 ctermfg=168 guibg=NONE ctermbg=NONE gui=underline cterm=underline
+highlight SpellCap guifg=#D0D0FF ctermfg=189 guibg=NONE ctermbg=NONE gui=underline cterm=underline
+highlight MatchParen guifg=#FFFFFF ctermfg=15 guibg=#005f5f ctermbg=23
122 vimrc
@@ -0,0 +1,122 @@
+" Notes {
+"
+" Sections
+" -> Basic
+" -> General
+" -> UI
+" -> Tabs/Layout
+" -> Search
+" -> Plugin Settings
+" -> Mappings
+" -> Autocommands
+"
+" }
+
+
+" Basic {
+ call pathogen#infect()
+ set nocompatible " don't use vi-compatible mode
+ set noexrc " don't use .vimrc in current directory
+ set history=1000 " remember most of the commands
+ set background=dark " dark is stark
+ if has("gui_running")
+ colorscheme railscasts
+ elseif $COLORTERM == 'gnome-terminal'
+ set term=gnome-256color
+ colorscheme railscasts
+ else
+ colorscheme default
+ endif
+ syntax on " syntax highlight on
+" }
+
+" General {
+ filetype plugin indent on " load filetype plugins/indent settings
+ set nobackup " use version control
+ set fileformats=unix,dos,mac " support all three, in this order
+ set hidden " change buffers w/out saving
+" set mouse=a " maybe i can need it
+ set mousehide " hide mouse while typing
+ set noerrorbells " no noise
+ set wildmenu " <TAB> completion shell-like
+ set wildmode=longest:full
+" }
+
+" UI {
+ set number " show line numbers
+ set numberwidth=4 " up to 9999 lines
+ set laststatus=2 " always show status line
+ set list " show tabs and trailing spaces
+ set listchars=tab:\ ,trail:¬ " nice symbols
+ highlight NonText guifg=#4a4a59 "
+ highlight SpecialKey guifg=#4a4a59 "
+ set matchtime=4 " show 0.4s matching bracket
+ set showmatch " show matching brackets
+ set nostartofline " leave cursor where it was
+ set ruler " show current position
+ set scrolloff=5 " keep 5 lines (top/bottom) when
+ " scrolling
+ set shortmess=aOstT " shortens msgs to avoid
+ " 'press a key' prompt
+ set showcmd " show command that is being typed
+ set statusline=%F%m%r%h%w[%L][%{&ff}]%y[%p%%][%04l,%04v]
+ " | | | | | | | | | | |
+ " | | | | | | | | | | + current column
+ " | | | | | | | | | |
+ " | | | | | | | | | +-- current line
+ " | | | | | | | | +-- current % into file
+ " | | | | | | | +-- current syntax in square brackets
+ " | | | | | | |
+ " | | | | | | +-- current fileformat
+ " | | | | | +-- number of lines
+ " | | | | +-- preview flag in square brackets
+ " | | | +-- help flag in square brackets
+ " | | +-- readonly flag in square brackets
+ " | +-- rodified flag in square brackets
+ " +-- full path to file in the buffer
+" }
+
+" Tabs/Layout {
+ set completeopt= " no popup menu for completion
+ set expandtab " no real tabs
+ set shiftround " when 3 spaces and one hits > go to 4, not 5
+ set tabstop=2 " real tabs are 2 spaces
+ set softtabstop=2 " tab and backspace are 2 spaces
+ set shiftwidth=2 " indent 2 spaces
+ set nowrap " do not wrap lines
+" }
+
+" Search {
+ set nohlsearch " don't highlight search hits
+ set ignorecase " case insensitive by default
+ set smartcase " if there are caps, go case-sensitive
+" }
+
+" Plugin Settings {
+
+" }
+
+" Mappings {
+ " Windows {
+ map <C-k> <C-W>k
+ map <C-j> <C-W>j
+ map <C-h> <C-W>h
+ map <C-l> <C-W>l
+ map <C-Up> <C-W>k
+ map <C-Down> <C-W>j
+ map <C-Left> <C-W>h
+ map <S-right> <C-W>l
+ " }
+ " Tabs {
+ map <S-Left> :tabprev<CR>
+ map <S-Right> :tabnext<CR>
+ " direct to tab # with #gt where # is the number of the tab
+ " }
+" }
+
+" Autocommands {
+ " make vim restore cursor position in files
+ if has("autocmd")
+ au BufReadPost * if line("'\"") > 1 && line("'\"") <= line("$") | exe "normal! g`\"" | endif
+ endif
+" }

0 comments on commit bcf4d44

Please sign in to comment.
Something went wrong with that request. Please try again.