/
HEInstaller.class.st
280 lines (212 loc) · 8.18 KB
/
HEInstaller.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
"
I am the entry point to load a package of Hermes.
I am the basic implementation, I can only handle basic cases:
- If there is a new undeclared I produce an error.
- If there is an existing element I produce an error.
For more extended options check HEExtendedEnvironment
Example:
file := 'aFile.hermes'.
installer := HEInstaller new.
reader := HEBinaryReader new
stream: (File named: file) readStream;
yourself.
readPackage := HEPackage readFrom: reader.
installer installPackage: readPackage
"
Class {
#name : #HEInstaller,
#superclass : #Object,
#instVars : [
'environment',
'originalUndeclareds',
'hasTraits'
],
#category : #'Hermes-ClassInstaller'
}
{ #category : #converting }
HEInstaller >> asClassVariables: aString [
| trimmed |
trimmed := aString trimBoth.
trimmed isEmpty
ifTrue: [ ^ #() ].
^ (trimmed substrings: ' ') collect: [:x | x asSymbol => ClassVariable]
]
{ #category : #converting }
HEInstaller >> asSlots: aString [
| trimmed |
trimmed := aString trimBoth.
trimmed isEmpty
ifTrue: [ ^ #() ].
^ (trimmed splitOn: ' ') collect: [ :e | e asSymbol asSlot ] as: Array
]
{ #category : #'creating classes' }
HEInstaller >> build: aHEClass [
| newClass superclass layoutType |
(self existingClass: aHEClass) ifNotNil: [ :x | ^ x ].
superclass := self classNamed: aHEClass superclass.
layoutType := self classNamed: aHEClass layoutClass.
newClass := self class classInstaller make: [ :builder |
builder name: aHEClass className;
superclass: superclass;
layoutClass: layoutType;
slots: (self asSlots: aHEClass instanceVariables);
sharedVariables: (self asClassVariables:aHEClass classVariables);
sharedPools: aHEClass sharedPools;
category: aHEClass category;
classSlots: (self asSlots: aHEClass classInstancevariables);
copyClassSlotsFromExistingClass ].
self processTraitsFrom: aHEClass in: newClass.
^newClass.
]
{ #category : #'creating traits' }
HEInstaller >> buildTrait: aTraitDefinition [
| newTrait traitComposition traitClass|
(self existingTrait: aTraitDefinition) ifNotNil: [:x | ^ x ].
traitComposition := (aTraitDefinition traitComposition asLiteralIn: environment) asTraitComposition.
traitClass := Smalltalk globals at: #Trait ifAbsent: [ self error: 'Trait support is not installed' ].
newTrait := traitClass
named: aTraitDefinition traitName
uses: traitComposition
category: aTraitDefinition category
env: environment.
newTrait classTrait traitComposition: (aTraitDefinition classTraitComposition asLiteralIn: environment) asTraitComposition.
^ newTrait
]
{ #category : #accessing }
HEInstaller >> classNamed: aSymbol [
aSymbol ifNil: [ ^ nil ].
^ self environment at: aSymbol
]
{ #category : #'reporting undeclared' }
HEInstaller >> createdUndeclared [
^ (Undeclared associations reject: [ :asoc | originalUndeclareds associations includes: asoc]) asDictionary
]
{ #category : #'installing package' }
HEInstaller >> doInstallPackage: aHEPackage [
| newTraits newClasses |
"Creating the package. It requires a number of steps.
1. Register the package in the organizer."
RPackageOrganizer default registerPackageNamed: aHEPackage packageName.
"2. Install the traits"
newTraits := aHEPackage traits collect: [ :exportedTrait | self buildTrait: exportedTrait ].
"3. Install traits methods"
aHEPackage traits with: newTraits do: [ :exportedTrait :newTrait | self installMethods: exportedTrait into: newTrait ].
"4. Install classes"
newClasses := aHEPackage classes
collect: [ :exportedClass | self build: exportedClass ].
"5. Install class methods"
aHEPackage classes with: newClasses do: [ :exportedClass :newClass | self installMethods: exportedClass into: newClass ].
"6. Install extension methods"
aHEPackage extensionMethods do: [ :e | self installExtensionMethod: e ].
"7. After all I validate if there are no new undeclared variables created in the environment.
A new undeclared is a sign of an improper modularization."
self validateNoNewUndeclared
]
{ #category : #accessing }
HEInstaller >> environment [
^ environment
]
{ #category : #accessing }
HEInstaller >> environment: anObject [
environment := anObject
]
{ #category : #'validating existance' }
HEInstaller >> existingClass: aHEClass [
(environment hasClassNamed: aHEClass className) ifTrue:[
self error: (self messageExistingClass: aHEClass)
].
^ nil
]
{ #category : #'validating existance' }
HEInstaller >> existingTrait: aHETrait. [
(environment includesKey: aHETrait traitName) ifTrue:[
self error: (self messageExistingTrait: aHETrait)
].
^nil
]
{ #category : #initialization }
HEInstaller >> initialize [
environment := self class environment.
originalUndeclareds := Undeclared copy.
hasTraits := Smalltalk globals hasClassNamed: #Trait.
]
{ #category : #'installing methods' }
HEInstaller >> installExtensionMethod: extensionMethod [
| aClass |
aClass := self environment classNamed: extensionMethod className.
aClass ifNil: [ self error: 'Required class named: ' , extensionMethod className, ' does not exists.' ].
self rebuildMethod: extensionMethod into: aClass.
]
{ #category : #'installing methods' }
HEInstaller >> installMethods: exportedClass into: aClass [
exportedClass methods do: [ :e | self rebuildMethod: e into: aClass ].
exportedClass classSideMethods
do:
[ :e | self rebuildMethod: e into: aClass classSide ]
]
{ #category : #'installing package' }
HEInstaller >> installPackage: aHEPackage [
| storedAnnouncements |
storedAnnouncements := SystemAnnouncer uniqueInstance suspendAllWhileStoring: [ self doInstallPackage: aHEPackage ].
storedAnnouncements do: [ :e | SystemAnnouncer uniqueInstance announce: e ].
]
{ #category : #messages }
HEInstaller >> messageExistingClass: aHEClass [
^ 'The class ' , aHEClass className asString
, ' already exists. Should not be overwritten'
]
{ #category : #messages }
HEInstaller >> messageExistingTrait: aHETrait [
^ 'The trait ' , aHETrait traitName asString
, ' already exists. Should not be overwritten'
]
{ #category : #messages }
HEInstaller >> messageMethod: aHEMethod alreadyExistsIn: aClass [
^ 'The method ' , aHEMethod name asString , ' already exists in class ' , aClass name asString
]
{ #category : #'creating classes' }
HEInstaller >> processTraitsFrom: aHEClass in: newClass [
hasTraits ifFalse: [ ^ self ].
newClass setTraitComposition: (aHEClass traitComposition asLiteralIn: environment) asTraitComposition.
newClass class setTraitComposition: (aHEClass classTraitComposition asLiteralIn: environment) asTraitComposition.
]
{ #category : #'installing methods' }
HEInstaller >> rebuildMethod: aMethod into: aClass [
| newMethod literalSpace extendedEnvironment |
(self shouldBuildMethod: aMethod in: aClass) ifFalse: [ ^ self ].
extendedEnvironment := HEExtendedEnvironment new.
extendedEnvironment inner: environment.
extendedEnvironment newClass: aClass.
extendedEnvironment newSelector: aMethod name.
newMethod := CompiledMethod newMethod: aMethod bytecode size header: (aMethod headerFor: extendedEnvironment).
extendedEnvironment newMethod: newMethod.
aMethod literals
doWithIndex:
[ :literal :idx | newMethod literalAt: idx put: (literal asLiteralIn: extendedEnvironment) ].
newMethod classBinding: aClass binding.
literalSpace := (aMethod literals size + 1) * Smalltalk wordSize.
aMethod bytecode doWithIndex: [ :e :idx | newMethod at: idx + literalSpace put: e ].
aClass
addAndClassifySelector: aMethod name
withMethod: newMethod
inProtocol: aMethod protocol
]
{ #category : #'reporting undeclared' }
HEInstaller >> reportNewUndeclareds: newUndeclareds [
newUndeclareds ifNotEmpty: [ self error: 'New Undeclared created... check dependencies: ' , newUndeclareds keys printString ]
]
{ #category : #'validating existance' }
HEInstaller >> shouldBuildMethod: aHEMethod in: aClass [
aClass
compiledMethodAt: aHEMethod name
ifPresent: [ :m |
(m isFromTrait and:[aClass isTrait not]) ifTrue:[ ^ true ].
self error: (self messageMethod: aHEMethod alreadyExistsIn: aClass ) ]
ifAbsent: [ ^ true ]
]
{ #category : #'reporting undeclared' }
HEInstaller >> validateNoNewUndeclared [
self reportNewUndeclareds: self createdUndeclared.
('[Hermes] Remaining Undeclared variables in the system: '
, Undeclared keys printString) logCr
]