Skip to content
This repository

HTTPS clone URL

Subversion checkout URL

You can clone with HTTPS or Subversion.

Download ZIP
branch: master
Fetching contributors…

Cannot retrieve contributors at this time

file 201 lines (145 sloc) 4.894 kb
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201
import processing.serial.*;
import geomerative.*; // http://www.ricardmarxer.com/geomerative/

Serial serialPort;
PFont font;

RPoint[] points;

int i = 0;
float scaleFactor = 1.3;
int msgQueue[];
int lstMsg; //last message sent
int wait = 0; // Variable um den Start der seriellen Kommunikation zu verzögern
boolean msgLock; // Plotqueue sperren, bis Antwort vom Arduino da ist

void setup() {

    msgQueue = new int[0];
    println(Serial.list());
    serialPort = new Serial(this, Serial.list()[0], 9600);

    // Setze Serialbuffer-Größe auf 4 Bytes
    serialPort.buffer(4);

    // Arbeitsfläche (Drawing Canvas) erstellen
    size(800, 800);

    background(255);

    // Linienfarbe auf Schwarz setzen
    stroke(0);

    // Create font object for drawing text
    font = createFont("Verdana", 14);

    // Load given svg file in sketch/data
    RG.init(this);

    RShape objShape = RG.loadShape("spirale.svg");

    // Break lines into smaller steps
    points = objShape.getPoints();

}

void draw() {

    // Warteschleife am Anfang weil sich sonst die serielle Kommunikation verschluckt
    if (wait == 0) {
        delay(2000);
        wait = 1;
    }

    // Plotqueue abarbeiten
    parseQueue();

    // Solange noch Punkte im Array sind Linie von Punkt zu Punkt zeichnen
    if (i < points.length - 1) {

        // Objekt auf der Arbeitsfläche zeichnen
        line(points[i].x * scaleFactor, points[i].y * scaleFactor,
             points[i + 1].x * scaleFactor, points[i + 1].y * scaleFactor);

        // Zwischenpunkte zischen den beiden koordinaten berechnen und dann in
        // die Plotqueue schreiben
        move(round(points[i].x * scaleFactor), round(points[i].y * scaleFactor),
             round(points[i + 1].x * scaleFactor), round(points[i + 1].y * scaleFactor));

    } else {

        // Motoren releasen nachdem geplottet wurde
        if (wait == 1) {
            queueMessage(16);
            wait = 2;
        }
    }

    // Nächster Punkt
    i++;
}

// Bresenham Linienalgorithmus
void move(int x0, int y0, int x1, int y1) {

    int md1, md2, s_s1, s_s2, ox, oy;

    int dx = abs(x1-x0)
        ,sx = (x0 < x1)? 1 : -1;

    int dy = abs(y1-y0)
        ,sy = (y0 < y1)? 1 : -1;

    int err = ((dx > dy)? dx : -dy)/2, e2;

    // Zwischenpunkte berechnen und die Bewegung in die Plotqueue schreiben
    for (;;) {

        ox = x0;
        oy = y0;

        if (x0 == x1 && y0 == y1) {
            break;
        }

        e2 = err;
        if (e2 > -dx) {
            err -= dy;
            x0 += sx;
        }

        if (e2 < dy) {
            err += dx;
            y0 += sy;
        }

        /*
* die Bewegung wird über bitcodierte Steuerbefehle an die serielle Schnittstelle geschickt.
* 0001: x0, y+ (1)
* 0010: x0, y- (2)
* 0100: x+, y0 (4)
* 1000: x-, y0 (8)
* 0101: x+, y+ (5)
* 0110: x+, y- (6)
* 1010: x-, y- (10)
* 1001: x-, y+ (9)
*/

        int movement = 0; //Bewegungsvariable auf Null setzen

        // Bewegungsbits setzen
        if (y0 < oy) { // runter
            movement |= 2;
        }

        if (y0 > oy) { // rauf
            movement |= 1;
        }

        if (x0 < ox) { // links
            movement |= 4;
        }

        if (x0 > ox) { // rechts
            movement |= 8;
        }

        // Steuerbefehl in die Plotqueue schreiben
        queueMessage(movement);
    }
}


// Plotqueue befüllen
public void queueMessage(int msg) {
    msgQueue = append(msgQueue, msg);
}


// Steuerbefehle per serial an den Arduino schicken
private void parseQueue() {

    // Solange noch was in der queue liegt, und sie nicht gesperrt ist...
      if(msgQueue.length > 0 && !msgLock) {
      msgLock = true; //Plotqueue sperren, damit keine Steuerbefehle verloren gehen
      lstMsg = msgQueue[0]; //queue the first message on the stack
      writeSerial(lstMsg);
      println("writing message: " + lstMsg);
      msgQueue = subset(msgQueue, 1);
    }

}

// auf Antwort vom Arduino warten und dann die Plotqueue wieder freigeben
void serialEvent(Serial serialPort) {

    if (serialPort.available() > 0) {

        String message = serialPort.readString(); // read serial buffer

        println(msgQueue.length);

        // Rest vom Serial-Inputbuffer löschen, falls irgendwas "übrig" ist
        serialPort.clear();

        // wenn Antwort vom Arduino da ist, Meldung ausgeben und Sperrung aufheben
        if (int(message) == 9999) {
            println("Anweisung durchgeführt");
            msgLock = false;
        }
    }

}

private void writeSerial(int msg) {

    if (serialPort.available() > 0) {
        serialPort.clear(); // Serial Port vor dem Senden leeren
    }
    serialPort.write(msg);

}
Something went wrong with that request. Please try again.