Acquisition/Retention Exercise

David’s Revolutionary Atlantic Telecommunications (DRAT) offers high-speed wireless Internet service. Based on its latest research, David’s Revolutionary Atlantic Telecommunications (DRAT) has identified 3 distinct consumer segments in the Atlanta market that it serves. The three segments are Tech-Savvy Singles (TSS; 25%), Dual-Income No Kids (DINK; 35%), and Professionals with Children (PWC; 40%). DRAT has found that, while the same segments are present in different markets, the proportion of consumers in each segment varies from market to market.

The consumer segments differ both in terms of their acquisition and retention of DRAT’s service. Below is the probability with which a consumer from each of the three segments acquiring DRAT’s services for different levels of marketing investments.

**DRAT Acquisition Probabilities**

|  |  |  |  |
| --- | --- | --- | --- |
| Marketing Investment | TSS | DINK | PWC |
| $1/consumer | 0.005 | 0.035 | 0.001 |
| $2/consumer | 0.035 | 0.040 | 0.005 |
| $3/consumer | 0.040 | 0.041 | 0.010 |
| $4/consumer | 0.045 | 0.042 | 0.015 |
| $5/consumer | 0.045 | 0.042 | 0.020 |

DRAT’s telecommunication services are offered at a price of $25/month. The cost of serving current customers includes customer service and marketing activity. DRAT can cut the costs associated with serving its current customers, but doing so is expected to result in an increase in customer churn. Below are the expected churn rates based on DRAT’s previous research.

**DRAT Monthly Churn Probabilities**

|  |  |  |  |
| --- | --- | --- | --- |
| Customer Investment | TSS | DINK | PWC |
| $2/month | 0.250 | 0.100 | 0.050 |
| $4/month | 0.225 | 0.100 | 0.050 |
| $6/month | 0.200 | 0.080 | 0.045 |
| $8/month | 0.175 | 0.080 | 0.045 |
| $10/month | 0.150 | 0.075 | 0.045 |

You have been tasked with developing a tool that DRAT can use to assess expected profitability by calculating the lifetime value of consumers in a given market. Your tool should allow DRAT to update the following:

1. Market size (assume 1,000,000 consumers for the Atlanta market)
2. The annual discount rate (assume initially to be 10%)
3. Mix of the three segments in the market (must add up to 100%)
4. Per consumer amount to invest in acquisition
5. Monthly amount to invest in serving customers

Walkthrough

The Excel file contains three worksheets:

**Financial Calculations**: The spending decisions on acquisition and retention efforts, as well as the financial calculations of interest, will all occur on this sheet.

**CLV Analysis**: Based on the designated acquisition and retention spending, we use this sheet to calculate the value of an acquired customer. This is based on (1) the retention rate, (2) the retention spending per period, and (3) the discount rate.

**Reference Tables**: This sheet contains the acquisition and churn rates associated with different levels of spending.

Let’s first begin with the Financial Calculations sheet. To ensure that the market segment sizes add up to 100%, we will display either “OK” if the market segment sizes do add to 100% or an error message otherwise. In cell B7, enter:

=IF(SUM(B4:B6)=1,"OK","Market Size Must Equal 1")

In the red shaded region, we will insert drop-down menus for the acquisition and retention spending amounts. For each cell under the Acquisition Spend column (B10:B12), we will use data validation to do this. On the Data tab, click on Data Validation. Under settings, change the Allow value from “Any Value” to “List.” In the Source field, click the icon at the end of the text box to select cells A3:A7 on the Reference Tables sheet. Similarly, for each cell in the Retention Spend column (C10:C12), use data validation with the source for the list being cells A11:A15 on the Reference Tables sheet. For each cell in B10:C12, you should now have dropdown menus that allow you to specify the level for per customer spending on acquisition and retention.

Moving to the blue shaded region, cells B14:B16 require us to calculate the incoming cashflows for each acquired customer. To do this, we will calculate CLV on the CLV Analysis tab. To set up this sheet, we will first identify the acquisition and retention probabilities associated with a given level of spending. We will use the VLOOKUP commands to identify the acquisition/retention probabilities associated with the spending level specified on the Financial Calculations sheet. In Cell B2, enter the command:

=VLOOKUP('Financial Calculations'!B10,'Reference Tables'!$A$3:$D$7,2,FALSE)

This will pull the acquisition probability from the Reference Table Sheet for the TSS segment associated with spending the amount listed in Cell B10 on the Financial Calculations sheet. In Cell C2, enter:

=1-VLOOKUP('Financial Calculations'!C10,'Reference Tables'!$A$10:$D$15,2,FALSE)

The VLOOKUP command retrieves the churn probability associated with a given level of retention spending. Our CLV calculations rely on the retention probability, which is given by 1 – Churn Probability. Repeat this process for the remaining two segments.

To calculate CLV for an acquired customer, we first need to calculate the likelihood that a customer is still a paying subscriber at a given point in time. We assume that customers are paying subscribers in the first month. The likelihood that a customer is still a paying subscriber the next month is given by the retention probability *r*. The probability of still being a subscriber the following month is given by *r*2. Another way of specifying this is recursively, with Pr(subscribe at *t*+1) = *r* × Pr(subscribe at *t*). For the TSS segment, the retention probability is given in Cell C2. In Cell B9, enter:

=B8\*'CLV Analysis'!$C$2

This formula can be copied down the column. Repeat this process of each of the remaining segments, being sure to use the appropriate retention probability.

Next, we need to calculate the cashflow per acquired customer, in present day value. This consists of three parts: (1) monthly revenue less costs, (2) the probability of still being a subscriber, and (3) the discounting term. The monthly revenue less cost can be calculated as the service price (cell B1 on Financial Calculations) minus the monthly retention cost. The probability of still being a subscriber was calculated in columns B-D on the CLV Analysis sheet. The final component requires that we convert the annual discount rate to a monthly rate, and account for how far into the future we are discounting back. In cell E9, enter:

=('Financial Calculations'!$B$1-'Financial Calculations'!$C$10)\*B8\*(((1/(1+'Financial Calculations'!$B$2))^(1/12))^$A8)

This combines all three of the components for the TSS segment. In cell F9, we change the retention spending and the survival probabilities to correspond to the DINK segment:

=('Financial Calculations'!$B$1-'Financial Calculations'!$C$11)\*C8\*(((1/(1+'Financial Calculations'!$B$2))^(1/12))^$A8)

Similarly, G9 uses the retention spending and survival probabilities for the PWC segment:

=('Financial Calculations'!$B$1-'Financial Calculations'!$C$12)\*D8\*(((1/(1+'Financial Calculations'!$B$2))^(1/12))^$A8)

Copy these formulas down their respective columns. Summing one of the columns gives the CLV for an acquired customer from a given segment.

To complete our workbook, return to the Financial Calculations sheet. The revenue per acquired customer, having accounted for retention spending is given by summing the CLV columns. For example, in B14, we enter:

=SUM('CLV Analysis'!E8:E247)

Next, in B17:B19, we calculate the number of acquired customers per segment. This is based on the market size, the size of each segment in the market, and the acquisition probability of individuals in the segment. For the TSS segment, in cell B17, enter:

=$B$3\*$B4\*'CLV Analysis'!$B2

In calculating segment profit, we multiply the value each customer provides and the number of expected customers from the segment, and subtract the costs associated with acquisition efforts. The acquisition efforts apply to all individuals in the segment, not just those who are eventually acquired. For the TSS segment in Cell B20, this is:

=(B14\*B17)-($B$3\*$B4\*'Financial Calculations'!$B10)

The total profit is then given in B23 by summing the segment profits:

=SUM(B20:B22)

Using this tool, we can now identify the best mix of acquisition and retention spending per segment. We can also explore how valuable it is to be able to distinguish among individuals from the segment by finding (1) the best acquisition/retention spending per segment, and comparing the associated profit to (2) the best acquisition/retention spending for overall profit by assuming that the spending levels are the same across segments.