***LAB解答***

**P8：思考時間（左右對齊 + 資料剖析）**

1. C2:C48：=B2&","

**P19：思考時間（表格建立與使用）**

1. I7：=IF(ISBLANK([@員工編號]),””,IFERROR(VLOOKUP([@員工編號],員工資料表格,2,0),  
"請輸入正確的員工編號"))

**P21：產品管理（表格的建立與使用）**

1. 產品資料（E49）：=SUMPRODUCT([成本],[庫存量])

2. 業務員（F4）：=COUNTIF(客戶資料表格[業務員編號],[@業務員編號])

3. 產品資料（G4）：=([@標價]-[@成本])/[@標價]

4. 訂單詳細（F4）：=[@數量]\*[@售價]

5. 訂單詳細（G4）：=[@數量]\*VLOOKUP([@產品編號],產品資料表格,4,FALSE)

6. 訂單（G4）：=SUMIF(訂單詳細資料表格[訂單編號],[@訂單編號],訂單詳細資料表格[小計])

7. 訂單（H4）：=SUMIF(訂單詳細資料表格[訂單編號],[@訂單編號],訂單詳細資料表格[成本])

**P25：產品管理（資料統計）**

1. C3:F14：=COUNTIFS(客戶資料表格[市/鎮],$B3,客戶資料表格[職稱],C$2)

2. J4:J12：=COUNTIF(訂單資料表格[業務員編號],$I4)

3. K4:K12：=AVERAGEIF(訂單資料表格[業務員編號],$I4,訂單資料表格[訂單金額總計])

**P31：思考時間（公式名稱）**

1. C5:F5：=COUNT(公式名稱一:公式名稱三!D5:D12)

2. C6:F6：=AVERAGE(公式名稱一:公式名稱三!D5:D12)

3. C7:F7：=MAX(公式名稱一:公式名稱三!D5:D12)

4. C8:F8：=MIN(公式名稱一:公式名稱三!D5:D12)

**解法一：**

5. C9:F9：=CONCATENATE(  
COUNTIF(公式名稱一!D5:D12,">=60")+COUNTIF(公式名稱二!D5:D12,">=60")+  
COUNTIF(公式名稱三!D5:D12,">=60")," ( ",TEXT((  
COUNTIF(公式名稱一!D5:D12,">=60")+COUNTIF(公式名稱二!D5:D12,">=60")+  
COUNTIF(公式名稱三!D5:D12,">=60"))/C5,"##.##%")," )")

**解法二（優）：**

5. C9（定義名稱 - 及格人數）：=COUNTIF(公式名稱一!D$5:D$12,">=60")+  
COUNTIF(公式名稱二!D$5:D$12,">=60")+  
COUNTIF(公式名稱三!D$5:D$12,">=60"))

6. C9:F9：=CONCATENATE(及格人數," ( ",TEXT(及格人數/C5,"##.##%")," )")

**P34：產品管理（名稱建立與使用）**

1. 定義名稱 – 今年：=YEAR(TODAY())

**P38：思考時間（資料驗證）**

1. F6:F13（資料驗證）：=(LEN(F7)=10)\*ISNUMBER(VALUE(RIGHT(F7,9)))\*  
(CODE(UPPER(F7))>=65)\*(CODE(UPPER(F7))<=90)

=(LEN(F7)=10),ISNUMBER(VALUE(RIGHT(F7,9)))\*  
(CODE(UPPER(LEFT(F7)))>=65)\*(CODE(UPPER(LEFT(F7)))<=90)

=AND(LEN(F7)=10,ISNUMBER(VALUE(RIGHT(F7,9))),  
CODE(UPPER(F7))>=65,CODE(UPPER(F7))<=90)

=AND(LEN(F7)=10,ISNUMBER(VALUE(RIGHT(F7,9))),  
CODE(UPPER(LEFT(F7)))>=65,CODE(UPPER(LEFT(F7)))<=90)

**P41：思考時間（母子選單）**

1. G4：=VLOOKUP(C3,INDIRECT(C2),2,0)  
=IF(C2=”一年級”,VLOOKUP(C3,B7:C10,2,0),  
 IF(C2=”二年級”,VLOOKUP(C3,E7:F10,2,0),VLOOKUP(C3,H7:I10,2,0)))

**P43：產品管理（資料驗證）**

1. 產品資料（B4:B48-資料驗證）：=COUNTIF($B:$B,B4)=1

2. 訂單詳細（E4:E2889-資料驗證）：=VLOOKUP(C4,產品資料,4,0)

**P46：產品管理（陣列公式）**

1. N4：｛=MAX(IF(訂單資料表格[業務員編號]=M4,訂單資料表格[訂單金額總計],""))｝

2. O4：｛=MIN(IF(訂單資料表格[業務員編號]=M4,訂單資料表格[訂單金額總計],""))｝

**P47：思考時間（頻率分佈）**

1. L3:P23=COUNTIF(D$3:D$2051,"<="&$J3)-SUM(L$2:L2)  
｛=FREQUENCY(D$3:D$2051,$J$3:$J$23)｝

**P49：產品管理（腦筋急轉彎）**

1. C5：｛=SUM(IF(產品資料表格[類別]=B5,產品資料表格[成本]\*產品資料表格[庫存量],0))｝  
C10：=SUMPRODUCT((產品資料表格[類別]=B10)\*產品資料表格[成本]\*產品資料表格[庫存量])

2. F4：｛=SUM(IF((訂單資料表格[業務員編號]=$E4)\*(訂單資料表格[付款類型]=F$3)\*  
 (YEAR(訂單資料表格[訂單日期])=今年),  
 訂單資料表格[訂單金額總計],0))｝

F17：=SUMPRODUCT((訂單資料表格[業務員編號]=$E17)\*(訂單資料表格[付款類型]=F$16)\*  
 (YEAR(訂單資料表格[訂單日期])=今年)\*  
 訂單資料表格[訂單金額總計])

F30：=SUMIFS(訂單資料表格[訂單金額總計],  
 訂單資料表格[業務員編號],$E30,訂單資料表格[付款類型],F$29,  
 訂單資料表格[訂單日期],">="&DATE(今年,1,1))

3. K4：｛=SUM(IF((訂單資料表格[業務員編號]=$J4)\*  
 (TEXT(訂單資料表格[訂單日期],"yyyymm")=今年&TEXT(K$3,"00")),  
 訂單資料表格[訂單金額總計],0))｝

K17：=SUMPRODUCT((訂單資料表格[業務員編號]=$J17)\*  
 (TEXT(訂單資料表格[訂單日期],"yyyymm")=今年&TEXT(K$16,"00"))\*  
 訂單資料表格[訂單金額總計])

K30：=SUMIFS(訂單資料表格[訂單金額總計],訂單資料表格[業務員編號],$J30,  
 訂單資料表格[訂單日期],">="&DATE(今年,K$29,1),  
 訂單資料表格[訂單日期],"<="&EOMONTH(DATE(今年,K$29,1),0))

**P60：思考時間（課表查詢）**

1. C2：=COUNTIF(D5:Q35,"\*"&B2&"\*")

2. D5:Q35（格式化條件）：=ISERROR(SEARCH($B$2,D5))

**P62：產品管理（條件化格式儲存格）**

1. B4:J48（格式化條件）：=$H4<=$I4

**P63：產品管理（關鍵效能指標）**

1. H2：=NOW()

2. H3：=DATE(今年,12,31)-TODAY()

3. H4：=SUM(業務員資料表格[本期業績目標])

4. H5：=SUMPRODUCT((YEAR(訂單資料表格[訂單日期])=今年)\*  
訂單資料表格[訂單金額總計])

=SUMIF(訂單資料表格[訂單日期],">="&DATE(今年,1,1),  
訂單資料表格[訂單金額總計])

5. H6：=(H5-SUMPRODUCT((YEAR(訂單資料表格[訂單日期])=今年)\*  
訂單資料表格[訂單成本]))/H5

=(H5-SUMIF(訂單資料表格[訂單日期],">="&DATE(今年,1,1),  
訂單資料表格[訂單成本]))/H5

6. H7：=產品資料表格[[#總計],[成本]]

7. H8：=SUMPRODUCT((產品資料表格[庫存量]<=產品資料表格[庫存臨界點])\*1)

｛=SUM(IF(產品資料表格[庫存量]-產品資料表格[庫存臨界點]<=0,1,0))｝

8. H9：=COUNTA(客戶資料表格[客戶編號])

9. I3：=YEARFRAC(DATE(今年,1,1)-1,TODAY(),1)

10. I4：=H5/H4

11. I5（格式化條件）：=$H$4\*$I$3\*0.95、=$H$4\*$I$3\*1.05

12. 定義名稱 – 總平均庫存：=SUM(產品資料表格[平均庫存])

13. I7（格式化條件）：=總平均庫存\*0.95、=總平均庫存\*1.15

14. I8（格式化條件）：=(COUNTA(產品資料!$B:$B)-2)\*0.2、=(COUNTA(產品資料!$B:$B)-2)\*0.3

**P68：思考時間（資料庫函數）**

1. O9：=DCOUNTA(B3:J48,J3,M3:W4)

2. O10：=DSUM(B3:J48,J3,M3:W4)

3. O11：=DMAX(B3:J48,J3,M3:W4)

4. O12：=DMIN(B3:J48,J3,M3:W4)

5. O13：=DAVERAGE(B3:J48,J3,M3:W4)

6. O14：=IFERROR(DGET(B3:$J48,H3,M3:W4),"資料數量太多")

7. (1) N4：<>飲料  
(2) M4：NWTD  
(3) S4：>=50  
(4) N4：\*果  
(5) V4：=(LEN(C4)=2)\*(RIGHT(C4)="果")

=AND(LEN(C4)=2,RIGHT(C4)="果")  
(6) V4：=(J4>=50000)\*(J4<=80000)

=AND(J4>=50000,J4<=80000)  
(7) V4：=H4<=I4  
(8) V4：=OR(C4={"乾果","蔬菜水果"})\*(E4>=1000)

=AND(OR(C4={"乾果","蔬菜水果"}),E4>=1000)

**P74：思考時間（資料篩選）**

1. C3：?生  
F3：大學

2. B3：<>行銷部  
F3：碩士

3. I3：=OR(B8="行銷部",F8="碩士")

4. I3：=OR((E8>=40)\*(E8<=60),(H8>=10)\*(H8<=20))  
=OR(AND(E8>=40,E8<=60),AND(H8>=10,H8<=20))

5. B8:I58（格式化條件）：=MONTH($D8)=MONTH(TODAY())  
B8:I58（格式化條件）：=TEXT($D8,"mmdd")=TEXT(TODAY(),"mmdd")  
I3：=MONTH(D8)=MONTH(TODAY())  
I3：=TEXT(D8,"mmdd")=TEXT(TODAY(),"mmdd")

**P84：案例場景（數學運算）**

1. C5:C14：=B5^3+B5^2+B5+1

2. F4：=F3^3+F3^2+F3+1

3. K5:T8：=CHOOSE(ROW(1:1),K$4+2,K$4-2,K$4\*2,K$4/2)

4. V5:V8：=CHOOSE(ROW(1:1),$V$3+2,$V$3-2,$V$3\*2,$V$3/2)

**P86：案例場景（貸款分析）**

1. C4：=-PMT(C3/12,D3\*12,B3)

2. H4：=-PMT(I3/12,J3\*12,H3)

**P88：案例場景（囍餅訂購）**

1. C6：=D2\*G2+D3\*G3

2. J6：=VLOOKUP(D2\*G2+D3\*G3,P7:Q12,2)\*(D2\*G2+D3\*G3)

3. K7:N12（格式化條件）：=K7<K6

4. K7:N12（格式化條件）：=K7<J7

**P91：案例場景（盈收預測）**

1. E3:I3：=D3\*(1+$L$6)

2. E5:I9：=D5\*(1+$L7)


3. E12:I12：=E3-E10

**P100：案例場景（鷄免同籠）**


1. C4,E4：=E2+E3

2. C5,E5：=2\*E2+4\*E3

**解法一：**

3. 

**解法二：**

3. 

**P101：案例場景（無解）**

1. D2：=SUMPRODUCT(C5:C6,G5:G6)

2. D7:E7：=SUMPRODUCT(D5:D6,$G$5:$G$6)

3. 


**P102：案例場景（九宮格）**

1. 

**P103：案例場景（工廠裝配）：*12,360***

1. C2：=SUMPRODUCT(C12:G12,C13:G13)

2. I6:I12：=H6-SUMPRODUCT(C6:G6,$C$13:$G$13)


3. 

**P104：案例場景（多重期間生產）：*15,705,000***

1. N2：=SUM(C14:F19)

2. C14:F19：=J6\*C$3+J14\*C$3\*0.02


3. J14:M19：=SUM(J13,J6)-C6

4. 

**P105：案例場景（投資決策）：*21,500***

1. C2：=SUMPRODUCT(C6:C12,I6:I12)

2. D13:H13：=SUMPRODUCT(D6:D12,$I$6:$I$12)


3. 

**P106：案例場景（任務指派）：*17,900***


1. C2：=SUMPRODUCT(C6:J13,C17:J24)

2. K17:K24：=IFERROR(INDEX($C$16:$J$16,MATCH(L17,C17:J17,0)),"")

**解法一：**

3. 

**解法二：**

3. 

**P108：案例場景（人力調度）：*69,022***


1. C11：=SUMPRODUCT(C9:E9,C10:E10)

2. G5:G8：=F5+Q5-P5

3. H5:H8：=SUMPRODUCT(C5:E5,$C$10:$E$10)

4. G5:G8：=F5+Q5-P5


5. Q5:Q8：｛=TRANSPOSE(K9:N9)｝

6. 

**P110：案例場景（值班人力）：*200,000***

1. C10：=8000\*SUM(G3:G9)

2. H3:N9：=IF(ISERROR(SEARCH(RIGHT(H$2),$F3)),$G3,0)

3. 

**P111：案例場景（公平分組）：*0.83***

1. I13：=STDEV.P(I9:I12)

2. F9:H12：=IFERROR(VLOOKUP(CHAR(F3+64),$B$3:$C$14,2,0),"")

3. 