Enable ? ] ; magics in inferior-julia and cleanup

This commit cleans up the code for inferior-julia and adds
highlighting and linking for error messages. It also allows ? ] and ;
REPL magic prefixes to work as expected.

Author: non-Jedi

julia-mode.el

@@ -863,49 +863,105 @@ following commands are defined:
 ;; Code for `inferior-julia-mode'
 (require 'comint)
 
-(defcustom julia-program "julia"
+(defcustom inferior-julia-program "julia"
   "Path to the program used by `inferior-julia'."
   :type 'string
   :group 'julia)
 
-(defcustom julia-arguments '("-i" "--color=yes")
-  "Commandline arguments to pass to `julia-program'."
+(defcustom inferior-julia-buffer "*Inferior Julia*"
+  "Name of buffer for running an inferior Julia process."
+  :type 'string
+  :group 'julia)
+
+(defcustom inferior-julia-arguments '("-i" "--color=yes")
+  "Commandline arguments to pass to `inferior-julia-program'."
   :type '(repeat (string :tag "argument"))
   :group 'julia)
 
-(defvar julia-prompt-regexp "^\\w*> "
+(defcustom inferior-julia-prompt-read-only comint-prompt-read-only
+  "If non-nil, the Julia prompt is read only."
+  :type 'boolean)
+
+(defvar inferior-julia-prompt-regexp "^\\w*> "
   "Regexp for matching `inferior-julia' prompt.")
 
+(defvar inferior-julia-error-regexp-alist
+  (list (list (rx line-start " " ?\[ (1+ num) "] " (1+ nonl) " at "
+                  (group (1+ (not (any ?\n ?:))))
+                  ?:
+                  (group (1+ num))) 1 2))
+  "Value for `compilation-error-regexp-alist' in inferior Julia.")
+
 (defvar inferior-julia-mode-map
   (nconc (make-sparse-keymap) comint-mode-map)
   "Basic mode map for `inferior-julia-mode'.")
 
+(defvar inferior-julia-mode-syntax-table
+  (make-syntax-table julia-mode-syntax-table)
+  "Syntax table for use in `inferior-julia-mode' buffers.")
+
 ;;;###autoload
-(defun inferior-julia ()
+(defun inferior-julia (&optional arg)
     "Run an inferior instance of julia inside Emacs."
-    (interactive)
-    (let ((julia-program julia-program))
-      (when (not (comint-check-proc "*Julia*"))
-        (apply #'make-comint-in-buffer "Julia" "*Julia*"
-               julia-program nil julia-arguments))
-      (pop-to-buffer-same-window "*Julia*")
-      (inferior-julia-mode)))
-
-(defun inferior-julia--initialize ()
-    "Helper function to initialize `inferior-julia'."
-    (setq comint-use-prompt-regexp t))
-
-(define-derived-mode inferior-julia-mode comint-mode "Julia"
-  "Major mode for `inferior-julia'.
-
+    (interactive "P")
+    (let ((buffer (get-buffer-create inferior-julia-buffer)))
+      (unless arg
+        (pop-to-buffer buffer))
+      (with-current-buffer buffer
+        (let ((proc (apply #'make-comint
+                           (substring inferior-julia-buffer 1 -1)
+                           inferior-julia-program nil
+                           inferior-julia-arguments)))
+          ;; Pkg and REPL modules must be accessible for ] and ? magics
+          (comint-send-string
+           proc "baremodule _InferiorJulia import Pkg, REPL end;"))
+        (inferior-julia-mode))
+      buffer))
+
+(defun inferior-julia--send (proc string)
+  "Send STRING to inferior Julia PROC.
+Checks if first character in STRING is special. \"?\" invokes Julia
+help, \"]\" uses the Pkg repl, and \";\" sends shell commands."
+  (let* ((c (aref string 0))
+         (wrapper (cond
+                   ((char-equal c ??)
+                    (cons "eval(_InferiorJulia.REPL.helpmode(\"" "\"))"))
+                   ((char-equal c ?\])
+                    (cons "_InferiorJulia.Pkg.pkg\"" "\""))
+                   ((char-equal c ?\;)
+                    (cons "Base.repl_cmd(`" "`, stdout)"))
+                   (t
+                    (cons "" ""))))
+         (wrapped-string (if (eq (length (car wrapper)) 0)
+                             string
+                           (substring string 1))))
+    (comint-simple-send
+     proc
+     (concat (car wrapper) wrapped-string (cdr wrapper)))))
+
+(define-derived-mode inferior-julia-mode comint-mode "Inferior Julia"
+  "Major mode for interacting with an inferior Julia process.
+
+Key bindings:
 \\<inferior-julia-mode-map>"
-  nil "Julia"
+  :group 'julia
   :abbrev-table julia-mode-abbrev-table
-  (setq-local comint-prompt-regexp julia-prompt-regexp)
-  (setq-local comint-prompt-read-only t)
+  (setq comint-prompt-regexp inferior-julia-prompt-regexp)
+  (setq-local comint-prompt-read-only inferior-julia-prompt-read-only)
+
+  (setq-local compilation-error-regexp-alist inferior-julia-error-regexp-alist)
+  (compilation-shell-minor-mode 1)
+  (compilation-forget-errors)
+
   (setq-local font-lock-defaults '(julia-font-lock-keywords t))
-  (setq-local paragraph-start julia-prompt-regexp)
+  (setq-local paragraph-start inferior-julia-prompt-regexp)
   (setq-local indent-line-function #'julia-indent-line)
+  (setq-local comment-use-syntax t)
+  (setq-local comment-start "# ")
+  (setq-local comment-start-skip "#+\\s-*")
+
+  (setq-local comint-input-sender #'inferior-julia--send)
+
   (when julia-force-tab-complete
     (setq-local tab-always-indent 'complete)
     (abbrev-mode 1))
@@ -914,8 +970,6 @@ following commands are defined:
   (add-hook 'completion-at-point-functions
             #'julia-mode-latexsub-completion-at-point-around nil t))
 
-(add-hook 'inferior-julia-mode-hook #'inferior-julia--initialize)
-
 ;;;###autoload
 (defalias 'run-julia #'inferior-julia
   "Run an inferior instance of julia inside Emacs.")