Permalink
Fetching contributors…
Cannot retrieve contributors at this time
50 lines (45 sloc) 1.14 KB
# Maintainer: FadeMind <fademind@gmail.com>
# Contributor: eloaders <eloaders at linux dot pl>
pkgname=i-nex
_gitname=I-Nex
_gitcommit=0c10102578e7c762674eaf9460b0903d76f151db
pkgver=7.6.0
pkgrel=5
pkgdesc="System information tool like hardinfo, sysinfo"
arch=('i686' 'x86_64')
url="http://i-nex.linux.pl/"
license=('LGPL3')
depends=('gambas3-runtime'
'gambas3-gb-image'
'gambas3-gb-form'
'gambas3-gb-desktop'
'gambas3-gb-qt5'
'gambas3-gb-desktop-x11'
'python2'
'libcpuid'
'lsb-release'
'curl'
'pastebinit'
'procps-ng')
makedepends=('gambas3-devel' 'gcc' 'imagemagick' 'git')
source=("git+https://github.com/${pkgname}/${_gitname}.git#commit=${_gitcommit}")
md5sums=('SKIP')
provides=('i-nex-git' 'i-nex-bzr' 'i-nex-dev')
conflicts=('i-nex-git' 'i-nex-bzr' 'i-nex-dev')
prepare() {
cd ${_gitname}
sed -i -e 's|^STATIC.*|STATIC = false|' i-nex.mk
sed -i -e 's|^UDEV_RULES_DIR.*|UDEV_RULES_DIR = /usr/lib/udev/rules.d|' i-nex.mk
cd ${_gitname}
autoreconf -i
}
build() {
cd ${_gitname}/${_gitname}
./configure --prefix=/usr
cd ..
make -j1
}
package() {
cd ${_gitname}
make -j1 install DESTDIR="$pkgdir"
}