Find solution for duplicate candidates

[minad]

Affected completion tables which return duplicates:

• Info-read-node-name-2
• read-library-name
• locate-file-completion-table

Either filter out duplicates using delete-dups (expensive hash table allocation) or delete-consecutive-dups (cheap, but does not work with flex, relies on sorting). Alternatively do nothing and try to fix this upstream. We could fix each of these completion tables on a case-by-case basis.

From my perspective the read-library-name and locate-file-completion-table are not particularly important. I don't think these functions are used often, therefore I consider this issue to be low priority.

[jkroes]

I believe this also affects Info-read-node-name-1, which is called after pressing "g" in an info buffer with default bindings, in the top info file ("dir"). Coming from ivy, which deduplicates and wraps the completion items (i.e., toplevel menu items) with "(...)", it took me a while to figure out why results weren't working when I typed the name of an info file.

[minad]

I suggest to open upstream bug reports regarding the completion tables in question. It does not make sense that the completion tables generate duplicate candidates. This requires expensive deduplication in the frontend. Instead of real deduplication we could omit consecutive dups, which is not perfect as I mentioned before but at least is cheap.

[jkroes]

I don't know how submit upstream bug reports for Emacs, and I'm not proficient enough in lisp to be confident I'm not introducing new bugs with a patch. But I did fix Info-read-node-name-2 according to my own tests by replacing push with add-to-list. I went a step further and removed all ./ and ../ completion items. (ivy.el handles those specially, but I don't think they have a well-defined purpose.) The modified lines are commented with "user mod: ..."

(defun my/Info-read-node-name-2 (dirs suffixes string pred action)
  "Modifies the original function to omit \"./\" and \"../\" from toplevel file
nodes and to delete duplicates by replacing `push' with `add-to-list'"
  (setq suffixes (remove "" suffixes))
  (when (file-name-absolute-p string)
    (setq dirs (list (file-name-directory string))))
  (let ((names nil)
	(names-sans-suffix nil)
        (suffix (concat (regexp-opt suffixes t) "\\'"))
        (string-dir (file-name-directory string)))
    (dolist (dir dirs)
      (unless dir
	(setq dir default-directory))
      (if string-dir (setq dir (expand-file-name string-dir dir)))
      (when (file-directory-p dir)
        ;; User mod: Don't complete string to "./" or "../"
	(dolist (file (delete "../"
                              (delete "./"
                                      (file-name-all-completions
                                       (file-name-nondirectory string) dir))))
	  ;; If the file name has no suffix or a standard suffix,
	  ;; include it.
	  (and (or (null (file-name-extension file))
		   (string-match suffix file))
	       ;; But exclude subfiles of split Info files.
	       (not (string-match "-[0-9]+\\'" file))
	       ;; And exclude backup files.
	       (not (string-match "~\\'" file))
               ;; User mod: Don't add duplicates
	       (add-to-list 'names (if string-dir
                                       (concat string-dir file)
                                     file)))
	  ;; If the file name ends in a standard suffix,
	  ;; add the unsuffixed name as a completion option.
	  (when (string-match suffix file)
	    (setq file (substring file 0 (match-beginning 0)))
            ;; User mod: don't add duplicates
	    (add-to-list 'names-sans-suffix (if string-dir
                                                (concat string-dir file)
                                              file))))))
    ;; If there is just one file, don't duplicate it with suffixes,
    ;; so `Info-read-node-name-1' will be able to complete a single
    ;; candidate and to add the terminating ")".
    (if (and (= (length names) 1) (= (length names-sans-suffix) 1))
	(setq names names-sans-suffix)
      (setq names (append names-sans-suffix names)))
    (complete-with-action action names string pred)))

[minad]

I don't know how submit upstream bug reports for Emacs

report-emacs-bug

But I did fix Info-read-node-name-2 according to my own tests by replacing push with add-to-list.

This is a bit problematic since it will lead to O(n^2) behavior. In order to do this properly use a hashtable or use push followed by a delete-dups afterwards. delete-dups uses a hashtable internally.