Generics + inheritable non-ref objects: type issue

[mratsim]

Doing InheritedType is RootType returns true when no generics are involved but false when they are.
Concepts don't have such issue.

Test case:

import macros

## 1. Sanity check

echo "\n 1. Sanity check"

type Foo = object {.inheritable.}
type Bar = object of Foo
type Baz = object of Foo

proc do_smth(x: Foo) =
  echo "got Foo"

proc do_smth(x: Bar) =
  echo "got Bar"

proc do_smth(x: Baz) =
  echo "got Baz"

block:
  var a: Baz
  do_smth(a)    # Got Baz
  echo a is Foo # True

##########################################
echo "\n 2. Generics stack inheritable vs concepts"

type
  TrainableLayer[T] = object {.inheritable.}
    weight: seq[T]
    bias: seq[T]

  Conv2DLayer[T] = object of TrainableLayer[T]
  LinearLayer[T] = object of TrainableLayer[T]

  Trainable[T] = concept layer
    layer.weight is seq[T]
    layer.bias   is seq[T]

type ExampleModel[TT] = object
  cv1: Conv2DLayer[TT]
  classifier: LinearLayer[TT]

block:
  var a: ExampleModel[int]

  for field, val in a.fieldPairs:
    echo "\n   Field: " & field.astToStr
    echo "Trainable: " & $(val is Trainable)
    echo "TrainableLayer: " & $(val is TrainableLayer) # <---- Doesn't work
    echo "Conv2D: " & $(val is Conv2DLayer)
    echo "Linear: " & $(val is LinearLayer)

  #    Field: "cv1"
  # Trainable: true        <---- Concepts works
  # TrainableLayer: false  <---- Doesn't work
  # Conv2D: true
  # Linear: false

  #    Field: "classifier"
  # Trainable: true
  # TrainableLayer: false <---- Doesn't work
  # Conv2D: false
  # Linear: true


##########################################
echo "\n 3. Concrete stack inheritable vs concepts"

type
  TrainableLayer2 = object {.inheritable.}
    weight: int
    bias: int

  Conv2DLayer2 = object of TrainableLayer2
  LinearLayer2 = object of TrainableLayer2

  Trainable2 = concept layer
    layer.weight is int
    layer.bias   is int

type ExampleModel2 = object
  ## Holds the Trainable layers
  cv1: Conv2DLayer2
  classifier: LinearLayer2

block:
  var a: ExampleModel2

  for field, val in a.fieldPairs:
    echo "\n   Field: " & field.astToStr
    echo "Trainable: " & $(val is Trainable2)
    echo "TrainableLayer: " & $(val is TrainableLayer2) # <------ Works
    echo "Conv2D: " & $(val is Conv2DLayer2)
    echo "Linear: " & $(val is LinearLayer2)

  #    Field: "classifier"
  # Trainable: true
  # TrainableLayer: true  <------ Works
  # Conv2D: false
  # Linear: true

[Araq]

Compiler bugs aside, you really should not use .inheritable here but inherit from RootObj. .inheritable is only for C++ interop, losing the runtime type information makes every runtime type conversation unchecked.

[shirleyquirk]

maybe related: https://forum.nim-lang.org/t/7798#49595 https://stackoverflow.com/questions/67118749/nim-invalid-type-in-this-context-error

type
  Foo = object of RootObj
  Bar = object of Foo
  Baz[T:Foo] = object of RootObj
    val:T
let x = Baz[Bar]()#Error object constructor needs an object type
type
  Qux = object
    val:Baz[Bar]
let y = Qux() #Error: invalid type: 'Baz[Baz.T]' in this context: 'Qux' for let

concepts work:

type
  Foo = object of RootObj
  IsFoo = concept type t
    t is Foo
  Bar = object of Foo
  Baz[T:IsFoo] = object of RootObj
    val:T
  Qux = object
    val:Baz[Bar]
let x = Baz[Bar]()#fine
let y = Qux() #fine

[shirleyquirk]

another workaround:

func init[T:Foo](b: type Baz; c: typedesc[T]):Baz[T] = discard
let x = Baz.init(Bar)

[metagn]

Original issue is fixed either by #24430 or #24425, the comment above is still not fixed, moved into #24447

Full test file for original case

discard """
  output: '''

 1. Sanity check
got Baz
true

 2. Generics stack inheritable vs concepts

Field: "cv1"
Trainable: true
TrainableLayer: true
Conv2D: true
Linear: false

Field: "classifier"
Trainable: true
TrainableLayer: true
Conv2D: false
Linear: true

 3. Concrete stack inheritable vs concepts

Field: "cv1"
Trainable: true
TrainableLayer: true
Conv2D: true
Linear: false

Field: "classifier"
Trainable: true
TrainableLayer: true
Conv2D: false
Linear: true
'''
"""

# issue #7713

import std/macros

## 1. Sanity check

echo "\n 1. Sanity check"

type Foo {.inheritable.} = object
type Bar = object of Foo
type Baz = object of Foo

proc do_smth(x: Foo) =
  echo "got Foo"

proc do_smth(x: Bar) =
  echo "got Bar"

proc do_smth(x: Baz) =
  echo "got Baz"

block:
  var a: Baz
  do_smth(a)    # Got Baz
  echo a is Foo # True

##########################################
echo "\n 2. Generics stack inheritable vs concepts"

type
  TrainableLayer[T] {.inheritable.} = object
    weight: seq[T]
    bias: seq[T]

  Conv2DLayer[T] = object of TrainableLayer[T]
  LinearLayer[T] = object of TrainableLayer[T]

  Trainable[T] = concept layer
    layer.weight is seq[T]
    layer.bias   is seq[T]

type ExampleModel[TT] = object
  cv1: Conv2DLayer[TT]
  classifier: LinearLayer[TT]

block:
  var a: ExampleModel[int]

  for field, val in a.fieldPairs:
    echo "\nField: " & field.astToStr
    echo "Trainable: " & $(val is Trainable)
    echo "TrainableLayer: " & $(val is TrainableLayer) # <---- Doesn't work
    echo "Conv2D: " & $(val is Conv2DLayer)
    echo "Linear: " & $(val is LinearLayer)

  #    Field: "cv1"
  # Trainable: true        <---- Concepts works
  # TrainableLayer: false  <---- Doesn't work
  # Conv2D: true
  # Linear: false

  #    Field: "classifier"
  # Trainable: true
  # TrainableLayer: false <---- Doesn't work
  # Conv2D: false
  # Linear: true


##########################################
echo "\n 3. Concrete stack inheritable vs concepts"

type
  TrainableLayer2 {.inheritable.} = object
    weight: int
    bias: int

  Conv2DLayer2 = object of TrainableLayer2
  LinearLayer2 = object of TrainableLayer2

  Trainable2 = concept layer
    layer.weight is int
    layer.bias   is int

type ExampleModel2 = object
  ## Holds the Trainable layers
  cv1: Conv2DLayer2
  classifier: LinearLayer2

block:
  var a: ExampleModel2

  for field, val in a.fieldPairs:
    echo "\nField: " & field.astToStr
    echo "Trainable: " & $(val is Trainable2)
    echo "TrainableLayer: " & $(val is TrainableLayer2) # <------ Works
    echo "Conv2D: " & $(val is Conv2DLayer2)
    echo "Linear: " & $(val is LinearLayer2)

  #    Field: "classifier"
  # Trainable: true
  # TrainableLayer: true  <------ Works
  # Conv2D: false
  # Linear: true