"SIGSEGV: Illegal storage access" error when I try to use libgit2's library.

[wicast]

I have installed libgit2 library on my linux PC.
And the following code will get "SIGSEGV: Illegal storage access" error whenever is in debug mode or release mode.

type
  git_commit=ptr pointer
const
  GIT_OID_RAWSZ* = 20
type
  git_oid* = object
    id*: array[GIT_OID_RAWSZ, cuchar]

proc git_commit_lookup*(commit:git_commit; repo: pointer; id: pointer):cint {.  importc: "git_commit_lookup",dynlib:"libgit2.so",cdecl.}

proc git_libgit2_init():cint {.importc,dynlib:"libgit2.so".}
# proc git_libgit2_init():cint {.importc:"git_libgit2_init",header:"<git2.h>".}
proc git_repository_init(ou:pointer,path:cstring,is_bare:bool):cint{.importc,dynlib:"libgit2.so".}
# proc git_repository_init(ou:pointer,path:cstring,is_bare:bool):cint{.importc:"git_repository_init",header:"<git2.h>".}

proc git_libgit2_version*(major: ptr cint; minor: ptr cint; rev: ptr cint) {.  importc: "git_libgit2_version",dynlib:"libgit2.so".}

proc git_repository_open(ou:pointer,path:cstring):cint {. importc: "git_repository_open",dynlib:"libgit2.so" .}


proc git_oid_fromstr*(ou:ptr git_oid,str:cstring):cint {.importc:"git_oid_fromstr",dynlib:"libgit2.so".}

var
  repo:pointer
  major,minor,rev:cint


git_libgit2_version(major.addr,minor.addr,rev.addr)
echo major
echo minor
echo rev

var err= git_repository_open(repo,"./tmp")
if err!=0:
  quit(1)

var
  id:git_oid
  sha:cstring="1da5570cc4153a7adfd01caaec666c6ae3a611d5"

err=git_oid_fromstr(id.addr,sha)
if err!=0:
  quit(1)

echo repr(id)

var
  commit:pointer

discard git_commit_lookup(commit.addr,repo,id.addr)

The problem is occured in last line of git_commit_lookup procedure.

The origin signature of git_commit_lookup is

git_commit_lookup(git_commit **commit, git_repository *repo, const git_oid *id);

And git_commit struct is defined in commit.h as:
typedef struct git_commit git_commit;
c2nim will skip this.

I tried C to call the libgit2,everything is ok.

#include <stdlib.h>
#include <stdio.h>
#include "git2.h"



int main(){
    /* void *repo = NULL; */
    git_repository *repo = NULL;
    int er=git_repository_open(&repo, "./tmp/");
    if(er!=0){
        exit(1);
    }
    git_oid oid;

    int error = git_oid_fromstr(&oid,"1da5570cc4153a7adfd01caaec666c6ae3a611d5");
    if(error!=0){
        exit(1);
    }

    /* git_commit *commit; */
    void *commit;
    int err = git_commit_lookup(&commit, repo, &oid);

    const char *message = git_commit_message(commit);
    printf("%s",message);
}

I need some help to get it work.

[jangko]

looks like this is not a compiler bug.

type
  git_oid* {.pure.} = object  #pure pragma will translate it into plain C struct, no runtime info
    id*: array[GIT_OID_RAWSZ, cuchar]

hope this can help

[wicast]

@jangko thanks,but this won't work.
The problem is about git_commit,not git_oid.
Nim can't get useful information of git_commit declaration from libgit2's head file.

I need to know how to convert

typedef struct git_commit git_commit;

to nim code.

Using this seems not correct.

type
  git_commit=ptr pointer #this will be convert to void** .

[jangko]

that can be translated to

type
   git_commit = pointer   #or distinct pointer

proc git_commit_lookup*(commit: var git_commit .....

var commit: git_commit
git_commit_lookup(commit, .....

but, your translation i think also ok. using ptr pointer is the same
btw, i think git_libgit2_init() also need to be called first, doesn't it?
i have no problem using this code(a bit different, but should be equal to your translation too):

const
  LIB_NAME* = "libgit2.dll"

{.push callconv: cdecl, dynlib: LIB_NAME .}

type
  git_commit= distinct pointer
  git_repository = distinct pointer

const
  GIT_OID_RAWSZ* = 20

type
  git_oid* {.pure.} = object
    id*: array[GIT_OID_RAWSZ, cuchar]

proc git_commit_lookup*(commit: ptr pointer; repo: git_repository; id: ptr git_oid): cint {.importc.}
proc git_libgit2_init(): cint {.importc.}
proc git_repository_init(ou: var git_repository, path: cstring, is_bare: bool): cint {.importc.}
proc git_libgit2_version*(major: var cint; minor: var cint; rev: var cint) {.importc.}
proc git_repository_open(ou: var git_repository, path: cstring): cint {.importc.}
proc git_oid_fromstr*(ou: var git_oid, str: cstring): cint {.importc.}
proc git_commit_message(commit: pointer): cstring {.importc.}

var
  repo: git_repository
  major, minor, rev: cint

discard git_libgit2_init()  #the only difference is only here

git_libgit2_version(major, minor, rev)
echo major
echo minor
echo rev

var err = git_repository_open(repo, "f:\\projects\\bugHunter")
if err != 0:
  quit(1)

var
  id: git_oid
  sha: cstring="a40560a75d65370ee9641412052bdd913123b940"

err = git_oid_fromstr(id, sha)
if err != 0:
  quit(1)
echo repr(id)

var
  commit: pointer

discard git_commit_lookup(commit.addr, repo, id.addr)

let msg = git_commit_message(commit)
echo msg

[wicast]

Thank you very much @jangko ! I got the point!
The parameters in nim is inmutable!I totally forgot that.

I was confused with error message.This issue can be closed.