汇编大作业之万年历

# 万年历程序设计报告

914106840745

周子聪

接收年份字符串并传化

开始

初始化每月第一天星期几

打印三个月份

**否**


Bx=26？

12个月显示完毕

Exit


设置的初始年份为1995年，若距离1995年一月一日不超过65536天的年份应该都不会出错。也就是说1995——2174年应该都可以查询

具体能查询多少年内的没有特意验证，百度日历最多只给查2050年。1995年到2050年均正确，抽取三年截图如下：

















# 万年历源代码（汇编）

DATAS SEGMENT

pwr dw 0

year dw ?

month dw 1,2,3,4,5,6,7,8,9,10,11,12

xingqi db 's','m','t','w','t','f','s'

day dw 32,31,30,29,28,27,26,25,24,23,22,21,20,19,18,17,16,15,14,13,12,11,10,9,8,7,6,5,4,3,2,1

nuofday dw 31,28,31,30,31,30,31,31,30,31,30,31

firstday dw 12 dup(?) ;存放每月第一天星期几

nowday dw 4 dup(?) ;动态变化，存放当前月份下次须输出几号

tishi db 'INPUT YEAR YOU WANT TO KNOW:',0dh,0dh,'$'

DATAS ENDS

CODES SEGMENT

ASSUME CS:CODES,DS:DATAS

START:

MOV AX,DATAS

MOV DS,AX

mov dx,offset tishi

mov ah,9

int 21h

CALL PrintOneLine

;接收输入的年份

input:

MOV AH,1

INT 21H;ÊäÈëÒ»¸öN

mov ah,0

MOV pwr,Ax

CMP al,0dH

jz next0

sub al,30h

mov ah,0

push ax

mov ax,year

shl ax,1

push ax

mov cl,2

shl ax,cl

pop bx

add ax,bx

pop bx

add ax,bx

mov year,ax

jmp input

;计算并初始化数据段中每个月第一天星期几

next0:

mov cx,year

CALL IsLeap

cmp ax,1

jnz InitFirstDayOfMonth

mov nuofday[2],29

InitFirstDayOfMonth:

CALL PrintOneLine

mov dx,0

mov bx,year

sub bx,1995

mov cx,year

caculator:

sub cx,1

CALL IsLeap

cmp ax,1

jnz next

inc dx

next:

cmp cx,1995

jnz caculator

mov ax,year

sub ax,1995

mov bx,365

push dx

mul bx

pop dx

add ax,dx

mov bx,7

MOV DX,0

div bx

mov firstday,dx

mov bx,0

InitLoop:

mov ax,firstday[bx]

add ax,nuofday[bx]

mov cx,7

mov dx,0

div cx

add bx,2

mov firstday[bx],dx

cmp bx,22

jnz InitLoop

mov bx,2

BIGLOOP:

push bx

CALL PRINTYEAR

CALL PrintOneLine

pop bx

add bx,6

cmp bx,26

jnz BIGLOOP

EXIT:

MOV AH,4CH

INT 21H

;打印第二三四行日期

PRINT234 PROC

push bx

loopline234:

CALL PrintOneLine

CALL PrintBlank

CALL PrintBlank

mov bx,2

printdayline234:

mov cx,7

mov si,nowday[bx]

CALL PrintBlank

CALL PrintBlank

ag7day234:

mov ax,day[si]

CALL PrintNum

cmp day[si],10

jae printoneblank234

CALL PrintBlank

CALL PrintBlank

jmp next234

printoneblank234:

CALL PrintBlank

next234:

sub si,2

loop ag7day234

mov nowday[bx],si

inc bx

inc bx

cmp bx,8

jnz printdayline234

pop bx

RET

PRINT234 ENDP

;打印第五/六行日期

PRINT56 PROC

push bx

CALL PrintOneLine

CALL PrintBlank

CALL PrintBlank

printdayline56:

mov cx,7

push bx

mov dx,0

mov ax,bx

shr ax,1

mov bx,3

div bx

mov bx,dx

cmp bx,0

jz bxis3

shl bx,1

jmp justbx

bxis3:

mov bx,6

justbx:

mov si,nowday[bx]

pop bx

CALL PrintBlank

CALL PrintBlank

ag7day5:

sub bx,2

mov ax,day[si]

sub ax,1

cmp nuofday[bx],ax

jz printblank2

mov ax,day[si]

CALL PrintNum

sub si,2

jmp nextline5

printblank2:

CALL PrintBlank

CALL PrintBlank

nextline5:

CALL PrintBlank

add bx,2

loop ag7day5

push bx

mov dx,0

mov ax,bx

shr ax,1

mov bx,3

div bx

mov bx,dx

cmp bx,0

jz ifbxequ3

shl bx,1

jmp bxjust

ifbxequ3:

mov bx,6

bxjust:

mov nowday[bx],si

mov ax,bx

pop bx

inc bx

inc bx

cmp ax,6

jnz printdayline56

pop bx

RET

PRINT56 ENDP

;将ax中数字转化为一个个ASCII码打印出来

PrintNum PROC

push ax

push bx

push cx

push dx

mov cx,0

mov bx,10

ag1:mov dx,0

div bx

add dl,30h

push dx

inc cx

cmp ax,0

jnz ag1

ag2:pop dx

mov ah,2

int 21h

loop ag2

pop dx

pop cx

pop bx

pop ax

RET

PrintNum ENDP

;入口参数为bx，bx为2/8/14/20则打印第一/二/三/四季度日历

PRINTYEAR PROC

push bx

printmonth:

mov dx,' '

mov ah,2

int 21h

CALL PrintBlank

CALL PrintBlank

CALL PrintBlank

CALL PrintBlank

CALL PrintBlank

CALL PrintBlank

again1:

sub bx,2

mov ax,month[bx]

add bx,2

CALL PrintNum

mov dx,' '

mov ah,2

int 21h

mov dx,' '

mov ah,2

int 21h

mov dx,' '

mov ah,2

int 21h

CALL PrintBlank

CALL PrintBlank

CALL PrintBlank

push bx

mov dx,0

mov ax,bx

shr ax,1

mov bx,3

div bx

mov bx,dx

cmp bx,0

jz ifbxequ300

shl bx,1

jmp bxjust00

ifbxequ300:

mov bx,6

bxjust00:

mov ax,bx

pop bx

add bx,2

cmp ax,6

jnz again1

pop bx

CALL PrintOneLine

push bx

mov cx,3

;显示星期日到星期六

printxingqi:

CALL PrintBlank

CALL PrintBlank

mov bx,0

again2:

CALL PrintBlank

CALL PrintBlank

mov dl,xingqi[bx]

mov ah,2

int 21h

inc bx

cmp bx,7

jnz again2

loop printxingqi

pop bx

CALL PrintOneLine

push bx

;显示第一行日期

printdayline1:

mov si,32 ;day[si]表示当前日期

shl si,1

sub si,2

sub bx,2

mov cx,firstday[bx]

add bx,2

push cx

agblank1:

cmp cx,0

jz next000

CALL PrintBlank

CALL PrintBlank

CALL PrintBlank

sub cx,1

jmp agblank1

next000:

CALL PrintBlank

CALL PrintBlank

pop cx

mov ax,7

sub ax,cx

mov cx,ax

outputline1:

CALL PrintBlank

CALL PrintBlank

mov ax,day[si]

CALL PrintNum

sub si,2

loop outputline1

push bx

mov dx,0

mov ax,bx

shr ax,1

mov bx,3

div bx

mov bx,dx

cmp bx,0

jz bxis31

shl bx,1

jmp justbx1

bxis31:

mov bx,6

justbx1:

mov nowday[bx],si

mov ax,bx

pop bx

add bx,2

cmp ax,6

jnz printdayline1

pop bx

;显示第二三四行日期

CALL PRINT234

CALL PRINT234

CALL PRINT234

;显示第五六行日期

next5:

;

CALL PRINT56

CALL PRINT56

RET

PRINTYEAR ENDP

;判断CX中的年份是不是闰年，是闰年AX置1否则置0

IsLeap PROC

push bx

push cx

push dx

;判断能否被4整除

mov ax,cx

mov bx,4

MOV dx,0

div bx

cmp dx,0

jnz notleap

;判断能否被100整除

mov ax,cx

mov bx,100

MOV DX,0

div bx

cmp dx,0

jnz leap

;判断能否被400整除

mov ax,cx

mov bx,400

MOV DX,0

div bx

cmp dx,0

jnz notleap

leap:

mov ax,1

jmp endleap

notleap:

mov ax,0

endleap:

pop dx

pop cx

pop bx

RET

IsLeap ENDP

;打印一个空格

PrintBlank PROC

mov dx,' '

mov ah,2

int 21h

RET

PrintBlank ENDP

;换行

PrintOneLine PROC

mov dx,0dh

mov ah,2

int 21h

mov dx,0ah

mov ah,2

int 21h

RET

PrintOneLine ENDP

CODES ENDS

END START

## 总结

调试至少100多次，历时两天完成，使用的是Masm for Windows 集成实验环境2015。剪切调试，打印寄存器值调试。

期间为写成子程序做过几次大的改动，导致运行时奔溃，难以快速定位错误，几乎是从头到尾将程序在心里一步不落的跑一遍，大约花了二十分钟找到了错误。

总结此次代码书写过程中的错误有：

1. PrintLine56子程序结尾忘加RET，导致输出奇怪的8

2. 子程序只push不pop，导致运行崩溃

3. 使用指令div之前没有将dx置0，导致编译环境报divider error

4. 子程序之前没有退出程序指令，导致子程序顺序执行

5. 使用jnz跳转地址超过规定短范围，导致运行时崩溃（改用jmp解决）

……