Permalink
Browse files

Added latest stable releases of clutter(-gtk) and cogl

  • Loading branch information...
1 parent a22db76 commit 358f0b21dac606308b74110e80bf56013a8d8544 @pimvullers committed Oct 1, 2012
@@ -0,0 +1,2 @@
+DIST clutter-gtk-1.3.2.tar.xz 309668 SHA256 ee50538daca9447be6ad1ed0d049fbb2dc5a1bcaecd13fda847b9b66f922ee37 SHA512 2a010234cd12f2e277a58f4c0b62deda990176c03f8634d87202edd2cc8e7f780c5faf468288ede640aa12a33d13b2f3dee0733e325ae06c646a335ef7a52873 WHIRLPOOL 6acc90b8bf09d95f069066acdd50a6e088e236d54fcbac3f96f9bd467b950077939f1004fda431e910a00419748d252dd11de5e19e2d5e093a81e0970098905d
+EBUILD clutter-gtk-1.3.2.ebuild 1024 SHA256 5c0c908f9474f6a5d3e2655cd866fb41cd9c58da337b940b08d4f195a1dda73e SHA512 a823864c1a5addd6f319171d0bbf073de104c74ac6d222f52843b59421889492f913a5608df0fd01595e02f651af46a189ca55067d55ca7090f15dc7cee86910 WHIRLPOOL 7f4e7bec31b11a122d414b75c9cbfc8ad67f096b8c776d3d1b3c95c099fb5533a7ed590ab7b63f84a20a680a05eaa53ab5ae9fd9cf76579da5cdcd640ff29182
@@ -0,0 +1,35 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter-gtk/clutter-gtk-1.2.0.ebuild,v 1.4 2012/07/14 13:21:33 blueness Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+CLUTTER_LA_PUNT="yes"
+
+# inherit clutter after gnome2 so that defaults aren't overriden
+inherit gnome2 clutter gnome.org
+
+DESCRIPTION="Clutter-GTK - GTK+3 Integration library for Clutter"
+
+SLOT="1.0"
+KEYWORDS="~alpha ~amd64 ~mips ~ppc ~ppc64 ~x86"
+IUSE="doc examples +introspection"
+
+# XXX: Needs gtk with X support (!directfb)
+RDEPEND="
+ >=x11-libs/gtk+-3.2.0:3[introspection?]
+ >=media-libs/clutter-1.9.16:1.0[introspection?]
+ introspection? ( >=dev-libs/gobject-introspection-0.9.12 )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ >=sys-devel/gettext-0.18
+ doc? ( >=dev-util/gtk-doc-1.14 )"
+
+pkg_setup() {
+ DOCS="NEWS README"
+ EXAMPLES="examples/{*.c,redhand.png}"
+ G2CONF="${G2CONF}
+ --disable-maintainer-flags
+ --enable-deprecated
+ $(use_enable introspection)"
+}
@@ -0,0 +1,2 @@
+DIST clutter-1.12.0.tar.xz 5009984 SHA256 e75130a5df6dbe97e8d350259278331c6352b2d213230712127160e42053e558 SHA512 3abe986b255687f04eea73ab24f34515a18d4928bd2e3390372f08a6d6945f73fa1d6620f9f51de47b0e0c4a26011bc86ffbae31990ad774bdef9a61333b98a2 WHIRLPOOL 8cd77e4edf161eb7deac3002e26da6d9e738e8a87eb1537c78b8c6387f4b728da825afd0758c922f0e1737c401382e085f608b8a4c4b2dc9a96f6d0c5098e2cc
+EBUILD clutter-1.12.0.ebuild 3068 SHA256 2611a67578bf24abda7fbd97ed44870c8da10e037512ee16d84270a07bb486af SHA512 29fb76f18f92acda2b35d11a8cbc37b9582877a4f6e1439c5ce69b07021865bd8b07ad72b4d58ae30e35e3d1157c8820704961ce143bb132aa5a5ebf36b7a78e WHIRLPOOL d149b66fe0fe8942d941a4b8f7bee64774a45552afa58bc7dfe6c81ceebc60a19674181bbd19ecdef004caffc296f11671b27067f89bfe5606f30eae616fdbcc
@@ -0,0 +1,113 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/clutter/clutter-1.10.8.ebuild,v 1.2 2012/07/14 13:19:30 blueness Exp $
+
+EAPI="4"
+CLUTTER_LA_PUNT="yes"
+WANT_AUTOMAKE="1.11"
+
+# Inherit gnome2 after clutter to download sources from gnome.org
+# since clutter-project.org doesn't provide .xz tarballs
+inherit clutter gnome2 virtualx
+if [[ ${PV} = 9999 ]]; then
+ inherit gnome2-live
+fi
+
+DESCRIPTION="Clutter is a library for creating graphical user interfaces"
+
+LICENSE="LGPL-2.1+ FDL-1.1+"
+SLOT="1.0"
+IUSE="debug doc gtk +introspection test" # evdev tslib
+if [[ ${PV} = 9999 ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~alpha ~amd64 ~mips ~ppc ~ppc64 ~x86"
+fi
+
+# NOTE: glx flavour uses libdrm + >=mesa-7.3
+# XXX: uprof needed for profiling
+# >=libX11-1.3.1 needed for X Generic Event support
+RDEPEND="
+ >=dev-libs/glib-2.31.19:2
+ >=dev-libs/atk-2.5.3[introspection?]
+ >=dev-libs/json-glib-0.12[introspection?]
+ >=media-libs/cogl-1.9.6:1.0[introspection?,pango]
+ media-libs/fontconfig
+ >=x11-libs/cairo-1.10[glib]
+ >=x11-libs/pango-1.30[introspection?]
+
+ virtual/opengl
+ x11-libs/libdrm
+ >=x11-libs/libX11-1.3.1
+ x11-libs/libXext
+ x11-libs/libXdamage
+ x11-proto/inputproto
+ >=x11-libs/libXi-1.3
+ >=x11-libs/libXfixes-3
+ >=x11-libs/libXcomposite-0.4
+
+ gtk? ( >=x11-libs/gtk+-3.3.18:3 )
+ introspection? ( >=dev-libs/gobject-introspection-0.9.6 )"
+DEPEND="${RDEPEND}
+ >=dev-util/gtk-doc-am-1.15
+ virtual/pkgconfig
+ >=sys-devel/gettext-0.17
+ doc? (
+ >=dev-util/gtk-doc-1.15
+ >=app-text/docbook-sgml-utils-0.6.14[jadetex]
+ dev-libs/libxslt )
+ test? ( x11-libs/gdk-pixbuf )"
+
+# Tests fail with both swrast and llvmpipe
+# They pass under r600g, so the bug is in mesa
+RESTRICT="test"
+
+pkg_setup() {
+ DOCS="README NEWS ChangeLog*"
+
+ # XXX: Conformance test suite (and clutter itself) does not work under Xvfb
+ # XXX: Profiling, coverage disabled for now
+ # XXX: What about cex100/egl/osx/wayland/win32 backends?
+ # XXX: evdev/tslib input seem to be experimental?
+ myconf="--enable-debug=minimum"
+ use debug && myconf="--enable-debug=yes"
+ G2CONF="${G2CONF} ${myconf}
+ --enable-xinput
+ --enable-x11-backend=yes
+ --disable-profile
+ --disable-maintainer-flags
+ --disable-gcov
+ --disable-cex100-backend
+ --disable-egl-backend
+ --disable-quartz-backend
+ --disable-wayland-backend
+ --disable-win32-backend
+ --disable-tslib-input
+ --disable-evdev-input
+ $(use_enable gtk gdk-backend)
+ $(use_enable introspection)
+ $(use_enable doc docs)
+ $(use_enable test conformance)
+ $(use_enable test gdk-pixbuf)"
+}
+
+src_prepare() {
+ gnome2_src_prepare
+
+ # We only need conformance tests, the rest are useless for us
+ sed -e 's/^\(SUBDIRS =\).*/\1/g' \
+ -i tests/Makefile.am || die "am tests sed failed"
+ sed -e 's/^\(SUBDIRS =\)[^\]*/\1/g' \
+ -i tests/Makefile.in || die "in tests sed failed"
+}
+
+src_test() {
+ # Run only the conformance tests
+ # The perf tests are useless because we run under sw rendering
+ cd tests/
+ Xemake test conform
+}
+
+src_install() {
+ clutter_src_install
+}
@@ -0,0 +1,3 @@
+AUX cogl-1.12.0-fix-experimental-doc-build.patch 1346 SHA256 f2db37267346ec3be8f42d1aa638f52b396b9399489fb2ddbc13f4599c4a2338 SHA512 60a3399359740c93c348ab7a1c4ab888b936c2f1cc9b52b9be02eb76080cf879fce93a527f158e22d6cebe0999f1fc3ecdb611c63632ad5309886f3cc6c599d6 WHIRLPOOL db6f563527fa5a44d7b3610cae97fcc6e7a7f9bf183e4418f0eed687ea82d2c53b40d5c04d927f61ad03b1840caa9a1262b4981e6e70e170d8090c05d6b738e1
+DIST cogl-1.12.0.tar.xz 1295520 SHA256 4e7b5abbf0a1e51d74618db1b513551e7c71b486e17e98373f4db93e7710e2f2 SHA512 fa776f1cd15a5d9803d29ced8f9ed3103f0838db7351a37832eb0697d728806f2a40187d7b850674e586adf8dd5da783c985968503c200bec34cff43897544bc WHIRLPOOL 5b466cd649cdd75b7246e94c8664e732f65b4260332ac3a5aae608c8965354bf15369e5727505200a1fc46a3e1266b56449fb8b0045cee8e72153eee508cfee3
+EBUILD cogl-1.12.0.ebuild 2770 SHA256 36f6b06bd56ace6c364d4087456a4dec2250857ae66a8416faa2ebb7e5b60b72 SHA512 c5081f1f91fc13d69da7bda418a830d9a7a8da812030828ea0d51d8442f158d607792de64f02f0d950fb19beeb8304cad2549478fa7b17d02c6d618917da3164 WHIRLPOOL cb8b640a7cf2c59f1fc3cf9ace8ae8a6a9e194b270ea47628c6cfe6e46a494fea3aa8e7730d0253cbfed1ad70b12771658b90507ba32bcd8eca86aa6b4e5139a
@@ -0,0 +1,99 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+CLUTTER_LA_PUNT="yes"
+
+# Inherit gnome2 after clutter to download sources from gnome.org
+inherit eutils clutter gnome2 multilib virtualx
+if [[ ${PV} = 9999 ]]; then
+ inherit gnome2-live
+fi
+
+DESCRIPTION="A library for using 3D graphics hardware to draw pretty pictures"
+HOMEPAGE="http://www.clutter-project.org/"
+
+LICENSE="LGPL-2.1+ FDL-1.1+"
+SLOT="1.0"
+IUSE="doc examples +introspection +opengl gles2 +pango"
+if [[ ${PV} = 9999 ]]; then
+ KEYWORDS=""
+else
+ KEYWORDS="~alpha ~amd64 ~mips ~ppc ~ppc64 ~x86"
+fi
+
+# XXX: need uprof for optional profiling support
+COMMON_DEPEND=">=dev-libs/glib-2.28.0:2
+ x11-libs/cairo
+ >=x11-libs/gdk-pixbuf-2:2
+ x11-libs/libdrm
+ x11-libs/libX11
+ >=x11-libs/libXcomposite-0.4
+ x11-libs/libXdamage
+ x11-libs/libXext
+ >=x11-libs/libXfixes-3
+ virtual/glu
+ virtual/opengl
+ gles2? ( media-libs/mesa[gles2] )
+
+ introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+ pango? ( >=x11-libs/pango-1.20.0[introspection?] )"
+# before clutter-1.7, cogl was part of clutter
+RDEPEND="${COMMON_DEPEND}
+ !<media-libs/clutter-1.7"
+DEPEND="${COMMON_DEPEND}
+ sys-devel/gettext
+ virtual/pkgconfig
+ doc? ( app-text/docbook-xml-dtd:4.1.2
+ >=dev-util/gtk-doc-1.13 )
+ test? ( app-admin/eselect-opengl
+ media-libs/mesa[classic] )"
+# Need classic mesa swrast for tests, llvmpipe causes a test failure
+
+pkg_setup() {
+ DOCS="NEWS README"
+ EXAMPLES="examples/{*.c,*.jpg}"
+ # XXX: think about kms-egl, gles, quartz, sdl, wayland
+ G2CONF="${G2CONF}
+ --disable-examples-install
+ --disable-profile
+ --disable-maintainer-flags
+ --enable-cairo
+ --enable-gdk-pixbuf
+ $(use_enable opengl glx)
+ $(use_enable opengl gl)
+ $(use_enable gles2)
+ $(use_enable gles2 cogl-gles2)
+ $(use_enable gles2 xlib-egl-platform)
+ --enable-glib
+ --enable-deprecated
+ $(use_enable introspection)
+ $(use_enable pango cogl-pango)"
+ use gles2 && G2CONF="${G2CONF} --with-default-driver=gles2"
+}
+
+src_prepare() {
+ # https://bugzilla.gnome.org/show_bug.cgi?id=684731
+ epatch "${FILESDIR}/${PN}-1.12.0-fix-experimental-doc-build.patch"
+ gnome2_src_prepare
+}
+
+src_test() {
+ # Use swrast for tests, llvmpipe is incomplete and "test_sub_texture" fails
+ # NOTE: recheck if this is needed after every mesa bump
+ if [[ "$(eselect opengl show)" != "xorg-x11" ]]; then
+ ewarn "Skipping tests because a binary OpenGL library is enabled. To"
+ ewarn "run tests for ${PN}, you need to enable the Mesa library:"
+ ewarn "# eselect opengl set xorg-x11"
+ return
+ fi
+ LIBGL_DRIVERS_PATH="${EROOT}/usr/$(get_libdir)/mesa" Xemake check
+}
+
+src_install() {
+ clutter_src_install
+
+ # Remove silly examples-data directory
+ rm -rvf "${ED}/usr/share/cogl/examples-data/" || die
+}
@@ -0,0 +1,33 @@
+Author: Dimitri <mitya@mageia.org>
+
+Build breaks on cogl-2.0-experimental docs
+
+https://bugzilla.gnome.org/show_bug.cgi?id=684731
+
+--- a/cogl/cogl-context.h
++++ b/cogl/cogl-context.h
+@@ -72,19 +72,19 @@
+ * help applications control the lifetime a context without us needing to
+ * introduce special api to handle the breakup of internal circular
+ * references due to internal resources and caches associated with the
+- * context.
++ * context.</note>
+ *
+- * One a context has been destroyed then all directly or indirectly
++ * <note>One a context has been destroyed then all directly or indirectly
+ * dependant resources will be in an inconsistent state and should not
+- * be manipulated or queried in any way.
++ * be manipulated or queried in any way.</note>
+ *
+- * For applications that rely on the operating system to clean up
++ * <note>For applications that rely on the operating system to clean up
+ * resources this policy shouldn't affect them, but for applications
+ * that need to carefully destroy and re-create Cogl contexts multiple
+ * times throughout their lifetime (such as Android applications) they
+ * should be careful to destroy all context dependant resources, such as
+ * framebuffers or textures etc before unrefing and destroying the
+- * context.<note>
++ * context.</note>
+ */
+
+ #ifdef COGL_ENABLE_EXPERIMENTAL_API

0 comments on commit 358f0b2

Please sign in to comment.