diff --git a/flake.nix b/flake.nix
index 57c7a5e9..0953fcd4 100644
--- a/flake.nix
+++ b/flake.nix
@@ -40,5 +40,7 @@
 
           nativeBuildInputs = with pkgs; [ pkg-config rust-bin.stable.latest.default pkgs.rust-bin.stable.latest.rust-analyzer ];
         };
-      });
+      }) // {
+        nixosModules.default = import ./module.nix self;
+      };
 }
diff --git a/module.nix b/module.nix
new file mode 100644
index 00000000..dd4aa855
--- /dev/null
+++ b/module.nix
@@ -0,0 +1,80 @@
+self: { config, lib, pkgs, ... }:
+
+with lib;
+let
+  cfg = config.services.minidsp;
+  tomlFormat = pkgs.formats.toml {};
+in
+{
+  options = {
+    services.minidsp = {
+      enable = mkOption {
+        type = types.bool;
+        default = false;
+        description = ''
+        Whether to enable the minidsp service
+        '';
+      };
+
+      package = mkOption {
+        type = types.package;
+        default = self.packages.${pkgs.system}.default;
+        description = ''
+        minidsp package to use
+        '';
+      };
+
+      config = mkOption {
+        type = tomlFormat.type;
+        default = {
+          http_server = {
+            bind_address = "127.0.0.1:5380";
+          };
+
+          tcp_server = [{
+            bind_address = "127.0.0.1:5333";
+          }];
+
+          static_device = [];
+        };
+        description = ''
+        Configuration file
+        For available options see <https://minidsp-rs.pages.dev/daemon/>
+        '';
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    environment.systemPackages = [ cfg.package ];
+
+    users = {
+      users.minidsp = {
+        description = "minidsp daemon user";
+        group = "minidsp";
+        isSystemUser = true;
+      };
+      groups.minidsp = {};
+    };
+
+    systemd.services.minidspd = {
+      after = ["network.target"];
+      description = "minidsp daemon";
+      wantedBy = ["multi-user.target"];
+
+      serviceConfig = {
+        User = "minidsp";
+        ExecStart = "${cfg.package}/bin/minidspd --config /etc/minidspd.toml";
+      };
+    };
+
+    environment.etc."minidspd.toml" = {
+      source = tomlFormat.generate "minidspd.toml" cfg.config;
+    };
+
+    services.udev.extraRules = ''
+      ATTR{idVendor}=="2752", MODE="660", GROUP="minidsp"
+      ATTR{idVendor}=="04d8", ATTRS{idProduct}=="003f", MODE="660", GROUP="minidsp"
+    '';
+  };
+}