Sub Calculate()

'

'This programs calcuates total volume, yearly change, greatest % increase, greatest % decrease, percentage change and high/low

'for all the ticker names listed on each spreadsheet.

'Each worksheet contains data for seperate years.

'Each ticker name will

'

'Variables

'

Dim TotalStockVolume As Double 'Calculates total volume for each stock

Dim YearlyChange As Double 'Calcualates the yearly change in price for a stock

Dim GreatestInc As Double 'Keeps track of which stock has the largest percent increase in price

Dim GreatestDec As Double 'Keeps track of which stock has the largest percent decrease in price

Dim GreatestVolume As Double 'Keeps track of which stock has the largest annual total volume

Dim PercentChange As Double 'Calculates the percent change in stock price for a stock

Dim StockHigh As Double 'Highest price for a stock for a given year

Dim StockLow As Double 'Lowest price for a stock for a given year

Dim HighDate As Double 'Date of the highest value

Dim LowDate As Double 'Date of the lowest vlue

Dim TickerName As String 'Keeps track of the stock ticker name

Dim StockClose As Double 'Keeps track of the closing price for a stock

Dim StockOpen As Double 'Keeps track of the opening price for a stock

Dim FirstTime As Boolean 'Determines if this is the first record read for a stock

Dim DataTableRow As Double 'Used to write data to the correct row number

Dim TickerNameIncrease As String 'Keeps track of ticker name for stock with greatest annual increase

Dim TickerNameDecrease As String 'Keeps track of ticker name for stock with greatest annual decrease

Dim TickerNameVolume As String 'Keeps track of ticker name for stock with greatest total volume

For Each ws In Worksheets

'

'Create new headings for all the worksheets

'

ws.Range("I1").Value = "Ticker"

ws.Range("J1").Value = "Yearly Change"

ws.Range("K1").Value = "Percent Change"

ws.Range("L1").Value = "Total Stock Volume"

ws.Range("M1").Value = "Open Value"

ws.Range("N1").Value = "Close Value"

ws.Range("O1").Value = "High Value"

ws.Range("P1").Value = "High Date"

ws.Range("Q1").Value = "Low Value"

ws.Range("R1").Value = "Low Date"

ws.Range("S2").Value = "Greatest % Increase"

ws.Range("S3").Value = "Greatest % Decrease"

ws.Range("S4").Value = "Greatest Total Volume"

ws.Range("T1").Value = "Ticker"

ws.Range("U1").Value = "Volume"

'

'Format Column K and cells Q2 and Q3 to be percentage

'

ws.Columns("K").NumberFormat = "0.00%"

ws.Range("U2").NumberFormat = "0.00%"

ws.Range("U3").NumberFormat = "0.00%"

'

'Find the last row of the spreadsheet

'

LastRow = ws.Cells(Rows.Count, "A").End(xlUp).Row

'

'Begin calculation of stock information

'

'Initialize variables

'

FirstTime = True

DataTableRow = 2

GreatestInc = 0

GreatestDec = 0

GreatestVolume = 0

PercentChange = 0

StockHigh = 0

StockLow = 0

For r = 2 To LastRow

If ws.Cells(r, 1).Value = ws.Cells(r + 1, 1).Value Then 'Check if Stock Ticker Name is the same

TotalStockVolume = TotalStockVolume + ws.Cells(r, 7) 'Accumulate Stock Volume for Ticker Name

If FirstTime Then 'Perform if first time a record is read for Ticker Name

StockOpen = ws.Cells(r, 3)

TickerName = ws.Cells(r, 1)

StockHigh = ws.Cells(r, 4)

StockLow = ws.Cells(r, 5)

HighDate = ws.Cells(r, 2)

LowDate = ws.Cells(r, 2)

FirstTime = False

End If

If ws.Cells(r, 4).Value > StockHigh Then

StockHigh = ws.Cells(r, 4)

HighDate = ws.Cells(r, 2)

End If

If ws.Cells(r, 5).Value < StockLow Then

StockLow = ws.Cells(r, 5)

LowDate = ws.Cells(r, 2)

End If

Else 'Perform when reading last record for Ticker Name

TotalStockVolume = TotalStockVolume + ws.Cells(r, 7)

If ws.Cells(r, 4).Value > StockHigh Then

StockHigh = ws.Cells(r, 4)

HighDate = ws.Cells(r, 2)

End If

If ws.Cells(r, 5).Value < StockLow Then

StockLow = ws.Cells(r, 5)

LowDate = ws.Cells(r, 2)

End If

StockClose = ws.Cells(r, 6)

YearlyChange = StockClose - StockOpen

If StockOpen <> 0 Then 'Check for divide by zero

PercentChange = (YearlyChange / StockOpen)

Else

PercentChange = 1

End If

ws.Cells(DataTableRow, 9).Value = TickerName 'Assign values accumulated or calculated to correct cells

ws.Cells(DataTableRow, 10).Value = YearlyChange

ws.Cells(DataTableRow, 11).Value = PercentChange

ws.Cells(DataTableRow, 12).Value = TotalStockVolume

ws.Cells(DataTableRow, 13).Value = StockOpen

ws.Cells(DataTableRow, 14).Value = StockClose

ws.Cells(DataTableRow, 15).Value = StockHigh

ws.Cells(DataTableRow, 16).Value = HighDate

ws.Cells(DataTableRow, 17).Value = StockLow

ws.Cells(DataTableRow, 18).Value = LowDate

If YearlyChange >= 0 Then 'Conditional formatting. Green(4) if = or > 0, Red(3) if < 0.

ws.Cells(DataTableRow, 10).Interior.ColorIndex = 4

Else

ws.Cells(DataTableRow, 10).Interior.ColorIndex = 3

End If

If PercentChange > GreatestInc Then 'Find the greatest percent increase for all the stocks listed on spreadsheet

TickerNameIncrease = ws.Cells(r, 1).Value

GreatestInc = PercentChange

End If

If PercentChange < GreatestDec Then 'Find the greatest percent decrease for all the stocks listed on spreadsheet

TickerNameDecrease = ws.Cells(r, 1).Value

GreatestDec = PercentChange

End If

If TotalStockVolume > GreatestVolume Then 'Find the largest stock volume for all the stocks listed on spreadsheet

TickerNameVolume = ws.Cells(r, 1).Value

GreatestVolume = TotalStockVolume

End If

DataTableRow = DataTableRow + 1 'Increase DataTableRow by one, used to print data for each Ticker Name

TotalStockVolume = 0 'Initialize variables for each evaluation of new Ticker Name

FirstTime = True

PercentChange = 0

StockHigh = 0

StockLow = 0

End If

Next r

ws.Range("T2").Value = TickerNameIncrease 'Assign values to cells for greatest increase, decrease & volume

ws.Range("T3").Value = TickerNameDecrease

ws.Range("T4").Value = TickerNameVolume

ws.Range("U2").Value = GreatestInc

ws.Range("U3").Value = GreatestDec

ws.Range("U4").Value = GreatestVolume

'

'Autofit columns I through U

'

ws.Columns("I:U").AutoFit

Next ws

End Sub