Permalink
Find file
91cc886 Feb 23, 2017
@apease @msvarny
16723 lines (14324 sloc) 625 KB
;; ================================================
;; SUMO (Suggested Upper Merged Ontology)
;; ================================================
;; The original versions of SUMO incorporated elements from many public sources
;; which are documented at http://www.ontologyportal.org/SUMOhistory/
;; The SUMO is freely available, subject to the following IEEE license.
;; ----------------------
;; Copyright � 2004 by the Institute of Electrical and Electronics Engineers, Inc.
;; Three Park Avenue
;; New York, NY 10016-5997, USA
;; All rights reserved.
;; 1. COPYRIGHT
;; The Institute of Electrical and Electronics Engineers, Inc., ("IEEE") owns the
;; copyright to this Document in all forms of media. Copyright in the text retrieved,
;; displayed or output from this Document is owned by IEEE and is protected by the
;; copyright laws of the United States and by international treaties. The IEEE reserves
;; all rights not expressly granted herein.
;; 2. ROYALTIES
;; The IEEE is providing the Document at no charge. However, the Document is not to be
;; considered "Public Domain," as the IEEE is, and at all times shall remain, the sole
;; copyright holder in the Document. The IEEE intends to revise the Document from time to
;; time; the latest version shall be available at http://standards.ieee.org/catalog/
;; 3. TERMS OF USE
;; The IEEE hereby grants Licensee a perpetual, non-exclusive, royalty-free, world-wide
;; right and license to copy, publish and distribute the Document in any way, and to
;; prepare derivative works that are based on or incorporate all or part of the Document
;; provided that the IEEE is appropriately acknowledged as the source and copyright owner
;; in each and every use.
;; 4. LIMITED WARRANTIES & LIMITATIONS OF REMEDIES
;; LICENSOR Does not warrant or represent the accuracy or content of the document and
;; Expressly Disclaims any Express or Implied Warranty, including any Implied Warranty of
;; Merchantability or Fitness for a Specific Purpose or that the use of the document is
;; free from patent infringement. The document is supplied ONLY "AS IS."
;; ----------------------
;; The SUMO was initially developed at Teknowledge Corp.
;; Any questions or comments about this ontology can be directed to the
;; Technical editor, Adam Pease, apease [at] articulatesoftware [dot] com
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; The knowledge representation language in which the SUMO is expressed is SUO-KIF,
;; which stands for "Standard Upper Ontology - Knowledge Interchange Format". SUO-KIF
;; is a simplified form of the popular KIF knowledge representation language. A
;; specification of SUO-KIF can be found at: http://www.ontologyportal.org
;; The SUMO is a modular ontology. That is, the ontology is divided into
;; self-contained subontologies. Each subontology is indicated by a section
;; header, and the dependencies between the subontologies are specified with
;; statements of the form ";; INCLUDES '<SUBONTOLOGY>'". These statements are
;; found at the beginning of each section.
;; We ask the people using or referencing SUMO cite our primary paper:
;; Niles, I., and Pease, A. 2001. Towards a Standard Upper Ontology. In
;; Proceedings of the 2nd International Conference on Formal Ontology in
;; Information Systems (FOIS-2001), Chris Welty and Barry Smith, eds,
;; Ogunquit, Maine, October 17-19, 2001. Also see http://www.ontologyportal.org
;; BEGIN FILE
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; STRUCTURAL ONTOLOGY ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; INCLUDES 'BASE ONTOLOGY'
;; The Structural Ontology consists of definitions of certain syntactic
;; abbreviations that can be both heuristically useful and computationally
;; advantageous.
(instance instance BinaryPredicate)
(domain instance 1 Entity)
(domain instance 2 SetOrClass)
(documentation instance EnglishLanguage "An object is an &%instance of a &%SetOrClass if
it is included in that &%SetOrClass. An individual may be an &%instance of many
classes, some of which may be subclasses of others. Thus, there is no
assumption in the meaning of &%instance about specificity or uniqueness.")
(documentation instance ChineseLanguage "如果一个物体属于一个&%SetOrClass, 这物体就那个 &%SetOrClass的一个&%instance。 一个个体可以是许多类别的一个&%instance, 其中有一些可以是其他类别 的子类别,所以对于&%instance并没有假设任何具体或独特的含义。")
(subrelation immediateInstance instance)
(instance immediateInstance AsymmetricRelation)
(instance immediateInstance IntransitiveRelation)
(instance immediateInstance TotalValuedRelation)
(documentation immediateInstance EnglishLanguage "An object is an &%immediateInstance of
a &%SetOrClass if it is an &%instance of the &%SetOrClass and it is not an
&%instance of a proper subclass of &%SetOrClass.")
(documentation immediateInstance ChineseLanguage "如果一个物体是一个&%SetOrClass的
&%instance,而且它并不是该&%SetOrClass真正的子类别的&%instance,那这个物体就是该&%SetOrClass的
&%immediateInstance。")
(=>
(immediateInstance ?ENTITY ?CLASS)
(not (exists (?SUBCLASS)
(and
(subclass ?SUBCLASS ?CLASS)
(not (equal ?SUBCLASS ?CLASS))
(instance ?ENTITY ?SUBCLASS)))))
(instance inverse BinaryPredicate)
(instance inverse IrreflexiveRelation)
(instance inverse IntransitiveRelation)
(instance inverse SymmetricRelation)
(instance inverse PartialValuedRelation)
(domain inverse 1 BinaryRelation)
(domain inverse 2 BinaryRelation)
(documentation inverse EnglishLanguage "The inverse of a &%BinaryRelation is a &%Relation
in which all the tuples of the original &%Relation are reversed. In other words, one
&%BinaryRelation is the inverse of another if they are equivalent when their arguments
are swapped.")
(documentation inverse ChineseLanguage "&%BinaryRelation的相反是一种&%Relation,而属于它
原本&%Relation所有元组的值都逆转。 换句话说,当一种二元关系和另一种二元关系的参数交换的结果是相等的
话,那这&%BinaryRelation就是另一种的相反。")
; causes a predicate variable expansion explosion
; (=>
; (and
; (inverse ?REL1 ?REL2)
; (instance ?REL1 Predicate)
; (instance ?REL2 Predicate))
; (forall (?INST1 ?INST2)
; (<=>
; (?REL1 ?INST1 ?INST2)
; (?REL2 ?INST2 ?INST1))))
(instance subclass BinaryPredicate)
(instance subclass PartialOrderingRelation)
(domain subclass 1 SetOrClass)
(domain subclass 2 SetOrClass)
(documentation subclass EnglishLanguage "(&%subclass ?CLASS1 ?CLASS2) means that ?CLASS1
is a &%subclass of ?CLASS2, i.e. every &%instance of ?CLASS1 is also an &%instance of
?CLASS2. A &%Class may have multiple superclasses and subclasses.")
(documentation subclass ChineseLanguage "(&%subclass ?CLASS1 ?CLASS2) 的意思是 ?CLASS1 是
?CLASS2 的&%subclass,也就是说, ?CLASS1 的每一个&%instance同时也是 ?CLASS2 的一个&%instance。
一个&%Class可以具有多个超类别和子类别。")
(=>
(subclass ?X ?Y)
(and
(instance ?X SetOrClass)
(instance ?Y SetOrClass)))
(=>
(and
(subclass ?X ?Y)
(instance ?Z ?X))
(instance ?Z ?Y))
(subrelation immediateSubclass subclass)
(instance immediateSubclass AsymmetricRelation)
(instance immediateSubclass IntransitiveRelation)
(documentation immediateSubclass EnglishLanguage "A &%SetOrClass ?CLASS1 is an
&%immediateSubclass of another &%SetOrClass ?CLASS2 just in case ?CLASS1 is a subclass of
?CLASS2 and there is no other subclass of ?CLASS2 such that ?CLASS1 is also a subclass of
it.")
(documentation immediateSubclass ChineseLanguage "一个&%SetOrClass的 ?CLASS1 是另一个
&%SetOrClass ?CLASS2 的&%immediateSubclass, 为免 ?CLASS1 成为 ?CLASS2 的子类别,而 ?CLASS2
再没有子类别,这样 ?CLASS1 也是 ?CLASS2 的子类别。")
(=>
(immediateSubclass ?CLASS1 ?CLASS2)
(not (exists (?CLASS3)
(and
(subclass ?CLASS3 ?CLASS2)
(subclass ?CLASS1 ?CLASS3)
(not (equal ?CLASS2 ?CLASS3))
(not (equal ?CLASS1 ?CLASS3))))))
(instance subrelation BinaryPredicate)
(instance subrelation PartialOrderingRelation)
(domain subrelation 1 Relation)
(domain subrelation 2 Relation)
(documentation subrelation EnglishLanguage "(&%subrelation ?REL1 ?REL2) means that
every tuple of ?REL1 is also a tuple of ?REL2. In other words, if
the &%Relation ?REL1 holds for some arguments arg_1, arg_2, ... arg_n,
then the &%Relation ?REL2 holds for the same arguments. A consequence
of this is that a &%Relation and its subrelations must have the same
&%valence.")
(documentation subrelation ChineseLanguage "(&%subrelation ?REL1 ?REL2)的意思是
?REL1的每个元组也是?REL2的元组。 也就是说,如果 ?REL1的一些参数 arg_1,arg_2,... arg_n
的&%Relation成立的话,那么?REL2的相同参数的 &%Relation也同样成立。 因此, 一个&%Relation和它
的&%subrelation必须拥有相同的&%valence。")
(=>
(and
(subrelation ?PRED1 ?PRED2)
(valence ?PRED1 ?NUMBER))
(valence ?PRED2 ?NUMBER))
(=>
(and
(subrelation ?PRED1 ?PRED2)
(domain ?PRED2 ?NUMBER ?CLASS1))
(domain ?PRED1 ?NUMBER ?CLASS1))
(=>
(and
(subrelation ?REL1 ?REL2)
(instance ?REL1 Predicate)
(instance ?REL2 Predicate)
(?REL1 @ROW))
(?REL2 @ROW))
(=>
(and
(subrelation ?PRED1 ?PRED2)
(instance ?PRED2 ?CLASS)
(subclass ?CLASS InheritableRelation))
(instance ?PRED1 ?CLASS))
(instance domain TernaryPredicate)
(domain domain 1 Relation)
(domain domain 2 PositiveInteger)
(domain domain 3 SetOrClass)
(documentation domain EnglishLanguage "Provides a computationally and heuristically
convenient mechanism for declaring the argument types of a given relation.
The formula (&%domain ?REL ?INT ?CLASS) means that the ?INT'th element of each
tuple in the relation ?REL must be an instance of ?CLASS. Specifying argument
types is very helpful in maintaining ontologies. Representation systems can
use these specifications to classify terms and check integrity constraints.
If the restriction on the argument type of a &%Relation is not captured by a
&%SetOrClass already defined in the ontology, one can specify a &%SetOrClass
compositionally with the functions &%UnionFn, &%IntersectionFn, etc.")
(documentation domain ChineseLanguage "为声明某种特定关系参数的类型, 提供一个便利计算机和应用启发
式运算的机制。公式(&%domain?REL?INT?CLASS)的意思是在?REL关系中,每个元组的第?INT个元素,必须是
?CLASS种的一个实例。 指定参数类型对维护知识本体甚有裨益。 表示知识的系统可以使用这些规范来把术语分类, 并
检查系统的完整性约束有否受到破坏。如果出现某个%Relation参数类型的限制,还没有在知识本体内现有
&%SetOrClass定义所描述时,可以使用&%UnionFn和&%IntersectionFn等这些功能,来逐一指定该
&%SetOrClass的限制。
")
(=>
(and
(domain ?REL ?NUMBER ?CLASS1)
(domain ?REL ?NUMBER ?CLASS2))
(or
(subclass ?CLASS1 ?CLASS2)
(subclass ?CLASS2 ?CLASS1)))
(instance domainSubclass TernaryPredicate)
(domain domainSubclass 1 Relation)
(domain domainSubclass 2 PositiveInteger)
(domain domainSubclass 3 SetOrClass)
(documentation domainSubclass EnglishLanguage "A &%Predicate that is used to specify
argument type restrictions of &%Predicates. The formula (&%domainSubclass
?REL ?INT ?CLASS) means that the ?INT'th element of each tuple in the
relation ?REL must be a subclass of ?CLASS.")
(documentation domainSubclass ChineseLanguage "这个 &%Predicate 是用来指定 &%Predicates 参数
类型的限制。 公式(&%domainSubclass ?REL ?INT ?CLASS) 的意思是在?REL关系中,每个元组的第?INT个元素,
必须是?CLASS种的一个子类别。")
(=>
(and
(subrelation ?REL1 ?REL2)
(domainSubclass ?REL2 ?NUMBER ?CLASS1))
(domainSubclass ?REL1 ?NUMBER ?CLASS1))
(=>
(and
(domainSubclass ?REL ?NUMBER ?CLASS1)
(domainSubclass ?REL ?NUMBER ?CLASS2))
(or
(subclass ?CLASS1 ?CLASS2)
(subclass ?CLASS2 ?CLASS1)))
(instance equal BinaryPredicate)
(instance equal EquivalenceRelation)
(instance equal RelationExtendedToQuantities)
(domain equal 1 Entity)
(domain equal 2 Entity)
(documentation equal EnglishLanguage "(equal ?ENTITY1 ?ENTITY2) is true just in case
?ENTITY1 is identical with ?ENTITY2.")
(documentation equal ChineseLanguage "假如 ?ENTITY1 等于 ?ENTITY2的话,那么
(equal ?ENTITY1 ?ENTITY2) 就是真的。")
(=>
(equal ?THING1 ?THING2)
(forall (?ATTR)
(<=>
(property ?THING1 ?ATTR)
(property ?THING2 ?ATTR))))
(=>
(equal ?ATTR1 ?ATTR2)
(forall (?THING)
(<=>
(property ?THING ?ATTR1)
(property ?THING ?ATTR2))))
(=>
(equal ?THING1 ?THING2)
(forall (?CLASS)
(<=>
(instance ?THING1 ?CLASS)
(instance ?THING2 ?CLASS))))
(=>
(equal ?CLASS1 ?CLASS2)
(forall (?THING)
(<=>
(instance ?THING ?CLASS1)
(instance ?THING ?CLASS2))))
;;(=>
;; (equal ?REL1 ?REL2)
;; (forall (@ROW)
;; (<=>
;; (?REL1 @ROW)
;; (?REL2 @ROW))))
(=>
(equal ?LIST1 ?LIST2)
(=>
(and
(equal ?LIST1 (ListFn @ROW1))
(equal ?LIST2 (ListFn @ROW2)))
(forall (?NUMBER)
(equal (ListOrderFn (ListFn @ROW1) ?NUMBER) (ListOrderFn (ListFn @ROW2) ?NUMBER)))))
(instance range BinaryPredicate)
(instance range AsymmetricRelation)
(domain range 1 Function)
(domain range 2 SetOrClass)
(documentation range EnglishLanguage "Gives the range of a function. In other words,
(&%range ?FUNCTION ?CLASS) means that all of the values assigned by
?FUNCTION are &%instances of ?CLASS.")
(documentation range ChineseLanguage "它为函数提供一个范围。就是说,(&%range ?FUNCTION ?CLASS)
的意思是,所有由 ?FUNCTION 所指定的值,都是这个 ?CLASS 的 &%instance。")
(=>
(and
(range ?FUNCTION ?CLASS)
(equal (AssignmentFn ?FUNCTION @ROW) ?VALUE))
(instance ?VALUE ?CLASS))
(=>
(and
(subrelation ?REL1 ?REL2)
(range ?REL2 ?CLASS1))
(range ?REL1 ?CLASS1))
(=>
(and
(range ?REL ?CLASS1)
(range ?REL ?CLASS2))
(or
(subclass ?CLASS1 ?CLASS2)
(subclass ?CLASS2 ?CLASS1)))
(instance rangeSubclass BinaryPredicate)
(instance rangeSubclass AsymmetricRelation)
(domain rangeSubclass 1 Function)
(domainSubclass rangeSubclass 2 SetOrClass)
(documentation rangeSubclass EnglishLanguage "(&%rangeSubclass ?FUNCTION ?CLASS) means
that all of the values assigned by ?FUNCTION are &%subclasses of ?CLASS.")
(documentation rangeSubclass ChineseLanguage "(&%rangeSubclass ?FUNCTION ?CLASS) 的意思是
所有由 ?FUNCTION 所指定的值,都是这个 ?CLASS 的 &%subclass。")
(=>
(and
(rangeSubclass ?FUNCTION ?CLASS)
(equal (AssignmentFn ?FUNCTION @ROW) ?VALUE))
(subclass ?VALUE ?CLASS))
(=>
(and
(subrelation ?REL1 ?REL2)
(rangeSubclass ?REL2 ?CLASS1))
(rangeSubclass ?REL1 ?CLASS1))
(=>
(and
(rangeSubclass ?REL ?CLASS1)
(rangeSubclass ?REL ?CLASS2))
(or
(subclass ?CLASS1 ?CLASS2)
(subclass ?CLASS2 ?CLASS1)))
(instance valence BinaryPredicate)
(instance valence AsymmetricRelation)
(instance valence SingleValuedRelation)
(domain valence 1 Relation)
(domain valence 2 PositiveInteger)
(documentation valence EnglishLanguage "Specifies the number of arguments that a
relation can take. If a relation does not have a fixed number of
arguments, it does not have a valence and it is an instance of
&%VariableArityRelation.")
(documentation valence ChineseLanguage "指定一个关系可接纳参数的数目。 如果一个关系没有设定参数
数目,那么它就没有配价,它也就是 &%VariableArityRelation 的一个实例。")
(instance documentation TernaryPredicate)
(domain documentation 1 Entity)
(domain documentation 2 HumanLanguage)
(domain documentation 3 SymbolicString)
(documentation documentation EnglishLanguage "A relation between objects
in the domain of discourse and strings of natural language text stated in
a particular &%HumanLanguage. The domain of &%documentation is not
constants (names), but the objects themselves. This means that one does
not quote the names when associating them with their documentation.")
(documentation documentation ChineseLanguage "在话语领域和自然语言的字符串,以某种
&%HumanLanguage 来陈述的物件之间一种关系。 &%documentation 领域不是常量 (名字),而是物体的本身。
也就是说在相关文档提到该物体时,是不会引用名字的。")
(instance format TernaryPredicate)
(domain format 1 Language)
(domain format 2 Entity)
(domain format 3 SymbolicString)
(documentation format EnglishLanguage "A relation that specifies how
to present an expression in a natural language format.")
(documentation format ChineseLanguage "这是一种关系,用于指定如何以自然语言格式来介绍表达式。")
(instance termFormat TernaryPredicate)
(domain termFormat 1 Language)
(domain termFormat 2 Entity)
(domain termFormat 3 SymbolicString)
(documentation termFormat EnglishLanguage "A relation that specifies how
to present a term in a natural language format.")
(documentation termFormat ChineseLanguage "这是一种关系,用于指定如何以自然语言格式来介绍一个术语。")
(instance disjoint BinaryPredicate)
(instance disjoint SymmetricRelation)
(domain disjoint 1 SetOrClass)
(domain disjoint 2 SetOrClass)
(documentation disjoint EnglishLanguage "&%Classes are &%disjoint only if they share no
instances, i.e. just in case the result of applying &%IntersectionFn to
them is empty.")
(documentation disjoint ChineseLanguage "如果&%Class 和 &%Class之间没有共同案例的话, 那么它们
就是 &%disjoint,也就是以防万一应用 &%IntersectionFn 的时候出现空的的结果。")
(=>
(disjoint ?CLASS1 ?CLASS2)
(forall (?INST)
(not
(and
(instance ?INST ?CLASS1)
(instance ?INST ?CLASS2)))))
(instance disjointRelation BinaryPredicate)
(instance disjointRelation IrreflexiveRelation)
(instance disjointRelation PartialValuedRelation)
(domain disjointRelation 1 Relation)
(domain disjointRelation 2 Relation)
(relatedInternalConcept disjointRelation disjoint)
(documentation disjointRelation EnglishLanguage "This predicate relates two &%Relations.
(&%disjointRelation ?REL1 ?REL2) means that the two relations have no tuples in
common.")
(documentation disjointRelation ChineseLanguage "这个术语把两种 &%Relation 连接。
(&%disjointRelation ?REL1 ?REL2) 的意思是指这两种关系没有共同的元组。")
(=>
(and
(domain ?REL1 ?NUMBER ?CLASS1)
(domain ?REL2 ?NUMBER ?CLASS2)
(disjoint ?CLASS1 ?CLASS2))
(disjointRelation ?REL1 ?REL2))
(=>
(and
(domainSubclass ?REL1 ?NUMBER ?CLASS1)
(domainSubclass ?REL2 ?NUMBER ?CLASS2)
(disjoint ?CLASS1 ?CLASS2))
(disjointRelation ?REL1 ?REL2))
(=>
(and
(range ?REL1 ?CLASS1)
(range ?REL2 ?CLASS2)
(disjoint ?CLASS1 ?CLASS2))
(disjointRelation ?REL1 ?REL2))
(=>
(and
(rangeSubclass ?REL1 ?CLASS1)
(rangeSubclass ?REL2 ?CLASS2)
(disjoint ?CLASS1 ?CLASS2))
(disjointRelation ?REL1 ?REL2))
(=>
(and
(instance ?REL1 Predicate)
(instance ?REL2 Predicate)
(disjointRelation ?REL1 ?REL2)
(not (equal ?REL1 ?REL2))
(?REL1 @ROW2))
(not (?REL2 @ROW2)))
(instance contraryAttribute Predicate)
(instance contraryAttribute VariableArityRelation)
(domain contraryAttribute 1 Attribute)
(documentation contraryAttribute EnglishLanguage "A &%contraryAttribute is a set of &%Attributes
such that something can not simultaneously have more than one of these &%Attributes.
For example, (&%contraryAttribute &%Pliable &%Rigid) means that nothing can be both
&%Pliable and &%Rigid.")
(documentation contraryAttribute ChineseLanguage "&%contraryAttribute 是一组 &%Attribute
,而某一件事物不能同时拥有超过一种这个组里的 &%Attributes。 举例说:
(&%contraryAttribute &%Pliable &%Rigid) 指的是没有一件东西是既 &%Pliable 又 &%Rigid 的。")
(=>
(contraryAttribute @ROW)
(=>
(inList ?ELEMENT (ListFn @ROW))
(instance ?ELEMENT Attribute)))
(=>
(and
(contraryAttribute @ROW1)
(identicalListItems (ListFn @ROW1) (ListFn @ROW2)))
(contraryAttribute @ROW2))
(=>
(contraryAttribute @ROW)
(forall (?ATTR1 ?ATTR2)
(=>
(and
(equal ?ATTR1 (ListOrderFn (ListFn @ROW) ?NUMBER1))
(equal ?ATTR2 (ListOrderFn (ListFn @ROW) ?NUMBER2))
(not (equal ?NUMBER1 ?NUMBER2)))
(=>
(property ?OBJ ?ATTR1)
(not (property ?OBJ ?ATTR2))))))
(instance exhaustiveAttribute Predicate)
(instance exhaustiveAttribute VariableArityRelation)
(domainSubclass exhaustiveAttribute 1 Attribute)
(domain exhaustiveAttribute 2 Attribute)
(documentation exhaustiveAttribute EnglishLanguage "This predicate relates a &%Class to a
set of &%Attributes, and it means that the elements of this set exhaust the
instances of the &%Class. For example, (&%exhaustiveAttribute &%PhysicalState
&%Solid &%Fluid &%Liquid &%Gas &%Plasma) means that there are only five instances of
the class &%PhysicalState, viz. &%Solid, &%Fluid, &%Liquid, &%Gas and &%Plasma.")
(documentation exhaustiveAttribute ChineseLanguage "这个术语把一个 &%Class 联系到一组
&%Attribute, 就是说这个组的单元已经是这个 &%Class 所有的实例。举例说: (&%exhaustiveAttribute
&%PhysicalState &%Solid &%Fluid &%Liquid &%Gas &%Plasma) 的意思是 &%PhysicalState 这个类别就
只有 &%Solid,&%Fluid, &%Liquid, &%Gas 和 &%Plasma 这五个实例了。")
(=>
(exhaustiveAttribute ?CLASS @ROW)
(=>
(inList ?ATTR (ListFn @ROW))
(instance ?ATTR Attribute)))
(=>
(exhaustiveAttribute ?CLASS @ROW)
(forall (?ATTR1)
(=>
(instance ?ATTR1 ?CLASS)
(exists (?ATTR2)
(and
(inList ?ATTR2 (ListFn @ROW))
(equal ?ATTR1 ?ATTR2))))))
(=>
(exhaustiveAttribute ?ATTRCLASS @ROW)
(not
(exists (?EL)
(and
(instance ?EL ?ATTRCLASS)
(not
(exists (?ATTR ?NUMBER)
(and
(equal ?EL ?ATTR)
(equal ?ATTR
(ListOrderFn
(ListFn @ROW) ?NUMBER)))))))))
(instance exhaustiveDecomposition Predicate)
(instance exhaustiveDecomposition VariableArityRelation)
(domain exhaustiveDecomposition 1 Class)
(domain exhaustiveDecomposition 2 Class)
(relatedInternalConcept exhaustiveDecomposition partition)
(documentation exhaustiveDecomposition EnglishLanguage "An &%exhaustiveDecomposition of a
&%Class C is a set of subclasses of C such that every instance of C is an
instance of one of the subclasses in the set. Note: this does not necessarily
mean that the elements of the set are disjoint (see &%partition - a &%partition
is a disjoint exhaustive decomposition).")
(documentation exhaustiveDecomposition ChineseLanguage "C &%Class 的
&%exhaustiveDecomposition 是C的一组子类别, 而C的每一个实例就是这个组内其中一个子类别的一个实例。按:
这并不一定是意会着这个组的单元都不相交 (可参考 &%partition - 一个 &%partition 是一个已列举尽
不相交的掏空成分。 ")
(=>
(exhaustiveDecomposition @ROW)
(=>
(inList ?ELEMENT (ListFn @ROW))
(instance ?ELEMENT Class)))
(instance disjointDecomposition Predicate)
(instance disjointDecomposition VariableArityRelation)
(domain disjointDecomposition 1 Class)
(domain disjointDecomposition 2 Class)
(relatedInternalConcept disjointDecomposition exhaustiveDecomposition)
(relatedInternalConcept disjointDecomposition disjoint)
(documentation disjointDecomposition EnglishLanguage "A &%disjointDecomposition of a
&%Class C is a set of subclasses of C that are mutually &%disjoint.")
(documentation disjointDecomposition ChineseLanguage "C &%Class 的 &%disjointDecomposition
是C的一组相互 &%disjoint 的子类别。")
(=>
(disjointDecomposition @ROW)
(=>
(inList ?ELEMENT (ListFn @ROW))
(instance ?ELEMENT Class)))
(instance partition Predicate)
(instance partition VariableArityRelation)
(domain partition 1 Class)
(domain partition 2 Class)
(documentation partition EnglishLanguage "A &%partition of a &%Class C
is a set of mutually &%disjoint classes (a subclass partition) which
covers C. Every instance of C is an instance of exactly one of the
subclasses in the partition.")
(documentation partition ChineseLanguage "C &%Class 的 &%partition 是一组包括C,而互不
&%disjoint 的类别 (一个子类别的分区)。C的每一个实例正正是这个分区子类别的一个实例。")
(<=>
(partition @ROW)
(and
(exhaustiveDecomposition @ROW)
(disjointDecomposition @ROW)))
(instance relatedInternalConcept BinaryPredicate)
(instance relatedInternalConcept EquivalenceRelation)
(domain relatedInternalConcept 1 Entity)
(domain relatedInternalConcept 2 Entity)
(documentation relatedInternalConcept EnglishLanguage "Means that the two arguments are
related concepts within the SUMO, i.e. there is a significant similarity
of meaning between them. To indicate a meaning relation between a SUMO
concept and a concept from another source, use the Predicate
&%relatedExternalConcept.")
(documentation relatedInternalConcept ChineseLanguage "这个意思是两个变量在SUMO是相关的概念,就是
说它们之间的含义极为相似。可以用 &%relatedExternalConcept 术语,来要表示一个SUMO概念和另一个出处的概念
在含义上的关系。")
(instance relatedExternalConcept TernaryPredicate)
(domain relatedExternalConcept 1 SymbolicString)
(domain relatedExternalConcept 2 Entity)
(domain relatedExternalConcept 3 Language)
(relatedInternalConcept relatedExternalConcept relatedInternalConcept)
(documentation relatedExternalConcept EnglishLanguage "Used to signify a three-place
relation between a concept in an external knowledge source, a concept
in the SUMO, and the name of the other knowledge source.")
(documentation relatedExternalConcept ChineseLanguage "这是用来表示一个概念联系的三重关系:概念的
外部知识来源、 SUMO概念和它外部知识来源的名字。")
(subrelation synonymousExternalConcept relatedExternalConcept)
(disjointRelation synonymousExternalConcept subsumedExternalConcept)
(disjointRelation synonymousExternalConcept subsumingExternalConcept)
(disjointRelation subsumedExternalConcept subsumingExternalConcept)
(documentation synonymousExternalConcept EnglishLanguage "(&%synonymousExternalConcept
?STRING ?THING ?LANGUAGE) means that the SUMO concept ?THING has the
same meaning as ?STRING in ?LANGUAGE.")
(documentation synonymousExternalConcept ChineseLanguage "(&%synonymousExternalConcept
?STRING ?THING ?LANGUAGE) 的意思是SUMO概念 ?THING 和概念 ?STRING 在语言 ?LANGUAGE 的含义是相同
的。")
(subrelation subsumingExternalConcept relatedExternalConcept)
(documentation subsumingExternalConcept EnglishLanguage "(&%subsumingExternalConcept
?STRING ?THING ?LANGUAGE) means that the SUMO concept ?THING subsumes
the meaning of ?STRING in ?LANGUAGE, i.e. the concept ?THING is broader
in meaning than ?STRING.")
(documentation subsumingExternalConcept ChineseLanguage "(&%subsumingExternalConcept
?STRING ?THING ?LANGUAGE) 的意思是SUMO概念 ?THING 包含了概念 ?STRING 在语言 ?LANGUAGE 的含义,
也就是说概念 ?THING 的含义比 ?STRING 要广。")
(subrelation subsumedExternalConcept relatedExternalConcept)
(documentation subsumedExternalConcept EnglishLanguage "(&%subsumedExternalConcept
?STRING ?THING ?LANGUAGE) means that the SUMO concept ?THING is subsumed
by the meaning of ?STRING in ?LANGUAGE, i.e. the concept ?THING is narrower
in meaning than ?STRING.")
(documentation subsumedExternalConcept ChineseLanguage "(&%subsumedExternalConcept
?STRING ?THING ?LANGUAGE) 的意思是SUMO概念 ?THING 被纳入概念 ?STRING 在语言 ?LANGUAGE 的含义,
也就是说概念 ?THING 的含义比 ?STRING 要窄。")
(instance externalImage BinaryPredicate)
(documentation externalImage EnglishLanguage "A link between an Entity and a
URL that represents or exemplifies the term in some way.")
(documentation externalImage ChineseLanguage "联系一个实体和在某方面代表或举例证明这个概念的网址。")
(domain externalImage 1 Entity)
(domain externalImage 2 SymbolicString)
(instance subAttribute BinaryPredicate)
(instance subAttribute PartialOrderingRelation)
(domain subAttribute 1 Attribute)
(domain subAttribute 2 Attribute)
(disjointRelation subAttribute successorAttribute)
(documentation subAttribute EnglishLanguage "Means that the second argument can be
ascribed to everything which has the first argument ascribed to it.")
(documentation subAttribute ChineseLanguage "这意思是第二个参数的属性可以归因于所有第一个参数
所归因的属性。")
(=>
(subAttribute ?ATTR1 ?ATTR2)
(forall (?OBJ)
(=>
(property ?OBJ ?ATTR1)
(property ?OBJ ?ATTR2))))
(=>
(and
(subAttribute ?ATTR1 ?ATTR2)
(instance ?ATTR2 ?CLASS))
(instance ?ATTR1 ?CLASS))
(instance successorAttribute BinaryPredicate)
(instance successorAttribute AsymmetricRelation)
(domain successorAttribute 1 Attribute)
(domain successorAttribute 2 Attribute)
(documentation successorAttribute EnglishLanguage "(&%successorAttribute ?ATTR1 ?ATTR2)
means that ?ATTR2 is the &%Attribute that comes immediately after ?ATTR1
on the scale that they share.")
(documentation successorAttribute ChineseLanguage "(&%successorAttribute ?ATTR1 ?ATTR2)
的意思是在它们共同有的尺度上 &%Attribute ?ATTR2 是紧接着 ?ATTR1。")
(=>
(and
(successorAttribute ?ATTR1 ?ATTR2)
(holdsDuring ?TIME1 (property ?ENTITY ?ATTR2)))
(exists (?TIME2)
(and
(temporalPart ?TIME2 (PastFn ?TIME1))
(holdsDuring ?TIME2 (property ?ENTITY ?ATTR1)))))
(instance successorAttributeClosure BinaryPredicate)
(instance successorAttributeClosure TransitiveRelation)
(instance successorAttributeClosure IrreflexiveRelation)
(instance successorAttributeClosure PartialValuedRelation)
(domain successorAttributeClosure 1 Attribute)
(domain successorAttributeClosure 2 Attribute)
(relatedInternalConcept successorAttributeClosure successorAttribute)
(documentation successorAttributeClosure EnglishLanguage "The transitive closure of
&%successorAttribute. (&%successorAttributeClosure ?ATTR1 ?ATTR2) means
that there is a chain of &%successorAttribute assertions connecting
?ATTR1 and ?ATTR2.")
(documentation successorAttributeClosure ChineseLanguage "&%successorAttribute 的
传递闭包;(&%successorAttributeClosure ?ATTR1 ?ATTR2) 的意思是 &%successorAttribute 有一连串
联系着 ?ATTR1 和 ?ATTR2 的断言。 ")
(=>
(successorAttribute ?ATTR1 ?ATTR2)
(successorAttributeClosure ?ATTR1 ?ATTR2))
(instance greaterThanByQuality TernaryPredicate)
(documentation greaterThanByQuality EnglishLanguage "(greaterThanByQuality
?ENTITY1 ?ENTITY2 ?ATT) means that ?ENTITY1 has more of the given
quality ?ATT than ?ENTITY2")
(documentation greaterThanByQuality ChineseLanguage "(greaterThanByQuality
?ENTITY1 ?ENTITY2 ?ATT) 的意思是 ?ENTITY1 既定的 ?ATT 量比 ?ENTITY2 的多。")
(domain greaterThanByQuality 1 Entity)
(domain greaterThanByQuality 2 Entity)
(domain greaterThanByQuality 3 Attribute)
(=>
(and
(greaterThanByQuality ?E1 ?E2 ?ATT)
(greaterThanByQuality ?E2 ?E3 ?ATT))
(greaterThanByQuality ?E1 ?E3 ?ATT))
(=>
(greaterThanByQuality ?E1 ?E2 ?ATT)
(not
(greaterThanByQuality ?E2 ?E1 ?ATT)))
(=>
(greaterThanByQuality ?E1 ?E2 ?ATT)
(not
(equal ?E2 ?E1)))
(instance entails BinaryPredicate)
(domain entails 1 Formula)
(domain entails 2 Formula)
(documentation entails EnglishLanguage "The operator of logical entailment. (&%entails
?FORMULA1 ?FORMULA2) means that ?FORMULA2 can be derived from ?FORMULA1
by means of the proof theory of SUO-KIF.")
(documentation entails ChineseLanguage "这是逻辑蕴涵的运算符。(&%entails ?FORMULA1 ?FORMULA2)
的意思是 ?FORMULA2 可以通过SUO-KIF的证明理论从 ?FORMULA1 得出来。")
;; The following axiom is commented out, because it is rejected by the
;; inference engine parser.
;;(=>
;; (entails ?FORMULA1 ?FORMULA2)
;; (=> ?FORMULA1 ?FORMULA2))
(instance AssignmentFn Function)
(instance AssignmentFn VariableArityRelation)
(domain AssignmentFn 1 Function)
(domain AssignmentFn 2 Entity)
(range AssignmentFn Entity)
(documentation AssignmentFn EnglishLanguage "If F is a &%Function with a value for the
objects denoted by N1,..., NK, then (&%AssignmentFn F N1 ... NK) is the
value of applying F to the objects denoted by N1,..., NK. Otherwise,
the value is undefined.")
(documentation AssignmentFn ChineseLanguage "如果F是一个 &%Function,它所代表物体的值以
N1,...,NK表示, 那么 (&%AssignmentFn F N1 ... NK) 就是应用F到这些物体以N1,..., NK所代表的值。
在其他情况下,这个值是没有被下定义的。")
(instance PowerSetFn UnaryFunction)
(instance PowerSetFn TotalValuedRelation)
(domain PowerSetFn 1 SetOrClass)
(rangeSubclass PowerSetFn SetOrClass)
(documentation PowerSetFn EnglishLanguage "(&%PowerSetFn ?CLASS) maps the &%SetOrClass
?CLASS to the &%SetOrClass of all &%subclasses of ?CLASS.")
(documentation PowerSetFn ChineseLanguage "(&%PowerSetFn ?CLASS) 把&%SetOrClass ?CLASS
的所有&%subclass,都纳入&%SetOrClass的?CLASS上。")
;; END FILE
;; BEGIN FILE
;;;;;;;;;;;;;;;;;;;;;;;
;; BASE ONTOLOGY ;;
;;;;;;;;;;;;;;;;;;;;;;;
;; INCLUDES 'STRUCTURAL ONTOLOGY'
;; The following hierarchy incorporates content from Sowa, Russell & Norvig,
;; and the top-level ontology from ITBM-CNR.
(partition Entity Physical Abstract)
(documentation Entity EnglishLanguage "The universal class of individuals. This is the root
node of the ontology.")
;; Informally, it is true that "Everything is Entity";
;; We comment out this axiom to avoid logical paradoxes.
;;(forall (?THING)
;; (instance ?THING Entity))
(exists (?THING)
(instance ?THING Entity))
(<=>
(instance ?CLASS Class)
(subclass ?CLASS Entity))
(subclass Physical Entity)
(partition Physical Object Process)
(documentation Physical EnglishLanguage "An entity that has a location in space-time.
Note that locations are themselves understood to have a location in
space-time.")
(documentation Physical ChineseLanguage "存在时空中某位置的个体。注:位置本身应理解为,存在于某个时空
的位置。")
(=>
(instance ?PHYS Physical)
(exists (?LOC ?TIME)
(and
(located ?PHYS ?LOC)
(time ?PHYS ?TIME))))
(subclass Object Physical)
(documentation Object EnglishLanguage "Corresponds roughly to the class of ordinary
objects. Examples include normal physical objects, geographical regions,
and locations of &%Processes, the complement of &%Objects in the &%Physical
class. In a 4D ontology, an &%Object is something whose spatiotemporal
extent is thought of as dividing into spatial parts roughly parallel to the
time-axis.")
(documentation Object ChineseLanguage "这可粗略地对应为一般物体。例子包括
正常物理对象、地理区域和 &%Process 的位置,在 &%Physical 类别 &%Object 的补充。
在四维本体论上, &%Object 的时空范畴可大致划分为与时间轴平行的空间间隔。")
(subclass SelfConnectedObject Object)
(documentation SelfConnectedObject EnglishLanguage "A &%SelfConnectedObject is any
&%Object that does not consist of two or more disconnected parts.")
(documentation SelfConnectedObject ChineseLanguage " &%SelfConnectedObject
是任何并非由两个或以上不相连部分所组成的 &%Object。")
(subclass OrganicThing SelfConnectedObject)
(documentation OrganicThing EnglishLanguage "A &%SelfConnectedObject that is
produced by a non-intentional process from an &%Organism. Note that this
refers only to the primary cause. That is, a &%PlantAgriculturalProduct
is firstly produced by a &%Plant, and only secondarily by a &%Human that is
tending the plant.")
(documentation OrganicThing ChineseLanguage "这是一个从 &%Organism 通过非刻意过程所产生的
&%SelfConnectedObject。注:这里指只是主要原因,就是说 &%PlantAgriculturalProduct 首先从 &%Plant
生长出来,次要才由 &%Human 产生,约就是耕种植物。")
(instance FrontFn SpatialRelation)
(instance FrontFn PartialValuedRelation)
(instance FrontFn UnaryFunction)
(instance FrontFn AsymmetricRelation)
(instance FrontFn IrreflexiveRelation)
(domain FrontFn 1 SelfConnectedObject)
(range FrontFn SelfConnectedObject)
(documentation FrontFn EnglishLanguage "A &%Function that maps an &%Object to the side
that generally receives the most attention or that typically faces the
direction in which the &%Object moves. Note that this is a partial
function, since some &%Objects do not have sides, e.g. apples and
spheres. Note too that the &%range of this &%Function is indefinite in
much the way that &%ImmediateFutureFn and &%ImmediatePastFn are indefinite.
Although this indefiniteness is undesirable from a theoretical standpoint,
it does not have significant practical implications, since there is
widespread intersubjective agreement about the most common cases.")
(documentation FrontFn ChineseLanguage "这是一个&%Function ,它能把 &%Object 转到一般能够得到
最大程度关注或者说通常是面对该 &%Object 移动的方向的那一面。注:这是一个部分函数, 因为有一些 &%Object
是没有侧面的,例如苹果和球体。 也要注意这个 &%Function 的 &%range 是无限的,就像 &%ImmediateFutureFn
和 &%ImmediatePastFn 一样也是无限的。从理论的观点来说,虽然这个无限性并不理想,但它没有太大的实际影响,
因为在共同意思间对于最常见的情况已经达成广泛的共识。")
(=>
(instance ?OBJ SelfConnectedObject)
(side (FrontFn ?OBJ) ?OBJ))
(instance BackFn SpatialRelation)
(instance BackFn PartialValuedRelation)
(instance BackFn UnaryFunction)
(instance BackFn AsymmetricRelation)
(instance BackFn IrreflexiveRelation)
(domain BackFn 1 SelfConnectedObject)
(range BackFn SelfConnectedObject)
(documentation BackFn EnglishLanguage "A &%Function that maps an &%Object to the side
that is opposite the &%FrontFn of the &%Object. Note that this is a
partial function, since some &%Objects do not have sides, e.g. apples
and spheres. Note too that the &%range of this &%Function is indefinite in
much the way that &%ImmediateFutureFn and &%ImmediatePastFn are indefinite.
Although this indefiniteness is undesirable from a theoretical standpoint,
it does not have significant practical implications, since there is
widespread intersubjective agreement about the most common cases.")
(documentation BackFn ChineseLanguage "这个 &%Function 把 &%Object 转到 与 这个 &%Object 的
&%FrontFn 相反的那面。注:这是一个部分函数, 因为有一些 &%Object 是没有侧面的,例如苹果和球体。 也要注意
这个 &%Function 的 &%range 是无限的,就像 &%ImmediateFutureFn 和 &%ImmediatePastFn
一样也是无限的。从理论的观点来说,虽然这个无限性并不理想,但它没有太大的实际影响,因为在共同意思间对于最常见
的情况已经达成广泛的共识。")
(=>
(instance ?OBJ SelfConnectedObject)
(side (BackFn ?OBJ) ?OBJ))
(instance part SpatialRelation)
(instance part PartialOrderingRelation)
(domain part 1 Object)
(domain part 2 Object)
(documentation part EnglishLanguage "The basic mereological relation. All other
mereological relations are defined in terms of this one.
(&%part ?PART ?WHOLE) simply means that the &%Object ?PART is part
of the &%Object ?WHOLE. Note that, since &%part is a
&%ReflexiveRelation, every &%Object is a part of itself.")
(documentation part ChineseLanguage "这是基本的逻辑分体关系。其他所有的逻辑分体关系都是根据它来下
定义的。 (&%part ?PART ?WHOLE) 的意思就是 &%Object ?PART 是 &%Object ?WHOLE 的一部分。 要注意
因为 &%part 是一个 &%ReflexiveRelation, 所以每个 &%Object 都是它自己本身的一部分。")
(instance properPart AsymmetricRelation)
(instance properPart TransitiveRelation)
(subrelation properPart part)
(documentation properPart EnglishLanguage "(&%properPart ?OBJ1 ?OBJ2) means that
?OBJ1 is a part of ?OBJ2 other than ?OBJ2 itself. This is a
&%TransitiveRelation and &%AsymmetricRelation (hence an
&%IrreflexiveRelation).")
(documentation properPart ChineseLanguage "(&%properPart ?OBJ1 ?OBJ2) 的意思是除了 ?OBJ2 本身
?OBJ1 是 ?OBJ2 的一部分。 这是一个 &%TransitiveRelation 和 &%AsymmetricRelation (因此也是一个
&%IrreflexiveRelation)。")
(<=>
(properPart ?OBJ1 ?OBJ2)
(and
(part ?OBJ1 ?OBJ2)
(not
(part ?OBJ2 ?OBJ1))))
(subrelation piece part)
(domain piece 1 Substance)
(domain piece 2 Substance)
(documentation piece EnglishLanguage "A specialized common sense notion of part for
arbitrary parts of &%Substances. Quasi-synonyms are: chunk, hunk, bit,
etc. Compare &%component, another subrelation of &%part.")
(documentation piece ChineseLanguage "这是对 &%Substance 某些部分的一个专业常识概念。类似的同意词
有:块、大块、小块等。可参考比较 &%part 的另外一个子关系 &%component 。")
(=>
(piece ?SUBSTANCE1 ?SUBSTANCE2)
(forall (?CLASS)
(=>
(instance ?SUBSTANCE1 ?CLASS)
(instance ?SUBSTANCE2 ?CLASS))))
(subrelation component part)
(domain component 1 CorpuscularObject)
(domain component 2 CorpuscularObject)
(documentation component EnglishLanguage "A specialized common sense notion of part
for heterogeneous parts of complexes. (&%component ?COMPONENT ?WHOLE)
means that ?COMPONENT is a component of ?WHOLE. Examples of component
include the doors and walls of a house, the states or provinces of a
country, or the limbs and organs of an animal. Compare &%piece, which
is also a subrelation of &%part.")
(documentation component ChineseLanguage "这是对复合物各个不同部分的一个专业常识概念。
(&%component ?COMPONENT ?WHOLE) 的意思是 ?COMPONENT 是 ?WHOLE 的组件。 组件的例子包括房子的门
和墙壁、国家的州或省,与动物的四肢和器官。 可参考比较 &%part 的另外一个子关系 &%piece。")
(instance material BinaryPredicate)
(domainSubclass material 1 Substance)
(domain material 2 CorpuscularObject)
(documentation material EnglishLanguage "(&%material ?SUBSTANCE ?OBJECT) means that
?OBJECT is structurally made up in part of ?SUBSTANCE. This relation
encompasses the concepts of 'composed of', 'made of', and 'formed of'.
For example, plastic is a &%material of my computer monitor. Compare
&%part and its subrelations, viz &%component and &%piece.")
(documentation material ChineseLanguage "(&%material ?SUBSTANCE ?OBJECT) 的意思是
?OBJECT 是由 ?SUBSTANCE 作为部件所构成的。 这个关系包括 「组成」、「做成」和「形成」等概念。例子有
塑料是我电算计屏幕的一种 &%material。可参考比较 &%part 和它的子关系,即 &%component 和 &%piece。")
(subrelation contains partlyLocated)
(instance contains SpatialRelation)
(instance contains AsymmetricRelation)
(instance contains PartialValuedRelation)
(disjointRelation contains part)
(domain contains 1 SelfConnectedObject)
(domain contains 2 Object)
(documentation contains EnglishLanguage "The relation of spatial containment for two
separable objects. When the two objects are not separable (e.g. an
automobile and one of its seats), the relation of &%part should be used.
(&%contains ?OBJ1 ?OBJ2) means that the &%SelfConnectedObject ?OBJ1 has
a space (i.e. a &%Hole) which is at least partially filled by ?OBJ2.")
(documentation contains ChineseLanguage "这是两个可分离物体的空间容量关系。 用于不可分离的物体(如汽
车和它的座位)时,应该用 &%part 这关系。(&%contains ?OBJ1 ?OBJ2) 的意思是 &%SelfConnectedObject
?OBJ1 有一个空间(即一个 &%Hole),而它 至少由 ?OBJ2 填满了一部分。")
(<=>
(contains ?OBJ1 ?OBJ2)
(exists (?HOLE)
(and
(hole ?HOLE ?OBJ1)
(properlyFills ?OBJ2 ?HOLE))))
(subclass Substance SelfConnectedObject)
(partition Substance PureSubstance Mixture)
(partition Substance SyntheticSubstance NaturalSubstance)
(documentation Substance EnglishLanguage "An &%Object in which every part is similar to
every other in every relevant respect. More precisely, something is a
&%Substance when it has only arbitrary pieces as parts - any parts have
properties which are similar to those of the whole. Note that a &%Substance
may nonetheless have physical properties that vary. For example, the
temperature, chemical constitution, density, etc. may change from one part
to another. An example would be a body of water.")
(documentation Substance ChineseLanguage "一个每一部分在各个相关方面跟所有同类都相似的 &%Object。
更确切而言, &%Substance是当一个东西的部分只有任意散件时 - 任何部分的特质跟它整体的特质相似时。
这就是。 注:但 &%Substance 的一些物理特质可能会有差异。例如:温度、化学成分、密度等 可从一个部分改变成
另一个部分。 一滩水就是一个例子。")
(=>
(and
(subclass ?OBJECTTYPE Substance)
(instance ?OBJECT ?OBJECTTYPE)
(part ?PART ?OBJECT))
(instance ?PART ?OBJECTTYPE))
(=>
(and
(instance ?OBJ Substance)
(attribute ?OBJ ?ATTR)
(part ?PART ?OBJ))
(attribute ?PART ?ATTR))
(subclass SyntheticSubstance Substance)
(documentation SyntheticSubstance EnglishLanguage "Any &%Substance that is the result of
an &%IntentionalProcess, i.e. any substance that is created by &%Humans.")
(documentation SyntheticSubstance ChineseLanguage "这是任何由 &%IntentionalProcess 所造成的
&%Substance , 也就是任何由 &%Humans 所制造的物质。")
(<=>
(instance ?SUBSTANCE SyntheticSubstance)
(exists (?PROCESS)
(and
(instance ?PROCESS IntentionalProcess)
(result ?PROCESS ?SUBSTANCE)
(instance ?SUBSTANCE Substance))))
(subclass NaturalSubstance Substance)
(documentation NaturalSubstance EnglishLanguage "Any &%Substance that is not the result of
an &%IntentionalProcess, i.e. any substance that occurs naturally.")
(documentation NaturalSubstance ChineseLanguage "这是任何不是由 &%IntentionalProcess 所造成的
&%Substance , 也就是任何自然地产生的物质。")
(subclass PureSubstance Substance)
(partition PureSubstance CompoundSubstance ElementalSubstance)
(documentation PureSubstance EnglishLanguage "The &%Class of &%Substances with constant
composition. A &%PureSubstance can be either an element (&%ElementalSubstance)
or a compound of elements (&%CompoundSubstance). Examples: Table salt
(sodium chloride, NaCl), sugar (sucrose, C_{12}H_{22}O_{11}), water (H_2O),
iron (Fe), copper (Cu), and oxygen (O_2).")
(documentation PureSubstance ChineseLanguage "这是拥有不变成分 &%Substance 的 &%Class 。
&%PureSubstance 可以是元素 (&%ElementalSubstance), 又或者是拥有多个元素的化合物
(&%CompoundSubstance)。例如:食盐(氯化钠,NaCl)、糖(蔗糖,C_{12}H_{22}O_{11})、水(H_2O)
、铁(Fe)、铜(Cu)和氧(O_2)。")
(subclass ElementalSubstance PureSubstance)
(documentation ElementalSubstance EnglishLanguage "The &%Class of &%PureSubstances that
cannot be separated into two or more &%Substances by ordinary chemical
(or physical) means. This excludes nuclear reactions. &%ElementalSubstances
are composed of only one kind of atom. Examples: Iron (Fe), copper (Cu),
and oxygen (O_2). &%ElementalSubstances are the simplest
&%PureSubstances.")
(documentation ElementalSubstance ChineseLanguage "这是&%PureSubstance &%Class,它是不能通
过普通的化学(或物理)手段分割成两个或以上 &%Substance。这不包括核反应。 &%ElementalSubstance 由单
一一个原子组成。例如:铁 (Fe)、 铜(Cu) 和氧 (O_2)。 &%ElementalSubstance 是最简单的
&%PureSubstance。")
(subclass Metal ElementalSubstance)
(documentation Metal EnglishLanguage "A &%Metal is an &%ElementalSubstance that conducts
heat and electricity, is shiny and reflects many colors of light, and can be hammered
into sheets or drawn into wire. About 80% of the known chemical elements
(&%ElementalSubstances) are metals.")
(documentation Metal ChineseLanguage " &%Metal 是能传热和电 的 &%ElementalSubstance,它有
光泽、能反射光的许多颜色,并且可以打造成片材或拉成线。 约有80%的已知化学元素(&%ElementalSubstance)
是金属。")
(subclass Atom ElementalSubstance)
(documentation Atom EnglishLanguage "An extremely small unit of matter that retains its
identity in Chemical reactions. It consists of an &%AtomicNucleus and
&%Electrons surrounding the &%AtomicNucleus.")
(documentation Atom ChineseLanguage "这是一个极小的物质单位,它能
在化学反应中保持自己的本性。它由一个 &%AtomicNucleus 和 以个包围着 &%AtomicNucleus 的 &%Electron
所组成。")
(=>
(instance ?ATOM Atom)
(exists (?PROTON ?ELECTRON)
(and
(component ?PROTON ?ATOM)
(component ?ELECTRON ?ATOM)
(instance ?PROTON Proton)
(instance ?ELECTRON Electron))))
(=>
(instance ?ATOM Atom)
(forall (?NUCLEUS1 ?NUCLEUS2)
(=>
(and
(component ?NUCLEUS1 ?ATOM)
(component ?NUCLEUS2 ?ATOM)
(instance ?NUCLEUS1 AtomicNucleus)
(instance ?NUCLEUS2 AtomicNucleus))
(equal ?NUCLEUS1 ?NUCLEUS2))))
(subclass SubatomicParticle ElementalSubstance)
(documentation SubatomicParticle EnglishLanguage "The class of &%ElementalSubstances that
are smaller than &%Atoms and compose &%Atoms.")
(documentation SubatomicParticle ChineseLanguage "这是比 &%Atom 还要小、由 &%Atom 组成
的 &%ElementalSubstance 类别。")
(=>
(instance ?PARTICLE SubatomicParticle)
(exists (?ATOM)
(and
(instance ?ATOM Atom)
(part ?PARTICLE ?ATOM))))
(subclass AtomicNucleus SubatomicParticle)
(documentation AtomicNucleus EnglishLanguage "The core of the &%Atom. It is composed of
&%Protons and &%Neutrons.")
(documentation AtomicNucleus ChineseLanguage "&%Atom 的核心, 由 &%Proton 和 &%Neutron
组成。")
(=>
(instance ?NUCLEUS AtomicNucleus)
(exists (?NEUTRON ?PROTON)
(and
(component ?NEUTRON ?NUCLEUS)
(component ?PROTON ?NUCLEUS)
(instance ?NEUTRON Neutron)
(instance ?PROTON Proton))))
(subclass Electron SubatomicParticle)
(documentation Electron EnglishLanguage "&%SubatomicParticles that surround the
&%AtomicNucleus. They have a negative charge.")
(documentation Electron ChineseLanguage "这是包围着 &%AtomicNucleus 的 &%SubatomicParticle
, 它们具有负电荷。")
(subclass Proton SubatomicParticle)
(documentation Proton EnglishLanguage "Components of the &%AtomicNucleus. They have a
positive charge.")
(documentation Proton ChineseLanguage "这是 &%AtomicNucleus 的组件, 它们具有正电荷。")
(subclass Neutron SubatomicParticle)
(documentation Neutron EnglishLanguage "Components of the &%AtomicNucleus. They have no
charge.")
(documentation Neutron ChineseLanguage "这是 &%AtomicNucleus 的组件, 它们不含电荷。")
(subclass CompoundSubstance PureSubstance)
(documentation CompoundSubstance EnglishLanguage "The &%Class of &%Substances that contain
two or more elements (&%ElementalSubstances), in definite proportion by weight.
The composition of a pure compound will be invariant, regardless of the method
of preparation. Compounds are composed of more than one kind of atom (element).
The term molecule is often used for the smallest unit of a compound that still
retains all of the properties of the compound. Examples: Table salt (sodium
chloride, NaCl), sugar (sucrose, C_{12}H_{22}O_{11}), and water (H_2O). ")
(documentation CompoundSubstance ChineseLanguage "这个 &%Substance &%Class ,以确定的重量比例
,拥有两个或以上元素 (&%ElementalSubstance)。不管事用什麽方法提炼,纯复合物的成分保持不变。复合物由
超过一中原子(元素)组成。分子这个术语通常用来识别哪些仍然保留化合物所有性质的最小单元。例如:食盐
(氯化钠,NaCl)、糖(蔗糖,C_{12}H_{22}O_{11})、水(H_2O)。")
(subclass Mixture Substance)
(documentation Mixture EnglishLanguage "A &%Mixture is two or more &%PureSubstances,
combined in varying proportions - each retaining its own specific properties.
The components of a &%Mixture can be separated by physical means, i.e. without
the making and breaking of chemical bonds. Examples: Air, table salt thoroughly
dissolved in water, milk, wood, and concrete. ")
(documentation Mixture ChineseLanguage " &%Mixture 是两个或以上、以各种比例组成 - 各自保留自身
特定性质的 &%PureSubstance。 &%Mixture 的成分可以通过物理途径分离,即不曾建立或打破成分之间的化学键。
例如:空气、彻底溶于水中的食盐、牛奶、木材和混凝土中。")
(=>
(instance ?MIXTURE Mixture)
(exists (?PURE1 ?PURE2)
(and
(instance ?PURE1 PureSubstance)
(instance ?PURE2 PureSubstance)
(not (equal ?PURE1 ?PURE2))
(part ?PURE1 ?MIXTURE)
(part ?PURE2 ?MIXTURE))))
(=>
(and
(instance ?MIXTURE Mixture)
(part ?SUBSTANCE ?MIXTURE)
(not (instance ?SUBSTANCE Mixture)))
(instance ?SUBSTANCE PureSubstance))
(subclass CorpuscularObject SelfConnectedObject)
(disjoint CorpuscularObject Substance)
(documentation CorpuscularObject EnglishLanguage "A &%SelfConnectedObject whose parts have
properties that are not shared by the whole.")
(documentation CorpuscularObject ChineseLanguage "这是一个整体和部分之间不存在共有的特性
&%SelfConnectedObject。 ")
(=>
(instance ?OBJ CorpuscularObject)
(exists (?SUBSTANCE1 ?SUBSTANCE2)
(and
(subclass ?SUBSTANCE1 Substance)
(subclass ?SUBSTANCE2 Substance)
(material ?SUBSTANCE1 ?OBJ)
(material ?SUBSTANCE2 ?OBJ)
(not (equal ?SUBSTANCE1 ?SUBSTANCE2)))))
(subclass Region Object)
(documentation Region EnglishLanguage "A topographic location. &%Regions encompass
surfaces of &%Objects, imaginary places, and &%GeographicAreas. Note
that a &%Region is the only kind of &%Object which can be located at
itself. Note too that &%Region is not a subclass of &%SelfConnectedObject,
because some &%Regions, e.g. archipelagos, have &%parts which are not
&%connected with one another.")
(documentation Region ChineseLanguage "这是一个地理位置。 &%Region 包括 &%Object 的表面、虚构的
地方 和 &%GeographicArea 。注:&%Region 是唯一能够定位于作自身的 &%Object 。 另外要注意的是
&%Region 不是 &%SelfConnectedObject 的子类别, 因为有一些 &%Region ,像群岛有些 &%part 跟其他部分
不 &%connected 。")
(=>
(instance ?REGION Region)
(exists (?PHYS)
(located ?PHYS ?REGION)))
(subclass Collection Object)
(disjoint Collection SelfConnectedObject)
(documentation Collection EnglishLanguage "Collections have &%members like &%Classes, but,
unlike &%Classes, they have a position in space-time and &%members can be
added and subtracted without thereby changing the identity of the
&%Collection. Some examples are toolkits, football teams, and flocks
of sheep.")
(documentation Collection ChineseLanguage "群体和 &%Class 一样,拥有 &%member ,可它又不像
&%Class, 因为它们在时空有一个定位,而且 &%Collection 可以加和减 &%member 却不会改变自身的身份。它的
例子有工具包、足球队和羊群。")
(=>
(instance ?COLL Collection)
(exists (?OBJ)
(member ?OBJ ?COLL)))
(subrelation member part)
(instance member AsymmetricRelation)
(instance member IntransitiveRelation)
(domain member 1 Object)
(domain member 2 Collection)
(relatedInternalConcept member instance)
(relatedInternalConcept member element)
(documentation member EnglishLanguage "A specialized common sense notion of part for
uniform parts of &%Collections. For example, each sheep in a flock of
sheep would have the relationship of member to the flock.")
(documentation member ChineseLanguage "这是对属于 &%Collection 相同部分的专业常识概念。例如:
羊群中的每只羊,跟羊群间,是成员关系。")
(instance subCollection BinaryPredicate)
(instance subCollection PartialOrderingRelation)
(domain subCollection 1 Collection)
(domain subCollection 2 Collection)
(documentation subCollection EnglishLanguage "(&%subCollection ?COLL1 ?COLL2) means that
the &%Collection ?COLL1 is a proper part of the &%Collection ?COLL2.")
(documentation subCollection ChineseLanguage "(&%subCollection ?COLL1 ?COLL2) 的意思是
&%Collection ?COLL1 是 &%Collection ?COLL2 的真正部分。")
(subrelation subCollection part)
(<=>
(subCollection ?COLL1 ?COLL2)
(forall (?MEMBER)
(=>
(member ?MEMBER ?COLL1)
(member ?MEMBER ?COLL2))))
(subclass ContentBearingPhysical Physical)
(documentation ContentBearingPhysical EnglishLanguage "Any &%Object or &%Process that
expresses content. This covers &%Objects that contain a &%Proposition,
such as a book, as well as &%ManualSignLanguage, which may similarly
contain a &%Proposition.")
(documentation ContentBearingPhysical ChineseLanguage "任何能表达内容的 &%Object 或 &%Process
。这包括有 &%Proposition 的 &%Object ,像一本书和同样有 &%Proposition 的 &%ManualSignLanguage。")
(=>
(instance ?OBJ ContentBearingPhysical)
(exists (?THING)
(represents ?OBJ ?THING)))
(subclass ContentBearingProcess ContentBearingPhysical)
;; NS: add. Missing!
(subclass ContentBearingProcess Process)
;; NS: cf. Note that &%ManualHumanLanguage is not a subclass of
;; &%Process, despite the documentation statement below.
(documentation ContentBearingProcess EnglishLanguage "Any &%Process, for example
&%ManualHumanLanguage, which may contain a &%Proposition.")
(documentation ContentBearingProcess ChineseLanguage "任何的 &%Process ,例如有 &%Proposition
的 &%ManualHumanLanguage 。")
(subclass ContentBearingObject CorpuscularObject)
(subclass ContentBearingObject ContentBearingPhysical)
(relatedInternalConcept ContentBearingObject containsInformation)
(documentation ContentBearingObject EnglishLanguage "Any &%SelfConnectedObject that
expresses content. This content may be a &%Proposition, e.g. when the
&%ContentBearingObject is a &%Sentence or &%Text, or it may be a representation of an
abstract or physical object, as with an &%Icon, a &%Word or a &%Phrase.")
(documentation ContentBearingObject ChineseLanguage "任何能表达内容的 &%SelfConnectedObject
内容可以是一篇 &%Proposition , 举例说当 &%ContentBearingObject 是一个 &%Sentence 或 &%Text ,
又或者是抽象或有形物体像一个 &%Icon 、一个 &%Word 或一个 &%Phrase 。")
(subclass SymbolicString ContentBearingObject)
(documentation SymbolicString EnglishLanguage "The &%Class of alphanumeric sequences.")
(documentation SymbolicString ChineseLanguage "这是文数字序列的 &%Class 。")
(subclass Character SymbolicString)
(documentation Character EnglishLanguage "An element of an alphabet, a set of numerals,
etc. Note that a &%Character may or may not be part of a &%Language. &%Character
is a subclass of &%SymbolicString, because every instance of &%Character is
an alphanumeric sequence consisting of a single element.")
(documentation Character ChineseLanguage "字母表中的一个元素、一组数字等。注: &%Character 可能是
也可能不是 &%Language 的一部分。 &%Character 是 &%SymbolicString 的子类别,因为 &%Character 的每
一个实例都是一个含又单一元素的文数字序列。")
(=>
(instance ?STRING SymbolicString)
(exists (?PART)
(and
(part ?PART ?STRING)
(instance ?PART Character))))
(instance containsInformation BinaryPredicate)
(instance containsInformation AsymmetricRelation)
(subrelation containsInformation represents)
(domain containsInformation 1 ContentBearingPhysical)
(domain containsInformation 2 Proposition)
(documentation containsInformation EnglishLanguage "A subrelation of &%represents. This
predicate relates a &%ContentBearingPhysical to the &%Proposition that is
expressed by the &%ContentBearingPhysical. Examples include the relationships
between a physical novel and its story and between a printed score and its
musical content.")
(documentation containsInformation ChineseLanguage "这是 &%represents 的子类别。这个术语把
&%ContentBearingPhysical 和这个 &%ContentBearingPhysical 所表达的 &%Proposition 联系起来。
它的例子包括一本实体小说和它所讲故事之间的关系,以及一篇总曲谱和的它音乐内容之间的关系。")
(subclass Icon ContentBearingPhysical)
(documentation Icon EnglishLanguage "This is the subclass of &%ContentBearingPhysical
which are not part of a &%Language and which have some sort of similarity
with the &%Objects that they represent. This &%Class would include symbolic
roadway signs, representational art works, photographs, etc.")
(documentation Icon ChineseLanguage "这是 &%ContentBearingPhysical 的子类别,
这不属于 &%Language 的部分,并且和 &%Object 所代表有相似的地方 这 &%Class 可包括具有象征性的路标、具
代表性的艺术品、照片等。")
(subclass MotionPicture Text)
(documentation MotionPicture EnglishLanguage "A &%ContentBearingObject which depicts
motion (and which may have an audio or text component as well). This &%Class covers
films, videos, etc.")
(documentation MotionPicture ChineseLanguage "这是描述动作(并且其也可以具有音频或文本成分)
的 &%ContentBearingObject 。 这个 &%Class 涵盖电影,视频等。")
(subclass LinguisticExpression ContentBearingPhysical)
(disjoint LinguisticExpression Icon)
(documentation LinguisticExpression EnglishLanguage "This is the subclass of
&%ContentBearingPhysical which are language-related. Note that this &%Class
encompasses both &%Language and the the elements of &%Languages,
e.g. &%Words.")
(documentation LinguisticExpression ChineseLanguage "这是 &%ContentBearingPhysical
和语言有关联的子类本。 注:这个 &%Class 涵盖 &%Language 和属于 &%Language 的元素,例如 &%Words 。")
(subclass Language LinguisticExpression)
(disjointDecomposition Language AnimalLanguage HumanLanguage ComputerLanguage)
(documentation Language EnglishLanguage "A system of signs for expressing thought. The
system can be either natural or artificial, i.e. something that emerges
gradually as a cultural artifact or something that is intentionally created
by a person or group of people.")
(documentation Language ChineseLanguage "这是表达思想的符号系统。这系统可以是自然或是人工的,也就是
说是一种逐渐形成的文化产品,或者是由一个人或一群人所故意创造的。")
(subclass AnimalLanguage Language)
(documentation AnimalLanguage EnglishLanguage "The &%subclass of &%Languages used by
&%Animals other than &%Humans.")
(documentation AnimalLanguage ChineseLanguage "这是除了 &%Human 以外 &%Animal 所用的
&%Language 的 &%subclass。 ")
(=>
(and
(instance ?LANG AnimalLanguage)
(agent ?PROC ?AGENT)
(instrument ?PROC ?LANG))
(and
(instance ?AGENT Animal)
(not (instance ?AGENT Human))))
(subclass ArtificialLanguage Language)
(documentation ArtificialLanguage EnglishLanguage "The &%subclass of &%Languages that are
designed by &%Humans.")
(documentation ArtificialLanguage ChineseLanguage "这是由 &%Human 所设计的 &%Language 的
&%subclass 。")
(subclass ComputerLanguage ArtificialLanguage)
(documentation ComputerLanguage EnglishLanguage "The class of &%Languages designed for
and interpreted by a computer.")
(documentation ComputerLanguage ChineseLanguage "这是一组为点算计而设,也是由电算计来解读的
&%Languages 类别。")
(=>
(and
(instance ?LANG ComputerLanguage)
(agent ?PROC ?AGENT)
(instrument ?PROC ?LANG))
(instance ?AGENT Machine))
(subclass HumanLanguage Language)
(partition HumanLanguage NaturalLanguage ConstructedLanguage)
(partition HumanLanguage SpokenHumanLanguage ManualHumanLanguage)
(documentation HumanLanguage EnglishLanguage "The &%subclass of &%Languages used by
&%Humans.")
(documentation HumanLanguage ChineseLanguage "这是 &%Human 所用 &%Language 的 &%subclass 。")
(=>
(and
(instance ?LANG HumanLanguage)
(agent ?PROC ?AGENT)
(instrument ?PROC ?LANG))
(instance ?AGENT Human))
(subclass ConstructedLanguage HumanLanguage)
(subclass ConstructedLanguage ArtificialLanguage)
(documentation ConstructedLanguage EnglishLanguage "An &%ConstructedLanguage is a
&%HumanLanguage that did not evolve spontaneously within a language
community, but rather had its core grammar and vocabulary invented by
one or more language experts, often with an aim to produce a more
grammatically regular language than any language that has evolved
naturally. This &%Class includes languages like Esperanto that were
created to facilitate international communication")
(documentation ConstructedLanguage ChineseLanguage " &%ConstructedLanguage 是一种没有机会
在语言社区自然的演变的 &%HumanLanguage ,反而它的核心语法和词汇是由一个或以上的语言专家所编造,一般的
目的是为了编制一个文法比其他任何自然演化语言更有规则的语言。这个 &%Class 包括像「世界语」的语言,它们的出
现是为了促进国际间的沟通。")
(=>
(instance ?LANG ConstructedLanguage)
(exists (?PLAN)
(and
(instance ?PLAN Planning)
(result ?PLAN ?LANG))))
(subclass NaturalLanguage HumanLanguage)
(documentation NaturalLanguage EnglishLanguage "The &%subclass of &%HumanLanguages which
are not designed and which evolve from generation to generation. This
&%Class includes all of the national languages, e.g. English, Spanish,
Japanese, etc. Note that this class includes dialects of natural
languages.")
(documentation NaturalLanguage ChineseLanguage "这个 &%subclass 的 &%HumanLanguage , 非由
设计而来, 而是经过世世代代演变而成。 这个 &%Class 包括所有国家语言,例如 英语、西班牙语、日本语等等。
注:这个类别也包括自然语言的方言。")
(subclass ManualHumanLanguage HumanLanguage)
(documentation ManualHumanLanguage EnglishLanguage "A &%ManualHumanLanguage is a
&%HumanLanguage which has as its medium gestures and movement, such
as the shape, position, and movement of the hands.")
(documentation ManualHumanLanguage ChineseLanguage " &%ManualHumanLanguage 是一种用手势和动作
来表达的 &%HumanLanguage , 例如像手的形状、位置和动作等。")
(subclass SpokenHumanLanguage HumanLanguage)
(documentation SpokenHumanLanguage EnglishLanguage "A &%SpokenHumanLanguage is a
&%HumanLanguage which has as its medium the human voice. It can also
be represented visually through writing, although not all
&%SpokenHumanLanguages have a codified written form.")
(documentation SpokenHumanLanguage ChineseLanguage " &%SpokenHumanLanguage 是一种用人类的声音
来表达的 &%HumanLanguage 。它也可以用书写,以视像的形式来表达,可是不是所有的 &%SpokenHumanLanguage
都编纂有书面语。")
(instance EnglishLanguage NaturalLanguage)
(instance EnglishLanguage SpokenHumanLanguage)
(documentation EnglishLanguage EnglishLanguage "A Germanic language that incorporates many
roots from the Romance languages. It is the official language of the &%UnitedStates,
the &%UnitedKingdom, and many other countries.")
(documentation EnglishLanguage ChineseLanguage "这是一种包括很多罗曼语族字根的日耳曼语族,它是
&%UnitedStates , &%UnitedKingdom 和很多其他国家的官方语言。")
(subclass Word LinguisticExpression)
(documentation Word EnglishLanguage "A term of a &%Language that represents a concept.")
(documentation Word ChineseLanguage "这是某种 &%Language 来表达一个概念的词语。")
(subclass Formula Sentence)
(documentation Formula EnglishLanguage "A syntactically well-formed formula in the
SUO-KIF knowledge representation language.")
(documentation Formula ChineseLanguage "一个句法结构良好、以SUO-KIF知识表示语言的公式。")
;; The following ground facts incorporate the 'Agent' hierarchy from the
;; corresponding ontology on the Ontolingua server. It also includes
;; predicates defined in the ITBM-CNR ontology "Actors".
(subclass Agent Object)
(documentation Agent EnglishLanguage "Something or someone that can act on its own and
produce changes in the world.")
(documentation Agent ChineseLanguage "能够自主行动、并对世界作出改变的人和物。")
(=>
(instance ?AGENT Agent)
(exists (?PROC)
(capability ?PROC agent ?AGENT)))
(subclass SentientAgent Agent)
;; NS: delete.
;; (documentation SentientAgent EnglishLanguage "An &%Agent that has rights but may or may
;; not have responsibilities and the ability to reason. If the latter are
;; present, then the &%Agent is also an instance of &%CognitiveAgent.
;; Domesticated animals are an example of &%SentientAgents that are not
;; also &%CognitiveAgents.")
;; NS: add.
(documentation SentientAgent EnglishLanguage "A &%SentientAgent is an
&%Agent that is capable of &%Perception and experiences some level of
consciousness (see &%ConsciousnessAttribute). If the &%Agent is able
to reason at a comparatively high level (evinced by the ability to
learn, plan, and feel emotions), then it is also an instance of
&%CognitiveAgent. A &%DomesticAnimal is a &%SentientAgent, but may or
may not be a &%CognitiveAgent, depending on the type of &%Animal.")
(documentation SentientAgent ChineseLanguage " &%SentientAgent 是一个能够 &%Perception
(感知)的 &%Agent, 并且在某程度上能感受到意识 (同时参考 &%ConsciousnessAttribute)。如果一个
&%Agent 能够以相对高层次的理智去思考的话(表现出能够学习、计划和体会情感),那么这个也是
&%CognitiveAgent 的一个实例。 &%DomesticAnimal 是一个 &%SentientAgent,但是它是不是一个
&%CognitiveAgent 却确定于究竟它是哪一种 &%Animal。")
(subclass CognitiveAgent SentientAgent)
;; NS: delete.
;; (documentation CognitiveAgent EnglishLanguage "A &%SentientAgent with
;; responsibilities and the ability to reason, deliberate, make plans,
;; etc. This is essentially the legal/ethical notion of a person. Note
;; that, although &%Human is a subclass of &%CognitiveAgent, there may be
;; instances of &%CognitiveAgent which are not also instances of &%Human.
;; For example, chimpanzees, gorillas, dolphins, whales, and some
;; extraterrestrials
;; (if they exist) may be &%CognitiveAgents.")
;; NS: add.
(documentation CognitiveAgent EnglishLanguage "A &%CognitiveAgent is
an &%Agent that has the ability to reason, deliberate, make plans, and
experience emotions. Although &%Human is a subclass of
&%CognitiveAgent, there may be instances of &%CognitiveAgent which are
not also instances of &%Human. For example, &%Primates, dolphins,
whales, and some extraterrestrials (if they exist) might be considered
&%CognitiveAgents.")
(documentation CognitiveAgent ChineseLanguage " &%CognitiveAgent 是一个能够思考、深思熟虑、计划
和体会感情的 &%Agent。虽然 &%Human 是 &%CognitiveAgent 的子类别,也可以出现非 &%Human 而却是
&%CognitiveAgent 的实例。例如:&%Primate、海豚、鲸鱼和外星人(如果它们存在的话)可以算是
&%CognitiveAgent。")
;; NS: new. Since an Entity might or might not be considered a
;; LegalAgent for its entire existence, depending on the
;; circumstances, it might be better to represent &%LegalAgent as a
;; &%RelationalAttribute.
(subclass LegalAgent Agent)
;; NS: add.
(documentation LegalAgent EnglishLanguage "A &%LegalAgent is an
&%Agent that is allowed by law to to act and be treated as a legal
person for certain purposes, such as being a party to a lawsuit,
owning property, and entering into a contract. Typically, a
&%LegalAgent is either an adult &%Human or some type of
&%Organization. Depending on the prevailing legal system in a given
time and location, &%Humans in general, as well as other
&%CognitiveAgents, typically will have additional legal rights and
obligations beyond those accorded to &%LegalAgents. See the Wikipedia
description of <a
href=http://en.wikipedia.org/wiki/Juristic_person>Juristic
person</a>.")
(documentation LegalAgent ChineseLanguage " &%LegalAgent 是一个在法律上能够为某种目的以法人身份
行事和被人对待的 &%Agent,例如:作为诉讼的当事人、拥有财产和签订合同。 通常一个 &%LegalAgent 要不是成年
的 &%Human 就是某类 &%Organization。 视乎当时当地盛行的法制,一般来说 &%Human 和其他的
&%CognitiveAgent 通常拥有超过赋予给 &%LegalAgent 的额外的法定权利和义务。可参考这个维基百科网址的注解
<ahref=http://en.wikipedia.org/wiki/Juristic_person>Juristicperson</a>。")
;; NS: add.
(<=>
(holdsDuring ?TIME
(instance ?AGENT LegalAgent))
(holdsDuring ?TIME
(or
(capability LegalAction agent ?AGENT)
(capability LegalAction patient ?AGENT))))
(instance leader BinaryPredicate)
(instance leader AsymmetricRelation)
(instance leader SingleValuedRelation)
(domain leader 1 Agent)
(domain leader 2 Human)
(documentation leader EnglishLanguage "(&%leader ?INSTITUTION ?PERSON)
means that the leader of ?INSTITUTION is ?PERSON.")
(=>
(holdsDuring ?TIME (leader ?X ?Y))
(holdsDuring ?TIME (attribute ?Y Living)))
(subclass Process Physical)
(documentation Process EnglishLanguage "The class of things that happen
and have temporal parts or stages. Examples include extended events
like a football match or a race, actions like &%Pursuing and &%Reading,
and biological processes. The formal definition is: anything that occurs in
time but is not an &%Object. Note that a &%Process may have
participants 'inside' it which are &%Objects, such as the players
in a football match. In a 4D ontology, a &%Process is something whose
spatiotemporal extent is thought of as dividing into temporal stages
roughly perpendicular to the time-axis.")
(documentation Process ChineseLanguage " 这个类别属于发生的事物,它具有时间的部分或阶段。
例子包括:历时颇长的事件如足球比赛或赛跑,行动如追踪、阅读和及各种生物过程。它的形式定义是:任何在某时间发生
而又不是 &%Object 的存在着。 注:&%Process 内可以有 &%Object 参加者介入,例如球赛的球员。四维的
知识本体论认为 &%Process 的时空幅度可分成大约和时间轴平衡的数个时间阶段。")
(subclass DualObjectProcess Process)
(documentation DualObjectProcess EnglishLanguage "Any &%Process that requires two,
nonidentical &%patients.")
(documentation DualObjectProcess ChineseLanguage "任何需要两个不同 &%patient 的 &%Process。")
(=>
(instance ?PROCESS DualObjectProcess)
(exists (?OBJ1 ?OBJ2)
(and
(patient ?PROCESS ?OBJ1)
(patient ?PROCESS ?OBJ2)
(not (equal ?OBJ1 ?OBJ2)))))
(subclass SingleAgentProcess Process)
(documentation SingleAgentProcess EnglishLanguage "&%SingleAgentProcess
is the &%Class of all &%Processes that require exactly one &%agent in order to occur.")
(documentation SingleAgentProcess ChineseLanguage " &%SingleAgentProcess 这个 &%Class 里
所有的 &%Process 都需要恰好一个 &%agent 才能发生。")
(=>
(instance ?PROC SingleAgentProcess)
(exists (?AGENT)
(agent ?PROC ?AGENT)))
(=>
(and
(instance ?PROC SingleAgentProcess)
(agent ?PROC ?AGENT_1)
(agent ?PROC ?AGENT_2))
(and
(equal ?AGENT_1 ?AGENT_2)
(not
(exists (?AGENT_3)
(and
(agent ?PROC ?AGENT_3)
(not
(equal ?AGENT_3 ?AGENT_1)))))))
(subclass Abstract Entity)
(disjointDecomposition Abstract Quantity Attribute SetOrClass Relation Proposition)
(documentation Abstract EnglishLanguage "Properties or qualities as distinguished from any
particular embodiment of the properties/qualities in a physical medium.
Instances of Abstract can be said to exist in the same sense as mathematical
objects such as sets and relations, but they cannot exist at a particular
place and time without some physical encoding or embodiment.")
(documentation Abstract ChineseLanguage "这些特质或质量,和任何以物理媒介化身的特质/质量不同。抽象
的实例在意义上,可以说是像数学物体如集合和关系般存在,但是它们不能没有任何物理编码或化身便存在于特定的时间
和地点。")
;; Something is Abstract just in case it has neither a spatial nor temporal
;; location.
(=>
(instance ?ABS Abstract)
(not
(exists (?POINT)
(or
(located ?ABS ?POINT)
(time ?ABS ?POINT)))))
(subclass Quantity Abstract)
(documentation Quantity EnglishLanguage "Any specification of how many or how much of
something there is. Accordingly, there are two subclasses of &%Quantity:
&%Number (how many) and &%PhysicalQuantity (how much).")
(documentation Quantity ChineseLanguage "这是任何表示东西数量或多少的规格。故此 &%Quantity 共有两个
子类别:&%Number (数量)和 &%PhysicalQuantity (多少)。")
(subclass Attribute Abstract)
;(partition Attribute InternalAttribute RelationalAttribute PerceptualAttribute)
(partition Attribute InternalAttribute RelationalAttribute)
(documentation Attribute EnglishLanguage "Qualities which we cannot or choose not to
reify into subclasses of .")
(documentation Attribute ChineseLanguage "这是我们不能够或选择不去具体化为 &%Object 的子类别的
质量。")
(instance property BinaryPredicate)
(domain property 1 Entity)
(domain property 2 Attribute)
(documentation property EnglishLanguage "This &%Predicate holds between an instance of
&%Entity and an instance of &%Attribute. (&%property ?ENTITY ?ATTR)
means that ?ENTITY has the &%Attribute ?ATTR.")
(documentation property ChineseLanguage "这个 &%Predicate 在 &%Entity 的实例和 &%Attribute 的
实例成立。(&%property ?ENTITY ?ATTR) 的意思是 ?ENTITY 有 ?ATTR 的 &%Attribute。")
(instance attribute AsymmetricRelation)
(instance attribute IrreflexiveRelation)
(instance attribute TotalValuedRelation)
(subrelation attribute property)
(domain attribute 1 Object)
(documentation attribute EnglishLanguage "(&%attribute ?OBJECT ?PROPERTY) means that
?PROPERTY is a &%Attribute of ?OBJECT. For example,
(&%attribute &%MyLittleRedWagon &%Red).")
(documentation attribute ChineseLanguage "(&%attribute ?OBJECT ?PROPERTY) 的意思是
?PROPERTY 是 ?OBJECT 的 &%Attribute。例如:(&%attribute &%MyLittleRedWagon &%Red)。")
(instance manner AsymmetricRelation)
(instance manner IrreflexiveRelation)
(instance manner TotalValuedRelation)
(subrelation manner property)
(domain manner 1 Process)
(disjointRelation manner attribute)
(documentation manner EnglishLanguage "(&%manner ?PROCESS ?MANNER) means that the
&%Process ?PROCESS is qualified by the &%Attribute ?MANNER. The &%Attributes
of &%Processes are usually denoted by adverbs and include things like the
speed of the wind, the style of a dance, or the intensity of a sports
competition.")
(documentation manner ChineseLanguage "(&%manner ?PROCESS ?MANNER) 的意思是 ?PROCESS 这个
&%Process 由 ?MANNER 这个 &%Attribute 来修饰。 &%Processe 的 &%Attribute 通常以副词来表示,这些
包括像风的速度、一个舞蹈的风格或一种运动比赛竞争的激烈程度等。")
; Seldom used function that appears to cause a very complex contradiction
; (instance AbstractionFn UnaryFunction)
; (instance AbstractionFn PartialValuedRelation)
; (domain AbstractionFn 1 Class)
; (range AbstractionFn Attribute)
; (documentation AbstractionFn EnglishLanguage "A &%UnaryFunction that maps a &%Class into
; the instance of &%Attribute that specifies the condition(s) for membership
; in the &%Class.")
; (<=>
; (equal (AbstractionFn ?CLASS) ?ATTR)
; (forall (?INST)
; (<=>
; (instance ?INST ?CLASS)
; (property ?INST ?ATTR))))
(instance ExtensionFn UnaryFunction)
(instance ExtensionFn PartialValuedRelation)
(domain ExtensionFn 1 Attribute)
(range ExtensionFn Class)
(documentation ExtensionFn EnglishLanguage "A &%UnaryFunction that maps an &%Attribute
into the &%Class whose condition for membership is the &%Attribute.")
(documentation ExtensionFn ChineseLanguage "这个 &%UnaryFunction 把一个 &%Attribute 联系到
属于这个 &%Attribute 属性条件的 &%Class。")
; (<=>
; (equal (ExtensionFn ?ATTRIBUTE) ?CLASS)
; (equal (AbstractionFn ?CLASS) ?ATTRIBUTE))
(subclass InternalAttribute Attribute)
(documentation InternalAttribute EnglishLanguage "Any &%Attribute of an &%Entity that is
an internal property of the &%Entity, e.g. its shape, its color, its fragility,
etc.")
(documentation InternalAttribute ChineseLanguage "这是 &%Entity 的 &%Attribute,任何属于
&%Entity 内在的特质,如它的形状、颜色和脆弱的程度等。")
(subclass PhysicalAttribute InternalAttribute)
(documentation PhysicalAttribute EnglishLanguage "An &%InternalAttribute given by physical
properties of the object.")
(documentation PhysicalAttribute ChineseLanguage "这是来自物体的物理特质的 &%InternalAttribute
。")
(subclass RelationalAttribute Attribute)
(documentation RelationalAttribute EnglishLanguage "Any &%Attribute that an &%Entity has
by virtue of a relationship that it bears to another &%Entity or set of &%Entities,
e.g. &%SocialRoles and &%PositionalAttributes.")
(documentation RelationalAttribute ChineseLanguage "这是 &%Entity 的 &%Attribute,属于任何来自
它和另一个 &%Entity 或 一组 &%Entity 之间的关系. 如: &%SocialRole 和 &%PositionalAttribute。")
;; The following formulas incorporate the Number hierarchy from the
;; ontology 'kif-numbers' on the Ontolingua server.
(subclass Number Quantity)
(partition Number RealNumber ImaginaryNumber ComplexNumber)
(documentation Number EnglishLanguage "A measure of how many things there are, or how
much there is, of a certain kind. &%Numbers are subclassed into
&%RealNumber, &%ComplexNumber, and &%ImaginaryNumber.")
(documentation Number ChineseLanguage "这是用来量度东西的数量或者某种东西的分量。 &%Numbers 可分为
&%RealNumber、 &%ComplexNumber 和 &%ImaginaryNumber。")
(instance lessThan BinaryPredicate)
(instance lessThan TransitiveRelation)
(instance lessThan IrreflexiveRelation)
(instance lessThan RelationExtendedToQuantities)
(trichotomizingOn lessThan RealNumber)
(domain lessThan 1 Quantity)
(domain lessThan 2 Quantity)
(documentation lessThan EnglishLanguage "(&%lessThan ?NUMBER1 ?NUMBER2) is true just
in case the &%Quantity ?NUMBER1 is less than the &%Quantity ?NUMBER2.")
(documentation lessThan ChineseLanguage "(&%lessThan ?NUMBER1 ?NUMBER2) 是真的
以防 ?NUMBER1 的 &%Quantity 比 ?NUMBER2 的 &%Quantity 要少。")
(instance greaterThan BinaryPredicate)
(instance greaterThan TotalValuedRelation)
(instance greaterThan TransitiveRelation)
(instance greaterThan IrreflexiveRelation)
(instance greaterThan RelationExtendedToQuantities)
(trichotomizingOn greaterThan RealNumber)
(domain greaterThan 1 Quantity)
(domain greaterThan 2 Quantity)
(inverse greaterThan lessThan)
(documentation greaterThan EnglishLanguage "(&%greaterThan ?NUMBER1 ?NUMBER2) is true
just in case the &%Quantity ?NUMBER1 is greater than the &%Quantity
?NUMBER2.")
(documentation greaterThan ChineseLanguage "(&%greaterThan ?NUMBER1 ?NUMBER2) 是真的以防
?NUMBER1 的 &%Quantity 比 ?NUMBER2 的 &%Quantity 要大。")
(instance lessThanOrEqualTo BinaryPredicate)
(instance lessThanOrEqualTo PartialOrderingRelation)
(instance lessThanOrEqualTo RelationExtendedToQuantities)
(trichotomizingOn lessThanOrEqualTo RealNumber)
(domain lessThanOrEqualTo 1 Quantity)
(domain lessThanOrEqualTo 2 Quantity)
(documentation lessThanOrEqualTo EnglishLanguage "(&%lessThanOrEqualTo ?NUMBER1 ?NUMBER2)
is true just in case the &%Quantity ?NUMBER1 is less than or equal to
the &%Quantity ?NUMBER2.")
(documentation lessThanOrEqualTo ChineseLanguage "(&%lessThanOrEqualTo ?NUMBER1 ?NUMBER2)
是真的以防 ?NUMBER1 的 &%Quantity 少于或者等于 ?NUMBER2 的 &%Quantity。")
(<=>
(lessThanOrEqualTo ?NUMBER1 ?NUMBER2)
(or
(equal ?NUMBER1 ?NUMBER2)
(lessThan ?NUMBER1 ?NUMBER2)))
(instance greaterThanOrEqualTo BinaryPredicate)
(instance greaterThanOrEqualTo PartialOrderingRelation)
(instance greaterThanOrEqualTo RelationExtendedToQuantities)
(trichotomizingOn greaterThanOrEqualTo RealNumber)
(domain greaterThanOrEqualTo 1 Quantity)
(domain greaterThanOrEqualTo 2 Quantity)
(inverse greaterThanOrEqualTo lessThanOrEqualTo)
(documentation greaterThanOrEqualTo EnglishLanguage "(&%greaterThanOrEqualTo ?NUMBER1
?NUMBER2) is true just in case the &%Quantity ?NUMBER1 is greater than or equal to the
&%Quantity ?NUMBER2.")
(documentation greaterThanOrEqualTo ChineseLanguage "(&%greaterThanOrEqualTo ?NUMBER1
?NUMBER2) 是真的以防 ?NUMBER1 的 &%Quantity 多于或者等于 ?NUMBER2 的 &%Quantity。")
(<=>
(greaterThanOrEqualTo ?NUMBER1 ?NUMBER2)
(or
(equal ?NUMBER1 ?NUMBER2)
(greaterThan ?NUMBER1 ?NUMBER2)))
(subclass RealNumber Number)
(partition RealNumber NegativeRealNumber NonnegativeRealNumber)
(partition RealNumber RationalNumber IrrationalNumber)
(documentation RealNumber EnglishLanguage "Any &%Number that can be expressed as a
(possibly infinite) decimal, i.e. any &%Number that has a position
on the number line.")
(documentation RealNumber ChineseLanguage "任何可以表达为一个(可能是无限的)十进制的 &%Number,
即任何在数字线上佔有一席位 &%Number。")
(subclass ImaginaryNumber Number)
(documentation ImaginaryNumber EnglishLanguage "Any &%Number that is the result of
multiplying a &%RealNumber by the square root of -1.")
(documentation ImaginaryNumber ChineseLanguage "这是将一个 &%RealNumber 乘以-1的平方根的积,它
可以是任何一个的 &%Number。")
(=>
(instance ?NUMBER ImaginaryNumber)
(exists (?REAL)
(and
(instance ?REAL RealNumber)
(equal ?NUMBER (MultiplicationFn ?REAL (SquareRootFn -1))))))
(subclass RationalNumber RealNumber)
(documentation RationalNumber EnglishLanguage "Any &%RealNumber that is the product of
dividing two &%Integers.")
(documentation RationalNumber ChineseLanguage "这是把两个 &%Integer 相除的商,它可以是任何一个的
&%RealNumber。")
(subclass IrrationalNumber RealNumber)
(documentation IrrationalNumber EnglishLanguage "Any &%RealNumber that is not also a
&%RationalNumber.")
(documentation IrrationalNumber ChineseLanguage "这是任何一个不是 &%RationalNumber 的
&%RealNumber。")
(subclass NonnegativeRealNumber RealNumber)
(documentation NonnegativeRealNumber EnglishLanguage "A &%RealNumber that is greater than
or equal to zero.")
(documentation NonnegativeRealNumber ChineseLanguage "这是一个大于或等于零的 &%RealNumber。")
(<=>
(instance ?NUMBER NonnegativeRealNumber)
(and
(greaterThanOrEqualTo ?NUMBER 0)
(instance ?NUMBER RealNumber)))
(subclass PositiveRealNumber NonnegativeRealNumber)
(documentation PositiveRealNumber EnglishLanguage "A &%RealNumber that is greater than
zero.")
(documentation PositiveRealNumber ChineseLanguage "这是一个大于零的 &%RealNumber。")
(<=>
(instance ?NUMBER PositiveRealNumber)
(and
(greaterThan ?NUMBER 0)
(instance ?NUMBER RealNumber)))
(subclass NegativeRealNumber RealNumber)
(documentation NegativeRealNumber EnglishLanguage "A &%RealNumber that is less than
zero.")
(documentation NegativeRealNumber ChineseLanguage "这是一个小于零的 &%RealNumber。")
(<=>
(instance ?NUMBER NegativeRealNumber)
(and
(lessThan ?NUMBER 0)
(instance ?NUMBER RealNumber)))
(subclass Integer RationalNumber)
(partition Integer OddInteger EvenInteger)
(partition Integer NegativeInteger NonnegativeInteger)
(documentation Integer EnglishLanguage "A negative or nonnegative whole number.")
(documentation Integer ChineseLanguage "这是一个负或非负的整数。")
(subclass EvenInteger Integer)
(documentation EvenInteger EnglishLanguage "An &%Integer that is evenly divisible
by 2.")
(documentation EvenInteger ChineseLanguage "这是一个可以被2整除的 &%Integer。")
(subclass OddInteger Integer)
(documentation OddInteger EnglishLanguage "An &%Integer that is not evenly divisible
by 2.")
(documentation OddInteger ChineseLanguage "这是一个不能被2整除的 &%Integer。")
(subclass PrimeNumber Integer)
(documentation PrimeNumber EnglishLanguage "An &%Integer that is evenly divisible only
by itself and 1.")
(documentation PrimeNumber ChineseLanguage "这是一个只能被自己或1整除的 &%Integer。")
(subclass NonnegativeInteger Integer)
(subclass NonnegativeInteger NonnegativeRealNumber)
(documentation NonnegativeInteger EnglishLanguage "An &%Integer that is greater than
or equal to zero.")
(documentation NonnegativeInteger ChineseLanguage "这是一个大于或等于零的 &%Integer。")
(=>
(instance ?X NonnegativeInteger)
(greaterThan ?X -1))
(subclass NegativeInteger Integer)
(subclass NegativeInteger NegativeRealNumber)
(documentation NegativeInteger EnglishLanguage "An &%Integer that is less than zero.")
(documentation NegativeInteger ChineseLanguage "这是一个小于零的 &%Integer。")
(=>
(instance ?X NegativeInteger)
(greaterThan 0 ?X))
(subclass PositiveInteger NonnegativeInteger)
(subclass PositiveInteger PositiveRealNumber)
(documentation PositiveInteger EnglishLanguage "An &%Integer that is greater than zero.")
(documentation PositiveInteger ChineseLanguage "这是一个大于零的 &%Integer。")
(=>
(instance ?X PositiveInteger)
(greaterThan ?X 0))
(subclass BinaryNumber RealNumber)
(documentation BinaryNumber EnglishLanguage "Elements from the number system with base 2.
Every &%BinaryNumber is expressed as a sequence of the digits 1 and 0.")
(documentation BinaryNumber ChineseLanguage "这是二进制数字系统的元素。
所有的 &%BinaryNumber 都是以1而0的排列来表示的。")
(subclass ComplexNumber Number)
(disjoint ComplexNumber RealNumber)
(documentation ComplexNumber EnglishLanguage "A &%Number that has the form: x + yi, where
x and y are &%RealNumbers and i is the square root of -1.")
(documentation ComplexNumber ChineseLanguage "这是一个有来自x + yi形式的&%Number,x和y是
&%RealNumber,i是-1的平方根。")
(=>
(instance ?NUMBER ComplexNumber)
(exists (?REAL1 ?REAL2)
(and
(instance ?REAL1 RealNumber)
(instance ?REAL2 RealNumber)
(equal ?NUMBER
(AdditionFn ?REAL1
(MultiplicationFn ?REAL2
(SquareRootFn -1)))))))
(subclass PhysicalQuantity Quantity)
(partition PhysicalQuantity ConstantQuantity FunctionQuantity)
(documentation PhysicalQuantity EnglishLanguage "A &%PhysicalQuantity is a measure of
some quantifiable aspect of the modeled world, such as 'the earth's
diameter' (a constant length) and 'the stress in a loaded deformable
solid' (a measure of stress, which is a function of three spatial
coordinates). Every &%PhysicalQuantity is either a &%ConstantQuantity
or &%FunctionQuantity. Instances of &%ConstantQuantity are dependent
on a &%UnitOfMeasure, while instances of &%FunctionQuantity are
&%Functions that map instances of &%ConstantQuantity to other instances
of &%ConstantQuantity (e.g., a &%TimeDependentQuantity is a
&%FunctionQuantity). Although the name and definition of
&%PhysicalQuantity is borrowed from physics, a &%PhysicalQuantity need
not be material. Aside from the dimensions of length, time, velocity,
etc., nonphysical dimensions such as currency are also possible.
Accordingly, amounts of money would be instances of &%PhysicalQuantity.
A &%PhysicalQuantity is distinguished from a pure &%Number by the fact that
the former is associated with a dimension of measurement.")
(documentation PhysicalQuantity ChineseLanguage "&%PhysicalQuantity是一种用来衡量建模世界上的
一些可以量度的部分,例如:「地球的直径」(长度固定)和「装满了可变形的固体的应力」(应力的衡量,它是一个有
三个空间坐标的函数)。 &%PhysicalQuantity 要不是 &%ConstantQuantity,就是 &%FunctionQuantity。
&%ConstantQuantity 的实例需要有一个 &%UnitOfMeasure,而 &%FunctionQuantity 的实例是要靠一个
&%Function, 它把 &%ConstantQuantity 的实例和其它 &%ConstantQuantity 的实例联系在一起(举例说,
&%TimeDependentQuantity 属于 &%FunctionQuantity)。 &%PhysicalQuantity 这个名字和定义是借用物
理理论,但是 &%PhysicalQuantity 不一定是指物质上的。 除了长度、时间和速度等这些尺度以外,非物理尺寸如
货币也是可行的。因此,金钱会是 &%PhysicalQuantity 的实例。 &%PhysicalQuantity 和纯 &%Number
的区别在于前者附有一个衡量的尺度。")
(subclass ConstantQuantity PhysicalQuantity)
(documentation ConstantQuantity EnglishLanguage "A &%ConstantQuantity
is a &%PhysicalQuantity that has a constant value, e.g. 3 &%Meters and
5 &%HourDurations. The magnitude (see &%MagnitudeFn) of every
&%ConstantQuantity is a &%RealNumber. &%ConstantQuantity is
distinguished from &%FunctionQuantity, in that each instance of the
latter is formed through the mapping of one &%PhysicalQuantity to
another &%PhysicalQuantity. Each instance of &%ConstantQuantity is
expressed with the &%BinaryFunction &%MeasureFn, which takes a
&%Number and a &%UnitOfMeasure as arguments. For example, 3 &%Meters
is expressed as (&%MeasureFn 3 &%Meter). Instances of
&%ConstantQuantity form a partial order (see
&%PartialOrderingRelation) with the &%lessThan relation, since
&%lessThan is a &%RelationExtendedToQuantities and &%lessThan is
defined over the &%RealNumbers. The &%lessThan relation is not a
total order (see &%TotalOrderingRelation) over the class
&%ConstantQuantity since elements of some subclasses of
&%ConstantQuantity (such as length quantities) are incomparable to
elements of other subclasses of &%ConstantQuantity
(such as mass quantities).")
(documentation ConstantQuantity ChineseLanguage "&%ConstantQuantity 是含不变值的
&%PhysicalQuantity,如 3 &%Meter 和 5 &%HourDuration。所有 &%ConstantQuantity 的幅度 (见
&%MagnitudeFn)都是 &%RealNumber。 &%ConstantQuantity 有别于 &%FunctionQuantity,
后者的每一个实例是通过把一个 &%PhysicalQuantity 连接到另一个 &%PhysicalQuantity 而成。 每个
&%ConstantQuantity 的实例使用 &%BinaryFunction &%MeasureFn 来表示, 它需要两个参数:一个
&%Number 和一个 &%UnitOfMeasure。例如:3 &%Meter 以 (&%MeasureFn 3 &%Meter) 表示。
&%ConstantQuantity 的实例与 &%lessThan 关系组成一个部分顺序 (见 &%PartialOrderingRelation),
因为 &%lessThan 是一个 &%RelationExtendedToQuantities,而 &%lessThan 以 &%RealNumber 来定义的。
&%lessThan 关系不是一个以 &%ConstantQuantity 类别的 全部顺序 (见 &%TotalOrderingRelation)因为
&%ConstantQuantity 一些子类别的元素 (如长度值)和 &%ConstantQuantity 其他子类别的元素 (如质量)
属完全不同。")
(subclass TimeMeasure ConstantQuantity)
(documentation TimeMeasure EnglishLanguage "The class of temporal durations (instances
of &%TimeDuration) and positions of &%TimePoints and &%TimeIntervals along
the universal timeline (instances of &%TimePosition).")
(documentation TimeMeasure ChineseLanguage "这个是通用时间轴( &%TimePosition 的实例)上的类别,
它包括时间段( &%TimeDuration 的实例),与 &%TimePoint 和 &%TimeInterval 的定位。")
(subclass TimeDuration TimeMeasure)
(documentation TimeDuration EnglishLanguage "Any measure of length of time,
with or without respect to the universal timeline.")
(documentation TimeDuration ChineseLanguage "这是任何量度时间的衡量,它可以是是基于通用时间轴的,
也可以是不基于通用时间轴的的。")
(subclass TimePosition TimeMeasure)
(partition TimePosition TimeInterval TimePoint)
(documentation TimePosition EnglishLanguage "Any &%TimePoint or &%TimeInterval
along the universal timeline from &%NegativeInfinity to
&%PositiveInfinity.")
(documentation TimePosition ChineseLanguage "这是从 &%NegativeInfinity到 &%PositiveInfinity
通用时间轴上的任何 &%TimePoint 或 &%TimeInterval。")
(subclass TimeInterval TimePosition)
(documentation TimeInterval EnglishLanguage "An interval of time.
Note that a &%TimeInterval has both an extent and a location on the
universal timeline. Note too that a &%TimeInterval has no gaps,
i.e. this class contains only convex time intervals.")
(documentation TimeInterval ChineseLanguage "这是一个时段。注: &%TimeInterval 在通用时间轴上
皆有范围和位置;另外 &%TimeInterval 是没有间隙的,即这个类别只含凸时间间隔。")
(subclass TimePoint TimePosition)
(documentation TimePoint EnglishLanguage "An extensionless point on
the universal timeline. The &%TimePoints at which &%Processes occur
can be known with various degrees of precision and approximation, but
conceptually &%TimePoints are point-like and not interval-like. That
is, it doesn't make sense to talk about how long a &%TimePoint
lasts.")
(documentation TimePoint ChineseLanguage "这是通用时间轴上无法延伸的的一点。 我们在不同程度的准确
和近似值上,可以知道 &%Process 发生的 &%TimePoint,但是 &%TimePoint 在概念上是成点状而非间隔状,
也就是说, 说 &%TimePoint 持续了多长是没有意义的。")
(subclass FunctionQuantity PhysicalQuantity)
(documentation FunctionQuantity EnglishLanguage "A &%FunctionQuantity
is a &%PhysicalQuantity that is returned by a &%Function that maps
from one or more instances of &%ConstantQuantity to another instance
of &%ConstantQuantity. For example, the velocity of a particle would
be represented by a &%FunctionQuantity relating values of time (which
are instances of &%ConstantQuantity) to values of distance
(also instances of &%ConstantQuantity). Note that all elements of the
range of the &%Function corresponding to a &%FunctionQuantity have the
same physical dimension as the &%FunctionQuantity itself.")
(documentation FunctionQuantity ChineseLanguage "
&%FunctionQuantity
是一个由 &%Function 它把 &%ConstantQuantity 的一个或以上的实例和其它 &%ConstantQuantity 的实例
联系在一起,例如:粒子的速度是用 &%FunctionQuantity, 把时间的值( &%ConstantQuantity的实例)和距离
的值(也是 &%ConstantQuantity的实例)连在一起来表示。注:和 &%FunctionQuantity 对应的 &%Function
范围内所有的元素和那个 &%FunctionQuantity 本身的物理尺寸是相同的。")
(subclass UnaryConstantFunctionQuantity FunctionQuantity)
(documentation UnaryConstantFunctionQuantity EnglishLanguage "A
&%subclass of &%FunctionQuantity, instances of which are returned by
&%UnaryFunctions that map from one instance of the &%Class
&%ConstantQuantity to another instance of the &%Class
&%ConstantQuantity.")
(documentation UnaryConstantFunctionQuantity ChineseLanguage "这是 &%FunctionQuantity 的一个
&%subclass,它的实例由 &%UnaryFunction 把 &%ConstantQuantity &%Class 的一个实例联系到
&%ConstantQuantity &%Class 的另一个 实例所产生。")
(subclass TimeDependentQuantity UnaryConstantFunctionQuantity)
(documentation TimeDependentQuantity EnglishLanguage "A
&%UnaryConstantFunctionQuantity of continuous time. All instances of
this &%Class are returned by &%Functions that map a time quantity into
another &%ConstantQuantity such as temperature. For example, 'the
temperature at the top of the Empire State Building' is a
&%TimeDependentQuantity, since its value depends on the time.")
(documentation TimeDependentQuantity ChineseLanguage "这是连续时间的
&%UnaryConstantFunctionQuantity。这个 &%Class 的所有实例都是由 &%Function 把时间和另一个
&%ConstantQuantity 如温度联系来表示的。例如:'在帝国大厦顶的温度‘是一个 &%TimeDependentQuantity,
因为它的值取决于时间。")
(subclass SetOrClass Abstract)
(partition SetOrClass Set Class)
(documentation SetOrClass EnglishLanguage "The &%SetOrClass of &%Sets
and &%Classes, i.e. any instance of &%Abstract that has &%elements or
&%instances.")
(documentation SetOrClass ChineseLanguage "这是 &%Set 和 &%Class 的 &%SetOrClass,也就是说
任何 &%Abstract 有 &%element 或 &%instance的实例。")
;; comment it out to avoid (instance SetOrClass SetOrClass)
;(subclass Class SetOrClass)
(documentation Class EnglishLanguage "&%Classes differ from &%Sets in three important
respects. First, &%Classes are not assumed to be extensional. That is, distinct
&%Classes might well have exactly the same instances. Second, &%Classes typically
have an associated `condition' that determines the instances of the &%Class. So,
for example, the condition `human' determines the &%Class of &%Humans. Note that
some &%Classes might satisfy their own condition (e.g., the &%Class of &%Abstract
things is &%Abstract) and hence be instances of themselves. Third, the instances
of a class may occur only once within the class, i.e. a class cannot contain
duplicate instances.")
(documentation Class ChineseLanguage " &%Class 在三个重要方面与 &%Set 不同:第一,我们不假设
&%Class 为能延伸的,也就是说不同的 &%Class 可能由完全相同的实例。第二,&%Class 通常有一个决定该
&%Class 实例的附带`条件'。所以举例说:`人类' 决定 &%Human 的 &%Class。注:有些 &%Class 可能满足自身
的条件(例如 &%Abstract 东西的 &%Class 是 &%Abstract) 所以它们本身成为实例。 第三:一个类别的实例可能
只在该类别出现一次,也就是输一个泪奔不能拥有重复的实例。")
(subclass Set SetOrClass)
(documentation Set EnglishLanguage "A &%SetOrClass that satisfies extensionality as well
as other constraints specified by some choice of set theory. &%Sets differ
from &%Classes in two important respects. First, &%Sets are extensional -
two &%Sets with the same &%elements are identical. Second, a &%Set can be
an arbitrary stock of objects. That is, there is no requirement that &%Sets
have an associated condition that determines their membership. Note that &%Sets
are not assumed to be unique sets, i.e. &%elements of a &%Set may occur more
than once in the &%Set.")
(documentation Set ChineseLanguage "这是个 &%SetOrClass 能满足延伸性和由集合理论的某些选择所指定
的其他约束。&%Set 在两个重要方面与 &%Classes 不同:第一,&%Sets 是可以延伸的 - 两个拥有一样
&%element 的 &%Set 是相同的。第二,一个 &%Set 可以是一堆随意组成的东西。这就是说 &%Set 不需要具有确定
其成员资格的相关联条件。注:我们并没有假设每个 &%Set 为独一无二的集合,即是说一个 &%Set 的组员可以在那个
&%Set 出现超过一次。")
(subclass Relation Abstract)
(disjointDecomposition Relation BinaryRelation TernaryRelation QuaternaryRelation
QuintaryRelation VariableArityRelation) (partition Relation Predicate Function List)
(partition Relation TotalValuedRelation PartialValuedRelation)
(documentation Relation EnglishLanguage "The &%Class of relations. There are three kinds
of &%Relation: &%Predicate, &%Function, and &%List. &%Predicates and
&%Functions both denote sets of ordered n-tuples. The difference between
these two &%Classes is that &%Predicates cover formula-forming operators, while
&%Functions cover term-forming operators. A &%List, on the other hand, is a
particular ordered n-tuple.")
(documentation Relation ChineseLanguage "这是关系的 &%Class。现有三类的 &%Relation:
&%Predicate, &%Function 和 &%List。 &%Predicate 和&%Function 皆表示有序的n元组集合, 这两个
&%Class 的差别在于 &%Predicate 包括组成公式的运算符,而&%Function 则包括组成 术语的运算符,而一个
&%List 却是一个特定的有序n元组。")
;; The following part of the ontology covers the various classes under
;; 'Relation'. Most of the content here is taken from frame-ontology,
;; abstract-algebra, kif-relations, and kif-extensions (ontologies
;; available on the Ontolingua server).
(subclass SingleValuedRelation Relation)
(subclass SingleValuedRelation InheritableRelation)
(documentation SingleValuedRelation EnglishLanguage "A &%Relation is a
&%SingleValuedRelation just in case an assignment of values to every argument position
except the last one determines at most one assignment for the last argument position.
Note that not all &%SingleValuedRelations are &%TotalValuedRelations.")
(documentation SingleValuedRelation ChineseLanguage "一个 &%Relation是
&%SingleValuedRelation 以确保除了最后一个参数之外,每一个参数的位置只有一个赋值,而最后的参数
顶多可以决定最后一个参数的位置。注:不是所有的 &%SingleValuedRelation 都是 &%TotalValuedRelation。")
;; TODO: this appears to be a syntax error when call replacePredVar in sigma's code
;(=>
; (instance ?REL SingleValuedRelation)
; (forall (@ROW ?ITEM1 ?ITEM2)
; (=>
; (and
; (?REL @ROW ?ITEM1)
; (?REL @ROW ?ITEM2))
; (equal ?ITEM1 ?ITEM2))))
(subclass TotalValuedRelation Relation)
(subclass TotalValuedRelation InheritableRelation)
(documentation TotalValuedRelation EnglishLanguage "A &%Relation is a
&%TotalValuedRelation just in case there exists an assignment for the last argument
position of the &%Relation given any assignment of values to every argument position
except the last one. Note that declaring a &%Relation to be both a &%TotalValuedRelation
and a &%SingleValuedRelation means that it is a total function.")
(documentation TotalValuedRelation ChineseLanguage "一个 &%Relation 是
&%TotalValuedRelation 以防该 &%Relation 最后参数位置出现一个赋值, 假设除了最后一个之外每个参数位置都
有一个赋值。注:声明一个 &%Relation 既是 &%TotalValuedRelation 又是 &%SingleValuedRelation
表示这是一个总函数。")
(<=>
(and
(instance ?REL TotalValuedRelation)
(instance ?REL Predicate))
(exists (?VALENCE)
(and
(instance ?REL Relation)
(valence ?REL ?VALENCE)
(=>
(forall (?NUMBER ?ELEMENT ?CLASS)
(=>
(and
(lessThan ?NUMBER ?VALENCE)
(domain ?REL ?NUMBER ?CLASS)
(equal ?ELEMENT (ListOrderFn (ListFn @ROW) ?NUMBER)))
(instance ?ELEMENT ?CLASS)))
(exists (?ITEM)
(?REL @ROW ?ITEM))))))
(subclass PartialValuedRelation Relation)
(documentation PartialValuedRelation EnglishLanguage "A &%Relation is a &%PartialValuedRelation
just in case it is not a &%TotalValuedRelation, i.e. just in case assigning values
to every argument position except the last one does not necessarily mean that there
is a value assignment for the last argument position. Note that, if a &%Relation
is both a &%PartialValuedRelation and a &%SingleValuedRelation, then it is a partial
function.")
(documentation PartialValuedRelation ChineseLanguage "一个 &%Relation 是
&%PartialValuedRelation 是为了确保它不是一个 &%TotalValuedRelation,也就是说除了最后一个之外给每一个
参数位置分配一个值,但这不一定等于已经为最后一个参数位置设定赋值。注:如果一个 &%Relation既是
&%PartialValuedRelation 又是 &%SingleValuedRelation的话,那么它就是一个部分函数。")
(subclass BinaryRelation Relation)
(subclass BinaryRelation InheritableRelation)
(documentation BinaryRelation EnglishLanguage "&%BinaryRelations are relations that are
true only of pairs of things. &%BinaryRelations are represented as slots
in frame systems.")
(documentation BinaryRelation ChineseLanguage " &%BinaryRelation 是只有在关系联系两样东西的时候
才算是真,框架理论以槽代表 &%BinaryRelation。")
(subclass ReflexiveRelation BinaryRelation)
(documentation ReflexiveRelation EnglishLanguage "&%Relation ?REL is reflexive iff
(?REL ?INST ?INST) for all ?INST.")
(documentation ReflexiveRelation ChineseLanguage "&%Relation ?REL 属于自反关系当且仅当所有
?INST 都是(?REL ?INST ?INST)。")
;; appear to be a contradiction when ?REL = subclass
;;(<=>
;; (instance ?REL ReflexiveRelation)
;; (?REL ?INST ?INST))
(subclass IrreflexiveRelation BinaryRelation)
(documentation IrreflexiveRelation EnglishLanguage "&%Relation ?REL is irreflexive
iff (?REL ?INST ?INST) holds for no value of ?INST.")
(documentation IrreflexiveRelation ChineseLanguage "&%Relation ?REL 属于非自反关系当且仅当没有
一个?INST 是(?REL ?INST ?INST)。")
(=>
(instance ?REL IrreflexiveRelation)
(forall (?INST)
(not
(?REL ?INST ?INST))))
(subclass SymmetricRelation BinaryRelation)
(disjoint SymmetricRelation AntisymmetricRelation)
(documentation SymmetricRelation EnglishLanguage "A &%BinaryRelation ?REL is
symmetric just iff (?REL ?INST1 ?INST2) imples (?REL
?INST2 ?INST1), for all ?INST1 and ?INST2.")
(documentation SymmetricRelation ChineseLanguage "一个 &%BinaryRelation ?REL 属于对称关系只是
当且仅当所有的 ?INST1 和 ?INST2 是 (?REL ?INST1 ?INST2) 意味着 (?REL ?INST2 ?INST1)。")
(=>
(instance ?REL SymmetricRelation)
(forall (?INST1 ?INST2)
(=>
(?REL ?INST1 ?INST2)
(?REL ?INST2 ?INST1))))
(subclass AsymmetricRelation IrreflexiveRelation)
(subclass AsymmetricRelation AntisymmetricRelation)
(documentation AsymmetricRelation EnglishLanguage "A &%BinaryRelation is asymmetric if and
only if it is both an &%AntisymmetricRelation and an &%IrreflexiveRelation.")
(documentation AsymmetricRelation ChineseLanguage "一个 &%BinaryRelation 属于不对称关系
当且仅当它既是一个 &%AntisymmetricRelation 又是一个 &%IrreflexiveRelation。")
(<=>
(instance ?REL AsymmetricRelation)
(and
(instance ?REL AntisymmetricRelation)
(instance ?REL IrreflexiveRelation)))
(subclass AntisymmetricRelation BinaryRelation)
(documentation AntisymmetricRelation EnglishLanguage "&%BinaryRelation ?REL is an
&%AntisymmetricRelation if for distinct ?INST1 and ?INST2, (?REL ?INST1
?INST2) implies not (?REL ?INST2 ?INST1). In other words, for all ?INST1
and ?INST2, (?REL ?INST1 ?INST2) and (?REL ?INST2 ?INST1) imply that ?INST1
and ?INST2 are identical. Note that it is possible for an
&%AntisymmetricRelation to be a &%ReflexiveRelation.")
(documentation AntisymmetricRelation ChineseLanguage "一个 &%BinaryRelation ?REL 是
&%AntisymmetricRelation 如果不同的 ?INST1 和 ?INST2 是(?REL ?INST1 ?INST2) 不意味着
(?REL ?INST2 ?INST1)。也就是说当所有的 ?INST1 和 ?INST2 是 (?REL ?INST1 ?INST2)和
(?REL ?INST2 ?INST1) 意味着 ?INST1 和 ?INST2 是相同的。注:一个&%AntisymmetricRelation 有可能
是一个 &%ReflexiveRelation。")
(=>
(instance ?REL AntisymmetricRelation)
(forall (?INST1 ?INST2)
(=>
(and
(?REL ?INST1 ?INST2)
(?REL ?INST2 ?INST1))
(equal ?INST1 ?INST2))))
(subclass TrichotomizingRelation BinaryRelation)
(documentation TrichotomizingRelation EnglishLanguage "A &%BinaryRelation ?REL is a
&%TrichotomizingRelation just in case all ordered pairs consisting of
distinct individuals are elements of ?REL.")
(documentation TrichotomizingRelation ChineseLanguage "一个 &%BinaryRelation ?REL 是
&%TrichotomizingRelation 万一所有有序的一对东西出现 ?REL 元素的不同个体。")
(=>
(instance ?REL TrichotomizingRelation)
(forall (?INST1 ?INST2)
(or
(and
(?REL ?INST1 ?INST2)
(not (equal ?INST1 ?INST2))
(not (?REL ?INST2 ?INST1)))
(and
(not (?REL ?INST1 ?INST2))
(equal ?INST1 ?INST2)
(not (?REL ?INST2 ?INST1)))
(and
(not (?REL ?INST1 ?INST2))
(not (equal ?INST1 ?INST2))
(?REL ?INST2 ?INST1)))))
(subclass TransitiveRelation BinaryRelation)
(disjoint TransitiveRelation IntransitiveRelation)
(documentation TransitiveRelation EnglishLanguage "A &%BinaryRelation ?REL is transitive
if (?REL ?INST1 ?INST2) and (?REL ?INST2 ?INST3) imply (?REL ?INST1 ?INST3),
for all ?INST1, ?INST2, and ?INST3.")
(documentation TransitiveRelation ChineseLanguage "一个 &%BinaryRelation ?REL 是传递关系
如果所有的 ?INST1, ?INST2和 ?INST3 是(?REL ?INST1 ?INST2) 和 (?REL ?INST2 ?INST3) 意味着
(?REL ?INST1 ?INST3)。")
(=>
(instance ?REL TransitiveRelation)
(forall (?INST1 ?INST2 ?INST3)
(=>
(and
(?REL ?INST1 ?INST2)
(?REL ?INST2 ?INST3))
(?REL ?INST1 ?INST3))))
(subclass IntransitiveRelation BinaryRelation)
(documentation IntransitiveRelation EnglishLanguage "A &%BinaryRelation ?REL is
intransitive only if (?REL ?INST1 ?INST2) and (?REL ?INST2 ?INST3) imply not
(?REL ?INST1 ?INST3), for all ?INST1, ?INST2, and ?INST3.")
(documentation IntransitiveRelation ChineseLanguage "野葛 &%BinaryRelation ?REL 是非传递关系
除非所有的 ?INST1, ?INST2 和 ?INST3 是 (?REL ?INST1 ?INST2) 和 (?REL ?INST2 ?INST3)不意味着
(?REL ?INST1 ?INST3)。")
(=>
(instance ?REL IntransitiveRelation)
(forall (?INST1 ?INST2 ?INST3)
(=>
(and
(?REL ?INST1 ?INST2)
(?REL ?INST2 ?INST3))
(not
(?REL ?INST1 ?INST3)))))
(subclass PartialOrderingRelation TransitiveRelation)
(subclass PartialOrderingRelation AntisymmetricRelation)
(subclass PartialOrderingRelation ReflexiveRelation)
(subclass PartialOrderingRelation TotalValuedRelation)
(documentation PartialOrderingRelation EnglishLanguage "A &%BinaryRelation is a partial
ordering if it is a &%ReflexiveRelation, an &%AntisymmetricRelation, and
a &%TransitiveRelation.")
(documentation PartialOrderingRelation ChineseLanguage "一个 &%BinaryRelation 属于部分顺序
关系如果它是一个 &%ReflexiveRelation、 &%AntisymmetricRelation 和 &%TransitiveRelation。")
(subclass TotalOrderingRelation PartialOrderingRelation)
(subclass TotalOrderingRelation TrichotomizingRelation)
(documentation TotalOrderingRelation EnglishLanguage "A &%BinaryRelation is a
&%TotalOrderingRelation if it is a &%PartialOrderingRelation
and a &%TrichotomizingRelation.")
(documentation TotalOrderingRelation ChineseLanguage "一个 &%BinaryRelation 是
&%TotalOrderingRelation 如果它是一个 &%PartialOrderingRelation和 &%TrichotomizingRelation。")
(=>
(instance ?REL TotalOrderingRelation)
(forall (?INST1 ?INST2)
(and
(or
(?REL ?INST1 ?INST2)
(?REL ?INST2 ?INST1))
(or
(not (?REL ?INST1 ?INST2))
(not (?REL ?INST2 ?INST1))))))
(subclass EquivalenceRelation TransitiveRelation)
(subclass EquivalenceRelation SymmetricRelation)
(subclass EquivalenceRelation ReflexiveRelation)
(documentation EquivalenceRelation EnglishLanguage "A &%BinaryRelation is an equivalence
relation if it is a &%ReflexiveRelation, a &%SymmetricRelation, and a
&%TransitiveRelation.")
(documentation EquivalenceRelation ChineseLanguage "一个 &%BinaryRelation 是等价关系如果它是
一个 &%ReflexiveRelation、 &%SymmetricRelation 和&%TransitiveRelation。")
(subclass CaseRole BinaryPredicate)
(subclass CaseRole InheritableRelation)
(subclass CaseRole AsymmetricRelation)
(documentation CaseRole EnglishLanguage "The &%Class of &%Predicates relating the
spatially distinguished parts of a &%Process. &%CaseRoles include, for
example, the &%agent, &%patient or &%destination of an action, the flammable
substance in a burning process, or the water that falls in rain.")
(documentation CaseRole ChineseLanguage "这是一个 &%Predicate 的 &%Class, 它把 &%Process
中可以从空间上区别的部分联系起来。 &%CaseRole 包括 &%agent、 &%patient 或行动的 &%destination
这些例子、燃烧过程中的易燃物质,或是降雨过程中的雨水。")
(documentation involvedInEvent EnglishLanguage "(involvedInEvent ?EVENT ?THING) means
that in the &%Process ?EVENT, the &%Entity ?THING plays some &%CaseRole.")
(documentation involvedInEvent ChineseLanguage "(involvedInEvent ?EVENT ?THING) 的意思是
在 ?EVENT这个 &%Process,?THING 这个 &%Entity 佔着一点 &%CaseRole。")
(instance involvedInEvent BinaryPredicate)
(instance involvedInEvent AsymmetricRelation)
(domain involvedInEvent 1 Process)
(domain involvedInEvent 2 Entity)
; AP - this axiom below seems questionable, what about relations we just haven't
; "discovered" yet.
;(=>
; (involvedInEvent ?E ?T)
; (exists (?R)
; (and
; (instance ?R CaseRole)
; (subrelation ?R involvedInEvent)
; (?R ?E ?T))))
(=>
(instance ?R CaseRole)
(subrelation ?R involvedInEvent))
(instance agent CaseRole)
(instance agent PartialValuedRelation)
(domain agent 1 Process)
(domain agent 2 Agent)
(subrelation agent involvedInEvent)
(documentation agent EnglishLanguage "(&%agent ?PROCESS ?AGENT) means that ?AGENT is
an active determinant, either animate or inanimate, of the &%Process
?PROCESS, with or without voluntary intention. For example, Eve is an
&%agent in the following proposition: Eve bit an apple.")
(documentation agent ChineseLanguage "(&%agent ?PROCESS ?AGENT) 的意思是 ?AGENT,不管它
有没有生命,也不管他有没有自主意图,它在 ?PROCESS 这个 &%Process 中是一个主动的决定因素。例如:在以下
'夏娃咬了一口苹果'这命题中,夏娃是个 &%agent。")
(instance destination CaseRole)
(instance destination PartialValuedRelation)
(domain destination 1 Process)
(domain destination 2 Entity)
(subrelation destination involvedInEvent)
(documentation destination EnglishLanguage "(destination ?PROCESS ?GOAL) means that
?GOAL is the target or goal of the Process ?PROCESS. For example,
Danbury would be the destination in the following proposition: Bob went
to Danbury. Note that this is a very general &%CaseRole and, in
particular, that it covers the concepts of 'recipient' and 'beneficiary'.
Thus, John would be the &%destination in the following proposition:
Tom gave a book to John.")
(documentation destination ChineseLanguage "(destination ?PROCESS ?GOAL) 的意思是
?GOAL 是 ?PROCESS 过程的目标或目的。例如:在以下'鲍勃去了丹伯里'这命题中,鲍勃会是终点。注:这是一个
非常概括的 &%CaseRole, 而特别是它包括'接受者' 和 '受益者'这两个概念,故此,在以下
'汤姆给了约翰一本书'这命题中,约翰会是 &%destination。")
(instance experiencer CaseRole)
(instance experiencer PartialValuedRelation)
(domain experiencer 1 Process)
(domain experiencer 2 Agent)
(subrelation experiencer involvedInEvent)
(documentation experiencer EnglishLanguage "(&%experiencer ?PROCESS ?AGENT) means
that ?AGENT experiences the &%Process ?PROCESS. For example, Yojo
is the &%experiencer of seeing in the following proposition: Yojo
sees the fish. Note that &%experiencer, unlike &%agent, does
not entail a causal relation between its arguments.")
(documentation experiencer ChineseLanguage "(&%experiencer ?PROCESS ?AGENT) 的意思是
?AGENT 在经历 ?PROCESS 这个 &%Process。 例如:在以下'佑舟看见哪尾鱼'这命题,佑舟是看见这过程的
&%experiencer。注: &%experiencer 不像 &%agent,参数之间并不需要含有因果关系。")
(subrelation instrument patient)
(instance instrument CaseRole)
(instance instrument PartialValuedRelation)
(domain instrument 1 Process)
(domain instrument 2 Object)
(documentation instrument EnglishLanguage "(instrument ?EVENT ?TOOL) means that ?TOOL
is used by an agent in bringing about ?EVENT and that ?TOOL is not
changed by ?EVENT. For example, the key is an &%instrument in the
following proposition: The key opened the door. Note that &%instrument
and &%resource cannot be satisfied by the same ordered pair.")
(documentation instrument ChineseLanguage "(instrument ?EVENT ?TOOL) 的意思是
?TOOL 是主事者令?EVENT 发生的工具,而且 ?TOOL 并没受到 ?EVENT 的改变。例如:在以下'哪钥匙把门打开了'
这命题,钥匙是个 &%instrument。 注:&%instrument 和 &%resource 这两个参数不可以用同一对的顺序来
表示。 ")
(instance origin CaseRole)
(instance origin PartialValuedRelation)
(domain origin 1 Process)
(domain origin 2 Object)
(subrelation origin involvedInEvent)
(documentation origin EnglishLanguage "(&%origin ?PROCESS ?SOURCE) means that ?SOURCE
indicates where the ?Process began. Note that this relation implies
that ?SOURCE is present at the beginning of the process, but need not
participate throughout the process. For example, the submarine is the
&%origin in the following proposition: the missile was launched from a
submarine.")
(documentation origin ChineseLanguage "(&%origin ?PROCESS ?SOURCE) 的意思是
?SOURCE 指出 ?Process 从哪开始。注:这个关系意味着 ?SOURCE 在过程开始时是存在的,但是它不一定有参与
整个过程中。例如:在以下'导弹是从潜艇发射的'这命题,潜艇是个 &%origin。")
(instance patient CaseRole)
(instance patient PartialValuedRelation)
(domain patient 1 Process)
(domain patient 2 Entity)
(subrelation patient involvedInEvent)
(documentation patient EnglishLanguage "(&%patient ?PROCESS ?ENTITY) means that ?ENTITY
is a participant in ?PROCESS that may be moved, said, experienced, etc.
For example, the direct objects in the sentences 'The cat swallowed the
canary' and 'Billy likes the beer' would be examples of &%patients. Note
that the &%patient of a &%Process may or may not undergo structural
change as a result of the &%Process. The &%CaseRole of &%patient is used
when one wants to specify as broadly as possible the object of a
&%Process.")
(documentation patient ChineseLanguage "(&%patient ?PROCESS ?ENTITY) 的意思是 ?ENTITY
是 ?PROCESS 中一个可以被搬动、被告诉和能体验等的参与者。例如:在'那只猫吞掉了那只金丝雀'和'比利喜欢这啤酒'
的直接受事体会是 &%patient 的例子。注:一个&%Process 的 &%patient 可能会也可能不会因为该 &%Process
而经历结构上的变化。用 &%patient 这个 &%CaseRole 是当我们想尽可能以最广泛的代表来 要指出 &%Process
的受事体。")
(subrelation resource patient)
(instance resource CaseRole)
(instance resource PartialValuedRelation)
(domain resource 1 Process)
(domain resource 2 Object)
(disjointRelation resource result)
(disjointRelation resource instrument)
(disjointRelation result instrument)
(documentation resource EnglishLanguage "(&%resource ?PROCESS ?RESOURCE) means that
?RESOURCE is present at the beginning of ?PROCESS, is used by ?PROCESS,
and as a consequence is changed by ?PROCESS. For example, soap is a
&%resource in the following proposition: the gun was carved out of soap.
Note that &%resource differs from &%instrument, another subrelation of
&%patient, in that its internal or physical properties are altered in
some way by the &%Process.")
(documentation resource ChineseLanguage "(&%resource ?PROCESS ?RESOURCE) 的意思是
?RESOURCE 在 ?PROCESS 开始时存在、?PROCESS 利用了他、结果它受到 ?PROCESS 的改变。例如:
在以下'这枪是用肥皂雕刻出来的'这命题,肥皂是个 &%resource。注:
&%resource 和 &%patient 的另外一个自关系 &%instrument 不同的地方在于,资源的内在或物理特性在某方面
收到了 &%Process 的改变。")
(documentation resourceExhausted EnglishLanguage "(&%resourceExhausted ?PROCESS ?RESOURCE) means that ?RESOURCE is present at the beginning of ?PROCESS, is used by ?PROCESS, and as a consequence is completely used up by the ?PROCESS. For example, fuel is a
&%resourceExhausted in the following proposition: the plane run out of fuel and ditched in the sea.")
(documentation resourceExhausted ChineseLanguage "(&%resourceExhausted ?PROCESS ?RESOURCE)
的意思是 ?RESOURCE 在 ?PROCESS 开始时存在、?PROCESS 利用了他、结果它完全被 ?PROCESS 消耗掉了。例如:
在以下'那飞机的燃料耗尽了,就丢到大海里了'这命题,燃料是个 &%resourceExhausted。")
(domain resourceExhausted 1 Process)
(domain resourceExhausted 2 Object)
(instance resourceExhausted CaseRole)
(instance resourceExhausted AsymmetricRelation)
(instance resourceExhausted BinaryPredicate)
(instance resourceExhausted PartialValuedRelation)
(=>
(and
(resourceExhausted ?P ?R)
(instance ?R ?C))
(holdsDuring (ImmediateFutureFn (WhenFn ?P))
(not
(exists (?OBJ1)
(and
(part ?OBJ1 ?R)
(instance ?OBJ1 ?C))))))
(subrelation result patient)
(instance result CaseRole)
(instance result PartialValuedRelation)
(domain result 1 Process)
(domain result 2 Entity)
(documentation result EnglishLanguage "(result ?ACTION ?OUTPUT) means that ?OUTPUT is
a product of ?ACTION. For example, house is a &%result in the
following proposition: Eric built a house.")
(documentation result ChineseLanguage "(result ?ACTION ?OUTPUT)的意思是 ?OUTPUT 是 ?ACTION
的产品。例如:在以下'埃里克建了一栋房子'这命题,房子是个 &%result。")
(subclass InheritableRelation Relation)
(documentation InheritableRelation EnglishLanguage "The class of &%Relations whose
properties can be inherited downward in the class hierarchy via the
&%subrelation &%Predicate.")
(documentation InheritableRelation ChineseLanguage "这是一个 &%Relation 类别,它的特性可以是
通过 &%subrelation &%Predicate 把特性在类别的层次结构承传下去。")
(subclass ProbabilityRelation Relation)
(subclass ProbabilityRelation InheritableRelation)
(documentation ProbabilityRelation EnglishLanguage "The &%Class of &%Relations that
permit assessment of the probability of an event or situation.")
(documentation ProbabilityRelation ChineseLanguage "这是一个 &%Relation 类别,它允许评估事件
或情况出现的机率。")
(instance ProbabilityFn ProbabilityRelation)
(instance ProbabilityFn TotalValuedRelation)
(instance ProbabilityFn UnaryFunction)
(domain ProbabilityFn 1 Formula)
(range ProbabilityFn RealNumber)
(instance ProbabilityFn AsymmetricRelation)
(documentation ProbabilityFn EnglishLanguage "One of the basic &%ProbabilityRelations,
&%ProbabilityFn is used to state the a priori probability of a state of
affairs. (&%ProbabilityFn ?FORMULA) denotes the a priori probability
of ?FORMULA.")
(documentation ProbabilityFn ChineseLanguage "这是其中一个基本的 &%ProbabilityRelation,
&%ProbabilityFn 是用来描述事态的先验机率。(&%ProbabilityFn ?FORMULA)表示 ?FORMULA 的先验机率。")
(instance conditionalProbability ProbabilityRelation)
(instance conditionalProbability TernaryPredicate)
(domain conditionalProbability 1 Formula)
(domain conditionalProbability 2 Formula)
(domain conditionalProbability 3 RealNumber)
(documentation conditionalProbability EnglishLanguage "One of the basic &%ProbabilityRelations.
&%conditionalProbability is used to state the numeric value of a conditional
probability. (&%conditionalProbability ?FORMULA1 ?FORMULA2 ?NUMBER) means
that the probability of ?FORMULA2 being true given that ?FORMULA1 is true is
?NUMBER.")
(documentation conditionalProbability ChineseLanguage "这是其中一个基本的
&%ProbabilityRelations,&%conditionalProbability 是用来描述一个条件机率的数值。
(&%conditionalProbability ?FORMULA1 ?FORMULA2 ?NUMBER) 的意思是,如果 ?FORMULA1 属真,那么
?FORMULA2 会是真,它出现的机率会是?NUMBER。")
(instance increasesLikelihood ProbabilityRelation)
(instance increasesLikelihood BinaryPredicate)
(instance increasesLikelihood IrreflexiveRelation)
(domain increasesLikelihood 1 Formula)
(domain increasesLikelihood 2 Formula)
(disjointRelation increasesLikelihood decreasesLikelihood)
(disjointRelation increasesLikelihood independentProbability)
(disjointRelation decreasesLikelihood independentProbability)
(documentation increasesLikelihood EnglishLanguage "One of the basic &%ProbabilityRelations.
(&%increasesLikelihood ?FORMULA1 ?FORMULA2) means that ?FORMULA2 is more
likely to be true if ?FORMULA1 is true.")
(documentation increasesLikelihood ChineseLanguage "这是其中一个基本的 &%ProbabilityRelation,
(&%increasesLikelihood ?FORMULA1 ?FORMULA2)的意思是如果 ?FORMULA1 属真,那么 ?FORMULA2 更有
可能会是真的。")
(=>
(and
(increasesLikelihood ?FORMULA1 ?FORMULA2)
(equal (ProbabilityFn ?FORMULA2) ?NUMBER1)
(conditionalProbability ?FORMULA1 ?FORMULA2 ?NUMBER2))
(greaterThan ?NUMBER2 ?NUMBER1))
(instance decreasesLikelihood ProbabilityRelation)
(instance decreasesLikelihood BinaryPredicate)
(instance decreasesLikelihood IrreflexiveRelation)
(domain decreasesLikelihood 1 Formula)
(domain decreasesLikelihood 2 Formula)
(documentation decreasesLikelihood EnglishLanguage "One of the basic &%ProbabilityRelations.
(&%decreasesLikelihood ?FORMULA1 ?FORMULA2) means that ?FORMULA2 is less
likely to be true if ?FORMULA1 is true.")
(documentation decreasesLikelihood ChineseLanguage "这是其中一个基本的 &%ProbabilityRelation,
(&%decreasesLikelihood ?FORMULA1 ?FORMULA2)的意思是如果 ?FORMULA1 属真,那么 ?FORMULA2 不太
可能会是真的。")
(=>
(and
(decreasesLikelihood ?FORMULA1 ?FORMULA2)
(equal (ProbabilityFn ?FORMULA2) ?NUMBER1)
(conditionalProbability ?FORMULA1 ?FORMULA2 ?NUMBER2))
(lessThan ?NUMBER2 ?NUMBER1))
(instance independentProbability ProbabilityRelation)
(instance independentProbability BinaryPredicate)
(instance independentProbability SymmetricRelation)
(domain independentProbability 1 Formula)
(domain independentProbability 2 Formula)
(documentation independentProbability EnglishLanguage "One of the basic &%ProbabilityRelations.
(&%independentProbability ?FORMULA1 ?FORMULA2) means that the probabilities of
?FORMULA1 and ?FORMULA2 being true are independent.")
(documentation independentProbability ChineseLanguage "这是其中一个基本的
&%ProbabilityRelation,(&%independentProbability ?FORMULA1 ?FORMULA2) 的意思是
?FORMULA1 和 ?FORMULA2 属真机率是独立的。")
(=>
(and
(independentProbability ?FORMULA1 ?FORMULA2)
(equal (ProbabilityFn ?FORMULA2) ?NUMBER1)
(conditionalProbability ?FORMULA1 ?FORMULA2 ?NUMBER2))
(equal ?NUMBER2 ?NUMBER1))
(=>
(and
(instance ?FORMULA1 Formula)
(instance ?FORMULA2 Formula))
(or
(increasesLikelihood ?FORMULA1 ?FORMULA2)
(decreasesLikelihood ?FORMULA1 ?FORMULA2)
(independentProbability ?FORMULA1 ?FORMULA2)))
(subclass SpatialRelation Relation)
(subclass SpatialRelation InheritableRelation)
(documentation SpatialRelation EnglishLanguage "The &%Class of &%Relations that are
spatial in a wide sense. This &%Class includes mereological relations
and topological relations.")
(documentation SpatialRelation ChineseLanguage "这是一个广义的空间 &%Relation &%Class,这个
&%Class 包括分体论关系和拓扑关系。")
(subclass TemporalRelation Relation)
(subclass TemporalRelation InheritableRelation)
(documentation TemporalRelation EnglishLanguage "The &%Class of temporal &%Relations.
This &%Class includes notions of (temporal) topology of intervals,
(temporal) schemata, and (temporal) extension.")
(documentation TemporalRelation ChineseLanguage "这是时间 &%Relation 的 &%Class,这个 &%Class
包括间隔拓扑的(时间)概念、(时间)模式和(时间)延伸。")
(subclass IntentionalRelation InheritableRelation)
(subclass IntentionalRelation Relation)
(documentation IntentionalRelation EnglishLanguage "The &%Class of &%Relations between
an &%Agent and one or more &%Entities, where the &%Relation requires that
the &%Agent have awareness of the &%Entity.")
(documentation IntentionalRelation ChineseLanguage "这是 &%Agent 和一个或以上的 &%Entity 之间
的 &%Relation &%Class,这个 &%Relation 要求 &%Agent 对 &%Entity 有认知。")
(=>
(and
(instance ?REL IntentionalRelation)
(?REL ?AGENT @ROW)
(inList ?OBJ (ListFn @ROW)))
(inScopeOfInterest ?AGENT ?OBJ))
(instance prefers TernaryPredicate)
(instance prefers IntentionalRelation)
(domain prefers 1 CognitiveAgent)
(domain prefers 2 Formula)
(domain prefers 3 Formula)
(documentation prefers EnglishLanguage "(&%prefers ?AGENT ?FORMULA1 ?FORMULA2) means that
&%CognitiveAgent ?AGENT prefers the state of affairs expressed by ?FORMULA1
over the state of affairs expressed by ?FORMULA2 all things being equal.")
(documentation prefers ChineseLanguage "(&%prefers ?AGENT ?FORMULA1 ?FORMULA2) 的意思是
在所有条件相同的情况下, &%CognitiveAgent ?AGENT 喜欢 ?FORMULA1 所描述的事态多于 ?FORMULA2 所描述
的事态。 ")
(subclass PropositionalAttitude IntentionalRelation)
(subclass PropositionalAttitude AsymmetricRelation)
(subclass PropositionalAttitude InheritableRelation)
(documentation PropositionalAttitude EnglishLanguage "The &%Class of
&%IntentionalRelations where the &%Agent has awareness of a
&%Proposition.")
(documentation PropositionalAttitude ChineseLanguage "这是一个 &%IntentionalRelation
&%Class,它的 &%Agent 对 &%Proposition 有认知。")
(=>
(and
(instance ?REL PropositionalAttitude)
(?REL ?AGENT ?FORMULA))
(instance ?FORMULA Formula))
(subclass ObjectAttitude IntentionalRelation)
(subclass ObjectAttitude InheritableRelation)
(disjoint ObjectAttitude PropositionalAttitude)
(documentation ObjectAttitude EnglishLanguage "The &%Class of &%IntentionalRelations
where the &%Agent has awareness of an instance of &%Physical.")
(documentation ObjectAttitude ChineseLanguage "这是一个 &%IntentionalRelation
&%Class,它的 &%Agent 对 &%Physical 的实例有认知。")
(=>
(and
(instance ?REL ObjectAttitude)
(?REL ?AGENT ?THING))
(instance ?THING Physical))
(instance inScopeOfInterest BinaryPredicate)
(instance inScopeOfInterest IntentionalRelation)
(domain inScopeOfInterest 1 CognitiveAgent)
(domain inScopeOfInterest 2 Entity)
(documentation inScopeOfInterest EnglishLanguage "A very general &%Predicate.
(&%inScopeOfInterest ?AGENT ?ENTITY) means that ?ENTITY is within the
scope of interest of ?AGENT. Note that the interest indicated can be
either positive or negative, i.e. the ?AGENT can have an interest in
avoiding or promoting ?ENTITY.")
(documentation inScopeOfInterest ChineseLanguage "这是一个十分笼统的 &%Predicate,
(&%inScopeOfInterest ?AGENT ?ENTITY) 的意思是 ?ENTITY 在 ?AGENT 的留意范围之内。注:这注意可以是
正面或负面的,也就是说 ?AGENT 可以是有意图要避开或是推荐 ?ENTITY。")
(<=>
(exists (?PROCESS)
(and
(instance ?PROCESS IntentionalProcess)
(agent ?PROCESS ?AGENT)
(instance ?AGENT CognitiveAgent)
(patient ?PROCESS ?OBJECT)))
(inScopeOfInterest ?AGENT ?OBJECT))
(instance needs ObjectAttitude)
(instance needs BinaryPredicate)
(subrelation needs inScopeOfInterest)
(domain needs 1 CognitiveAgent)
(domain needs 2 Physical)
(documentation needs EnglishLanguage "(&%needs ?AGENT ?OBJECT) means that ?OBJECT is
physically required for the continued existence of ?AGENT.")
(documentation needs ChineseLanguage "(&%needs ?AGENT ?OBJECT) 的意思是 ?AGENT的继续存在物质上
需要 ?OBJECT。")
(=>
(needs ?AGENT ?OBJECT)
(wants ?AGENT ?OBJECT))
(instance wants ObjectAttitude)
(instance wants BinaryPredicate)
(subrelation wants inScopeOfInterest)
(relatedInternalConcept wants desires)
(domain wants 1 CognitiveAgent)
(domain wants 2 Physical)
(documentation wants EnglishLanguage "(&%wants ?AGENT ?OBJECT) means that ?OBJECT is desired by ?AGENT,
i.e. ?AGENT believes that ?OBJECT will satisfy one of its goals. Note that there is
no implication that what is wanted by an agent is not already possessed by the agent.")
(documentation wants ChineseLanguage "(&%wants ?AGENT ?OBJECT) 的意思是 ?AGENT 想要 ?OBJECT,
也就是说 ?AGENT 相信 ?OBJECT 会满足它其中一个的意愿。 注:这并不意味着施事体没有它所想要的东西。")
(=>
(wants ?AGENT ?OBJ)
(exists (?PURP)
(hasPurposeForAgent ?OBJ ?PURP ?AGENT)))
(=>
(and
(wants ?AGENT ?OBJ)
(instance ?OBJ Object))
(desires ?AGENT
(possesses ?AGENT ?OBJ)))
(instance desires PropositionalAttitude)
(instance desires BinaryPredicate)
(subrelation desires inScopeOfInterest)
(relatedInternalConcept desires wants)
(domain desires 1 CognitiveAgent)
(domain desires 2 Formula)
(documentation desires EnglishLanguage "(&%desires ?AGENT ?FORMULA) means that ?AGENT wants
to bring about the state of affairs expressed by ?FORMULA. Note that there
is no implication that what is desired by the agent is not already true.
Note too that &%desires is distinguished from &%wants only in that the former
is a &%PropositionalAttitude, while &%wants is an &%ObjectAttitude.")
(documentation desires ChineseLanguage "(&%desires ?AGENT ?FORMULA) 的意思是 ?AGENT 想要
实现 ?FORMULA 所表达的事态。注:这并不意味着施事体想要的东西不能成真。另外要注意的是 &%desires 和
&%wants 的区别只在于前者是一个 &%PropositionalAttitude, 而 &%wants 是一个 &%ObjectAttitude。")
(instance considers PropositionalAttitude)
(instance considers BinaryPredicate)
(subrelation considers inScopeOfInterest)
(domain considers 1 CognitiveAgent)
(domain considers 2 Formula)
(documentation considers EnglishLanguage "(&%considers ?AGENT ?FORMULA) means that ?AGENT
considers or wonders about the truth of the proposition expressed by
?FORMULA.")
(documentation considers ChineseLanguage "(&%considers ?AGENT ?FORMULA) 的意思是 ?AGENT 在
考虑或怀疑 ?FORMULA 所表达的命题是否真实。")
(instance believes PropositionalAttitude)
(instance believes BinaryPredicate)
(subrelation believes inScopeOfInterest)
(domain believes 1 CognitiveAgent)
(domain believes 2 Formula)
(documentation believes EnglishLanguage "The epistemic predicate of belief.
(&%believes ?AGENT ?FORMULA) means that ?AGENT believes the proposition
expressed by ?FORMULA.")
(documentation believes ChineseLanguage "这是信念的知识谓词,(&%believes ?AGENT ?FORMULA)的
意思是 ?AGENT 相信 ?FORMULA 所表达的命题。")
(=>
(believes ?AGENT ?FORMULA)
(exists (?TIME)
(holdsDuring ?TIME (considers ?AGENT ?FORMULA))))
(instance knows PropositionalAttitude)
(instance knows BinaryPredicate)
(subrelation knows inScopeOfInterest)
(domain knows 1 CognitiveAgent)
(domain knows 2 Formula)
(documentation knows EnglishLanguage "The epistemic predicate of knowing. (&%knows
?AGENT ?FORMULA) means that ?AGENT knows the proposition expressed by
?FORMULA. Note that &%knows entails conscious awareness, so this
&%Predicate cannot be used to express tacit or subconscious or
unconscious knowledge.")
(documentation knows ChineseLanguage "这是认识的知识谓词, (&%knows ?AGENT ?FORMULA) 的意思是
?AGENT 认识 ?FORMULA 所表达的命题。 注:&%knows 意味着有意识的认知,因此这个 &%Predicate 不能够用来
表达沉默或无意识的知识。")
(=>
(knows ?AGENT ?FORMULA)
(believes ?AGENT ?FORMULA))
(=>
(knows ?AGENT ?FORMULA)
(truth ?FORMULA True))
(subclass TernaryRelation Relation)
(subclass TernaryRelation InheritableRelation)
(documentation TernaryRelation EnglishLanguage "&%TernaryRelations relate three items.
The two &%subclasses of &%TernaryRelation are &%TernaryPredicate and
&%BinaryFunction.")
(documentation TernaryRelation ChineseLanguage "&%TernaryRelation 连接三个项目,
&%TernaryRelation 的两个 &%subclass 是 &%TernaryPredicate 和 &%BinaryFunction。")
(subclass QuaternaryRelation Relation)
(subclass QuaternaryRelation InheritableRelation)
(documentation QuaternaryRelation EnglishLanguage "&%QuaternaryRelations relate four
items. The two &%subclasses of &%QuaternaryRelation are
&%QuaternaryPredicate and &%TernaryFunction.")
(documentation QuaternaryRelation ChineseLanguage "&%QuaternaryRelation 连接四个项目。
&%QuaternaryRelation 的两个 &%subclass 是 &%QuaternaryPredicate 和 &%TernaryFunction。")
(subclass QuintaryRelation Relation)
(subclass QuintaryRelation InheritableRelation)
(documentation QuintaryRelation EnglishLanguage "&%QuintaryRelations relate five items.
The two &%subclasses of &%QuintaryRelation are &%QuintaryPredicate and
&%QuaternaryFunction.")
(documentation QuintaryRelation ChineseLanguage "&%QuintaryRelation 连接物个项目。
&%QuintaryRelation 的两个 &%subclass 是 &%QuintaryPredicate 和 &%QuaternaryFunction。")
(subclass List Relation)
(documentation List EnglishLanguage "Every &%List is a particular ordered n-tuple of
items. Generally speaking, &%Lists are created by means of the &%ListFn
&%Function, which takes any number of items as arguments and returns a
&%List with the items in the same order. Anything, including other
&%Lists, may be an item in a &%List. Note too that &%Lists are
extensional - two lists that have the same items in the same order are
identical. Note too that a &%List may contain no items. In that case,
the &%List is the &%NullList.")
(documentation List ChineseLanguage "每个 &%List 是项目一个独特有序的n元组。 一般来说,&%List
是由 &%ListFn &%Function 来造成的,它可以接受任何数量的参数,然后交出一个有相同顺序项目的 &%List。
任何东西,包括其它的 &%List 都可以是一个 &%List 的项目。注:&%List 是可以延伸的 - 两个含有相同项目以
相同顺序排列的列表是一样的。另外也注意 一个 &%List 可以是空项的,在这情况下,这个 &%List 是个
&%NullList。
")
;(=>
; (and
; (instance ?LIST List)
; (not
; (instance ?LIST NullList)))
; (exists (?NUMBER1 ?ITEM1)
; (and
; (not
; (equal (ListOrderFn ?LIST ?NUMBER1) ?ITEM1))
; (forall (?NUMBER2)
; (=>
; (and
; (instance ?NUMBER2 PositiveInteger)
; (lessThan ?NUMBER2 ?NUMBER1))
; (exists (?ITEM2)
; (equal (ListOrderFn ?LIST ?NUMBER2) ?ITEM2)))))))
(subclass UniqueList List)
(documentation UniqueList EnglishLanguage "A &%List in which no item appears more than
once,i.e. a &%List for which there are no distinct numbers ?NUMBER1 and ?NUMBER2
such that (&%ListOrderFn ?LIST ?NUMBER1) and (&%ListOrderFn ?LIST ?NUMBER2)
return the same value.")
(documentation UniqueList ChineseLanguage "这个 &%List 里的没有一个项目是出现超过一次的,也就是说
这是一个没有不同数字 ?NUMBER1 和 ?NUMBER2 的 &%List,使得(&%ListOrderFn ?LIST ?NUMBER1) 和
(&%ListOrderFn ?LIST ?NUMBER2) 会交出相同的值。")
(=>
(instance ?LIST UniqueList)
(forall (?NUMBER1 ?NUMBER2)
(=>
(equal (ListOrderFn ?LIST ?NUMBER1) (ListOrderFn ?LIST ?NUMBER2))
(equal ?NUMBER1 ?NUMBER2))))
(instance NullList List)
(documentation NullList EnglishLanguage "The &%List that has no items. The uniqueness of
&%NullList follows from the extensionality of &%Lists, i.e. the fact that
two &%Lists with the same items in the same order are identical.")
(documentation NullList ChineseLanguage "这是一个没有项目的 &%List,&%NullList 的独特之处是因为
&%List 是可以延伸,也就是说俩个含有相同项目以相同顺序排列的列表是一样的。")
;(<=>
; (equal ?LIST NullList)
; (and
; (instance ?LIST List)
; (not
; (exists (?ITEM)
; (inList ?ITEM ?LIST)))))
(instance ListFn Function)
(instance ListFn VariableArityRelation)
(domain ListFn 1 Entity)
;; (instance ListFn TotalValuedRelation) - appears to be a contradiction with VariableArityRelation
(range ListFn List)
(documentation ListFn EnglishLanguage "A &%Function that takes any number of arguments and
returns the &%List containing those arguments in exactly the same order.")
(documentation ListFn ChineseLanguage "这是一个可以接受任何数量的参数,然后交出含有跟哪些参数完全
相同顺序的 &%Function。")
(=>
(exhaustiveDecomposition ?CLASS @ROW)
(forall (?OBJ)
(=>
(instance ?OBJ ?CLASS)
(exists (?ITEM)
(and
(inList ?ITEM (ListFn @ROW))
(instance ?OBJ ?ITEM))))))
(=>
(disjointDecomposition ?CLASS @ROW)
(forall (?ITEM)
(=>
(inList ?ITEM (ListFn @ROW))
(subclass ?ITEM ?CLASS))))
(=>
(disjointDecomposition ?CLASS @ROW)
(forall (?ITEM1 ?ITEM2)
(=>
(and
(inList ?ITEM1 (ListFn @ROW))
(inList ?ITEM2 (ListFn @ROW))
(not
(equal ?ITEM1 ?ITEM2)))
(disjoint ?ITEM1 ?ITEM2))))
(<=>
(disjointDecomposition ?CLASS ?ROW1 ?ROW2 ?ROW3)
(and
(disjoint ?ROW1 ?ROW2)
(disjoint ?ROW2 ?ROW3)
(disjoint ?ROW3 ?ROW1)))
(instance ListOrderFn BinaryFunction)
(instance ListOrderFn PartialValuedRelation)
(domain ListOrderFn 1 List)
(domain ListOrderFn 2 PositiveInteger)
(range ListOrderFn Entity)
(documentation ListOrderFn EnglishLanguage "(&%ListOrderFn ?LIST ?NUMBER) denotes the item
that is in the ?NUMBER position in the &%List ?LIST. For example,
(&%ListOrderFn (&%ListFn &%Monday &%Tuesday &%Wednesday) 2) would return the
value &%Tuesday.")
(documentation ListOrderFn ChineseLanguage "(&%ListOrderFn ?LIST ?NUMBER) 表示在 ?LIST
&%List 第?NUMBER个位置的项目。例如:
(&%ListOrderFn (&%ListFn &%Monday &%Tuesday &%Wednesday) 2) 交出的值会是 &%Tuesday。")
;(=>
; (and
; (instance ?LIST1 List)
; (not
; (equal ?LIST1 NullList))
; (not
; (equal ?LIST2 NullList))
; (instance ?LIST2 List)
; (forall (?NUMBER)
; (equal (ListOrderFn ?LIST1 ?NUMBER) (ListOrderFn ?LIST2 ?NUMBER))))
; (equal ?LIST1 ?LIST2))
(=>
(and
(domain ?REL ?NUMBER ?CLASS)
(instance ?REL Predicate)
(?REL @ROW))
(instance (ListOrderFn (ListFn @ROW) ?NUMBER) ?CLASS))
(=>
(and
(domainSubclass ?REL ?NUMBER ?CLASS)
(instance ?REL Predicate)
(?REL @ROW))
(subclass (ListOrderFn (ListFn @ROW) ?NUMBER) ?CLASS))
(instance ListLengthFn UnaryFunction)
(instance ListLengthFn TotalValuedRelation)
(domain ListLengthFn 1 List)
(range ListLengthFn NonnegativeInteger)
(documentation ListLengthFn EnglishLanguage "A &%Function that takes a &%List as its sole
argument and returns the number of items in the &%List. For example,
(&%ListLengthFn (&%ListFn &%Monday &%Tuesday &%Wednesday)) would return the
value 3.")
(documentation ListLengthFn ChineseLanguage "这个 &%Function 接受一个 &%List 作为它唯一的参数,
然后交出这个 &%List 中项目的数量。例如:
(&%ListLengthFn (&%ListFn &%Monday &%Tuesday &%Wednesday))交出的值会是3。")
;(=>
; (and
; (equal (ListLengthFn ?LIST) ?NUMBER1)
; (instance ?LIST List)
; (not
; (equal ?LIST NullList))
; (instance ?NUMBER1 PositiveInteger))
; (forall (?NUMBER2)
; (<=>
; (exists (?ITEM)
; (and
; (equal (ListOrderFn ?LIST ?NUMBER2) ?ITEM)
; (inList ?ITEM ?LIST)))
; (lessThanOrEqualTo ?NUMBER2 ?NUMBER1))))
(forall (@ROW ?ITEM)
(equal
(ListLengthFn (ListFn @ROW ?ITEM))
(SuccessorFn (ListLengthFn (ListFn @ROW)))))
(forall (@ROW ?ITEM)
(equal
(ListOrderFn
(ListFn @ROW ?ITEM)
(ListLengthFn (ListFn @ROW ?ITEM))) ?ITEM))
(=>
(and
(valence ?REL ?NUMBER)
(instance ?REL Predicate))
(forall (@ROW)
(=>
(?REL @ROW)
(equal (ListLengthFn (ListFn @ROW)) ?NUMBER))))
;(=>
; (and
; (equal (ListLengthFn ?LIST1) ?NUMBER)
; (instance ?LIST List)
; (not
; (equal ?LIST NullList))
; (instance ?NUMBER1 PositiveInteger))
; (exists (?LIST2 ?ITEM)
; (and
; (initialList ?LIST1 ?LIST2)
; (equal (SuccessorFn ?NUMBER) (ListLengthFn ?LIST2))
; (equal (ListOrderFn ?LIST2 (SuccessorFn ?NUMBER)) ?ITEM))))
(instance ListConcatenateFn BinaryFunction)
(instance ListConcatenateFn TotalValuedRelation)
(domain ListConcatenateFn 1 List)
(domain ListConcatenateFn 2 List)
(range ListConcatenateFn List)
(documentation ListConcatenateFn EnglishLanguage "A &%Function that returns the
concatenation
of the two &%Lists that are given as arguments. For example, the value of
(&%ListConcatenateFn (&%ListFn &%Monday &%Tuesday) (&%ListFn &%Wednesday
&%Thursday)) would be (&%ListFn &%Monday &%Tuesday &%Wednesday &%Thursday).")
(documentation ListConcatenateFn ChineseLanguage "这个 &%Function 把由两个参数所设定的 &%List
串联起来。例如:(&%ListConcatenateFn (&%ListFn &%Monday &%Tuesday) (&%ListFn &%Wednesday
&%Thursday)) 会成了 (&%ListFn &%Monday &%Tuesday &%Wednesday &%Thursday)。")
; removed to solve an obscure contradiction, but needs to be reexamined
;
;(<=>
; (and
; (equal ?LIST3 (ListConcatenateFn ?LIST1 ?LIST2))
; (not
; (equal ?LIST1 NullList))
; (not
; (equal ?LIST2 NullList)))
; (forall (?NUMBER1 ?NUMBER2)
; (=>
; (and
; (lessThanOrEqualTo ?NUMBER1 (ListLengthFn ?LIST1))
; (lessThanOrEqualTo ?NUMBER2 (ListLengthFn ?LIST2))
; (instance ?NUMBER1 PositiveInteger)
; (instance ?NUMBER2 PositiveInteger))
; (and
; (equal (ListOrderFn ?LIST3 ?NUMBER1) (ListOrderFn ?LIST1 ?NUMBER1))
; (equal (ListOrderFn ?LIST3 (AdditionFn (ListLengthFn ?LIST1) ?NUMBER2)) (ListOrderFn ?LIST2 ?NUMBER2))))))
(instance inList BinaryPredicate)
(instance inList IrreflexiveRelation)
(instance inList AsymmetricRelation)
(instance inList PartialValuedRelation)
(domain inList 1 Entity)
(domain inList 2 List)
(documentation inList EnglishLanguage "The analog of &%element and &%instance for &%Lists.
(&%inList ?OBJ ?LIST) means that ?OBJ is in the &%List ?LIST. For example,
(&%inList &%Tuesday (&%ListFn &%Monday &%Tuesday &%Wednesday)) would be true.")
(documentation inList ChineseLanguage "这是类似 &%List 的 &%element 和 &%instance。
(&%inList ?OBJ ?LIST) 的意思是 ?OBJ 是在 ?LIST &%List 里。例如:
(&%inList &%Tuesday (&%ListFn &%Monday &%Tuesday &%Wednesday)) 是真的")
(=>
(inList ?ITEM ?LIST)
(exists (?NUMBER)
(equal (ListOrderFn ?LIST ?NUMBER) ?ITEM)))
(instance subList BinaryPredicate)
(instance subList PartialOrderingRelation)
(domain subList 1 List)
(domain subList 2 List)
(documentation subList EnglishLanguage "(&%subList ?LIST1 ?LIST2) means that ?LIST1 is a
sublist of ?LIST2, i.e. every element of ?LIST1 is an element of ?LIST2 and
the elements that are common to both &%Lists have the same order in both
&%Lists. Elements that are common to both Lists and are consecutive in one
list must also be consecutive in the other list. (Therefore - the list of
prime numbers smaller than 10 [1 2 3 5 7] is not a subList of the
natural numbers smaller than 10 [1 2 3 4 5 6 7 8 9]).")
(documentation subList ChineseLanguage "(&%subList ?LIST1 ?LIST2) 的意思是 ?LIST1 是 ?LIST2
的子类别,也就是说 ?LIST1 的所有的元素都是 ?LIST2 的元素,同时属于这两个 &%List 的元素在两个 &%List
的顺序是相同的。同时出现在这两个表列的元素,如果那些元素在其中一个表列是连续的,那么它们在另外一个表列也必须
会连续的。(所以 - 小于10 [1 2 3 5 7]的素数表列不是小于10 [1 2 3 4 5 6 7 8 9]自然数表列的子类别)。")
;(=>
; (and
; (subList ?LIST1 ?LIST2)
; (not
; (equal ?LIST1 NullList))
; (not
; (equal ?LIST2 NullList)))
; (forall (?ITEM)
; (=>
; (inList ?ITEM ?LIST1)
; (inList ?ITEM ?LIST2))))
;(=>
; (and
; (subList ?LIST1 ?LIST2)
; (not
; (equal ?LIST1 NullList))
; (not
; (equal ?LIST2 NullList)))
; (exists (?NUMBER3)
; (forall (?ITEM)
; (=>
; (inList ?ITEM ?LIST1)
; (exists (?NUMBER1 ?NUMBER2)
; (and
; (equal (ListOrderFn ?LIST1 ?NUMBER1) ?ITEM)
; (equal (ListOrderFn ?LIST2 ?NUMBER2) ?ITEM)
; (equal ?NUMBER2 (AdditionFn ?NUMBER1 ?NUMBER3))))))))
(instance initialList BinaryPredicate)
(instance initialList PartialOrderingRelation)
(subrelation initialList subList)
(documentation initialList EnglishLanguage "(&%initialList ?LIST1 ?LIST2) means that
?LIST1
is a &%subList of ?LIST2 and (&%ListOrderFn ?LIST1 ?NUMBER) returns the same
value as (&%ListOrderFn ?LIST2 ?NUMBER) for all of the values of ?NUMBER over
which (&%ListOrderFn ?LIST1 ?NUMBER) is defined.")
(documentation initialList ChineseLanguage "(&%initialList ?LIST1 ?LIST2) 的意思是 ?LIST1
是 ?LIST2 的一个 &%subList,而且(&%ListOrderFn ?LIST1 ?NUMBER),所交出按照
(&%ListOrderFn ?LIST1 ?NUMBER)里定义 ?NUMBER 的所有的值和(&%ListOrderFn ?LIST2 ?NUMBER)相同
的值。")
;(=>
; (and
; (initialList ?LIST1 ?LIST2)
; (not
; (equal ?LIST1 NullList))
; (not
; (equal ?LIST2 NullList)))
; (forall (?NUMBER1 ?NUMBER2)
; (=>
; (and
; (equal (ListLengthFn ?LIST1) ?NUMBER1)
; (lessThanOrEqualTo ?NUMBER2 ?NUMBER1))
; (equal (ListOrderFn ?LIST1 ?NUMBER2) (ListOrderFn ?LIST2 ?NUMBER2)))))
(forall (@ROW ?ITEM)
(initialList (ListFn @ROW) (ListFn @ROW ?ITEM)))
(instance identicalListItems BinaryPredicate)
(instance identicalListItems EquivalenceRelation)
(domain identicalListItems 1 List)
(domain identicalListItems 2 List)
(documentation identicalListItems EnglishLanguage "(&%identicalListItems ?LIST1 ?LIST2)
means that ?LIST1 and ?LIST2 have exactly the same items in their
respective lists. Although ?LIST1 and ?LIST2 are required to share
exactly the same items, they may order these items differently.")
(documentation identicalListItems ChineseLanguage "(&%identicalListItems ?LIST1 ?LIST2)
的意思是?LIST1 和 ?LIST2 在它们各自的列表,拥有完全相同的项目。虽然 ?LIST1 和 ?LIST2 需要共同拥有完全
相同的项目,但是它们的项目可以按不同的顺序排列。")
;(=>
; (and
; (identicalListItems ?LIST1 ?LIST2)
; (not
; (equal ?LIST1 NullList))
; (not
; (equal ?LIST2 NullList)))
; (<=>
; (inList ?ITEM ?LIST1)
; (inList ?ITEM ?LIST2)))
(subclass Predicate Relation)
(subclass Predicate InheritableRelation)
(documentation Predicate EnglishLanguage "A &%Predicate is a sentence-forming &%Relation.
Each tuple in the &%Relation is a finite, ordered sequence of objects.
The fact that a particular tuple is an element of a &%Predicate is denoted
by '(*predicate* arg_1 arg_2 .. arg_n)', where the arg_i are the
objects so related. In the case of &%BinaryPredicates, the fact can
be read as `arg_1 is *predicate* arg_2' or `a *predicate* of
arg_1 is arg_2'.")
(documentation Predicate ChineseLanguage "&%Predicate 是一个作句的 &%Relation,这个
&%Relation 的每一个元组都是物体有限、有序的的句子。一个特定组员是一个 &%Predicate 的元素这事实,由
'(*predicate* arg_1 arg_2 .. arg_n)'来表示, arg_i 是关联的事物。在 &%BinaryPredicate 的情况下,
可以读成 `arg_1 是 *predicate* arg_2' 或者 `arg_1 的一个 *predicate* 是 arg_2'。")
(subclass Function SingleValuedRelation)
(subclass Function InheritableRelation)
(documentation Function EnglishLanguage "A &%Function is a term-forming &%Relation that
maps from a n-tuple of arguments to a range and that associates this
n-tuple with at most one range element. Note that the range is a &%SetOrClass,
and each element of the range is an instance of the &%SetOrClass.")
(documentation Function ChineseLanguage "&%Function 是一个造词的 &%Relation,它以最多一个元素
范围,把n元组的参数和这n元组有关的范围联系起来。注:范围是一个&%SetOrClass,而且范围内的每个元素是这个
&%SetOrClass 的一个实例。")
(subclass UnaryFunction Function)
(subclass UnaryFunction BinaryRelation)
(subclass UnaryFunction InheritableRelation)
(documentation UnaryFunction EnglishLanguage "The &%Class of &%Functions that require a
single argument.")
(documentation UnaryFunction ChineseLanguage "这是个需要单一一个参数的 &%Function &%Class。")
(=>
(instance ?FUNCTION UnaryFunction)
(valence ?FUNCTION 1))
(subclass OneToOneFunction UnaryFunction)
(documentation OneToOneFunction EnglishLanguage "The &%Class of &%UnaryFunctions which
are one to one. A function F is one to one just in case for all X, Y in the
domain of F, if X is not identical to Y, then F(X) is not identical to F(Y).")
(documentation OneToOneFunction ChineseLanguage "这是个一对一的 &%UnaryFunction &%Class,对于
所有在定义域F的X和Y,函数F是一对一的,这是以防X不同于Y,那么F(X)就和F(Y)不相同。 ")
(=>
(instance ?FUN OneToOneFunction)
(forall (?ARG1 ?ARG2)
(=>
(and
(domain ?FUN 1 ?CLASS)
(instance ?ARG1 ?CLASS)
(instance ?ARG2 ?CLASS)
(not (equal ?ARG1 ?ARG2)))
(not (equal (AssignmentFn ?FUN ?ARG1) (AssignmentFn ?FUN ?ARG2))))))
(subclass SequenceFunction OneToOneFunction)
(documentation SequenceFunction EnglishLanguage "The &%Class of &%OneToOneFunctions whose
rangeis a subclass of the &%PositiveIntegers.")
(documentation SequenceFunction ChineseLanguage "这是 &%OneToOneFunction &%Class, 它的范围
是 &%PositiveInteger 的子类别。")
(=>
(and
(instance ?SEQ SequenceFunction)
(range ?SEQ ?CLASS))
(subclass ?CLASS Integer))
(subclass BinaryFunction Function)
(subclass BinaryFunction TernaryRelation)
(subclass BinaryFunction InheritableRelation)
(documentation BinaryFunction EnglishLanguage "The &%Class of &%Functions that require
two arguments.")
(documentation BinaryFunction ChineseLanguage "这是个需要两个参数的 &%Function &%Class。")
(=>
(instance ?FUNCTION BinaryFunction)
(valence ?FUNCTION 2))
(subclass AssociativeFunction BinaryFunction)
(documentation AssociativeFunction EnglishLanguage "A &%BinaryFunction is associative if
bracketing has no effect on the value returned by the &%Function. More
precisely, a &%Function ?FUNCTION is associative just in case
(?FUNCTION ?INST1 (?FUNCTION ?INST2 ?INST3)) is equal to
(?FUNCTION (?FUNCTION ?INST1 ?INST2) ?INST3), for all ?INST1, ?INST2,
and ?INST3.")
(documentation AssociativeFunction ChineseLanguage "一个 &%BinaryFunction 属于关联性的如果
使用括号并没有影响 &%Function 所交出的值,更确切的说,对于所有的?INST1、 ?INST2 和 ?INST3,
&%Function ?FUNCTION 是关联性的,以防(?FUNCTION ?INST1 (?FUNCTION ?INST2 ?INST3))和
(?FUNCTION (?FUNCTION ?INST1 ?INST2) ?INST3)相同。")
(=>
(instance ?FUNCTION AssociativeFunction)
(forall (?INST1 ?INST2 ?INST3)
(=>
(and
(domain ?FUNCTION 1 ?CLASS)
(instance ?INST1 ?CLASS)
(instance ?INST2 ?CLASS)
(instance ?INST3 ?CLASS))
(equal (AssignmentFn ?FUNCTION ?INST1 (AssignmentFn ?FUNCTION ?INST2 ?INST3))
(AssignmentFn ?FUNCTION (AssignmentFn ?FUNCTION ?INST1 ?INST2) ?INST3)))))
(subclass CommutativeFunction BinaryFunction)
(documentation CommutativeFunction EnglishLanguage "A &%BinaryFunction is commutative if
the ordering of the arguments of the function has no effect on the value
returned by the function. More precisely, a function ?FUNCTION is
commutative just in case (?FUNCTION ?INST1 ?INST2) is equal to (?FUNCTION
?INST2 ?INST1), for all ?INST1 and ?INST2.")
(documentation CommutativeFunction ChineseLanguage "一个 &%BinaryFunction 属于可交换的如果
参数的顺序不影响函数所交出的值,更确切的说,对于所有的?INST1 和 ?INST2,&%Function ?FUNCTION
是可交换的,以防(?FUNCTION ?INST1 ?INST2) 和 (?FUNCTION ?INST2 ?INST1)相同。")
(=>
(instance ?FUNCTION CommutativeFunction)
(forall (?INST1 ?INST2)
(=>
(and
(domain ?FUNCTION 1 ?CLASS)
(instance ?INST1 ?CLASS)
(instance ?INST2 ?CLASS))
(equal (AssignmentFn ?FUNCTION ?INST1 ?INST2)
(AssignmentFn ?FUNCTION ?INST2 ?INST1)))))
(subclass TernaryFunction Function)
(subclass TernaryFunction QuaternaryRelation)
(subclass TernaryFunction InheritableRelation)
(documentation TernaryFunction EnglishLanguage "The &%Class of &%Functions that require
exactly three arguments.")
(documentation TernaryFunction ChineseLanguage "这是个需要恰好三个参数的 &%Function &%Class。")
(=>
(instance ?FUNCTION TernaryFunction)
(valence ?FUNCTION 3))
(subclass QuaternaryFunction Function)
(subclass QuaternaryFunction QuintaryRelation)
(subclass QuaternaryFunction InheritableRelation)
(documentation QuaternaryFunction EnglishLanguage "The &%Class of &%Functions that require
exactly four arguments.")
(documentation QuaternaryFunction ChineseLanguage "这是个需要恰好四个参数的 &%Function
&%Class。")
(=>
(instance ?FUNCTION QuaternaryFunction)
(valence ?FUNCTION 4))
(subclass ContinuousFunction Function)
(documentation ContinuousFunction EnglishLanguage "&%Functions which are continuous.
This concept is taken as primitive until representations for limits
are devised.")
(documentation ContinuousFunction ChineseLanguage "这是连续的 &%Function,直到得出了它的极限,
这个概念会被看成为原函数。")
(subclass BinaryPredicate Predicate)
(subclass BinaryPredicate BinaryRelation)
(subclass BinaryPredicate InheritableRelation)
(documentation BinaryPredicate EnglishLanguage "A &%Predicate relating two items - its
valence is two.")
(documentation BinaryPredicate ChineseLanguage "这是一个联系两个项目的 &%Predicate
- 它的配价是二。")
(=>
(instance ?REL BinaryPredicate)
(valence ?REL 2))
(subclass TernaryPredicate Predicate)
(subclass TernaryPredicate TernaryRelation)
(subclass TernaryPredicate InheritableRelation)
(documentation TernaryPredicate EnglishLanguage "The &%Class of &%Predicates that require
exactly three arguments.")
(documentation TernaryPredicate ChineseLanguage "这是一个需要三个参数的 &%Predicate &%Class。")
(=>
(instance ?REL TernaryPredicate)
(valence ?REL 3))
(subclass QuaternaryPredicate Predicate)
(subclass QuaternaryPredicate QuaternaryRelation)
(subclass QuaternaryPredicate InheritableRelation)
(documentation QuaternaryPredicate EnglishLanguage "The &%Class of &%Predicates that
require four arguments.")
(documentation QuaternaryPredicate ChineseLanguage "这是一个需要四个参数的 &%Predicate
&%Class。")
(=>
(instance ?REL QuaternaryPredicate)
(valence ?REL 4))
(subclass QuintaryPredicate Predicate)
(subclass QuintaryPredicate QuintaryRelation)
(subclass QuintaryPredicate InheritableRelation)
(documentation QuintaryPredicate EnglishLanguage "The &%Class of &%Predicates that
require five arguments.")
(documentation QuintaryPredicate ChineseLanguage "这是一个需要五个参数的 &%Predicate
&%Class。")
(=>
(instance ?REL QuintaryPredicate)
(valence ?REL 5))
(subclass VariableArityRelation Relation)
(documentation VariableArityRelation EnglishLanguage "The &%Class of &%Relations that
do not have a fixed number of arguments.")
(documentation VariableArityRelation ChineseLanguage "这是个没有固定数量参数的 &%Relation
&%Class。")
(=>
(instance ?REL VariableArityRelation)
(not
(exists (?INT)
(valence ?REL ?INT))))
(subclass RelationExtendedToQuantities Relation)
(subclass RelationExtendedToQuantities InheritableRelation)
(documentation RelationExtendedToQuantities EnglishLanguage "A
&%RelationExtendedToQuantities is a &%Relation that, when it is true on
a sequence of arguments that are &%RealNumbers, it is also true on a
sequence of instances of &%ConstantQuantity with those magnitudes in some unit of
measure. For example, the &%lessThan relation is extended to quantities.
This means that for all pairs of quantities ?QUANTITY1 and ?QUANTITY2,
(&%lessThan ?QUANTITY1 ?QUANTITY2) if and only if, for some ?NUMBER1,
?NUMBER2, and ?UNIT, ?QUANTITY1 = (&%MeasureFn ?NUMBER1 ?UNIT),
?QUANTITY2 = (&%MeasureFn ?NUMBER2 ?UNIT), and (&%lessThan ?NUMBER1 ?NUMBER2),
for all units ?UNIT on which ?QUANTITY1 and ?QUANTITY2 can be measured.
Note that, when a &%RelationExtendedToQuantities is extended from
&%RealNumbers to instances of &%ConstantQuantity, the &%ConstantQuantity must be
measured along the same physical dimension.")
(documentation RelationExtendedToQuantities ChineseLanguage "
&%RelationExtendedToQuantities 是一个 &%Relation,如果它对一串 &%RealNumber 的参数值是真的,那么
他对一串有着和一些衡量单位幅度 &%ConstantQuantity 的实例也是真的。例如: &%lessThan 关系可延伸到数量
上, 意思是(&%lessThan ?QUANTITY1 ?QUANTITY2) 对于 ?QUANTITY1 和 ?QUANTITY2 所有的数量对,
当且仅当对于某些 ?NUMBER1,?NUMBER2 和 ?UNIT,?QUANTITY1 = (&%MeasureFn ?NUMBER1 ?UNIT),
?QUANTITY2 = (&%MeasureFn ?NUMBER2 ?UNIT)和(&%lessThan ?NUMBER1 ?NUMBER2),对于所有
?QUANTITY1 和 ?QUANTITY2 可以量度的单位 ?UNIT。注:当一个 &%RelationExtendedToQuantities 由
&%RealNumber 被延伸到 &%ConstantQuantity 的实例实时,该 &%ConstantQuantity 必须以相同的实物尺寸
来量度。")
(subclass LogicalOperator Predicate)
(documentation LogicalOperator EnglishLanguage "This &%Class comprises all
of the logical operators (viz. 'and', 'or', 'not', '=>', and '<=>').")
(subclass Proposition Abstract)
(documentation Proposition EnglishLanguage "&%Propositions are &%Abstract entities that
express a complete thought or a set of such thoughts. As an example,
the formula '(instance Yojo Cat)' expresses the &%Proposition that the
entity named Yojo is an element of the &%Class of Cats. Note that
propositions are not restricted to the content expressed by individual
sentences of a &%Language. They may encompass the content expressed by
theories, books, and even whole libraries. It is important to distinguish
&%Propositions from the &%ContentBearingObjects that express them. A
&%Proposition is a piece of information, e.g. that the cat is on the mat,
but a &%ContentBearingObject is an &%Object that represents this information.
A &%Proposition is an abstraction that may have multiple representations:
strings, sounds, icons, etc. For example, the &%Proposition that the cat is
on the mat is represented here as a string of graphical characters displayed
on a monitor and/or printed on paper, but it can be represented by a sequence
of sounds or by some non-latin alphabet or by some cryptographic form")
(documentation Proposition ChineseLanguage "&%Proposition 是 &%Abstract 实体, 它表达一个完整
的意思或是一套想法。例如:公式 '(instance Yojo Cat)' 表达 &%Proposition 为那个叫佑舟的实体是猫
&%Class 的一个元素。注:命题限于由 &%Language 的个别句子所表达的内容,这可以包括由理论、书本和甚至整个
图书馆所表达的内容。千万要区别 &%Proposition 和表达命题的 &%ContentBearingObject ,
&%Proposition 实一个信息,例如说猫在地毯上;但是 &%ContentBearingObject 是一个表达该信息的
&%Object。 &%Proposition 可以有多个描述的抽象概念:字符串、声音和图标等。例如:猫在地毯上这个
&%Proposition 在这里是以显示器上或者是打印在纸上的一串图形字符来表示,但是它也可以由一系列的声音或者是某些
非拉丁字母或是某些加密形式来表示。")
(instance closedOn BinaryPredicate)
(instance closedOn AsymmetricRelation)
(domain closedOn 1 Function)
(domain closedOn 2 SetOrClass)
(documentation closedOn EnglishLanguage "A &%BinaryFunction is closed on a &%SetOrClass
if it is defined for all instances of the &%SetOrClass and its value is
always an instance of the &%SetOrClass.")
(documentation closedOn ChineseLanguage "一个 &%BinaryFunction 在一个 &%SetOrClass 是封闭的
如果它在这个 &%SetOrClass 所有的实例已经定义了,而且它的值永远是这个 &%SetOrClass 的一个实例。")
;(=>
; (and
; (closedOn ?FUNCTION ?CLASS)
; (instance ?FUNCTION UnaryFunction))
; (forall (?INST)
; (=>
; (instance ?INST ?CLASS)
; (instance (AssignmentFn ?FUNCTION ?INST) ?CLASS))))
;(=>
; (and
; (closedOn ?FUNCTION ?CLASS)
; (instance ?FUNCTION BinaryFunction))
; (forall (?INST1 ?INST2)
; (=>
; (and
; (instance ?INST1 ?CLASS)
; (instance ?INST2 ?CLASS))
; (instance (AssignmentFn ?FUNCTION ?INST1 ?INST2) ?CLASS))))
(instance reflexiveOn BinaryPredicate)
(instance reflexiveOn AsymmetricRelation)
(domain reflexiveOn 1 BinaryRelation)
(domain reflexiveOn 2 SetOrClass)
(documentation reflexiveOn EnglishLanguage "A &%BinaryRelation is reflexive on a
&%SetOrClass only if every instance of the &%SetOrClass bears the relation
to itself.")
(documentation reflexiveOn ChineseLanguage "一个 &%BinaryRelation 在一个 &%SetOrClass是自反
的除非这个 &%SetOrClass 的每一个实例戴着和自身相关的关系。")
(=>
(and
(reflexiveOn ?RELATION ?CLASS)
(instance ?RELATION Predicate))
(forall (?INST)
(=>
(instance ?INST ?CLASS)
(?RELATION ?INST ?INST))))
(instance irreflexiveOn BinaryPredicate)
(instance irreflexiveOn AsymmetricRelation)
(domain irreflexiveOn 1 BinaryRelation)
(domain irreflexiveOn 2 SetOrClass)
(documentation irreflexiveOn EnglishLanguage "A &%BinaryRelation is irreflexive on a
&%SetOrClass only if no instance of the &%SetOrClass bears the relation to
itself.")
(documentation irreflexiveOn ChineseLanguage "一个 &%BinaryRelation 在一个 &%SetOrClass 是
非自反的除非这个 &%SetOrClass 里没有一个实里戴着和自身相关的关系。")
(=>
(and
(irreflexiveOn ?RELATION ?CLASS)
(instance ?RELATION Predicate))
(forall (?INST)
(=>
(instance ?INST ?CLASS)
(not
(?RELATION ?INST ?INST)))))
(instance partialOrderingOn BinaryPredicate)
(instance partialOrderingOn AsymmetricRelation)
(domain partialOrderingOn 1 BinaryRelation)
(domain partialOrderingOn 2 SetOrClass)
(documentation partialOrderingOn EnglishLanguage "A &%BinaryRelation is a partial
ordering on a &%SetOrClass only if the relation is &%reflexiveOn the
&%SetOrClass, and it is both an &%AntisymmetricRelation, and a
&%TransitiveRelation.")
(documentation partialOrderingOn ChineseLanguage "一个 &%BinaryRelation 在一个 &%SetOrClass
使部分顺序的,除非这个关系是在这个&%SetOrClass 是 &%reflexiveOn,而且它既是 &%AntisymmetricRelation
又是 &%TransitiveRelation。")
(=>
(partialOrderingOn ?RELATION ?CLASS)
(and
(reflexiveOn ?RELATION ?CLASS)
(instance ?RELATION TransitiveRelation)
(instance ?RELATION AntisymmetricRelation)))
(instance totalOrderingOn BinaryPredicate)
(instance totalOrderingOn AsymmetricRelation)
(domain totalOrderingOn 1 BinaryRelation)
(domain totalOrderingOn 2 SetOrClass)
(documentation totalOrderingOn EnglishLanguage "A &%BinaryRelation ?REL is a total
ordering on a &%SetOrClass only if it is a partial ordering for which either
(?REL ?INST1 ?INST2) or (?REL ?INST2 ?INST1) for every ?INST1 and ?INST2
in the &%SetOrClass.")
(documentation totalOrderingOn ChineseLanguage "一个 &%BinaryRelation ?REL 在一个
&%SetOrClass 是一个完全的顺序的,除非对于这个 &%SetOrClass 里每一个?INST1 和 ?INST2,
(?REL ?INST1 ?INST2) 或者是 (?REL ?INST2 ?INST1) 是部分顺序的。")
(<=>
(totalOrderingOn ?RELATION ?CLASS)
(and
(partialOrderingOn ?RELATION ?CLASS)
(trichotomizingOn ?RELATION ?CLASS)))
(instance trichotomizingOn BinaryPredicate)
(instance trichotomizingOn AsymmetricRelation)
(domain trichotomizingOn 1 BinaryRelation)
(domain trichotomizingOn 2 SetOrClass)
(documentation trichotomizingOn EnglishLanguage "A &%BinaryRelation ?REL is
trichotomizing on a &%SetOrClass only if, for all instances ?INST1 and ?INST2
of the &%SetOrClass, at least one of the following holds: (?REL ?INST1 ?INST2),
(?REL ?INST2 ?INST1) or (equal ?INST1 ?INST2).")
(documentation trichotomizingOn ChineseLanguage "一个 &%BinaryRelation ?REL 在一个
&%SetOrClass 属于三分关系,除非对于这个 &%SetOrClass 所有的 ?INST1 和 ?INST2 的实例,
起码任何以下一个 (?REL ?INST1 ?INST2),(?REL ?INST2 ?INST1) 或 (equal ?INST1 ?INST2)
是真的。")
(=>
(and
(trichotomizingOn ?RELATION ?CLASS)
(instance ?RELATION Predicate))
(forall (?INST1 ?INST2)
(=>
(and
(instance ?INST1 ?CLASS)
(instance ?INST2 ?CLASS))
(or
(?RELATION ?INST1 ?INST2)
(?RELATION ?INST2 ?INST1)
(equal ?INST1 ?INST2)))))
(instance equivalenceRelationOn BinaryPredicate)
(instance equivalenceRelationOn AsymmetricRelation)
(domain equivalenceRelationOn 1 BinaryRelation)
(domain equivalenceRelationOn 2 SetOrClass)
(documentation equivalenceRelationOn EnglishLanguage "A &%BinaryRelation is an
&%equivalenceRelationOn a &%SetOrClass only if the relation is &%reflexiveOn
the &%SetOrClass and it is both a &%TransitiveRelation and a
&%SymmetricRelation.")
(documentation equivalenceRelationOn ChineseLanguage "一个 &%BinaryRelation 在一个
&%SetOrClass 是 &%equivalenceRelationOn,除非这个关系在这个 &%SetOrClass 是 &%reflexiveOn,
而且也要既是 &%TransitiveRelation,又是 &%SymmetricRelation。")
(=>
(equivalenceRelationOn ?RELATION ?CLASS)
(and
(instance ?RELATION TransitiveRelation)
(instance ?RELATION SymmetricRelation)
(reflexiveOn ?RELATION ?CLASS)))
(instance distributes BinaryPredicate)
(domain distributes 1 BinaryFunction)
(domain distributes 2 BinaryFunction)
(documentation distributes EnglishLanguage "A &%BinaryFunction ?FUNCTION1 is distributive
over another &%BinaryFunction ?FUNCTION2 just in case
(?FUNCTION1 ?INST1 (?FUNCTION2 ?INST2 ?INST3)) is equal to
(?FUNCTION2 (?FUNCTION1 ?INST1 ?INST2) (?FUNCTION1 ?INST1 ?INST3)),
for all ?INST1, ?INST2, and ?INST3.")
(documentation distributes ChineseLanguage "一个 &%BinaryFunction ?FUNCTION1 是另一个
&%BinaryFunction ?FUNCTION2 的分布函数, 以防对于所有的 ?INST1,?INST2 和 ?INST3,
(?FUNCTION1 ?INST1 (?FUNCTION2 ?INST2 ?INST3)) 等于
(?FUNCTION2 (?FUNCTION1 ?INST1 ?INST2) (?FUNCTION1 ?INST1 ?INST3))。")
;(=>
; (distributes ?FUNCTION1 ?FUNCTION2)
; (forall (?INST1 ?INST2 ?INST3)
; (=>
; (and
; (domain ?FUNCTION1 1 ?CLASS1)
; (instance ?INST1 ?CLASS1)
; (instance ?INST2 ?CLASS1)
; (instance ?INST3 ?CLASS1)
; (domain ?FUNCTION2 1 ?CLASS2)
; (instance ?INST1 ?CLASS2)
; (instance ?INST2 ?CLASS2)
; (instance ?INST3 ?CLASS2))
; (equal
; (AssignmentFn ?FUNCTION1 ?INST1
; (AssignmentFn ?FUNCTION2 ?INST2 ?INST3))
; (AssignmentFn ?FUNCTION2
; (AssignmentFn ?FUNCTION1 ?INST1 ?INST2)
; (AssignmentFn ?FUNCTION1 ?INST1 ?INST3))))))
(documentation relatedEvent EnglishLanguage "(relatedEvent ?EVENT1 ?EVENT2) means
that the &%Process ?EVENT1 is related to the Process ?EVENT2. The
relationship is between separate individual events, not events and
their subprocesses. On the other hand, two &%subProcesses of the same
overarching event may be &%relatedEvents. The argument order does not
imply temporal ordering.")
(documentation relatedEvent ChineseLanguage "(relatedEvent ?EVENT1 ?EVENT2) 的意思是
&%Process ?EVENT1 和 过程 ?EVENT2 有关连,这是个别事件之间的关系, 而非事件和它自过程之间的关系。但是
一个总体时间的两个 &%subProcess 可以是 &%relatedEvent,参数的顺序并不代表时间的时许。")
(instance relatedEvent BinaryPredicate)
(instance relatedEvent SymmetricRelation)
(domain relatedEvent 1 Process)
(domain relatedEvent 2 Process)
(=>
(and
(subProcess ?S1 ?P)
(subProcess ?S2 ?P))
(relatedEvent ?S1 ?S2))
(instance causes BinaryPredicate)
(instance causes AsymmetricRelation)
(domain causes 1 Process)
(domain causes 2 Process)
(relatedInternalConcept causes causesSubclass)
(subrelation causes relatedEvent)
(documentation causes EnglishLanguage "The causation relation between instances of
&%Process.(&%causes ?PROCESS1 ?PROCESS2) means that the instance of &%Process ?PROCESS1
brings about the instance of &%Process ?PROCESS2.")
(documentation causes ChineseLanguage "这是 &%Process 实例之间的因果关系,
(&%causes ?PROCESS1 ?PROCESS2)的意思是 &%Process ?PROCESS1 的实例引起 &%Process ?PROCESS2 的
实例。")
(=>
(instance ?PROC1 Process)
(exists (?PROC2)
(causes ?PROC2 ?PROC1)))
(=>
(causes ?P1 ?P2)
(earlier (WhenFn ?P1) (WhenFn ?P2)))
(instance causesSubclass BinaryPredicate)
(instance causesSubclass AsymmetricRelation)
(domainSubclass causesSubclass 1 Process)
(domainSubclass causesSubclass 2 Process)
(documentation causesSubclass EnglishLanguage "The causation relation
between subclasses of &%Process.
(&%causesSubclass ?PROCESS1 ?PROCESS2) means that the subclass of &%Process ?PROCESS1
brings about the subclass of &%Process ?PROCESS2, e.g. (&%causesSubclass &%Killing
&%Death).")
(documentation causesSubclass ChineseLanguage "这是 &%Process 子类别之间的因果关系,
(&%causesSubclass ?PROCESS1 ?PROCESS2) 的意思是 &%Process ?PROCESS1 的子类别导致
&%Process ?PROCESS2 的子类别,例如: (&%causesSubclass &%Killing &%Death)。")
(=>
(causesSubclass ?PROC1 ?PROC2)
(forall (?INST2)
(=>
(instance ?INST2 ?PROC2)
(exists (?INST1)
(and
(instance ?INST1 ?PROC1)
(causes ?INST1 ?INST2))))))
(instance causesProposition BinaryPredicate)
(instance causesProposition AsymmetricRelation)
(domain causesProposition 1 Formula)
(domain causesProposition 2 Formula)
(documentation causesProposition EnglishLanguage "(&%causesProposition ?FORMULA1
?FORMULA2) means that the state of affairs described by ?FORMULA1
causes, or mechanistically brings about, the state of affairs
described by ?FORMULA2. Note that unlike &%entails, the time
during which ?FORMULA2 holds cannot precede the time during which
?FORMULA1 holds, although ?FORMULA1 and ?FORMULA2 can hold
simultaneously. Note, also, that &%causesProposition is a
predicate, not a truth function. The following rule
(contraposition) does not hold: (=> (causesProp ?FORMULA1
?FORMULA2) (causesProp (not ?FORMULA2) (not ?FORMULA1))).")
(documentation causesProposition ChineseLanguage "(&%causesProposition ?FORMULA1
?FORMULA2) 的意思是由 ?FORMULA1 描述事态引起或者是决定性和实质上地导致由 ?FORMULA2 描述的事态。注:
有别于 &%entails,?FORMULA2 发生的时间不能够早过 ?FORMULA1 发生地时间,但是 ?FORMULA1 和
?FORMULA2 可以同时发生,也要注意的是 &%causesProposition 是一个谓词,而不是一个真值函数。以下的规则
(对立)不能成立:(=> (causesProp ?FORMULA1 ?FORMULA2)
(causesProp (not ?FORMULA2) (not ?FORMULA1)))。")
(=>
(and
(holdsDuring ?T2 ?SIT2)
(holdsDuring ?T1 ?SIT1)
(instance ?T1 TimeInterval)
(instance ?T2 TimeInterval)
(causesProposition ?SIT1 ?SIT2))
(beforeOrEqual (BeginFn ?T1) (BeginFn ?T2)))
(instance copy BinaryPredicate)
(instance copy EquivalenceRelation)
(domain copy 1 Object)
(domain copy 2 Object)
(documentation copy EnglishLanguage "relates an &%Object to an exact copy of the
&%Object, where an exact copy is indistinguishable from the original
with regard to every property except (possibly) spatial and/or temporal
location.")
(documentation copy ChineseLanguage "这个概念把一个 &%Object 和这个 &%Object 一摸一样地副本联系
起来,而原本和它一摸一样的副本,在所有的特性除了(可能) 空间和/或时间地位置上,是没有区别的。")
(=>
(copy ?OBJ1 ?OBJ2)
(forall (?ATTR)
(=>
(attribute ?OBJ1 ?ATTR)
(attribute ?OBJ2 ?ATTR))))
(instance time BinaryPredicate)
(instance time TemporalRelation)
(instance time AsymmetricRelation)
(instance time TotalValuedRelation)
(domain time 1 Physical)
(domain time 2 TimePosition)
(relatedInternalConcept time located)
(relatedInternalConcept time holdsDuring)
(documentation time EnglishLanguage "This relation holds between an instance of
&%Physical and an instance of &%TimePosition just in case the temporal
lifespan of the former includes the latter. In other words, (&%time
?THING ?TIME) means that ?THING existed or occurred at ?TIME. Note
that &%time does for instances of &%Physical what &%holdsDuring does
for instances of &%Formula. The constants &%located and &%time are
the basic spatial and temporal predicates, respectively.")
(documentation time ChineseLanguage "这个关系用于一个 &%Physical 实例 和一个 &%TimePosition
实例之间,以防前者所存在的的时间包含了后者的。 换句话说,(&%time ?THING ?TIME) 的意思是 ?THING 在 ?TIME
出现或发生。注: &%time 在于 &%Physical 实例,就相等于 &%holdsDuring 用在 &%Formula 的实例上,常数
&%located 和 &%time 分别是是基本的空间和时间谓词。")
(instance holdsDuring BinaryPredicate)
(instance holdsDuring AsymmetricRelation)
(domain holdsDuring 1 TimePosition)
(domain holdsDuring 2 Formula)
(documentation holdsDuring EnglishLanguage "(&%holdsDuring ?TIME ?FORMULA) means that the
proposition denoted by ?FORMULA is true in the time frame ?TIME. Note
that this implies that ?FORMULA is true at every &%TimePoint which is a
&%temporalPart of ?TIME.")
(documentation holdsDuring ChineseLanguage "(&%holdsDuring ?TIME ?FORMULA) 的意思是
由 ?FORMULA 表示的命题在 ?TIME时段是事实。注:这意味着 ?FORMULA 在每一个 &%TimePoint 都是真的,
&%TimePoint 是 ?TIME 一个的 &%temporalPart。")
(=>
(and
(holdsDuring ?TIME ?SITUATION1)
(entails ?SITUATION1 ?SITUATION2))
(holdsDuring ?TIME ?SITUATION2))
(=>
(holdsDuring ?TIME (not ?SITUATION))
(not (holdsDuring ?TIME ?SITUATION)))
(instance capability TernaryPredicate)
(domainSubclass capability 1 Process)
(domain capability 2 CaseRole)
(domain capability 3 Object)
(documentation capability EnglishLanguage "(&%capability ?PROCESS ?ROLE ?OBJ) means
that ?OBJ has the ability to play the role of ?ROLE in &%Processes of
type ?PROCESS.")
(documentation capability ChineseLanguage "(&%capability ?PROCESS ?ROLE ?OBJ) 的意思是 ?OBJ
由能力在 ?PROCESS 类型的 &%Process 担任 ?ROLE 的本分。")
(=>
(and
(instance ?ROLE CaseRole)
(?ROLE ?ARG1 ?ARG2)
(instance ?ARG1 ?PROC)
(subclass ?PROC Process))
(capability ?PROC ?ROLE ?ARG2))
(=>
(capability ?PROCESS ?ROLE ?OBJ)
(modalAttribute
(exists (?P)
(and
(instance ?P ?PROCESS)
(?ROLE ?P ?OBJ))) Possibility))
(instance exploits BinaryPredicate)
(instance exploits AsymmetricRelation)
(domain exploits 1 Object)
(domain exploits 2 Agent)
(documentation exploits EnglishLanguage "(&%exploits ?OBJ ?AGENT) means that ?OBJ is used
by ?AGENT as a &%resource in an unspecified instance of &%Process. This
&%Predicate, as its corresponding axiom indicates, is a composition of the
relations &%agent and &%resource.")
(documentation exploits ChineseLanguage "(&%exploits ?OBJ ?AGENT) 的意思是 ?AGENT 利用 ?OBJ
作为一个没有指定 &%Process 实例的 &%resource,这个 &%Predicate 就如它的相关定义所说的,是由 &%agent
和 &%resource 的关系所组成的。")
(=>
(exploits ?OBJ ?AGENT)
(exists (?PROCESS)
(and
(agent ?PROCESS ?AGENT)
(resource ?PROCESS ?OBJ))))
(instance hasPurpose BinaryPredicate)
(instance hasPurpose AsymmetricRelation)
(domain hasPurpose 1 Physical)
(domain hasPurpose 2 Formula)
(documentation hasPurpose EnglishLanguage "This &%Predicate expresses the concept of a
conventional goal, i.e. a goal with a neutralized agent's intention.
Accordingly, (&%hasPurpose ?THING ?FORMULA) means that the instance of
&%Physical ?THING has, as its purpose, the &%Proposition expressed by
?FORMULA. Note that there is an important difference in meaning between
the &%Predicates &%hasPurpose and &%result. Although the second argument
of the latter can satisfy the second argument of the former,
a conventional goal is an expected and desired outcome, while a result
may be neither expected nor desired. For example, a machine process may
have outcomes but no goals, aimless wandering may have an outcome but no
goal, a learning process may have goals with no outcomes, and so on.")
(documentation hasPurpose ChineseLanguage "这个 &%Predicate 表达一个常规目标的概念,也就是说这个
目标事出自一个中立主事者的意图。 因此,(&%hasPurpose ?THING ?FORMULA) 的意思是 &%Physical 的实例
?THING 的意图是由 ?FORMULA 所表达的 &%Proposition。注:&%Predicates &%hasPurpose 和 &%result
之间在意义上存在着一个重要的差异。虽然后者的第二个参数可以满足前者的第二个参数,常规目标是一个预期和
受期待的成果,而结果可以是预期或者受期待的。例如:一个机器过程可以有出果却没有目标,毫无目的的游荡会有一个
成果却没有目标,一个学习过程可以有目标却没有任何的成果,如此类推。")
(instance hasPurposeForAgent TernaryPredicate)
(domain hasPurposeForAgent 1 Physical)
(domain hasPurposeForAgent 2 Formula)
(domain hasPurposeForAgent 3 Agent)
(documentation hasPurposeForAgent EnglishLanguage "Expresses a cognitive attitude of an
agent with respect to a particular instance of Physical. More precisely,
(&%hasPurposeForAgent ?THING ?FORMULA ?AGENT) means that the purpose of
?THING for ?AGENT is the proposition expressed by ?FORMULA. Very complex
issues are involved here. In particular, the rules of inference of the
first order predicate calculus are not truth-preserving for the second
argument position of this &%Predicate.")
(documentation hasPurposeForAgent ChineseLanguage "这个是由主事对于一个特定的物理实例表达的一种
认知态度,更确实的说,(&%hasPurposeForAgent ?THING ?FORMULA ?AGENT) 的意思是 ?FORMULA 所表达的
命题是 ?AGENT 做 ?THING 的目,这里包含了一些十分复杂的问题,特别是一阶逻辑的推理原则对于这个
&%Predicate 的第二个参数位置并不能保持真实。")
(=>
(hasPurpose ?THING ?PURPOSE)
(exists (?AGENT)
(hasPurposeForAgent ?THING ?PURPOSE ?AGENT)))
(instance hasSkill BinaryPredicate)
(instance hasSkill AsymmetricRelation)
(domainSubclass hasSkill 1 Process)
(domain hasSkill 2 Agent)
(documentation hasSkill EnglishLanguage "Similar to the &%capability &%Predicate
with the additional restriction that the ability be practised/
demonstrated to some measurable degree.")
(documentation hasSkill ChineseLanguage "这个是类似 &%capability &%Predicate 但有额外的限制,
就是这个能力是可以用某种可量度的程度实践/演示出来。")
(=>
(hasSkill ?PROC ?AGENT)
(capability ?PROC agent ?AGENT))
(instance confersNorm TernaryPredicate)
(domain confersNorm 1 Entity)
(domain confersNorm 2 Formula)
(domain confersNorm 3 ObjectiveNorm)
(documentation confersNorm EnglishLanguage "Expresses the relationship between a
&%Formula,an &%Entity, and an &%ObjectiveNorm when the &%Entity brings it about that
the &%Formula has the &%ObjectiveNorm.")
(documentation confersNorm ChineseLanguage "这个概念表达一个 &%Formula 、一个 &%Entity 和一个
&%ObjectiveNorm 之间的关系:就是这个 &%Entity 所表示的 &%Formula 有那个 &%ObjectiveNorm。")
(=>
(holdsDuring ?TIME (confersNorm ?ENTITY ?FORMULA ?NORM))
(and
(holdsDuring (ImmediatePastFn ?TIME) (not (modalAttribute ?FORMULA ?NORM)))
(holdsDuring (ImmediateFutureFn ?TIME) (modalAttribute ?FORMULA ?NORM))))
(instance deprivesNorm TernaryPredicate)
(disjointRelation deprivesNorm confersNorm)
(domain deprivesNorm 1 Entity)
(domain deprivesNorm 2 Formula)
(domain deprivesNorm 3 ObjectiveNorm)
(documentation deprivesNorm EnglishLanguage "Expresses the relationship between an
&%Entity, a &%Formula, and an &%ObjectiveNorm when the &%Entity
brings it about that the &%Formula does not have the &%ObjectiveNorm.")
(documentation deprivesNorm ChineseLanguage "这个概念表达了一个 &%Entity,&%Formula 和一个
&%ObjectiveNorm 之间的关系:就是这个 &%Entity 所表示的 &%Formula 没有那个 &%ObjectiveNorm。")
(=>
(holdsDuring ?TIME (deprivesNorm ?ENTITY ?FORMULA ?NORM))
(and
(holdsDuring (ImmediatePastFn ?TIME) (modalAttribute ?FORMULA ?NORM))
(holdsDuring (ImmediateFutureFn ?TIME) (not (modalAttribute ?FORMULA ?NORM)))))
(instance partlyLocated SpatialRelation)
(instance partlyLocated BinaryPredicate)
(instance partlyLocated TotalValuedRelation)
(domain partlyLocated 1 Physical)
(domain partlyLocated 2 Object)
(documentation partlyLocated EnglishLanguage "(&%partlyLocated ?OBJ1 ?OBJ2) means
that the instance of &%Physical ?OBJ1 is at least partially located at ?OBJ2. For
example, Istanbul is partly located in &%Asia and partly located in &%Europe.
Note that &%partlyLocated is the most basic localization relation: &%located
is an immediate &%subrelation of &%partlyLocated and &%exactlyLocated is
an immediate &%subrelation of &%located.")
(documentation partlyLocated ChineseLanguage "(&%partlyLocated ?OBJ1 ?OBJ2)的意思是
&%Physical 的实例 ?OBJ1 起码有一部分位于 ?OBJ2。例如:伊斯坦布尔有一部分位于 &%Asia, 并有一部分位于
&%Europe。注:&%partlyLocated 是最基本的位置关系: &%located 是 &%partlyLocated 的直接
&%subrelation,而 &%exactlyLocated 是 &%located 的直接 &%subrelation。")
(=>
(and
(instance ?OBJ1 Object)
(partlyLocated ?OBJ1 ?OBJ2))
(overlapsSpatially ?OBJ1 ?OBJ2))
(=>
(and
(instance ?OBJ1 Object)
(partlyLocated ?OBJ1 ?OBJ2))
(exists (?SUB)
(and
(part ?SUB ?OBJ1)
(located ?SUB ?OBJ2))))
(instance located AntisymmetricRelation)
(instance located TransitiveRelation)
(instance located TotalValuedRelation)
(subrelation located partlyLocated)
(domain located 1 Physical)
(domain located 2 Object)
(documentation located EnglishLanguage "(&%located ?OBJ1 ?OBJ2) means that ?OBJ1 is
&%partlyLocated at ?OBJ2, and there is no &%part of ?OBJ1 that is not &%located at
?OBJ2.")
(documentation located ChineseLanguage "(&%located ?OBJ1 ?OBJ2) 的意思是 ?OBJ1
&%partlyLocated 在 ?OBJ2,而且没有一处 ?OBJ1的 &%part 不是 &%located 在?OBJ2。")
(=>
(located ?OBJ1 ?OBJ2)
(forall (?SUB)
(=>
(part ?SUB ?OBJ1)
(located ?SUB ?OBJ2))))
(instance eventPartlyLocated CaseRole)
(instance eventPartlyLocated PartialValuedRelation)
(subrelation eventPartlyLocated partlyLocated)
(domain eventPartlyLocated 1 Process)
(domain eventPartlyLocated 2 Object)
(documentation eventPartlyLocated EnglishLanguage "(&%eventPartlyLocated ?PROC ?OBJ)
means that some &%subProcess of &%Process ?PROC is located in &%Object ?OBJ.")
(documentation eventPartlyLocated ChineseLanguage "(&%eventPartlyLocated ?PROC ?OBJ)
的意思是 &%Process ?PROC 的某些 &%subProcess 是位于 &%Object ?OBJ。")
(termFormat EnglishLanguage eventPartlyLocated "event partly located")
(=>
(eventPartlyLocated ?PROC ?OBJ)
(exists (?SUB)
(and
(subProcess ?SUB ?PROC)
(eventLocated ?SUB ?OBJ))))
(=>
(origin ?PROCESS ?LOC)
(eventPartlyLocated ?PROCESS ?LOC))
(=>
(destination ?PROCESS ?LOC)
(eventPartlyLocated ?PROCESS ?LOC))
(subrelation eventPartlyLocated involvedInEvent)
(subrelation eventLocated eventPartlyLocated)
(instance eventLocated CaseRole)
(instance eventLocated TotalValuedRelation)
(documentation eventLocated EnglishLanguage "(&%eventLocated ?PROC ?OBJ) means that
the entire &%Process ?PROC is located on &%Object ?OBJ, meaning that all &%subProcess
of ?PROC is located on ?OBJ")
(documentation eventLocated ChineseLanguage "(&%eventLocated ?PROC ?OBJ) 的意思是整个
&%Process ?PROC 是位于 &%Object ?OBJ,也就是说所有 ?PROC 的 &%subProcess 是位于 ?OBJ。")
(termFormat EnglishLanguage eventLocated "event located")
(=>
(eventLocated ?PROCESS ?OBJ)
(forall (?SUB)
(=>
(subProcess ?SUB ?PROCESS)
(eventLocated ?SUB ?OBJ))))
(subrelation exactlyLocated located)
(documentation exactlyLocated EnglishLanguage "The actual, minimal location of an
Object. This is a subrelation of the more general &%Predicate
&%located.")
(documentation exactlyLocated ChineseLanguage "这是一个物体的实际和最简约的位置,这是更加概括的
&%Predicate &%located 的子关系。")
(=>
(exactlyLocated ?OBJ ?REGION)
(not
(exists (?OTHEROBJ)
(and
(exactlyLocated ?OTHEROBJ ?REGION)
(not
(equal ?OTHEROBJ ?OBJ))))))
(instance between SpatialRelation)
(instance between TernaryPredicate)
(domain between 1 Object)
(domain between 2 Object)
(domain between 3 Object)
(documentation between EnglishLanguage "(between ?OBJ1 ?OBJ2 ?OBJ3) means that ?OBJ2 is
spatially located between ?OBJ1 and ?OBJ3. Note that this implies that
?OBJ2 is directly between ?OBJ1 and ?OBJ3, i.e. the projections of ?OBJ1
and ?OBJ3 overlap with ?OBJ2.")
(documentation between ChineseLanguage "(between ?OBJ1 ?OBJ2 ?OBJ3) 的意思是 ?OBJ2 在空间上
位于 ?OBJ1 和 ?OBJ3 之间。 注:这意味着 ?OBJ2 正正位于在 ?OBJ1 和?OBJ3 之间,即是 ?OBJ1 和 ?OBJ3
的射影 和 ?OBJ2 的射影重叠。")
(=>
(between ?END1 ?MID ?END2)
(between ?END2 ?MID ?END1))
(documentation betweenOnPath EnglishLanguage "(betweenOnPath ?OBJ1 ?OBJ2 ?OBJ3 ?PATH)
means that ?OBJ2 is spatially located between ?OBJ1 and ?OBJ3 on the path
?PATH. Note that this is a more specialized relation of between since any
object that is between others with respect to a particular path is also
simply between them.")
(documentation betweenOnPath ChineseLanguage "(betweenOnPath ?OBJ1 ?OBJ2 ?OBJ3 ?PATH)
的意思是 ?OBJ2 所处的路径 ?PATH 在空间上位于 ?OBJ1 和 ?OBJ3 之间。注:这是之间的一个更加专门的关系,
因为在一条路径上之间的任何物体,根本就是在它们之间。")
(instance betweenOnPath SpatialRelation)
(instance betweenOnPath QuaternaryPredicate)
(domain betweenOnPath 1 Object)
(domain betweenOnPath 2 Object)
(domain betweenOnPath 3 Object)
(domain betweenOnPath 4 Object)
(=>
(betweenOnPath ?OBJ1 ?OBJ2 ?OBJ3 ?PATH)
(between ?OBJ1 ?OBJ2 ?OBJ3))
(instance traverses BinaryPredicate)
(instance traverses SpatialRelation)
(domain traverses 1 Object)
(domain traverses 2 Object)
(documentation traverses EnglishLanguage "(&%traverses ?OBJ1 ?OBJ2) means that ?OBJ1
crosses or extends across ?OBJ2. Note that &%crosses and
&%penetrates are subrelations of &%traverses.")
(documentation traverses ChineseLanguage "(&%traverses ?OBJ1 ?OBJ2) 的意思是 ?OBJ1 横过或者
是延伸跨越跨 ?OBJ2. 注:&%crosses 和 &%penetrates是 &%traverses 的子类别。")
(=>
(traverses ?OBJ1 ?OBJ2)
(or
(crosses ?OBJ1 ?OBJ2)
(penetrates ?OBJ1 ?OBJ2)))
(subrelation crosses traverses)
(instance crosses AsymmetricRelation)
(instance crosses TransitiveRelation)
(disjointRelation crosses connected)
(documentation crosses EnglishLanguage "(crosses ?OBJ1 ?OBJ2) means that
&%Object ?OBJ1 &%traverses Object ?OBJ2, without being &%connected
to it.")
(documentation crosses ChineseLanguage "(crosses ?OBJ1 ?OBJ2) 的意思是 &%Object ?OBJ1
&%traverses 物体 ?OBJ2,但是并没有和它 &%connected。")
(subrelation penetrates traverses)
(instance penetrates AsymmetricRelation)
(instance penetrates IntransitiveRelation)
(instance penetrates PartialValuedRelation)
(documentation penetrates EnglishLanguage "(penetrates ?OBJ1 ?OBJ2) means that
?OBJ1 is &%connected to ?OBJ2 along at least one whole dimension (length,
width or depth).")
(documentation penetrates ChineseLanguage "(penetrates ?OBJ1 ?OBJ2) 的意思是 ?OBJ1 和 ?OBJ2
起码在一整个维度(长度、阔度或深度) &%connected。")
(=>
(penetrates ?X ?Y)
(meetsSpatially ?X ?Y))
(instance WhereFn BinaryFunction)
(instance WhereFn SpatialRelation)
(instance WhereFn TotalValuedRelation)
(domain WhereFn 1 Physical)
(domain WhereFn 2 TimePoint)
(range WhereFn Region)
(relatedInternalConcept WhereFn WhenFn)
(documentation WhereFn EnglishLanguage "Maps an &%Object and a &%TimePoint at which the
&%Object exists to the &%Region where the &%Object existed at that
&%TimePoint.")
(documentation WhereFn ChineseLanguage "这个函数把一个 &%Object 和 一个 &%TimePoint 连在一起,
它的意思是这个 &%Object 在 &%TimePoint 存在于 &%Region。")
(<=>
(equal (WhereFn ?THING ?TIME) ?REGION)
(holdsDuring ?TIME (exactlyLocated ?THING ?REGION)))
(instance possesses BinaryPredicate)
(instance possesses AsymmetricRelation)
(domain possesses 1 Agent)
(domain possesses 2 Object)
(documentation possesses EnglishLanguage "&%Relation that holds between an &%Agent and
an &%Object when the &%Agent has ownership of the &%Object.")
(documentation possesses ChineseLanguage "这是一个属于一个 &%Agent 和一个 &%Object 的
&%Relation,当这个 &%Agent 拥有这个 &%Object 时,这段关系就成立了。 ")
(=>
(possesses ?PERSON ?OBJ)
(modalAttribute (uses ?OBJ ?PERSON) Permission))
(=>
(and
(instance ?TIME TimePosition)
(holdsDuring ?TIME (possesses ?AGENT1 ?OBJ))
(holdsDuring ?TIME (possesses ?AGENT2 ?OBJ)))
(equal ?AGENT1 ?AGENT2))
(instance PropertyFn UnaryFunction)
(instance PropertyFn TotalValuedRelation)
(domain PropertyFn 1 Agent)
(range PropertyFn Set)
(documentation PropertyFn EnglishLanguage "A &%UnaryFunction that maps an &%Agent to the
&%Set of &%Objects owned by the &%Agent.")
(documentation PropertyFn ChineseLanguage "这是个 &%UnaryFunction,它把一个 &%Agent 和属于
&%Agent 的 &%Object &%Set 联系起来。")
(<=>
(instance ?OBJ (PropertyFn ?PERSON))
(possesses ?PERSON ?OBJ))
(instance precondition BinaryPredicate)
(instance precondition AsymmetricRelation)
(instance precondition TransitiveRelation)
(domainSubclass precondition 1 Process)
(domainSubclass precondition 2 Process)
(documentation precondition EnglishLanguage "A very general &%Predicate. (&%precondition
?PROC1 ?PROC2) means that an instance of ?PROC2 can exist only if an
instance of ?PROC1 also exists.")
(documentation precondition ChineseLanguage "这是一个十分概括的 &%Predicate。(&%precondition
?PROC1 ?PROC2) 的意思是 ?PROC2 的实例只能在 ?PROC1 的实例也存在的时候才能存在。")
(=>
(precondition ?PROC1 ?PROC2)
(=>
(exists (?INST2) (instance ?INST2 ?PROC2))
(exists (?INST1) (instance ?INST1 ?PROC1))))
(instance hindersSubclass BinaryPredicate)
(instance hindersSubclass IrreflexiveRelation)
(instance hindersSubclass PartialValuedRelation)
(domainSubclass hindersSubclass 1 Process)
(domainSubclass hindersSubclass 2 Process)
(documentation hindersSubclass EnglishLanguage "A very general &%Predicate.
(&%hindersSubclass
?PROC1 ?PROC2) means that the &%Process ?PROC1 hindersSubclass or hinders
the occurrence of the &%Process ?PROC2. For example, obstructing an
object hindersSubclass moving it. Note that this is a relation between types
of &%Processes, not between instances.")
(documentation hindersSubclass ChineseLanguage "这是一个十分概括的 &%Predicate,
(&%hindersSubclass ?PROC1 ?PROC2)的意思是 &%Process 类 ?PROC1 &%hindersSubclass 或是阻碍
&%Process 类 ?PROC2 发生。例如:阻挡一个物体 &%hindersSubclass 移动它。注:这是 &%Process 类别之间
的关系,而不是 &%Process 的实例之间的关系。 ")
(=>
(hindersSubclass ?PROC1 ?PROC2)
(forall (?TIME ?PLACE)
(decreasesLikelihood
(holdsDuring ?TIME
(exists (?INST1)
(and
(instance ?INST1 ?PROC1)
(eventLocated ?INST1 ?PLACE))))
(holdsDuring ?TIME
(exists (?INST2)
(and
(instance ?INST2 ?PROC2)
(eventLocated ?INST2 ?PLACE)))))))
(instance preventsSubclass BinaryPredicate)
(instance preventsSubclass IrreflexiveRelation)
(instance preventsSubclass PartialValuedRelation)
(domainSubclass preventsSubclass 1 Process)
(domainSubclass preventsSubclass 2 Process)