Skip to content

HTTPS clone URL

Subversion checkout URL

You can clone with
or
.
Download ZIP
Browse files

use Railscasts colorscheme

  • Loading branch information...
commit f571d4bb8ad9f111be57d808351071a331b2bf8b 1 parent b187c25
@mislav authored
Showing with 727 additions and 4 deletions.
  1. +630 −0 colors/badwolf.vim
  2. +96 −0 colors/railscasts.vim
  3. +1 −4 vimrc
View
630 colors/badwolf.vim
@@ -0,0 +1,630 @@
+" _ _ _ __
+" | |__ __ _ __| | __ _____ | |/ _|
+" | '_ \ / _` |/ _` | \ \ /\ / / _ \| | |_
+" | |_) | (_| | (_| | \ V V / (_) | | _|
+" |_.__/ \__,_|\__,_| \_/\_/ \___/|_|_|
+"
+" I am the Bad Wolf. I create myself.
+" I take the words. I scatter them in time and space.
+" A message to lead myself here.
+"
+" A Vim colorscheme pieced together by Steve Losh.
+" Available at http://stevelosh.com/projects/badwolf/
+"
+" Why? {{{
+"
+" After using Molokai for quite a long time, I started longing for
+" a replacement.
+"
+" I love Molokai's high contrast and gooey, saturated tones, but it can be
+" a little inconsistent at times.
+"
+" Also it's winter here in Rochester, so I wanted a color scheme that's a bit
+" warmer. A little less blue and a bit more red.
+"
+" And so Bad Wolf was born. I'm no designer, but designers have been scattering
+" beautiful colors through time and space long before I came along. I took
+" advantage of that and reused some of my favorites to lead me to this scheme.
+"
+" }}}
+
+" Supporting code -------------------------------------------------------------
+" Preamble {{{
+
+if !has("gui_running") && &t_Co != 88 && &t_Co != 256
+ finish
+endif
+
+set background=dark
+
+if exists("syntax_on")
+ syntax reset
+endif
+
+let colors_name = "badwolf"
+
+if !exists("g:badwolf_html_link_underline") " {{{
+ let g:badwolf_html_link_underline = 1
+endif " }}}
+
+if !exists("g:badwolf_css_props_highlight") " {{{
+ let g:badwolf_css_props_highlight = 0
+endif " }}}
+
+" }}}
+" Palette {{{
+
+let s:bwc = {}
+
+" The most basic of all our colors is a slightly tweaked version of the Molokai
+" Normal text.
+let s:bwc.plain = ['f8f6f2', 15]
+
+" Pure and simple.
+let s:bwc.snow = ['ffffff', 15]
+let s:bwc.coal = ['000000', 16]
+
+" All of the Gravel colors are based on a brown from Clouds Midnight.
+let s:bwc.brightgravel = ['d9cec3', 252]
+let s:bwc.lightgravel = ['998f84', 245]
+let s:bwc.gravel = ['857f78', 243]
+let s:bwc.mediumgravel = ['666462', 241]
+let s:bwc.deepgravel = ['45413b', 238]
+let s:bwc.deepergravel = ['35322d', 236]
+let s:bwc.darkgravel = ['242321', 235]
+let s:bwc.blackgravel = ['1c1b1a', 233]
+let s:bwc.blackestgravel = ['141413', 232]
+
+" A color sampled from a highlight in a photo of a glass of Dale's Pale Ale on
+" my desk.
+let s:bwc.dalespale = ['fade3e', 221]
+
+" A beautiful tan from Tomorrow Night.
+let s:bwc.dirtyblonde = ['f4cf86', 222]
+
+" Delicious, chewy red from Made of Code for the poppiest highlights.
+let s:bwc.taffy = ['ff2c4b', 196]
+
+" Another chewy accent, but use sparingly!
+let s:bwc.saltwatertaffy = ['8cffba', 121]
+
+" The star of the show comes straight from Made of Code.
+let s:bwc.tardis = ['0a9dff', 39]
+
+" This one's from Mustang, not Florida!
+let s:bwc.orange = ['ffa724', 214]
+
+" A limier green from Getafe.
+let s:bwc.lime = ['aeee00', 154]
+
+" Rose's dress in The Idiot's Lantern.
+let s:bwc.dress = ['ff9eb8', 211]
+
+" Another play on the brown from Clouds Midnight. I love that color.
+let s:bwc.toffee = ['b88853', 137]
+
+" Also based on that Clouds Midnight brown.
+let s:bwc.coffee = ['c7915b', 173]
+let s:bwc.darkroast = ['88633f', 95]
+
+" }}}
+" Highlighting Function {{{
+function! s:HL(group, fg, ...)
+ " Arguments: group, guifg, guibg, gui, guisp
+
+ let histring = 'hi ' . a:group . ' '
+
+ if strlen(a:fg)
+ if a:fg == 'fg'
+ let histring .= 'guifg=fg ctermfg=fg '
+ else
+ let c = get(s:bwc, a:fg)
+ let histring .= 'guifg=#' . c[0] . ' ctermfg=' . c[1] . ' '
+ endif
+ endif
+
+ if a:0 >= 1 && strlen(a:1)
+ if a:1 == 'bg'
+ let histring .= 'guibg=bg ctermbg=bg '
+ else
+ let c = get(s:bwc, a:1)
+ let histring .= 'guibg=#' . c[0] . ' ctermbg=' . c[1] . ' '
+ endif
+ endif
+
+ if a:0 >= 2 && strlen(a:2)
+ let histring .= 'gui=' . a:2 . ' cterm=' . a:2 . ' '
+ endif
+
+ if a:0 >= 3 && strlen(a:3)
+ let c = get(s:bwc, a:3)
+ let histring .= 'guisp=#' . c[0] . ' '
+ endif
+
+ " echom histring
+
+ execute histring
+endfunction
+" }}}
+" Configuration Options {{{
+
+if exists('g:badwolf_darkgutter') && g:badwolf_darkgutter
+ let s:gutter = 'blackestgravel'
+else
+ let s:gutter = 'blackgravel'
+endif
+
+if exists('g:badwolf_tabline')
+ if g:badwolf_tabline == 0
+ let s:tabline = 'blackestgravel'
+ elseif g:badwolf_tabline == 1
+ let s:tabline = 'blackgravel'
+ elseif g:badwolf_tabline == 2
+ let s:tabline = 'darkgravel'
+ elseif g:badwolf_tabline == 3
+ let s:tabline = 'deepgravel'
+ else
+ let s:tabline = 'blackestgravel'
+ endif
+else
+ let s:tabline = 'blackgravel'
+endif
+
+" }}}
+
+" Actual colorscheme ----------------------------------------------------------
+" Vanilla Vim {{{
+
+" General/UI {{{
+
+call s:HL('Normal', 'plain', 'blackgravel')
+
+call s:HL('Folded', 'mediumgravel', 'bg', 'none')
+
+call s:HL('VertSplit', 'lightgravel', 'bg', 'none')
+
+call s:HL('CursorLine', '', 'darkgravel', 'none')
+call s:HL('CursorColumn', '', 'darkgravel')
+call s:HL('ColorColumn', '', 'darkgravel')
+
+call s:HL('TabLine', 'plain', s:tabline, 'none')
+call s:HL('TabLineFill', 'plain', s:tabline, 'none')
+call s:HL('TabLineSel', 'coal', 'tardis', 'none')
+
+call s:HL('MatchParen', 'dalespale', 'darkgravel', 'bold')
+
+call s:HL('NonText', 'deepgravel', 'bg')
+call s:HL('SpecialKey', 'deepgravel', 'bg')
+
+call s:HL('Visual', '', 'deepgravel')
+call s:HL('VisualNOS', '', 'deepgravel')
+
+call s:HL('Search', 'coal', 'dalespale', 'bold')
+call s:HL('IncSearch', 'coal', 'tardis', 'bold')
+
+call s:HL('Underlined', 'fg', '', 'underline')
+
+call s:HL('StatusLine', 'coal', 'tardis', 'bold')
+call s:HL('StatusLineNC', 'snow', 'deepgravel', 'bold')
+
+call s:HL('Directory', 'dirtyblonde', '', 'bold')
+
+call s:HL('Title', 'lime')
+
+call s:HL('ErrorMsg', 'taffy', 'bg', 'bold')
+call s:HL('MoreMsg', 'dalespale', '', 'bold')
+call s:HL('ModeMsg', 'dirtyblonde', '', 'bold')
+call s:HL('Question', 'dirtyblonde', '', 'bold')
+call s:HL('WarningMsg', 'dress', '', 'bold')
+
+" This is a ctags tag, not an HTML one. 'Something you can use c-] on'.
+call s:HL('Tag', '', '', 'bold')
+
+" hi IndentGuides guibg=#373737
+" hi WildMenu guifg=#66D9EF guibg=#000000
+
+" }}}
+" Gutter {{{
+
+call s:HL('LineNr', 'mediumgravel', s:gutter)
+call s:HL('SignColumn', '', s:gutter)
+call s:HL('FoldColumn', 'mediumgravel', s:gutter)
+
+" }}}
+" Cursor {{{
+
+call s:HL('Cursor', 'coal', 'tardis', 'bold')
+call s:HL('vCursor', 'coal', 'tardis', 'bold')
+call s:HL('iCursor', 'coal', 'tardis', 'none')
+
+" }}}
+" Syntax highlighting {{{
+
+" Start with a simple base.
+call s:HL('Special', 'plain')
+
+" Comments are slightly brighter than folds, to make 'headers' easier to see.
+call s:HL('Comment', 'gravel')
+call s:HL('Todo', 'snow', 'bg', 'bold')
+call s:HL('SpecialComment', 'snow', 'bg', 'bold')
+
+" Strings are a nice, pale straw color. Nothing too fancy.
+call s:HL('String', 'dirtyblonde')
+
+" Control flow stuff is taffy.
+call s:HL('Statement', 'taffy', '', 'bold')
+call s:HL('Keyword', 'taffy', '', 'bold')
+call s:HL('Conditional', 'taffy', '', 'bold')
+call s:HL('Operator', 'taffy', '', 'none')
+call s:HL('Label', 'taffy', '', 'none')
+call s:HL('Repeat', 'taffy', '', 'none')
+
+" Functions and variable declarations are orange, because plain looks weird.
+call s:HL('Identifier', 'orange', '', 'none')
+call s:HL('Function', 'orange', '', 'none')
+
+" Preprocessor stuff is lime, to make it pop.
+"
+" This includes imports in any given language, because they should usually be
+" grouped together at the beginning of a file. If they're in the middle of some
+" other code they should stand out, because something tricky is
+" probably going on.
+call s:HL('PreProc', 'lime', '', 'none')
+call s:HL('Macro', 'lime', '', 'none')
+call s:HL('Define', 'lime', '', 'none')
+call s:HL('PreCondit', 'lime', '', 'bold')
+
+" Constants of all kinds are colored together.
+" I'm not really happy with the color yet...
+call s:HL('Constant', 'toffee', '', 'bold')
+call s:HL('Character', 'toffee', '', 'bold')
+call s:HL('Boolean', 'toffee', '', 'bold')
+
+call s:HL('Number', 'toffee', '', 'bold')
+call s:HL('Float', 'toffee', '', 'bold')
+
+" Not sure what 'special character in a constant' means, but let's make it pop.
+call s:HL('SpecialChar', 'dress', '', 'bold')
+
+call s:HL('Type', 'dress', '', 'none')
+call s:HL('StorageClass', 'taffy', '', 'none')
+call s:HL('Structure', 'taffy', '', 'none')
+call s:HL('Typedef', 'taffy', '', 'bold')
+
+" Make try/catch blocks stand out.
+call s:HL('Exception', 'lime', '', 'bold')
+
+" Misc
+call s:HL('Error', 'snow', 'taffy', 'bold')
+call s:HL('Debug', 'snow', '', 'bold')
+call s:HL('Ignore', 'gravel', '', '')
+
+" }}}
+" Completion Menu {{{
+
+call s:HL('Pmenu', 'plain', 'deepergravel')
+call s:HL('PmenuSel', 'coal', 'tardis', 'bold')
+call s:HL('PmenuSbar', '', 'deepergravel')
+call s:HL('PmenuThumb', 'brightgravel')
+
+" }}}
+" Diffs {{{
+
+call s:HL('DiffDelete', 'coal', 'coal')
+call s:HL('DiffAdd', '', 'deepergravel')
+call s:HL('DiffChange', '', 'darkgravel')
+call s:HL('DiffText', 'snow', 'deepergravel', 'bold')
+
+" }}}
+" Spelling {{{
+
+if has("spell")
+ call s:HL('SpellCap', 'dalespale', 'bg', 'undercurl,bold', 'dalespale')
+ call s:HL('SpellBad', '', 'bg', 'undercurl', 'dalespale')
+ call s:HL('SpellLocal', '', '', 'undercurl', 'dalespale')
+ call s:HL('SpellRare', '', '', 'undercurl', 'dalespale')
+endif
+
+" }}}
+
+" }}}
+" Plugins {{{
+
+" CtrlP {{{
+
+ " the message when no match is found
+ call s:HL('CtrlPNoEntries', 'snow', 'taffy', 'bold')
+
+ " the matched pattern
+ call s:HL('CtrlPMatch', 'orange', 'bg', 'none')
+
+ " the line prefix '>' in the match window
+ call s:HL('CtrlPLinePre', 'deepgravel', 'bg', 'none')
+
+ " the prompt’s base
+ call s:HL('CtrlPPrtBase', 'deepgravel', 'bg', 'none')
+
+ " the prompt’s text
+ call s:HL('CtrlPPrtText', 'plain', 'bg', 'none')
+
+ " the prompt’s cursor when moving over the text
+ call s:HL('CtrlPPrtCursor', 'coal', 'tardis', 'bold')
+
+ " 'prt' or 'win', also for 'regex'
+ call s:HL('CtrlPMode1', 'coal', 'tardis', 'bold')
+
+ " 'file' or 'path', also for the local working dir
+ call s:HL('CtrlPMode2', 'coal', 'tardis', 'bold')
+
+ " the scanning status
+ call s:HL('CtrlPStats', 'coal', 'tardis', 'bold')
+
+ " TODO: CtrlP extensions.
+ " CtrlPTabExtra : the part of each line that’s not matched against (Comment)
+ " CtrlPqfLineCol : the line and column numbers in quickfix mode (|s:HL-Search|)
+ " CtrlPUndoT : the elapsed time in undo mode (|s:HL-Directory|)
+ " CtrlPUndoBr : the square brackets [] in undo mode (Comment)
+ " CtrlPUndoNr : the undo number inside [] in undo mode (String)
+
+" }}}
+" EasyMotion {{{
+
+call s:HL('EasyMotionTarget', 'tardis', 'bg', 'bold')
+call s:HL('EasyMotionShade', 'deepgravel', 'bg')
+
+" }}}
+" Interesting Words {{{
+
+" These are only used if you're me or have copied the <leader>hNUM mappings
+" from my Vimrc.
+call s:HL('InterestingWord1', 'coal', 'orange')
+call s:HL('InterestingWord2', 'coal', 'lime')
+call s:HL('InterestingWord3', 'coal', 'saltwatertaffy')
+call s:HL('InterestingWord4', 'coal', 'toffee')
+call s:HL('InterestingWord5', 'coal', 'dress')
+call s:HL('InterestingWord6', 'coal', 'taffy')
+
+
+" }}}
+" Makegreen {{{
+
+" hi GreenBar term=reverse ctermfg=white ctermbg=green guifg=coal guibg=#9edf1c
+" hi RedBar term=reverse ctermfg=white ctermbg=red guifg=white guibg=#C50048
+
+" }}}
+" ShowMarks {{{
+
+call s:HL('ShowMarksHLl', 'tardis', 'blackgravel')
+call s:HL('ShowMarksHLu', 'tardis', 'blackgravel')
+call s:HL('ShowMarksHLo', 'tardis', 'blackgravel')
+call s:HL('ShowMarksHLm', 'tardis', 'blackgravel')
+
+" }}}
+
+" }}}
+" Filetype-specific {{{
+
+" Clojure {{{
+
+call s:HL('clojureSpecial', 'taffy', '', '')
+call s:HL('clojureDefn', 'taffy', '', '')
+call s:HL('clojureDefMacro', 'taffy', '', '')
+call s:HL('clojureDefine', 'taffy', '', '')
+call s:HL('clojureMacro', 'taffy', '', '')
+call s:HL('clojureCond', 'taffy', '', '')
+
+call s:HL('clojureKeyword', 'orange', '', 'none')
+
+call s:HL('clojureFunc', 'dress', '', 'none')
+call s:HL('clojureRepeat', 'dress', '', 'none')
+
+call s:HL('clojureParen0', 'lightgravel', '', 'none')
+
+call s:HL('clojureAnonArg', 'snow', '', 'bold')
+
+" }}}
+" CSS {{{
+
+if g:badwolf_css_props_highlight
+ call s:HL('cssColorProp', 'dirtyblonde', '', 'none')
+ call s:HL('cssBoxProp', 'dirtyblonde', '', 'none')
+ call s:HL('cssTextProp', 'dirtyblonde', '', 'none')
+ call s:HL('cssRenderProp', 'dirtyblonde', '', 'none')
+ call s:HL('cssGeneratedContentProp', 'dirtyblonde', '', 'none')
+else
+ call s:HL('cssColorProp', 'fg', '', 'none')
+ call s:HL('cssBoxProp', 'fg', '', 'none')
+ call s:HL('cssTextProp', 'fg', '', 'none')
+ call s:HL('cssRenderProp', 'fg', '', 'none')
+ call s:HL('cssGeneratedContentProp', 'fg', '', 'none')
+end
+
+call s:HL('cssValueLength', 'toffee', '', 'bold')
+call s:HL('cssColor', 'toffee', '', 'bold')
+call s:HL('cssBraces', 'lightgravel', '', 'none')
+call s:HL('cssIdentifier', 'orange', '', 'bold')
+call s:HL('cssClassName', 'orange', '', 'none')
+
+" }}}
+" Diff {{{
+
+call s:HL('gitDiff', 'lightgravel', '',)
+
+call s:HL('diffRemoved', 'dress', '',)
+call s:HL('diffAdded', 'lime', '',)
+call s:HL('diffFile', 'coal', 'taffy', 'bold')
+call s:HL('diffNewFile', 'coal', 'taffy', 'bold')
+
+call s:HL('diffLine', 'coal', 'orange', 'bold')
+call s:HL('diffSubname', 'orange', '', 'none')
+
+" }}}
+" Django Templates {{{
+
+call s:HL('djangoArgument', 'dirtyblonde', '',)
+call s:HL('djangoTagBlock', 'orange', '')
+call s:HL('djangoVarBlock', 'orange', '')
+" hi djangoStatement guifg=#ff3853 gui=bold
+" hi djangoVarBlock guifg=#f4cf86
+
+" }}}
+" HTML {{{
+
+" Punctuation
+call s:HL('htmlTag', 'darkroast', 'bg', 'none')
+call s:HL('htmlEndTag', 'darkroast', 'bg', 'none')
+
+" Tag names
+call s:HL('htmlTagName', 'coffee', '', 'bold')
+call s:HL('htmlSpecialTagName', 'coffee', '', 'bold')
+call s:HL('htmlSpecialChar', 'lime', '', 'none')
+
+" Attributes
+call s:HL('htmlArg', 'coffee', '', 'none')
+
+" Stuff inside an <a> tag
+
+if g:badwolf_html_link_underline
+ call s:HL('htmlLink', 'lightgravel', '', 'underline')
+else
+ call s:HL('htmlLink', 'lightgravel', '', 'none')
+endif
+
+" }}}
+" Java {{{
+
+call s:HL('javaClassDecl', 'taffy', '', 'bold')
+call s:HL('javaScopeDecl', 'taffy', '', 'bold')
+call s:HL('javaCommentTitle', 'gravel', '')
+call s:HL('javaDocTags', 'snow', '', 'none')
+call s:HL('javaDocParam', 'dalespale', '', '')
+
+" }}}
+" LaTeX {{{
+
+call s:HL('texStatement', 'tardis', '', 'none')
+call s:HL('texMathZoneX', 'orange', '', 'none')
+call s:HL('texMathZoneA', 'orange', '', 'none')
+call s:HL('texMathZoneB', 'orange', '', 'none')
+call s:HL('texMathZoneC', 'orange', '', 'none')
+call s:HL('texMathZoneD', 'orange', '', 'none')
+call s:HL('texMathZoneE', 'orange', '', 'none')
+call s:HL('texMathZoneV', 'orange', '', 'none')
+call s:HL('texMathZoneX', 'orange', '', 'none')
+call s:HL('texMath', 'orange', '', 'none')
+call s:HL('texMathMatcher', 'orange', '', 'none')
+call s:HL('texRefLabel', 'dirtyblonde', '', 'none')
+call s:HL('texRefZone', 'lime', '', 'none')
+call s:HL('texComment', 'darkroast', '', 'none')
+call s:HL('texDelimiter', 'orange', '', 'none')
+call s:HL('texZone', 'brightgravel', '', 'none')
+
+augroup badwolf_tex
+ au!
+
+ au BufRead,BufNewFile *.tex syn region texMathZoneV start="\\(" end="\\)\|%stopzone\>" keepend contains=@texMathZoneGroup
+ au BufRead,BufNewFile *.tex syn region texMathZoneX start="\$" skip="\\\\\|\\\$" end="\$\|%stopzone\>" keepend contains=@texMathZoneGroup
+augroup END
+
+" }}}
+" LessCSS {{{
+
+call s:HL('lessVariable', 'lime', '', 'none')
+
+" }}}
+" Lispyscript {{{
+
+call s:HL('lispyscriptDefMacro', 'lime', '', '')
+call s:HL('lispyscriptRepeat', 'dress', '', 'none')
+
+" }}}
+" Mail {{{
+
+call s:HL('mailSubject', 'orange', '', 'bold')
+call s:HL('mailHeader', 'lightgravel', '', '')
+call s:HL('mailHeaderKey', 'lightgravel', '', '')
+call s:HL('mailHeaderEmail', 'snow', '', '')
+call s:HL('mailURL', 'toffee', '', 'underline')
+call s:HL('mailSignature', 'gravel', '', 'none')
+
+call s:HL('mailQuoted1', 'gravel', '', 'none')
+call s:HL('mailQuoted2', 'dress', '', 'none')
+call s:HL('mailQuoted3', 'dirtyblonde', '', 'none')
+call s:HL('mailQuoted4', 'orange', '', 'none')
+call s:HL('mailQuoted5', 'lime', '', 'none')
+
+" }}}
+" Markdown {{{
+
+call s:HL('markdownHeadingRule', 'lightgravel', '', 'bold')
+call s:HL('markdownHeadingDelimiter', 'lightgravel', '', 'bold')
+call s:HL('markdownOrderedListMarker', 'lightgravel', '', 'bold')
+call s:HL('markdownListMarker', 'lightgravel', '', 'bold')
+call s:HL('markdownItalic', 'snow', '', 'bold')
+call s:HL('markdownBold', 'snow', '', 'bold')
+call s:HL('markdownH1', 'orange', '', 'bold')
+call s:HL('markdownH2', 'lime', '', 'bold')
+call s:HL('markdownH3', 'lime', '', 'none')
+call s:HL('markdownH4', 'lime', '', 'none')
+call s:HL('markdownH5', 'lime', '', 'none')
+call s:HL('markdownH6', 'lime', '', 'none')
+call s:HL('markdownLinkText', 'toffee', '', 'underline')
+call s:HL('markdownIdDeclaration', 'toffee')
+call s:HL('markdownAutomaticLink', 'toffee', '', 'bold')
+call s:HL('markdownUrl', 'toffee', '', 'bold')
+call s:HL('markdownUrldelimiter', 'lightgravel', '', 'bold')
+call s:HL('markdownLinkDelimiter', 'lightgravel', '', 'bold')
+call s:HL('markdownLinkTextDelimiter', 'lightgravel', '', 'bold')
+call s:HL('markdownCodeDelimiter', 'dirtyblonde', '', 'bold')
+call s:HL('markdownCode', 'dirtyblonde', '', 'none')
+call s:HL('markdownCodeBlock', 'dirtyblonde', '', 'none')
+
+" }}}
+" MySQL {{{
+
+call s:HL('mysqlSpecial', 'dress', '', 'bold')
+
+" }}}
+" Python {{{
+
+hi def link pythonOperator Operator
+call s:HL('pythonBuiltin', 'dress')
+call s:HL('pythonBuiltinObj', 'dress')
+call s:HL('pythonBuiltinFunc', 'dress')
+call s:HL('pythonEscape', 'dress')
+call s:HL('pythonException', 'lime', '', 'bold')
+call s:HL('pythonExceptions', 'lime', '', 'none')
+call s:HL('pythonPrecondit', 'lime', '', 'none')
+call s:HL('pythonDecorator', 'taffy', '', 'none')
+call s:HL('pythonRun', 'gravel', '', 'bold')
+call s:HL('pythonCoding', 'gravel', '', 'bold')
+
+" }}}
+" SLIMV {{{
+
+" Rainbow parentheses
+call s:HL('hlLevel0', 'gravel')
+call s:HL('hlLevel1', 'orange')
+call s:HL('hlLevel2', 'saltwatertaffy')
+call s:HL('hlLevel3', 'dress')
+call s:HL('hlLevel4', 'coffee')
+call s:HL('hlLevel5', 'dirtyblonde')
+call s:HL('hlLevel6', 'orange')
+call s:HL('hlLevel7', 'saltwatertaffy')
+call s:HL('hlLevel8', 'dress')
+call s:HL('hlLevel9', 'coffee')
+
+" }}}
+" Vim {{{
+
+call s:HL('VimCommentTitle', 'lightgravel', '', 'bold')
+
+call s:HL('VimMapMod', 'dress', '', 'none')
+call s:HL('VimMapModKey', 'dress', '', 'none')
+call s:HL('VimNotation', 'dress', '', 'none')
+call s:HL('VimBracket', 'dress', '', 'none')
+
+" }}}
+
+" }}}
+
View
96 colors/railscasts.vim
@@ -0,0 +1,96 @@
+" Vim color scheme
+"
+" Name: railscasts.vim
+" Maintainer: Nick Moffitt <nick@zork.net>
+" Last Change: 01 Mar 2008
+" License: WTFPL <http://sam.zoy.org/wtfpl/>
+" Version: 2.1
+"
+" This theme is based on Josh O'Rourke's Vim clone of the railscast
+" textmate theme. The key thing I have done here is supply 256-color
+" terminal equivalents for as many of the colors as possible, and fixed
+" up some of the funny behaviors for editing e-mails and such.
+"
+" To use for gvim:
+" 1: install this file as ~/.vim/colors/railscasts.vim
+" 2: put "colorscheme railscasts" in your .gvimrc
+"
+" If you are using Ubuntu, you can get the benefit of this in your
+" terminals using ordinary vim by taking the following steps:
+"
+" 1: sudo apt-get install ncurses-term
+" 2: put the following in your .vimrc
+" if $COLORTERM == 'gnome-terminal'
+" set term=gnome-256color
+" colorscheme railscasts
+" else
+" colorscheme default
+" endif
+" 3: if you wish to use this with screen, add the following to your .screenrc:
+" attrcolor b ".I"
+" termcapinfo xterm 'Co#256:AB=\E[48;5;%dm:AF=\E[38;5;%dm'
+" defbce "on"
+" term screen-256color-bce
+
+set background=dark
+hi clear
+if exists("syntax_on")
+ syntax reset
+endif
+
+let g:colors_name = "railscasts"
+
+hi link htmlTag xmlTag
+hi link htmlTagName xmlTagName
+hi link htmlEndTag xmlEndTag
+
+highlight Normal guifg=#E6E1DC guibg=#111111
+highlight Cursor guifg=#000000 ctermfg=0 guibg=#FFFFFF ctermbg=15
+highlight CursorLine guibg=#000000 ctermbg=233 cterm=NONE
+
+highlight Comment guifg=#BC9458 ctermfg=180 gui=italic
+highlight Constant guifg=#6D9CBE ctermfg=73
+highlight Define guifg=#CC7833 ctermfg=173
+highlight Error guifg=#FFC66D ctermfg=221 guibg=#990000 ctermbg=88
+highlight Function guifg=#FFC66D ctermfg=221 gui=NONE cterm=NONE
+highlight Identifier guifg=#6D9CBE ctermfg=73 gui=NONE cterm=NONE
+highlight Include guifg=#CC7833 ctermfg=173 gui=NONE cterm=NONE
+highlight PreCondit guifg=#CC7833 ctermfg=173 gui=NONE cterm=NONE
+highlight Keyword guifg=#CC7833 ctermfg=173 cterm=NONE
+highlight LineNr guifg=#2B2B2B ctermfg=159 guibg=#C0C0FF
+highlight Number guifg=#A5C261 ctermfg=107
+highlight PreProc guifg=#E6E1DC ctermfg=103
+highlight Search guifg=NONE ctermfg=NONE guibg=#2b2b2b ctermbg=235 gui=italic cterm=underline
+highlight Statement guifg=#CC7833 ctermfg=173 gui=NONE cterm=NONE
+highlight String guifg=#A5C261 ctermfg=107
+highlight Title guifg=#FFFFFF ctermfg=15
+highlight Type guifg=#DA4939 ctermfg=167 gui=NONE cterm=NONE
+highlight Visual guibg=#5A647E ctermbg=60
+
+highlight DiffAdd guifg=#E6E1DC ctermfg=7 guibg=#519F50 ctermbg=71
+highlight DiffDelete guifg=#E6E1DC ctermfg=7 guibg=#660000 ctermbg=52
+highlight Special guifg=#DA4939 ctermfg=167
+
+highlight pythonBuiltin guifg=#6D9CBE ctermfg=73 gui=NONE cterm=NONE
+highlight rubyBlockParameter guifg=#FFFFFF ctermfg=15
+highlight rubyClass guifg=#FFFFFF ctermfg=15
+highlight rubyConstant guifg=#DA4939 ctermfg=167
+highlight rubyInstanceVariable guifg=#D0D0FF ctermfg=189
+highlight rubyInterpolation guifg=#519F50 ctermfg=107
+highlight rubyLocalVariableOrMethod guifg=#D0D0FF ctermfg=189
+highlight rubyPredefinedConstant guifg=#DA4939 ctermfg=167
+highlight rubyPseudoVariable guifg=#FFC66D ctermfg=221
+highlight rubyStringDelimiter guifg=#A5C261 ctermfg=143
+
+highlight xmlTag guifg=#E8BF6A ctermfg=179
+highlight xmlTagName guifg=#E8BF6A ctermfg=179
+highlight xmlEndTag guifg=#E8BF6A ctermfg=179
+
+highlight mailSubject guifg=#A5C261 ctermfg=107
+highlight mailHeaderKey guifg=#FFC66D ctermfg=221
+highlight mailEmail guifg=#A5C261 ctermfg=107 gui=italic cterm=underline
+
+highlight SpellBad guifg=#D70000 ctermfg=160 ctermbg=NONE cterm=underline
+highlight SpellRare guifg=#D75F87 ctermfg=168 guibg=NONE ctermbg=NONE gui=underline cterm=underline
+highlight SpellCap guifg=#D0D0FF ctermfg=189 guibg=NONE ctermbg=NONE gui=underline cterm=underline
+highlight MatchParen guifg=#FFFFFF ctermfg=15 guibg=#005f5f ctermbg=23
View
5 vimrc
@@ -20,10 +20,7 @@ if has('gui_running')
else
set background=dark
endif
-set t_Co=256 " 256 colors
-color grb256
-" let g:solarized_termcolors=256
-" colorscheme solarized
+color railscasts
set nonumber " line numbers aren't needed
set ruler " show the cursor position all the time
Please sign in to comment.
Something went wrong with that request. Please try again.