**Lab 3 Report**

Sage Marks, Matt Krueger

3360:0001 - Embedded Systems

Professor Beichel

University of Iowa, College of Engineering

## Introduction

Embedded Systems Lab 3 builds on the concepts and circuitry implemented in lab 2. Once again, we are using the 74HC595 Shift Register, 5161AS 7-Segment Display, and an enable low push button. However, the focus of this lab was working with timer/counters in the Atmel studio environment as delay loops, lookup tables, and utilizing an RPG for user inputs. The goal of the lab using the hardware described below was to create a simple electronic door lock system that accepts a 5-digit hexadecimal code. Digits selected for the code are to be scrolled through with the RPG and then selected with a push button press of less than one second. In this report, we will outline the new concepts that were employed to achieve this result and focus less on information from the prior lab.

Listed below is an exhaustive list of hardware required to replicate the lab 3 circuit. Please note that an Arduino Uno contains the microcontroller needed and is sufficient for use in lab. We opted to use the Arduino Uno for simplicity when developing the circuit.

|  |  |  |
| --- | --- | --- |
| Hardware | Quantity | Description |
| Atmega 328P µC | 1 | Programmable µC |
| 74HC595 Shift Register | 1 | Storage of hex codes for 7-Segment display |
| 5161AS 7-Segment Display | 1 | Display current counter |
| Enable Low Push Button | 1 | Enables user input interaction with display |
| 560Ω Resistor | 8 | Resist current into 7-Segment display LEDs |
| 10KΩ Resistor | 5 | RC low pass filtering, Pull-up resistor for RPG |
| 100KΩ Resistor | 1 | Pull-up resistor for push button |
| 0.01µF Capacitor | 4 | µC Decoupling & push button RC low pass filtering |
| EVE-GA1F2012B Encoder | 1 | Rotary pulse generator |

Figure 1: Materials List

## Schematic

A computer screen shot of a computer program

AI-generated content may be incorrect.

Figure 2: Electrical circuit schematic created using KiCAD

The lab 3 circuit was built off the existing 7-segment display, shift register, and push button circuit utilized in lab 2. The main difference is found in the addition of the RPG and two new input lines to the microcontroller.

The pinout of the RPG is as shown below with pin A being the A signal, pin B being the B signal and pin C being the signal ground.

A screenshot of a computer

AI-generated content may be incorrect.

The wiring of the RPG is as follows. To read the signals from pins B and A we connected pin B to PD7 and pin A to PD6 and configured these as inputs. Each pin, A and B, has a low pass RC filter connected to help with debouncing. These were created with 0.01µF capacitors and 10KΩ resistors. Then there is also a 10-kiloohm resistor that acts as a pullup resistor keeping the pins at defined states when the RPG is not being turned. Pin C is tied to the ground signal of the microcontroller.

Reading of the RPG was dependent on the signals that the RPG generates when it is turned either clockwise or counterclockwise. When turning the RPG, you can hear clicking sounds and there are defined points or grooves within the RPG called detents. These detents and the values (1 or 0) of the two signals are crucial to reading user RPG inputs. A signal being “off” is represented by 1, and a signal that is “on” is represented by a 0. When turning the RPG clockwise the B signal is the first to be on, followed by the A signal because of a 90-degree phase lag. When turning counterclockwise the A signal is the first to be on, followed by the B signal because of the 90-degree phase lag. Following a gray code system, which is reflected binary code such that only one bit at a time from 1->0 or vice versa, we can see the order that the signals will change when rotating the dial in each direction.

A clockwise rotation pattern for the signals in the order BA is as follows,

00 🡪 01 🡪 11 🡪 10 🡪 00 …

A counterclockwise rotation pattern for the signals in the order BA is as follows,

00 🡪 10 🡪 11 🡪 01 🡪 00 …

The difference in these signal patterns becomes relevant in the code section. A detent that represents the end of a “turn” of the RPG is the signal combination 00.

## 3. Discussion

As part of the changes made from lab 2 to lab 3, the acquisition of the hex codes to represent with the 7-Segment was simplified with a lookup table (LUT). Previously, we had chained many subroutines to display each character triggered by a register tracking the current hex number 0-F. This was tedious to program and required many lines of code. A suitable fix was to incorporate a LUT named *seven\_segment\_codes* to store the hex codes in program memory:

seven\_segment\_codes:

.db 0x3f, 0x06, 0x5b, 0x4f, 0x66, 0x6d, 0x7d, 0x07 ; 0-7

.db 0x7f, 0x6f, 0x77, 0x7c, 0x39, 0x5e, 0x79, 0x71 ; 8-f

Similarly, we employed another LUT to store the correct password of the electronic lock. This LUT, named *password\_codes*, is also stored in program memory:

password\_codes:

.db 0x0a, 0x0a, 0x05, 0x0c, 0x04; AA5C4

The assembler directive “.db” (define byte*)*, is prepended to the beginning of a sorted list of bytes. Upon loading the program, the assembler allocates and initializes these bytes at contiguous addresses in program memory, whose contents are then accessed using “LPM” (Load Program Memory) with the known memory address.

For example, to obtain the memory address for the *seven\_segment\_display\_codes* we used a register to track the current hex displayed. Because the bytes in this LUT are sorted it is possible to simply count the offset from the beginning of the LUT memory address. We tracked this offset using a register; upon each clockwise RPG turn, the register content was incremented and after counter-clockwise RPG turn, the register content decremented. Alone, this offset is of no use as the memory address of the wanted hex in the LUT is unknown. To find its address in memory, the Z register is utilized by loading the first two bytes of the *seven\_segment\_display\_codes* as our program memory is word addressed and AVR architecture is 16-bit words. The Z register is a 16-bit pointer to memory locations formed by the register pair R31:R30 aliased by ZH:ZL. Note that because our LUT is defined within of the first 256 bytes, we were able to avoid using instructions to load both ZH and ZL as ZL sufficed. This is not the best practice as accessing an address in a more crowded address space (outside of the first 256 bytes) would result in an overflow into the higher byte of the Z register. This will be considered for Lab 4. Nevertheless, we can load the address of the beginning of the LUT using “LDI” (load immediate) and then add the offset to this immediate and then finally use “LPM” to get the wanted hex.

ldi ZL, low(seven\_segment\_codes << 1)

add ZL, r17

…

lpm r16, Z

The wanted hex from *password\_codes* is obtained through a similar process using a different register. Additionally, instead of incrementing or decrementing on RPG rotations, the value in the offset register only increments at each button press less than one seconds.

The push-button functionality was also modified from lab 2 to lab 3. Now, there are only two actions distinguished by the duration of the user press.

First action: user press < 1 seconds. If the user’s press is less than one second long, the program checks the current digit displayed by the 7-Segment with the correct digit at the current index of the password. Recall that the current index of the password is obtained as explained previously using LUTs. If the current index is 5, then the user has guessed all digits in the code. To determine the correctness, we used register R0 to store a single bit to flag whether the user has successfully guessed all digits; if R0 is “1” the user has not entered an incorrect digit and if R0 is “0” then the user has. If R0 is 0 before password index, then it propagates throughout the entire password check process. At any password index 0-4, if the user presses the button for less than one seconds and the digit in the 7-Segment does not match the correct digit in the LUT, then bit is flagged as such. Additionally, for password indexes 0-4, following the user press for less than one second and check for match, the LUT offset stored is incremented such that the next guess is for the next index in the password. For password index 5, after the user press for less than one seconds, the last comparison takes place. After all 5 comparisons between the user’s digits and the correct password digits, the status of R0 determines the next subroutine call. If the R0 bit is still “1”, signifying correct password, the “correct password display” is set. The on-board LED of the Arduino Uno is turned on for 4 seconds and the decimal point “.” is displayed on the 7-Segment display for this duration. During this time, the program responds to no user input. After the 4 seconds is up, the program is reset. The reset consists of restoring contents two offsets registers to the beginning of their respective LUTs, restoring R0 to “1,” and setting the display on the 7-Segment display to “-“ to signify the start of the program. However, If the R0 bit is “0” after all 5 password comparisons, the “incorrect password display” is set. The underscore “\_” character is displayed on the 7-Segment display for 7 seconds. During this time, the program responds to no user input. After the 7 seconds is up, the program is reset in the same manner as previously described.

Second action: user press > 2 seconds. If the user’s press is greater than two seconds long, then the program is reset. After releasing the button, the program simply resets. Identical to in the first action, the program reset consists of restoring contents two offsets registers to the beginning of their respective LUTs, restoring R0 to “1,” and setting the display on the 7-Segment display to “-“ to signify the start of the program.

## 4. Conclusion

Rome was not built in a day, nor is any million-dollar idea. Lab 3 builds on existing knowledge gained during Lab 2, extending the circuit's functionality to a rudimentary electrical locking system. We learned foundational skills of digital signal processing utilizing hardware to de-bounce and de-chatter the rotary pulse generator with pull-up resistors and low-pass filters. We also utilized software to recognize the sequencing of RPG signals using low-level AVR assembly. Although we are far off creating the next big thing, we have begun laying the mortar for the expertise required.

## 5. Appendix A: Source Code

; Assignment: Lab 3

; Date: 2025-03-12

; Authors: Sage Marks & Matt Krueger

;

; Description:

; This programs a simple lock with a 7-segment display, pushbutton, and a rotary pulse generator.

; Lookup table for 7-segment display

rjmp start

seven\_segment\_codes:

.db 0x3f, 0x06, 0x5b, 0x4f, 0x66, 0x6d, 0x7d, 0x07 ; 0-7

.db 0x7f, 0x6f, 0x77, 0x7c, 0x39, 0x5e, 0x79, 0x71 ; 8-f

; Lookup table for password (AA5C4)

password\_codes:

.db 0x0a, 0x0a, 0x05, 0x0c, 0x04, 0x00

start:

.cseg

.org 0x0000

; Port B Data Direction Configuration

sbi DDRB, 0 ; SER

sbi DDRB, 1 ; RCLK

sbi DDRB, 2 ; SRCLK

cbi DDRB, 3 ; pushbutton signal

sbi DDRB, 5 ; LED on arduino board

; Port D Data Direction Configuration

cbi DDRD, 6 ; A signal from RPG

cbi DDRD, 7 ; B signal from RPG

; Register Aliases

.def tmp1 = r23 ; temporary variables 1

.def tmp2 = r24 ; temporary variablues 2

.def count = r22 ; count of loops for timer delay

.def rpg\_current\_state = r21 ; current state of RPG

.def rpg\_previous\_state = r20 ; register to hold previous state of RPG

; register aliases 16..19 were redacted for clarity as they are not as consistently throughout the program.

; these registers are used to track the two LUTs, however during some subroutines their function is more ambiguous.

; power\_on:

; ENTRY POINT OF THE PROGRAM

; - initializes the timer and rpg before jumping to reset\_program

; - additionally initializes the password index to 0 and the password correctness flag to 1 (this fixes bug where the first program loop never works)

power\_on:

rcall setup\_timer

rcall setup\_rpg

ldi r19, 0x00

ldi tmp1, 1

mov r0, tmp1

rjmp start\_program

; setup\_rpg:

; INITIALIZE THE ROTARY PULSE GENERATOR

; - load PIND into rpg\_previous\_state (76......)

; - mask all other bits beside wanted RPG bits 6 and 7

setup\_rpg:

in rpg\_previous\_state, PIND

andi rpg\_previous\_state, 0xC0

ret

; setup\_timer:

; INITIALIZE TIMER0

; - Timer/Counter setup for 500 μs delay

; - 8-bit timer, so we need to set the prescalar to 64

; - atmega328p has a CPU clock speed of 16 MHz, so

; 16,000,000/64 = 250,000

; 1/250,000 = 4 μs per cycle

; - setting count of loops to 131, we have 125 more loops to

; reach max 8 bit value of 255.

; 125 \* 4 μs = 500 μs

;

; TCNT0: timer counter

; TCCR0B: timer/counter control register (CS02:00 = 011 -> fclk/64)

setup\_timer:

ldi count, 0x83

ldi tmp1, (1<<CS01)|(1<<CS00)

out TCNT0, count

out TCCR0B, tmp1

ret

; start\_program:

; INITIAL DISPLAY

; - initialize the 7-segment display, call rpg check, and display number

; - dislpay a dash on the 7-segment display "-" (0x40)

start\_program:

ldi r16, 0x40

rcall display

rcall rpg\_check

cpi r17, 0x00

breq program\_loop

rjmp start\_program

; program\_loop:

; MAIN PROGRAM LOOP

; - update the value to be displayed on the 7-segment display via rpg interaction

; - checks for button press & duration, and compares with password or resets program (after 5 button clicks, code is either correct & LED shines or incorrect and program resets after 7 seconds)

program\_loop:

rcall compute\_current\_seven\_segment\_hex

rcall rpg\_check

; button\_check:

; BUTTON LISTENER

; - if the pushbutton is pressed for <1 second, add current value stored in r17 to password value

; - if the pushbutton is pressed for 1<t<2 seconds, do nothing

; - if the pushbutton is pressed for >2 second, reset the password value

button\_check:

sbic PINB, 3

rjmp program\_loop

; less\_than\_one:

; - pressed less than 1 second second, compare value with password digit

; - loops 0000011111010000 (2000) 2000 times \* 500 microseconds = 1 second

less\_than\_one:

ldi R26, 0xd0

ldi R27, 0x07

; less\_than\_one\_loop:

; - loop contained in less\_than\_one subroutine

less\_than\_one\_loop:

rcall timer\_delay\_500us

sbiw R27:R26, 1

breq one\_to\_two

sbis PINB, 3

rjmp less\_than\_one\_loop

rjmp compute\_hex\_at\_password\_index

; one\_to\_two:

; - pressed 1<t<2 seconds, do nothing

; - identical to less\_than\_one subroutine, but does not do anything if button is pressed

; - loops 0000011111010000 (2000) 2000 times \* 500 microseconds = 1 second (we already know that the less than one loop has been completed)

one\_to\_two:

ldi R26, 0xd0

ldi R27, 0x07

; one\_to\_two loop:

; - loop contained in one\_to\_two subroutine

one\_to\_two\_loop:

rcall timer\_delay\_500us

sbiw R27:R26, 1

breq greater\_than\_two

sbis PINB, 3

rjmp one\_to\_two\_loop

rjmp program\_loop

; greater\_than\_two:

; - pressed >2 seconds, reset the password value

; - we know that 2 seconds has already elapsed while the user is pressing the button

; - simply wait until the button is released, and then reset the program

greater\_than\_two:

sbis PINB, 3

rjmp greater\_than\_two

rjmp reset\_program

; compute\_hex\_at\_password\_index:

; TRAVERSE THE PASSWORD LOOKUP TABLE

; - load the value of the password at the current index

; - compare with the user's selected digit

; - if the values are equal, jump to correct\_value\_at\_index

; - otherwise, continue to incorrect\_value\_at\_index

compute\_hex\_at\_password\_index:

ldi ZL, low(password\_codes << 1)

add ZL, r19

lpm r18, Z

cp r17, r18

breq correct\_value\_at\_index

; incorrect\_value\_at\_index:

; USER PASSWORD IS INCORRECT

; - increment the index of the password lookup table

; - set r0 to 0 (this functions as a flag to indicate that the user's code is incorrect)

; - if the index of the password lookup table is 5, jump to incorrect\_code\_display

; - else, jump to program\_loop to continue current attempt

incorrect\_value\_at\_index:

inc r19

ldi tmp1, 0

mov r0, tmp1

cpi r19, 0x05

breq incorrect\_password\_display

rjmp program\_loop

; incorrect\_password\_display:

; DISPLAY IF USER ENTERS INCORRECT CODE

; - display the incorrect code pattern "\_"

incorrect\_password\_display:

ldi R26, 0xb0

ldi R27, 0x36

ldi r16, 0x08

rcall display

; incorrect\_password\_display\_loop:

; - display "\_" for 7 seconds and then reset

incorrect\_password\_display\_loop:

rcall timer\_delay\_500us

sbiw R27:R26, 1

breq reset\_program

rjmp incorrect\_password\_display\_loop

; correct\_value\_at\_index:

; USER VALUE AT INDEX IS CORRECT

; - set r0 to 1 (this functions as a flag to indicate that the user's code is correct)

; - if r0 = 0, jump to incorrect\_value\_at\_index

; - else, continue to program\_loop

correct\_value\_at\_index:

Mov tmp1, r0

cpi tmp1, 0

breq incorrect\_value\_at\_index

inc r19

ldi tmp1, 1

mov r0, tmp1

cpi r19, 0x05

breq check\_password\_correctness

rjmp program\_loop

; check\_password\_correctness:

; CHECK IF THE USER PASSWORD IS CORRECT

; - set r0 to 1 (this functions as a flag to indicate that the user's code is correct)

; - if r0 = 1, jump to LED\_ON, else continue to reset\_program

; - triggered after 5 button presses regardless of correctness

check\_password\_correctness:

mov tmp1, r0

cpi tmp1, 0x01

breq correct\_password

; reset\_program:

; RESET THE PROGRAM

; - set r0 to 1 (true initially... user hasnt entered the wrong code yet)

; - reset the index of the password lookup table to 0

; - jump to power\_on to restart the program

;

; 'ldi r17, 0x01'

; - no significance of 0x01 other than it isnt 0x00... needed to fix error when

; restarting resetting at 0. Because r17 would be set to 0x00, it would branch

; after the cpi in start\_program, skipping the display of the "-".

; This fixes the issue; the user can now stay at "-" until rotary is moved cw.

reset\_program:

ldi tmp1, 1

mov r0, tmp1

ldi r19, 0x00

ldi r17, 0x01

rjmp power\_on

; correct\_password:

;

; - display the LED on the arduino board

; - display a "." on the 7-segment display

; - only displayed if the user's code is correct

; - runs for 4 seconds

correct\_password:

ldi R26, 0x40

ldi R27, 0x1f

sbi PORTB, 5

ldi r16, 0x80

rcall display

; correct\_password\_loop:

; - display the LED on the arduino board for 4 seconds

correct\_password\_loop:

rcall timer\_delay\_500us

sbiw R27:R26, 1

breq LED\_off

rjmp correct\_password\_loop

; LED\_off:

; - turn off the LED on the arduino board

LED\_off:

cbi PORTB, 5

rjmp reset\_program

; rpg\_check:

; - check the state of the RPG

; - if the state has not changed, jump to no\_change

; - otherwise, jump to check\_state

; - rotary pulse generator has 3 pins: A, B, and C

; - A and B are used to determine the direction of the rotation

; - A and B are set to pin 6 and 7 of the arduino board

; - C is used to reset the program

rpg\_check:

rcall timer\_delay\_500us

in rpg\_current\_state, PIND

andi rpg\_current\_state, 0xC0

cp rpg\_current\_state, rpg\_previous\_state

breq no\_change

cpi rpg\_current\_state, 0x00

breq check\_state

rjmp save\_rpg\_state

; check\_state:

; - check the state of the RPG

; - if the state is 0x80, jump to cw\_check (10000000 - A is high)

; - if the state is 0x40, jump to ccw\_check (01000000 - B is high

; - otherwise, jump to save\_rpg\_state

check\_state:

cpi rpg\_previous\_state, 0x80

breq cw\_check

cpi rpg\_previous\_state, 0x40

breq ccw\_check

rjmp save\_rpg\_state

; ccw\_check:

; - check the state of the RPG

; - if the state is 0x00, jump to counter\_clockwise

; - otherwise, jump to ret

ccw\_check:

cpi rpg\_current\_state, 0x00

breq counter\_clockwise

ret

; cw\_check:

; - check the state of the RPG

; - if the state is 0x00, jump to clockwise

; - otherwise, jump to ret

cw\_check:

cpi rpg\_current\_state, 0x00

breq clockwise

ret

; counter\_clockwise:

; - check the state of the RPG

; - if the state is 0x40, jump to save\_rpg\_state

; - otherwise, jump to ret

; - note - if the current value displayed is '0', and the user continues to rotate clockwise, remain at 0

counter\_clockwise:

cpi r16, 0x40

breq save\_rpg\_state

dec r17

cpi r17, 0xff

breq display\_min\_bound

rjmp save\_rpg\_state

; clockwise:

; - check the state of the RPG

; - if the state is 0x40, jump to firstMovement

; - otherwise, jump to ret

; - note - if the current value displayed is 'f', and the user continues to rotate clockwise, remain at 'f'

clockwise:

cpi r16, 0x40

breq first\_movement

inc r17

cpi r17, 0x10

breq display\_max\_bound

rjmp save\_rpg\_state

; first\_movement:

; - set the value of r17 to 0

; - jump to save\_rpg\_state

first\_movement:

ldi r17, 0x00

rjmp save\_rpg\_state

; display\_min\_bound:

; - set the value of r17 to 0

; - jump to save\_rpg\_state

display\_min\_bound:

ldi r17, 0x00

rjmp save\_rpg\_state

; display\_max\_bound:

; - set the value of r17 to 0xf

; - jump to save\_rpg\_state

display\_max\_bound:

ldi r17, 0x0f

rjmp save\_rpg\_state

; save\_rpg\_state:

; - save the current state of the RPG

; - move the current state of the RPG to the previous state

; - this is used to determine the direction of the rotation

save\_rpg\_state:

mov rpg\_previous\_state, rpg\_current\_state

; no\_change:

; RPG STATE HAS NOT CHANGED

; - if this code block is reached, simply return

no\_change:

ret

; compute\_current\_seven\_segment\_hex:

; TRAVERSE THE SEVEN SEGMENT DISPLAY LOOKUP TABLE

; - find the value to be displayed on the 7-segment display

; - lookup the value in the seven\_segment\_codes table

; - load the value into r16

compute\_current\_seven\_segment\_hex:

ldi ZL, low(seven\_segment\_codes << 1)

add ZL, r17

; display\_call:

; DISPLAY THE VALUE ON THE 7-SEGMENT DISPLAY (driver)

; - calls the function display after loading z into r16 (current hex code) before returning to loop

display\_call:

lpm r16, Z

rcall display

ret

; display:

; DISPLAY THE VALUE ON THE 7-SEGMENT DISPLAY

; - display the current value on the 7-segment display

; - utilizes the stack to save the value of r16 and r17 and the status register

display:

push r16

push r17

in r17, SREG

push r17

ldi r17, 8

; rotate\_bits:

; SERIAL INPUT OF DATA TO 74HC595 SHIFT REGISTER

; - subroutine for 74hc595 shift register to shift in the value of the hex code to be displayed on the 7-segment display

; - shift the value of r16 to the left

; - if the carry flag is set, set the value of PORTB.0

; - otherwise, clear the value of PORTB.0

; - this runs 8 times to rotate all 8 bits of the hex code into the shift register

rotate\_bits:

rol r16

brcs set\_ser\_in\_1

cbi PORTB, 0

rjmp shift\_register\_out

; set\_ser\_in\_1:

; PULSE 1 TO SERIAL INPUT OF 74HC595 SHIFT REGISTER

; - subroutine for 74hc595 shift register to shift in the value of the hex code to be displayed on the 7-segment display

; - set the value of PORTB 0

set\_ser\_in\_1:

sbi PORTB, 0

; shift\_register\_out:

; OUTPUT DATA TO 74HC595 SHIFT REGISTER

; - subroutine for 74hc595 shift register to shift in the value of the hex code to be displayed on the 7-segment display

; - pulse srclk and rclk to shift in the value of the hex code to be displayed on the 7-segment display.

; - first shifts all digits in from r16 using rotate\_bit loop, then stores them (upon storage, because OE active, there is output from shift register... electrical circuit handles the rest).

; - restore the values in registers pushed onto stack

shift\_register\_out:

sbi PORTB, 2

cbi PORTB, 2

dec r17

brne rotate\_bits

sbi PORTB, 1

cbi PORTB, 1

pop r17

out SREG, r17

pop r17

pop r16

ret

;timer\_delay\_500us:

; DELAY FOR 500 MICROSECONDS

; - delay for 500 microseconds using timer0 of the atmega328p

;

; relevant registers:

; - TCCR0: timer counter control register - setting modes of timer/counter

; - TIFR0: timer counter interrupt flag register - if TOV0 set (1), then the timer is overflown

; - TCNT0: timer counter register - counts up with each pulse to the value loaded into it

timer\_delay\_500us:

in tmp1, TCCR0B

ldi tmp2, 0x00

out TCCR0B, tmp2

in tmp2, TIFR0

sbr tmp2, 1<<TOV0

out TIFR0, tmp2

out TCNT0, count

out TCCR0B, tmp1

; wait\_for\_overflow:

; - wait for the value of TOV0 to be set (overflown)

wait\_for\_overflow:

in tmp2, TIFR0

sbrs tmp2, TOV0

rjmp wait\_for\_overflow

ret

## 6. Appendix B: References

Beichel, Reinhard. *Embedded Systems Lab 2, ECE:3360. The University of Iowa, 2025* <<https://uiowa.instructure.com/courses/248357/files/29567265?module_item_id=8134634>>

Beichel, Reinard. *Embedded Systems, Rotary Pulse Generators and Lab 3. The University of Iowa, 2025 <*[*https://uiowa.instructure.com/courses/248357/files/29778930?module\_item\_id=8162158*](https://uiowa.instructure.com/courses/248357/files/29778930?module_item_id=8162158) *>*

Beichel, Reinard. *Embedded Systems, Lecture 8: Timers. The University of Iowa, 2025 <*[*https://uiowa.instructure.com/courses/248357/files/29853139?module\_item\_id=8165716*](https://uiowa.instructure.com/courses/248357/files/29853139?module_item_id=8165716) *>*

Components101. *7 Segment Display. 22 September 2019.*  <<https://components101.com/displays/7-segment-display-pinout-working-datasheet>>

Pighixxx. *The Definitive Arduino Uno Pinout Diagram*. *May 5, 2013. <*<https://uiowa.instructure.com/courses/248357/files/29320694?module_item_id=8042318>>

Texas Instruments. *SNx4HC595 8-Bit Shift Registers With 3-State Output Register. September 2015*. <<https://www.ti.com/lit/ds/symlink/sn74hc595.pdf>>

XLITX. *5161AS Datasheet <*<http://www.xlitx.com/datasheet/5161AS.pdf>>