CMakeLists.txt

cmake_minimum_required(VERSION 3.20)

project(pocketpy)

if(PK_BUILD_SHARED_LIB OR NOT PK_BUILD_STATIC_MAIN)
    set(CMAKE_POSITION_INDEPENDENT_CODE ON)
endif()

set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED ON)

include(CMakeOptions.txt)

if(WIN32)
    add_definitions(-D_CRT_SECURE_NO_WARNINGS)
endif()

if(MSVC)
    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /utf-8 /jumptablerdata")
    add_compile_options(/wd4267 /wd4244 /wd4146 /wd4819 /experimental:c11atomics)
    if(PK_ENABLE_DETERMINISM)
        add_compile_options(/fp:precise)
    endif()

    if(NOT CMAKE_BUILD_TYPE STREQUAL "Debug")
        set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /Ox")
        add_definitions(-DNDEBUG)
    endif()

    # if(CMAKE_BUILD_TYPE STREQUAL "Debug")
    #     message(">> Enable Address Sanitizer")
    #     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /fsanitize=address /Zi")
    # endif()
else()
    if(NOT CMAKE_BUILD_TYPE STREQUAL "Debug")
        set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -O2")
        add_definitions(-DNDEBUG)
    endif()

    if(APPLE)
        set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-shorten-64-to-32")
    else()
        set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-pointer-to-int-cast -Wno-int-to-pointer-cast")
    endif()

    if(PK_ENABLE_DETERMINISM)
        add_compile_options(-fno-fast-math -ffp-contract=off)
        # x87's extended intermediates violate the binary64 kernel contract.
        if(CMAKE_SIZEOF_VOID_P EQUAL 4 AND CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x86_64|AMD64)$")
            add_compile_options(-msse2 -mfpmath=sse)
        endif()
    endif()
endif()

include_directories(${CMAKE_CURRENT_LIST_DIR}/include)
file(GLOB_RECURSE POCKETPY_SRC ${CMAKE_CURRENT_LIST_DIR}/src/*.c)


if(PK_ENABLE_OS)
    add_definitions(-DPK_ENABLE_OS=1)
else()
    add_definitions(-DPK_ENABLE_OS=0)
endif()

if(PK_ENABLE_THREADS)
    add_definitions(-DPK_ENABLE_THREADS=1)
else()
    add_definitions(-DPK_ENABLE_THREADS=0)
endif()

if(PK_ENABLE_DLL)
    add_definitions(-DPK_ENABLE_DLL=1)
else()
    add_definitions(-DPK_ENABLE_DLL=0)
endif()

if(PK_ENABLE_DETERMINISM)
    add_definitions(-DPK_ENABLE_DETERMINISM=1)
else()
    add_definitions(-DPK_ENABLE_DETERMINISM=0)
endif()

if(PK_ENABLE_WATCHDOG)
    add_definitions(-DPK_ENABLE_WATCHDOG=1)
else()
    add_definitions(-DPK_ENABLE_WATCHDOG=0)
endif()

if(PK_ENABLE_CUSTOM_SNAME)
    add_definitions(-DPK_ENABLE_CUSTOM_SNAME=1)
else()
    add_definitions(-DPK_ENABLE_CUSTOM_SNAME=0)
endif()

if(PK_ENABLE_MIMALLOC)
    message(">> Fetching mimalloc")
    include(FetchContent)
    
    FetchContent_Declare(
        mimalloc
        GIT_REPOSITORY https://github.com/microsoft/mimalloc.git
        GIT_TAG        v3.1.5
    )

    set(MI_OVERRIDE OFF CACHE BOOL "" FORCE)
    set(MI_NO_USE_CXX ON CACHE BOOL "" FORCE)
    set(MI_BUILD_SHARED OFF CACHE BOOL "" FORCE)
    set(MI_BUILD_OBJECT OFF CACHE BOOL "" FORCE)
    set(MI_BUILD_STATIC ON CACHE BOOL "" FORCE)
    set(MI_BUILD_TESTS OFF CACHE BOOL "" FORCE)
    FetchContent_MakeAvailable(mimalloc)
    include_directories(${mimalloc_SOURCE_DIR}/include)

    add_definitions(-DPK_ENABLE_MIMALLOC=1)
else()
    add_definitions(-DPK_ENABLE_MIMALLOC=0)
endif()


if(PK_BUILD_MODULE_LZ4)
    add_subdirectory(3rd/lz4)
    add_definitions(-DPK_BUILD_MODULE_LZ4)
endif()

if(PK_BUILD_MODULE_CUTE_PNG)
    add_subdirectory(3rd/cute_png)
    add_definitions(-DPK_BUILD_MODULE_CUTE_PNG)
endif()

if(PK_BUILD_MODULE_MSGPACK)
    add_subdirectory(3rd/msgpack)
    add_definitions(-DPK_BUILD_MODULE_MSGPACK)
endif()

if(PK_BUILD_MODULE_PERIPHERY)
    add_subdirectory(3rd/periphery)
    add_definitions(-DPK_BUILD_MODULE_PERIPHERY)
endif()

if(PK_BUILD_SHARED_LIB)
    message(">> Building shared library")
    add_library(${PROJECT_NAME} SHARED ${POCKETPY_SRC})
elseif(PK_BUILD_STATIC_LIB)
    message(">> Building static library")
    add_library(${PROJECT_NAME} STATIC ${POCKETPY_SRC})
else()
    if(PK_BUILD_STATIC_MAIN)
        message(">> Building static library + executable")
        add_library(${PROJECT_NAME} STATIC ${POCKETPY_SRC})
    else()
        message(">> Building shared library + executable")
        add_library(${PROJECT_NAME} SHARED ${POCKETPY_SRC})
    endif()
    add_executable(main src2/main.c)
    target_link_libraries(main ${PROJECT_NAME})
endif()

target_include_directories(
    ${PROJECT_NAME}
    INTERFACE
    ${CMAKE_CURRENT_LIST_DIR}/include
)

if(PK_ENABLE_THREADS)
    find_package(Threads REQUIRED)
    target_link_libraries(${PROJECT_NAME} Threads::Threads)
endif()

if(UNIX AND NOT APPLE)
    if(PK_ENABLE_OS AND PK_ENABLE_DLL)
        target_link_libraries(${PROJECT_NAME} dl)
    endif()
elseif(WIN32)
    target_link_libraries(${PROJECT_NAME} ws2_32)
endif()

if(PK_BUILD_WITH_UNITY)
    set_source_files_properties(${POCKETPY_SRC} PROPERTIES UNITY_GROUP "pocketpy")
    set_target_properties(${PROJECT_NAME} PROPERTIES UNITY_BUILD_MODE GROUP)
    set_target_properties(${PROJECT_NAME} PROPERTIES UNITY_BUILD ON)
endif()

############################################
if(PK_BUILD_MODULE_LZ4)
    target_link_libraries(${PROJECT_NAME} lz4)
endif()

if(PK_BUILD_MODULE_CUTE_PNG)
    target_link_libraries(${PROJECT_NAME} cute_png)
endif()

if(PK_BUILD_MODULE_MSGPACK)
    target_link_libraries(${PROJECT_NAME} msgpack)
endif()

if(PK_BUILD_MODULE_PERIPHERY)
    target_link_libraries(${PROJECT_NAME} periphery-ffi)
endif()
############################################

if(PK_ENABLE_MIMALLOC)
    target_link_libraries(${PROJECT_NAME} mimalloc-static)
endif()

if(PK_BUILD_MATH_TESTS)
    enable_testing()
    # Compile the kernels directly so the test also works with DLL builds that
    # intentionally do not export the internal dmath symbols.
    set(DMATH_TEST_SOURCES src2/test_dmath.c src/common/dmath.c
                           src/common/dmath_zig.c src/common/dmath_openlibm.c)
    add_executable(test_dmath ${DMATH_TEST_SOURCES})
    add_executable(test_dmath_soft_sqrt ${DMATH_TEST_SOURCES})
    target_compile_definitions(test_dmath_soft_sqrt PRIVATE PK_DMATH_SOFT_SQRT=1)
    if(UNIX)
        target_link_libraries(test_dmath m)
        target_link_libraries(test_dmath_soft_sqrt m)
    endif()
    set(DMATH_CASE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/tests/dmath/cases)
    foreach(function isfinite isinf isnan isnormal fabs copysign fmin fmax
                     ceil floor trunc modf fmod sqrt cbrt exp exp2 exp10 pow
                     log log2 log10 log_base sin cos tan sincos asin acos atan atan2)
        add_test(NAME dmath.${function}
                 COMMAND test_dmath --cases ${DMATH_CASE_DIR} ${function})
    endforeach()
    add_test(NAME dmath.sqrt_software
             COMMAND test_dmath_soft_sqrt --cases ${DMATH_CASE_DIR} sqrt)
endif()