Skip to content
This repository
Fetching contributors…

Cannot retrieve contributors at this time

file 722 lines (574 sloc) 19.799 kb
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722
# Copyright 2001-2003, Paul Johnson (pjcj@cpan.org)

# This software is free. It is licensed under the same terms as Perl itself.

# The latest version of this software should be available from my homepage:
# http://www.pjcj.net

package Devel::Cover;

use strict;
use warnings;

our @ISA = qw( DynaLoader );
our $VERSION = "0.22";

use DynaLoader ();

use Devel::Cover::DB 0.22;
use Devel::Cover::Inc 0.22;

use B qw( class ppname main_cv main_start main_root walksymtable OPf_KIDS );
use B::Debug;
use B::Deparse;

use Cwd ();

use Data::Dumper;

BEGIN { eval "use Pod::Coverage 0.06" } # We'll use this if it is available.

my $Silent = 0; # Output nothing.

my $DB = "cover_db"; # DB name.
my $Indent = 1; # Data::Dumper indent.
my $Merge = 1; # Merge databases.

my @Ignore; # Packages to ignore.
my @Inc; # Original @INC to ignore.
my @Select; # Packages to select.

my $Pod = $INC{"Pod/Coverage.pm"}; # Do pod coverage.
my %Pod; # Pod coverage data.

my $Summary = 1; # Output coverage summary.

my @Cvs; # All the Cvs we want to cover.
my $Cv; # Cv we are looking in.

my $Coverage; # Raw coverage data.
my $Cover; # Coverage data.

my %Criteria; # Names of coverage criteria.
my %Coverage; # Coverage criteria to collect.

my $Cwd = Cwd::cwd(); # Where we start from.

use vars qw($File $Line $Collect %Files);

($File, $Line, $Collect) = ("", 0, 1);

BEGIN { @Inc = @Devel::Cover::Inc::Inc }
# BEGIN { $^P = 0x02 | 0x04 | 0x100 }
BEGIN { $^P = 0x04 | 0x100 }

CHECK
{
    check_files();

    # reset_op_seq(main_root);
    # reset_op_seq($_->ROOT) for @Cvs;

    set_coverage(keys %Coverage);

    my @coverage = get_coverage();
    my $last = pop @coverage;
    print __PACKAGE__, " $VERSION: Collecting coverage data for ",
          join(", ", @coverage),
          @coverage ? " and " : "",
          "$last.\n",
          "Selecting packages matching:", join("\n ", "", @Select), "\n",
          "Ignoring packages matching:", join("\n ", "", @Ignore), "\n",
          "Ignoring packages in:", join("\n ", "", @Inc), "\n"
        unless $Silent;
}

END { report() }

sub import
{
    my $class = shift;

    # print __PACKAGE__, ": Parsing options from [@_]\n";

    @Inc = () if "@_" =~ /-inc /;
    while (@_)
    {
        local $_ = shift;
        /^-silent/ && do { $Silent = shift; next };
        /^-db/ && do { $DB = shift; next };
        /^-indent/ && do { $Indent = shift; next };
        /^-merge/ && do { $Merge = shift; next };
        /^-summary/ && do { $Summary = shift; next };
        /^-coverage/ &&
            do { $Coverage{+shift} = 1 while @_ && $_[0] !~ /^[-+]/; next };
        /^-ignore/ &&
            do { push @Ignore, shift while @_ && $_[0] !~ /^[-+]/; next };
        /^[-+]inc/ &&
            do { push @Inc, shift while @_ && $_[0] !~ /^[-+]/; next };
        /^-select/ &&
            do { push @Select, shift while @_ && $_[0] !~ /^[-+]/; next };
        warn __PACKAGE__ . ": Unknown option $_ ignored\n";
    }

    for my $c (Devel::Cover::DB->new->criteria)
    {
        my $func = "coverage_$c";
        no strict "refs";
        $Criteria{$c} = $func->();
    }

    %Coverage = map { $_ => 1 } qw(statement branch condition time)
         unless keys %Coverage;
}

sub cover_names_to_val
{
    my $val = 0;
    for my $c (@_)
    {
        if (exists $Criteria{$c})
        {
            $val |= $Criteria{$c};
        }
        elsif ($c eq "all" || $c eq "none")
        {
            my $func = "coverage_$c";
            no strict "refs";
            $val |= $func->();
        }
        else
        {
            warn __PACKAGE__ . qq(: Unknown coverage criterion "$c" ignored.\n);
        }
    }
    $val;
}

sub set_coverage
{
    set_criteria(cover_names_to_val(@_));
}

sub add_coverage
{
    add_criteria(cover_names_to_val(@_));
}

sub remove_coverage
{
    remove_criteria(cover_names_to_val(@_));
}

sub get_coverage
{
    return unless defined wantarray;
    my @names;
    my $val = get_criteria();
    for my $c (sort keys %Criteria)
    {
        push @names, $c if $val & $Criteria{$c};
    }
    return wantarray ? @names : "@names";
}

my %File_cache;

sub get_location
{
    my ($op) = @_;

    $File = $op->file;
    $Line = $op->line;

    # warn "$File::$Line\n";

    # If there's an eval, get the real filename. Enabled from $^P & 0x100.

    ($File, $Line) = ($1, $2) if $File =~ /^\(eval \d+\)\[(.*):(\d+)\]/;

    if (exists $File_cache{$File})
    {
        $File = $File_cache{$File};
        return;
    }

    my $file = $File;

    $File =~ s/ \(autosplit into .*\)$//;
    $File =~ s/^$Cwd\///;
    # $File =~ s/^blib\///;
    # $File =~ s/^lib\///;

    $File_cache{$file} = $File;

    # warn "File: $file => $File\n";
}

sub use_file
{
    my ($file) = @_;
    $file = $1 if $file =~ /^\(eval \d+\)\[(.*):\d+\]/;
    $file =~ s/ \(autosplit into .*\)$//;
    $file =~ s|\.\./\.\./lib/POSIX.pm|$INC{"POSIX.pm"}|e;
    # print "checking <$file>\n";
    my $files = \%Files;
    return $files->{$file} if exists $files->{$file};
    for (@Select) { return $files->{$file} = 1 if $file =~ /$_/ }
    for (@Ignore) { return $files->{$file} = 0 if $file =~ /$_/ }
    for (@Inc) { return $files->{$file} = 0 if $file =~ /^\Q$_\// }
    $files->{$file} = -e $file;
    warn __PACKAGE__ . qq(: Can't find file "$file": ignored.\n)
        unless $Silent || ($files->{$file} || $file =~ /\(eval \d+\)/);
    $files->{$file}
}

sub check_file
{
    my ($cv) = @_;

    return unless class($cv) eq "CV";

    my $op = $cv->START;
    return unless $op->can("file") && class($op) ne "NULL" && is_state($op);

    my $file = $op->file;
    my $use = use_file($file);
    # printf "%6s $file\n", $use ? "use" : "ignore";

    $use
}

sub B::GV::find_cv
{
    my $cv = $_[0]->CV;
    return unless $$cv;

    push @Cvs, $cv if check_file($cv);
    push @Cvs, grep check_file($_), $cv->PADLIST->ARRAY->ARRAY
        if $cv->PADLIST->can("ARRAY") &&
           $cv->PADLIST->ARRAY &&
           $cv->PADLIST->ARRAY->can("ARRAY");
};

sub check_files
{
    # print "Checking files\n";

    @Cvs = grep check_file($_), B::main_cv->PADLIST->ARRAY->ARRAY;

    my %seen_pkg;

    walksymtable(\%main::, "find_cv", sub { !$seen_pkg{$_[0]}++ });

    # print Dumper \%seen_pkg;
    # print Dumper \%Files;
}

sub report
{
    my @collected = get_coverage();
    # print "Collected @collected\n";
    return unless @collected;
    set_coverage("none");

    # print "Processing cover data\n@Inc\n";

    $Coverage = coverage() || die "No coverage data available.\n";

    # print Dumper $Coverage;

    check_files();

    get_cover(main_cv, main_root);
    # print "init, ", Dumper \B::begin_av;
    # print "init array, ", Dumper B::begin_av->ARRAY;
    get_cover($_) for B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
    get_cover($_) for B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
    get_cover($_) for B::init_av ->isa("B::AV") ? B::init_av ->ARRAY : ();
    get_cover($_) for B::end_av ->isa("B::AV") ? B::end_av ->ARRAY : ();
    get_cover($_) for @Cvs;

    for my $file (keys %$Cover)
    {
        my $use = use_file($file);
        # warn sprintf "%-4s using $file\n", $use ? "" : "not";
        delete $Cover->{$file} unless $use;
    }

    my $cover = Devel::Cover::DB->new
    (
        cover => $Cover,
        collected => [ @collected ],
    );
    my $existing;
    eval
    {
        $existing = Devel::Cover::DB->new(db => $DB,
                                          collected => [ @collected ])
            if $Merge
    };
    $cover->merge($existing) if $existing;
    $cover->indent($Indent);
    $cover->write($DB);
    $cover->print_summary if $Summary && !$Silent;
}

sub add_statement_cover
{
    my ($op) = @_;

    get_location($op);
    return unless $File;

    return unless $Collect;

    # print "Statement: ", $op->name, "\n";

    my $key = pack("I*", $$op) . pack("I*", $op->seq);
    push @{$Cover->{$File}{statement}{$Line}},
         [[$Coverage->{statement}{$key} || 0]];
    push @{$Cover->{$File}{time}{$Line}},
         [[$Coverage->{time}{$key}]]
        if exists $Coverage->{time} && exists $Coverage->{time}{$key};
}

sub add_branch_cover
{
    return unless $Collect && $Coverage{branch};

    my ($op, $type, $text, $file, $line) = @_;

    $text =~ s/^\s+//;
    $text =~ s/\s+$//;

    my $key = pack("I*", $$op) . pack("I*", $op->seq);
    # print STDERR "Branch cover from $file:$line $type:$text\n";

    my $c = $Coverage->{condition}{$key};
    # print STDERR Dumper $c;
    if ($type eq "and")
    {
        shift @$c;
        $c = [ ($c->[2] || 0), ($c->[0] || 0) + ($c->[1] || 0) ];
    }
    elsif ($type eq "or")
    {
        shift @$c;
        $c = [ ($c->[2] || 0) + ($c->[0] || 0), ($c->[1] || 0) ];
    }
    else
    {
        $c = $Coverage->{branch}{$key} || [0, 0];
    }

    push @{$Cover->{$file}{branch}{$line}},
         [
             [ map($_ || 0, @$c) ],
             {
                 text => $text,
             },
         ];
}

sub add_condition_cover
{
    return unless $Collect;

    my ($op, $strop, $left, $right) = @_;

    my $key = pack("I*", $$op) . pack("I*", $op->seq);
    # print STDERR "Condition cover from $File:$Line\n";

    my $type = $op->name;
    $type =~ s/assign$//;

    my $c = $Coverage->{condition}{$key};
    shift @$c;

    my $count;

    if ($type eq "or")
    {
        if ($op->first->sibling->name eq "const")
        {
            $c = [ ($c->[2] || 0), ($c->[0] || 0) + ($c->[1] || 0) ];
            $count = 2;
        }
        else
        {
            @$c = @{$c}[2, 1, 0];
            $count = 3;
        }
    }
    elsif ($type eq "and")
    {
        @$c = @{$c}[2, 0, 1];
        $count = 3;
    }
    elsif ($type eq "xor")
    {
        # !l&&!r l&&!r l&&r !l&&r
        @$c = @{$c}[2, 1, 3, 0];
        $count = 4;
    }
    else
    {
        die qq(Unknown type "$type" for conditional);
    }

    push @{$Cover->{$File}{condition}{$Line}},
         [
             $c,
             {
                 type => "${type}_${count}",
                 op => $strop,
                 left => $left,
                 right => $right,
             },
         ];
}

sub is_scope { &B::Deparse::is_scope }
sub is_state { &B::Deparse::is_state }
sub is_ifelse_cont { &B::Deparse::is_ifelse_cont }

{

no warnings "redefine";

my $original_deparse;
BEGIN { $original_deparse = \&B::Deparse::deparse }

sub B::Deparse::deparse
{
    my $self = shift;
    my ($op, $cx) = @_;

    my $class = class($op);
    my $null = $class eq "NULL";

    my $name = $op->can("name") ? $op->name : "Unknown";

    # print "Deparse <$name>\n";

    if ($Collect)
    {
        # Get the coverage on this op.

        if ($class eq "COP" && $Coverage{statement})
        {
            add_statement_cover($op);
        }
        elsif (!$null && $name eq "null"
                      && ppname($op->targ) eq "pp_nextstate"
                      && $Coverage{statement})
        {
            # If the current op is null, but it was nextstate, we can still
            # get at the file and line number, but we need to get dirty.

            bless $op, "B::COP";
            add_statement_cover($op);
            bless $op, "B::$class";
        }
        elsif ($name eq "cond_expr")
        {
            local ($File, $Line) = ($File, $Line);
            my $cond = $op->first;
            my $true = $cond->sibling;
            my $false = $true->sibling;
            if (!($cx < 1 && (is_scope($true) && $true->name ne "null") &&
                    (is_scope($false) || is_ifelse_cont($false))
                    && $self->{'expand'} < 7))
            {
                my ($file, $line) = ($File, $Line);
                { local $Collect; $cond = $self->deparse($cond, 8) }
                add_branch_cover($op, "if", "$cond ? :", $file, $line);
            }
            else
            {
                my ($file, $line) = ($File, $Line);
                { local $Collect; $cond = $self->deparse($cond, 1) }
                add_branch_cover($op, "if", "if ($cond) { }", $file, $line);
                while (class($false) ne "NULL" && is_ifelse_cont($false))
                {
                    my $newop = $false->first;
                    my $newcond = $newop->first;
                    my $newtrue = $newcond->sibling;
                    # last in chain is OP_AND => no else
                    $false = $newtrue->sibling;
                    my ($file, $line) = ($File, $Line);
                    { local $Collect; $newcond = $self->deparse($newcond, 1) }
                    add_branch_cover($newop, "elsif", "elsif ($newcond) { }",
                                     $file, $line);
                }
            }
        }
    }

    my $d = eval { $original_deparse->($self, @_) };
    $@ ? "Deparse error: $@" : $d
}

sub B::Deparse::logop
{
    my $self = shift;
    my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
    my $left = $op->first;
    my $right = $op->first->sibling;
    my ($file, $line) = ($File, $Line);
    if ($cx < 1 && is_scope($right) && $blockname && $self->{expand} < 7)
    {
        # if ($a) {$b}
        $left = $self->deparse($left, 1);
        $right = $self->deparse($right, 0);
        add_branch_cover($op, $lowop, "$blockname ($left)", $file, $line);
        return "$blockname ($left) {\n\t$right\n\b}\cK"
    }
    elsif ($cx < 1 && $blockname && !$self->{parens} && $self->{expand} < 7)
    {
        # $b if $a
        $right = $self->deparse($right, 1);
        $left = $self->deparse($left, 1);
        add_branch_cover($op, $lowop, "$blockname $left", $file, $line);
        return "$right $blockname $left"
    }
    elsif ($cx > $lowprec && $highop)
    {
        # $a && $b
        $left = $self->deparse_binop_left($op, $left, $highprec);
        $right = $self->deparse_binop_right($op, $right, $highprec);
        add_condition_cover($op, $highop, $left, $right);
        return $self->maybe_parens("$left $highop $right", $cx, $highprec)
    }
    else
    {
        # $a and $b
        $left = $self->deparse_binop_left($op, $left, $lowprec);
        $right = $self->deparse_binop_right($op, $right, $lowprec);
        add_condition_cover($op, $lowop, $left, $right);
        return $self->maybe_parens("$left $lowop $right", $cx, $lowprec)
    }
}

sub B::Deparse::logassignop {
    my $self = shift;
    my ($op, $cx, $opname) = @_;
    my $left = $op->first;
    my $right = $op->first->sibling->first; # skip sassign
    $left = $self->deparse($left, 7);
    $right = $self->deparse($right, 7);
    add_condition_cover($op, $opname, $left, $right);
    return $self->maybe_parens("$left $opname $right", $cx, 7);
}

}

sub get_cover
{
    my $deparse = B::Deparse->new("-l");

    my $cv = $deparse->{curcv} = shift;

    if ($Pod && $Coverage{pod})
    {
        my $gv = $cv->GV;
        unless ($gv->isa("B::SPECIAL"))
        {
            my $stash = $gv->STASH;
            my $pkg = $stash->NAME;
            my $file = $cv->FILE;
            if ($Pod{$file} ||= Pod::Coverage->new(package => $pkg))
            {
                my $sub_name = $cv->GV->SAFENAME;
                get_location($cv->START);
                my $covered;
                for ($Pod{$file}->covered)
                {
                    $covered = 1, last if $_ eq $sub_name;
                }
                unless ($covered)
                {
                    for ($Pod{$file}->uncovered)
                    {
                        $covered = 0, last if $_ eq $sub_name;
                    }
                }
                push @{$Cover->{$File}{pod}{$Line}[0]}, $covered if defined $covered;
            }
        }
    }

    @_ ? $deparse->deparse(shift, 0) : $deparse->deparse_sub($cv, 0)
}

sub get_cover_x
{
    my $cv = shift;
    printf "get_cover_x %p\n", $cv;
    print "cv - $cv - ", Dumper $cv;
    print ">>>";
    print get_cover($cv);
    print "<<<\n";
}

bootstrap Devel::Cover $VERSION;

1

__END__

=head1 NAME

Devel::Cover - Code coverage metrics for Perl

=head1 SYNOPSIS

perl -MDevel::Cover yourprog args
cover cover_db -report html

perl -MDevel::Cover=-db,cover_db,-coverage,statement,time yourprog args

To test an uninstalled module:



=head1 DESCRIPTION

This module provides code coverage metrics for Perl.

If you can't guess by the version number this is an alpha release.

Code coverage data are collected using a pluggable runops function which
counts how many times each op is executed. These data are then mapped
back to reality using the B compiler modules. There is also a statement
profiling facility which needs a better backend to be really useful.

The B<cover> program can be used to generate coverage reports.

Statement, branch, condition, pod and time coverage information is
reported. Statement coverage data should be reasonable, although there
may be some statements which are not reported. Branch and condition
coverage data should be mostly accurate too. These data should be
mostly accurate, although not always what one might initially expect.
Pod coverage comes from Pod::Coverage. Coverage data for path coverage
are not yet collected.

The B<gcov2perl> program can be used to convert gcov files to
Devel::Cover databases.

You may find that the results don't match your expectations. I would
imagine that at least one of them is wrong.

THe most appropriate mailing list on which to discuss this module would
be perl-qa. Discussion has migrated there from perl-qa-metrics which is
now defunct. http://lists.perl.org/showlist.cgi?name=perl-qa

Requirements:

Perl 5.6.1 or greater. (Perl 5.7.0 is also unsupported.)
The ability to compile XS extensions.
Pod::Coverage if you want pod coverage.
Template Toolkit 2 if you want HTML output.

=head1 OPTIONS

-coverage criterion - Turn on coverage for the specified criterion. Criteria
include statement, branch, path, pod, time, all and none.
-db cover_db - Store results in coverage db (default ./cover_db).
-inc path - Set prefixes of files to ignore (default @INC).
+inc path - Append to prefixes of files to ignore.
-ignore RE - Ignore files matching RE.
-indent indent - Set indentation level to indent. Don't use this.
-merge val - Merge databases, for multiple test benches (default on).
-profile val - Turn on profiling iff val is true (default on).
-select RE - Only report on files matching RE.
-summary val - Print summary information iff val is true (default on).

=head1 ACKNOWLEDGEMENTS

Some code and ideas cribbed from:

Devel::OpProf
B::Concise
B::Deparse

=head1 SEE ALSO

Devel::Cover::Tutorial
Data::Dumper
B
Pod::Coverage

=head1 BUGS

Did I mention that this is alpha code?

See the BUGS file.

=head1 VERSION

Version 0.22 - 2nd September 2003

=head1 LICENCE

Copyright 2001-2003, Paul Johnson (pjcj@cpan.org)

This software is free. It is licensed under the same terms as Perl itself.

The latest version of this software should be available from my homepage:
http://www.pjcj.net

=cut
Something went wrong with that request. Please try again.