Permalink
Fetching contributors…
Cannot retrieve contributors at this time
93 lines (72 sloc) 2.35 KB
buildscript {
repositories {
mavenLocal() //for local testing of mockito-release-tools
jcenter()
maven { url "https://plugins.gradle.org/m2/" }
}
dependencies {
classpath 'gradle.plugin.nl.javadude.gradle.plugins:license-gradle-plugin:0.14.0'
//Using buildscript.classpath so that we can resolve shipkit from maven local, during local testing
classpath 'org.shipkit:shipkit:0.9.144'
}
}
plugins {
id 'com.gradle.build-scan' version '1.9.1'
id 'me.champeau.buildscan-recipes' version '0.1.7'
}
description = 'Mockito mock objects library core API and implementation'
apply plugin: "org.shipkit.java"
allprojects {
plugins.withId("java") {
//Only upload specific modules we select
bintrayUpload.enabled = false
}
}
apply from: 'gradle/root/ide.gradle'
apply from: 'gradle/root/gradle-fix.gradle'
apply from: 'gradle/java-library.gradle'
apply from: 'gradle/license.gradle'
apply from: 'gradle/root/coverage.gradle'
apply from: 'gradle/mockito-core/inline-mock.gradle'
apply from: 'gradle/mockito-core/osgi.gradle'
apply from: 'gradle/mockito-core/javadoc.gradle'
apply from: 'gradle/mockito-core/testing.gradle'
apply from: 'gradle/dependencies.gradle'
archivesBaseName = "mockito-core"
allprojects {
repositories {
jcenter()
}
tasks.withType(JavaCompile) {
//I don't believe those warnings add value given modern IDEs
options.warnings = false
options.encoding = 'UTF-8'
}
apply plugin: 'checkstyle'
checkstyle {
configFile = rootProject.file('config/checkstyle/checkstyle.xml')
}
}
configurations {
testUtil //TODO move to separate project
}
dependencies {
compile libraries.bytebuddy, libraries.bytebuddyagent
compileOnly libraries.junit4, libraries.hamcrest
compile libraries.objenesis
testCompile libraries.asm
testCompile libraries.assertj
//putting 'provided' dependencies on test compile and runtime classpath
testCompileOnly configurations.compileOnly
testRuntime configurations.compileOnly
testUtil sourceSets.test.output
}
task wrapper(type: Wrapper) {
gradleVersion = '3.5'
}
//Posting Build scans to https://scans.gradle.com
buildScan {
licenseAgreementUrl = 'https://gradle.com/terms-of-service'
licenseAgree = 'yes'
recipes 'git-commit', 'travis-ci'
}