
**Unity的渲染路径**

在Unity中，渲染路径决定了光照是如何应用到Unity Shader中的。因此，如果要和光源打交道，我们需要为每个Pass指定它使用的渲染路径，只有这样才能让Unity知道，“哦，原来这个程序员想要这种渲染路径，那么好的，我把光源和处理后的光照信息都放在这些数据里，你可以访问啦”，也就是说，我们只有为Shader正确的选择和设置了需要的渲染路径，该Shader的光照计算才能被正确执行。

Unity支持多种类型的渲染路径。在Unity 5.0版本以前，主要有3种：前向渲染路径（Forward Rendering Path）、延迟渲染路径（Deferred Rendering Path）和顶点照明渲染路径（Vertex Lit Rendering Path）。但在Unity 5.0以后，Unity做了很多更改，主要有两个变化：S后弦，顶点照明渲染路径已经被Unity抛弃（但目前仍然可以对之前使用了顶点照明渲染路径的Unity Shader兼容）；其次，新的延迟渲染路径代替了原来的延迟渲染路径（同样，目前也提供了对旧版本的兼容）


**需要注意的是，如果当前的显卡并不支持所渲染的渲染路径，Unity会自动使用更低一级的渲染路径。例如，如果一个GPU不支持延迟渲染，那么Unity就会使用前向渲染。在Unity 5.x中如果使用了前向渲染又没有为Pass指定任何前向渲染适合的标签，就会被当成一个和顶点照明渲染路径等同的Pass，那么一些光照变量很可能不会被正确赋值，我们计算出的效果也很可能有错误**



**Unity中的前向渲染**

事实上，一个Pass不仅仅可以用来计算逐像素光照，它也可以用来计算逐顶点等其他光照。这取决于光照计算所处流水线阶段以及计算时使用的数学模型。当我们渲染一个物体时，Unity会计算那些光照照亮了它，以及这些关照照亮该物体的方式。

在Unity中，前向渲染路径有3种处理光照的方式：逐顶点处理、逐像素处理、球谐喊函数处理。而决定一个光源使用哪种处理模式取决于它的类型和渲染模式。光源类型指的是该光源是平行光还是其他类型的光源，而光源的渲染模式指的是该光源是否是重要的。如果我们把一个光照的模式设置为Important，意味着我们告诉Unity，“嘿老兄，这个光源很重要，我希望你可以认真对待它，把它当成一个逐像素光源来处理”，我们可以在光源的Light组件中设置这些属性：



在前向渲染中，当我们渲染一个物体时，Unity会根据场景中各个光源的设置以及这些光源对物体的影响程度（例如，距离该物体的远近、光源强度等）对这些光源进行一个重要度排序。其中，一定数量的光源会按逐像素的方式处理，然后由最多4个光源按逐顶点的方式处理，剩下的光源可以按照SH方式处理。Unity使用的判断规则如下：

1）场景中最亮的平行光总是按逐像素处理的

2）渲染模式被设置成Not Important的光源会按照逐顶点或者SH处理

3）渲染模式被设置成Important的光源，会按逐像素处理


4）如果根据以上规则得到的逐像素光源数量小于Quality Setting中的逐像素光源数量（Pixel Light Count），会有更多的光源以逐像素的方式进行渲染

对于Base Pass来说，它处理的逐像素光源类型一定是平行光，如果场景中没有任何的平行光，那么Base Pass会当成全黑的光源处理，如果有多个平行光，Unity会选择最亮的平行光传递给Base Pass进行逐像素处理，其他的平行光会按照逐顶点或者在Additional Pass中按逐像素处理

在Quality Setting中有：



那么，在哪里进行光照计算？当然是在pass里，前面提到过，前向渲染有两种Pass：Base Pass和Additional Pass。通常来说，这两种Pass进行的标签和渲染设置以及常规光照计算如下图所示：




对于上图有几点需要说明的地方：

1. 首先可以发现在渲染设置中，我们除了设置了Pass的标签外，还使用了#pragma multi\_compile\_fwdbase这样的编译命令。虽然#pragma multi\_compile\_fwdbase和#pragma multi\_compile\_fwdadd在官方文档中还没有给出相关说明，但实验表明，只有分别为Base Pass和Additional Pass使用这两个编译指令，我们才可以在相关的Pass中得到一些正确的光照变量，例如光照衰减值
2. Base Pass旁边的注释给出了Base Pass中支持的一些光照特性。例如，在Base Pass中，我们可以访问光照纹理。
3. Base Pass中渲染的平行光默认是支持阴影的（如果开启了光源的阴影功能），而Additional Pass中渲染的光源在默认情况下是没有阴影效果的，即便我们在它的Light组件在宏设置了有阴影的Shadow Type。但我们可以在Additional Pass中使用#pragma multi\_compile\_fwdadd\_fullshadows代替#pragma multi\_compile\_fwdadd编译指令，为点光源和聚光灯开启阴影效果，但这需要Unity在内部使用更多的Shader变种
4. 环境光和自发光也是在Base Pass中计算的。这是因为，对于一个物体来说，环境光和自发光我们只希望计算一次即可，而如果我们在Additional Pass中计算着两种光照，就会造成叠加多次环境光和自发光，这不是我们想要的
5. 在Additional Pass的渲染设置中，我们还开启和设置了混合模式。这是因为，我们希望每个Additional Pass可以与上一次的光照结果在帧缓冲中进行叠加，从而得到最终的有多个光照的渲染效果。如果我们没有开启和设置混合模式，那么Additional Pass的渲染结果会覆盖掉之前的渲染结果，看起来就好像改物体只受到该光源的影响。通常情况下我们选择的混合模式是Blend One One
6. 对于前向渲染来说，一个Unity Shader通常会定义一个Base Pass（Base Pass也可以定义多次，例如需要双面渲染等情况）以及一个Additional Pass。一个Base Pass仅会执行一次（定义了多个Base Pass的情况除外），而一个Additional Pass会根据影响该物体的其它逐像素光源的数目被多次调用，即每个逐像素光源会执行一次Additional Pass。

**Unity中的顶点照明渲染路径**

顶点照明渲染路径是对硬件配置要求最少、运算性能最高，但同时也是得到的效果最差的一种类型，它不支持哪些逐像素才能得到的效果，例如阴影、法线映射、高精度的高光反射等。实际上，它仅仅是前向渲染路径的一个子集，也就是说，所有可以在顶点照明渲染路径中实现的功能都可以在前向渲染路径中完成。就如它的名字一样，顶点照明渲染路径只是使用了逐顶点的方式来计算光照，并没有什么神奇的地方。实际上，我们在上面的前向渲染路径中也可以计算一些逐顶点的光源。但如果选择使用顶点照明渲染路径，那么Unity只会填充那些逐顶点相关的光源变量，意味着我们不可以使用一些逐像素光照变量。

在Unity中，我们可以在一个顶点照明Pass中最多访问到8个逐顶点光源，如果我们只需要渲染其中两个光源对物体的照明，可以仅仅使用下表内置光照数据的前两个。如果影响该物体的光源数量小于8，那么数组中剩下的光源颜色会设置成黑色。



**Unity中的延迟渲染路径**

除了前向渲染中使用的颜色缓冲和深度缓冲外，延迟渲染还会利用额外的缓冲区，这些缓冲区被统称为G缓冲，G是应为geometry的缩写。G缓冲区存储了我们所关心的表面（通常指的是离摄像机最近的表面）的其他信息，例如该表面的法线、位置、用于光照计算的材质属性等。

延迟渲染主要包含了两个Pass。在第一个Pass中，我们不进行任何光照计算，而是仅仅计算那些片元是可见的，这主要是通过深度缓冲技术来实现，当法线一个片元是可见的，我们就把它的相关信息存储到G缓冲区中。然后，在第二个Pass中，我们利用G缓冲区的各个片元信息，例如表面法线、视角方向、满发射系数等，仅仅真正的光照计算。我们可以看出，延迟渲染使用的Pass数目通常就是两个，这跟场景中包含的光源数目是没有关系的。换句话说，延迟渲染的效率不依赖于场景的复杂度，而是和我们使用的屏幕空间的大小有关。这是因为，我们需要的信息都存储在缓冲区中，而这些缓冲区可以理解成是一张张2D图像，我们的计算实际上就是在这些图像空间中进行的。

延迟渲染有一些缺点：

1. 不支持真正的抗锯齿功能
2. 不能处理半透明物体
3. 对显卡有一定要求。如要要使用延迟渲染的话，显卡必须支持MRT（Multiple Render Targets）、Shader Mode 3.0以上、深度渲染纹理以及双面的模板缓冲

默认的G缓冲区（注意，不同Unity版本的渲染纹理存储内容会有所不同）包含了一下几个渲染纹理（Render Texture，RT）

1. RT0：格式是ARGB32，RGB通道用于存储漫反射颜色，A通道没有被使用
2. RT1：格式是ARGB32，RGB通道用于存储高光反射颜色，A通道用于存储高光发射的指数部分
3. RT2：格式是ARGB2101010，RGB通道用于存储法线，A通道没有被使用
4. RT3：格式是ARGB32（非HDR）或ARGBHalf（HDR），用于存储自发光+lightmao+反射探针（reflection probes）
5. 深度缓冲和模板缓冲

测试一下前向渲染：

Shader "Unlit/ForwardRendering"

{

Properties

{

\_Gloss ("Gloss", Range(9.0, 256.0)) = 20.0

}

SubShader

{

pass

{

Tags { "LightMode" = "ForwardBase" }

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#pragma multi\_compile\_fwdbase

#include "UnityCG.cginc"

#include "Lighting.cginc"

float \_Gloss;

struct a2v

{

float4 vertex : POSITION;

float3 normal : NORMAL;

};

struct v2f

{

float4 position : SV\_POSITION;

float3 worldNormal : TEXCOORD0;

float4 worldPosition : TEXCOORD1;

};

v2f vert(a2v v)

{

v2f o;

o.position = mul(UNITY\_MATRIX\_MVP, v.vertex);

o.worldNormal = UnityObjectToWorldNormal(v.normal);

o.worldPosition = mul(unity\_ObjectToWorld, v.vertex);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

// ambient

float3 ambient = UNITY\_LIGHTMODEL\_AMBIENT.rgb;

// diffuse

fixed3 worldNormal = normalize(o.worldNormal);

fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(o.worldPosition));

fixed3 diffuse = \_LightColor0.rgb \* saturate(dot(worldNormal, worldLightDir));

// specular

fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(o.worldPosition));

fixed3 halfViewDir = normalize(worldLightDir + worldViewDir);

fixed3 specular = \_LightColor0.rgb \* pow(saturate(dot(halfViewDir, worldNormal)), \_Gloss);

return fixed4(diffuse + specular, 1.0);

//return fixed4(0.0, 1.0, 0.0, 1.0);

}

ENDCG

}

pass

{

Tags { "LightMode" = "ForwardAdd" }

Blend One One

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#pragma multi\_compile\_fwdadd

#include "UnityCG.cginc"

#include "Lighting.cginc"

#include "AutoLight.cginc"

float \_Gloss;

struct a2v

{

float4 vertex : POSITION;

float3 normal : NORMAL;

};

struct v2f

{

float4 position : SV\_POSITION;

float3 worldNormal : TEXCOORD0;

float4 worldPosition : TEXCOORD1;

};

v2f vert(a2v v)

{

v2f o;

o.position = mul(UNITY\_MATRIX\_MVP, v.vertex);

o.worldNormal = UnityObjectToWorldNormal(v.normal);

o.worldPosition = mul(unity\_ObjectToWorld, v.vertex);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

// diffuse

fixed3 worldNormal = normalize(o.worldNormal);

fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(o.worldPosition));

fixed3 diffuse = \_LightColor0.rgb \* saturate(dot(worldNormal, worldLightDir));

// specular

fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(o.worldPosition));

fixed3 halfViewDir = normalize(worldLightDir + worldViewDir);

fixed3 specular = \_LightColor0.rgb \* pow(saturate(dot(halfViewDir, worldNormal)), \_Gloss);

fixed atten = 1.0;

#ifdef USING\_DIRECTIONAL\_LIGHT

atten = 1.0;

#else

float3 lightCoord = mul(unity\_WorldToLight, o.worldPosition).xyz;

atten = tex2D(\_LightTexture0, dot(lightCoord, lightCoord).rr).UNITY\_ATTEN\_CHANNEL;

#endif

//return fixed4((diffuse + specular) \* 1, 1.0);

return fixed4(1.0, 0.0, 0.0, 1.0);

}

ENDCG

}

}

FallBack "Diffuse"

}

在上面的例子中，ForwardBase渲染路径得到了正常的光照颜色，在ForwardAdd渲染路径中始终返回红色

我们设置了#pragma multi\_compile\_fwdbase与#pragma multi\_compile\_fwdadd，这两个指令可以保证我们在Base Pass与Additional Pass中访问到正确的光照变量。与Base Pass不同的是，我们还使用Blend命令开启和设置了混合模式，如果没有Blend命令的话，Additional Pass会直接覆盖掉之前的光照结果，因为Base Pass只执行一次，而Additional Pass会执行剩下的光源，需要与颜色缓冲区的已有颜色进行混合，同时，由于Additional Pass处理的光源类型可能是平行光、点光源或是聚光灯，因此区分了光源类型。如果是平行光的话衰减值为1.0，对于非平行光会有强度衰减，我们可以使用数学表达式来计算给定点相对于点光源和聚光灯的衰减，但这些计算往往涉及到开根号、除法等计算量较大的操作，因此Unity选择了使用一张纹理作为查找表（Lookup Table，LUT），以在片元着色器中得到光源的衰减。我们首先得到光源空间下的坐标，然后使用该坐标对衰减纹理进行采样得到衰减值。

在之前的表中，我们可以看到

ForwardBase用于前向渲染，该Pass会计算环境光、最重要的平行光、逐顶点/SH光源和Lightmaps

ForwardAdd用于前向渲染，该Pass会计算额外的逐像素光源，每个Pass对应一个光源

对于ForwardBase Pass来说，它处理的逐像素光源类型一定是平行光

也就是说场景中的Pixel光源数为n，则ForwardAdd Pass会被执行n-1次

Light组件的Render Mode决定该光源是顶点光还是像素光

1）在没有任何光照时



2）没有平行光只有一个点光源时

说明此时点光源为ForwardAdd

3）没有平行光只有一个点光源时，且点光源为Not Important

说明ForwardAdd处理的是逐像素光源，逐顶点光源没有效果

4）只有一个绿色平行光时

也就是说此时执行的是ForwardBase

5）只有一个绿色平行光，并且设置该平行光的Render Mode为Not Important时

必须是处理逐像素的平行光？

6）有两个平行光，增加了一个白色的平行光

如果两个的Render Mode都是Not Important



如果两个都设置为Auto或者Important

我们设置绿色的光照强度为1.4，白色的光照强度为0.65



我们设置绿色的光照强度为1.4，白色的光照强度为1



也就是说这两个平行光一个执行了ForwardBase，一个执行了ForwardAdd

7）在添加几个点光源

发现都是执行的ForwardAdd，并且如果将点光源设置为Not Important时点光源都不会有效果，这是因为我们没有再Base Pass中计算逐顶点和SH光源

8）将相机的Rendering Path改为Vertex Lit

即使我们将ForwardBase的像素着色器修改为返回固定的绿色，仍然是这样的显示

也就是说着两类Pass不能在Camera为VertexLit时被渲染，但可以被渲染路径为Forward和Deffered的Camera渲染

可以注意到，Unity处理这些点光源的顺序是按照他们的重要度排序的，但是Unity官方文档中并没有给出光源强度、颜色和距离物体的远近是如何具体影响光源的重要度排序的，我们仅知道排序结果和这三者都有关系。同时，对于场景中的一个物体，如果它不在一个光源的光照范围内，Unity是不会为这个物体调用Pass来处理这个光源的。可以通过Frame Debugger的渲染事件查看


**Unity的光照衰减**

在上面的例子中，我们提到Unity使用一张纹理作为查看表来在片元着色器中计算逐像素光照的衰减。这样做的好处是，计算衰减不依赖于数学公式的复杂性，我们只要使用一个参数值去纹理中采样即可。但使用纹理查看来计算衰减也有一些弊端：

1. 需要预处理得到采样纹理，而且纹理的大小也会影响衰减的精度
2. 不直观，同时也不方便，因此一旦把数据存储到查找表中，我们就无法使用其他数学公式来计算衰减

但由于这种方法可以在一定程度上提升性能，而且得到的效果在大部分情况下都是良好的，因此，Unity默认就是使用这种纹理查找的方式来计算逐像素的点光源和聚光灯的衰减的。Unity在内部使用一张名为\_LightTexture0的纹理来计算光源衰减。需要注意的是，如果我么对该光源使用了cookie，那么衰减查找纹理是\_LightTextureB0。我们通常指关心\_LightTexture0对角线上的纹理颜色值，这些值表明了在光源空间中不同位置的点的衰减值。例如（0,0）点表明了与光源位置重合的点的衰减值，而（1，1）点表明了在光源空间中所关心的距离最远的点的衰减。

为了对\_LightTexture0纹理采样得到给定到该光源的衰减值，我们首先需要得到该点在光源空间中的位置，这是通过\_LightMatrix0变换矩阵得到的，它可以将顶点从世界坐标变换到光源坐标。然后我们可以使用这个坐标的模的平方对衰减纹理进行采样，得到衰减值。



**Unity中的阴影**

阴影的实现原理：

在实时渲染中，我们最常用的是一种名为Shadow Map的技术。这种技术理解起来非常简单，它会首先把摄像机的位置放在与光源重合的位置，那么场景中该光源的阴影区域就是那些摄像机看不到的地方。而Unity就是使用的这种技术。

在前向渲染路径中，如果场景中最重要的平行光开启了阴影，Unity就会为该光源计算它的阴影映射纹理（shadowmap）。这张阴影映射纹理本质上也是一张深度图，它记录了从该光源的位置出发，能看到的场景中距离它最近的表面位置（深度信息）。

阴影采样：

1. 传统方法：

正常渲染Pass，计算顶点的光源空间，用xy分量对纹理采样，如果顶点值大于该深度值，就说明在阴影区域

1. Unity5及以后

屏幕空间的阴影映射技术（screenspace shadow map），是在延迟渲染中产生阴影的方法，不过需要显卡支持MRT。根据

阴影映射纹理和深度纹理得到屏幕空间的阴影图。阴影图包含了屏幕空间所有阴影区域


当使用了屏幕空间的阴影映射技术时，

**不透明的物体阴影**

1）让物体投射阴影

将平行光的阴影设置为soft shadows，创建一个Plane，默认该平面会采用Standard的shader，同时Reveive Shadows也是开启的，将上面的ForwardRenderingMat赋值给正方形






Cast Shadows可以被设置为开启（On）或关闭（Off）。如果开启了Cast Shadow属性，那么Unity就会把该物体加入到光源的阴影映射纹理的计算中，从而让其他物体在对阴影映射纹理采样时可以得到该物体的相关信息。正如之前所说，这个过程是通过为该物体执行LightMode为ShadowCast的Pass来实现的。Reveive Shadows则可以选择是否让物体接受来自其他物体的阴影。如果没有开始Receive Shadows，那么当我们调用Unity的内置宏和变量计算阴影时，这些宏通过判断该物体没有开启接受阴影的功能，就不会在内部为我们计算阴影。

从上面的例子中我们发现尽管我们使用ForwardRendering的Shader没有LightMode=ShadowCast标志，但是正方形仍然可以向下面的平面投射阴影，这是为什么？其秘密就在于FallBack “Specular”,Specular对应于Normal-Glossy.shader，其目录对应于Legacy Shaders/Specular，虽然Specular本身也没有包含这样一个Pass，但是由于它的FallBack调用了VertexLit，它会继续回调，并最终回调到内置的VertexLit。




这个shader对应于Normal-VertexLit.shader，我们在这个shader中看到了传说中的Pass标记为ShadowCaster




实际上我们改为FallBack “Diffuse”也仍然会有阴影，Diffuse对应Normal-Diffuse.shader文件，Diffuse的Fallback也会对应到Legacy-Shaders/VertexLit

我们看到，上面的代码非常简短，尽管有一些宏和指令使我们之前没有遇到过的，但它们的用处实际上就是为了把深度信息写入渲染目标中。在Unity 5中，这个Pass的渲染目标可以是光源的阴影映射纹理，或是摄像机的深度纹理。如果我们将ForwardRendering.shader中的FallBack去掉就发现没有阴影了（已验证）。当然，我们可以不依赖FallBack，而自行在SubShader中定义自己的LightMode为ShadowCaster的Pass。这种自定义的Pass可以让我们更加灵活地控制阴影的产生。但由于这个Pass的功能通常是可以在多个Unity Shader间通用的，英雌直接FallBack是一个更加方便的用法。

我们在添加一个Plane，会发现新添加右边的Plane并没有在底部的Plane中产生阴影，即使我们给该新的Plane设置Cast Shadows开启：



在默认情况下，我们在计算光源的阴影映射纹理时会剔除掉物体的背面，但对于内置的平面来说，它只有有一个面，因此在本例中当计算阴影映射纹理时，由于右侧的平面的光源空间下么有任何正面，因此就不会添加到阴影映射纹理中。我们可以将Cast Shadows设置为Two Sided来允许对物体的所有面都计算阴影信息。




在本例中，最下面的平面之所有可以接受阴影是因为它使用了内置的Standard Shader，而这个内置的Shader进行了接受阴影的相关操作。但由于正方体使用的ForwardRendering并没有对阴影进行任何处理，因此它不会显示出右侧平面投射来的阴影。

2）让物体接受阴影

**立方体纹理**

和之前见到的纹理不同，立方体纹理 一共包含6张图像。立方体的每个面表示沿着世界空间下的轴向（上、下、左、右、前、后）观察所得到的图像。对立方体纹理采样我们需要提供一个三维的纹理坐标，这个三维纹理坐标表示了我们在世界空间下的一个3D方向。这个方向矢量从立方体的中心出发，当它向外部延伸时就会和立方体的6个纹理之一发生相交，而采样得到的结果就是该交点计算而来的，下图展示了采样过程：



立方体纹理在实时渲染中有很多应用，最常见的是用于天空盒子以及环境映射

添加天空盒我们有两种方式：

1. 创建一个天空盒材质，将改材质赋值给Window-Lighting的Skybox选项，为了让摄像机正常显示天空盒，我们还需要保证场景的摄像机Camera组件中的Clear Flags被设置为Skybox，这种方式设置的天空盒会应用于该场景中的所有摄像机
2. 如果我们希望某些摄像机可以使用不同的天空盒，可以通过向该摄像机添加Skybox组件来覆盖掉之前的设置

在Unity中，天空盒是在所有不透明物体之后渲染的，而其背后使用的网格是一个立方体或一个细分后的球体

在Camera中添加Skybox组件





我们可以通过这个Skybox修改旋转角度：

void Update()

{

Skybox skybox = gameObject.GetComponent<Skybox>();

float rotation = skybox.material.GetFloat("\_Rotation");

if (skybox.material.HasProperty("\_Rotation"))

{

skybox.material.SetFloat("\_Rotation", rotation + 0.1f);

}

}

**环境映射的立方体纹理**

除了天空盒，立方体纹理最常见的用处是用于环境映射。通过这总方法，我们可以模拟出金属质感的材质。在unity 5中，创建用于环境映射的立方体纹理的方法有三种：第一种方法是直接由一些特殊布局的纹理创建；第二种方法是手动创建一个Cubemap资源，再把6张图赋给它；第三种方法是由脚本生成

如果使用第一种方法，我们需要提供一张具有特殊布局的纹理，例如类似立方体展开图的交叉布局、全景布局等。然后我们只需要把该纹理的Texture Type设置为Cubemap即可，unity会为我们做好剩下的事情。在基于物理的渲染中，我们通常会使用一张HDR图像来生成高质量的Cubemap。

第二种方法是unity 5之前的版本中使用的方法。我们首先需要在项目资源中创建一个Cubemap，然后把6张纹理拖曳到它的面板中。在Unity 5中，官方推荐使用第一种方法创建立方体纹理，这是因为第一种方法可以对纹理数据进行压缩，而且可以支持边缘修正、光滑反射和HDR等功能。

1）反射：

Shader "Unlit/Refection"

{

Properties

{

\_Color ("Color Tint", Color) = (1.0, 1.0, 1.0, 1.0)

\_ReflectColor ("Reflection Color", Color) = (1.0, 1.0, 1.0, 1.0)

\_ReflectAmount ("Reflect Amount", Range(0, 1)) = 1

\_Cubemap ("Reflection Cubemap", Cube) = "\_Skybox" {}

}

SubShader

{

Pass

{

Tags { "LightMode" = "ForwardBase" }

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

#include "Lighting.cginc"

struct a2v

{

float4 vertex : POSITION;

float4 texcoord : TEXCOORD0;

float3 normal : NORMAL;

};

struct v2f

{

float4 pos : SV\_POSITION;

float3 worldNormal : TEXCOORD0;

float4 worldPosition : TEXCOORD1;

float3 worldViewDir : TEXCOORD2;

float3 worldRef1 : TEXCOORD3;

};

fixed4 \_Color;

fixed4 \_ReflectColor;

float \_ReflectAmount;

samplerCUBE \_Cubemap;

v2f vert(a2v v)

{

v2f o;

o.pos = UnityObjectToClipPos(v.vertex);

o.worldNormal = UnityObjectToWorldNormal(v.normal);

o.worldPosition = mul(unity\_ObjectToWorld, v.vertex);

o.worldViewDir = UnityWorldSpaceViewDir(o.worldPosition);

o.worldRef1 = reflect(-o.worldViewDir, o.worldNormal);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

fixed3 worldNormal = normalize(o.worldNormal);

fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(o.worldPosition));

fixed3 worldViewDir = normalize(o.worldViewDir);

fixed3 ambient = UNITY\_LIGHTMODEL\_AMBIENT.xyz;

fixed3 diffuse = \_LightColor0.rgb \* \_Color.rgb \* saturate(dot(worldNormal, worldLightDir));

fixed3 reflection = texCUBE(\_Cubemap, o.worldRef1).rgb \* \_ReflectColor.rgb;

return fixed4(ambient + lerp(diffuse, reflection, \_ReflectAmount), 1.0);

}

ENDCG

}

}

FallBack "Diffuse"

}



对于立方体纹理的采样需要使用CG的texCUBE函数。注意到，在上面的计算中，我们在采样时并没有与oworldRef1进行归一化处理。这是因为，用于采样的参数仅仅是作为方向变量传递给texCUBE函数的，因此我们没有必要进行一次归一化操作。然后我们使用\_ReflectAmount来混合漫反射颜色与反射颜色，并和环境光照相加都返回。

2）折射

通常来说，当得到折射方向后我们就会直接使用它来对立方体纹理进行采样，但是这是不符合物理规律的。对于一个透明物体来说，一种更准确的模拟方法需要计算两次折射—---一次是当光线进入它的内部时，而另一次则是从它内部射出时。但是要实时渲染第二次折射方向是比较负责的，而且仅仅模拟一次得到的效果也可以接受，因此在实时渲染中我们通常仅模拟第一次折射。

Shader "Unlit/Refaction"

{

Properties

{

\_Color ("Color Tint", Color) = (1.0, 1.0, 1.0, 1.0)

\_RefactionColor ("Refaction Color", Color) = (1.0, 1.0, 1.0, 1.0)

\_RefactionAmount ("Refaction Amount", Range(0.0, 1.0)) = 0.5

\_RefactionRatio ("Refaction Rate", Range(0.1, 1.0)) = 0.5

\_CubeMap ("Cube Map", Cube) = "\_Skybox" {}

}

SubShader

{

Tags { "Queue" = "Geometry" }

Pass

{

Tags { "LightMode" = "ForwardBase" }

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

#include "Lighting.cginc"

struct a2v

{

float4 vertex : POSITION;

float3 normal : NORMAL;

};

struct v2f

{

float4 pos : SV\_POSITION;

float4 worldPosition : TEXCOORD0;

float3 worldNormal : TEXCOORD1;

};

fixed4 \_Color;

fixed4 \_RefactionColor;

float \_RefactionAmount;

float \_RefactionRatio;

samplerCUBE \_CubeMap;

v2f vert(a2v v)

{

v2f o;

o.pos = UnityObjectToClipPos(v.vertex);

o.worldPosition = mul(unity\_ObjectToWorld, v.vertex);

o.worldNormal = UnityObjectToWorldNormal(v.normal);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

fixed3 worldNormal = normalize(o.worldNormal);

fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(o.worldPosition));

fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(o.worldPosition));

fixed3 ambient = UNITY\_LIGHTMODEL\_AMBIENT.rgb;

fixed3 diffuse = \_Color.rgb \* \_LightColor0.rgb \* saturate(dot(worldNormal, worldLightDir));

fixed3 refactionDir = refract(-worldViewDir, worldNormal, \_RefactionRatio);

fixed3 refaction = texCUBE(\_CubeMap, refactionDir) \* \_RefactionColor.rgb;

return fixed4(ambient + lerp(diffuse, refaction, \_RefactionAmount), 1.0);

}

ENDCG

}

}

FallBack "Diffuse"

}



**菲涅尔反射**

菲涅尔反射描述了一种光学现象，即当光线照射到物体表面上时，一部分发生发射，一部分进入物体内部发生折射或散射。被反射的光和入射光之间存在一定的比率广西，这个比率关系可以通过菲涅尔等式进行计算。一个例子是，站在湖边，直接低头看水面会发现几乎是透明的，但是看远处的水面，就只能看到水面反射的环境。事实上，几乎任何物体都或多或少包含了菲涅尔效果，这是基于物体的渲染中非常重要的一项高光反射计算因子。那么，我们如何极端菲涅尔反射呢？这就需要使用菲尼尔等式。真实世界的菲涅尔等式是非常复杂的，在实时渲染中，我们通常会使用一些近似公式来计算，其中一个著名的近似公式就是Schlick 菲涅尔近似等式：



其中，F0是一个反射系数，同于控制菲涅尔反射的强度，V是视角方向，n是表面法线。从这个公式可以看出看的角度和点的法线越垂直，反射现象越明显

另外一个应用比较广泛的等式是Empricial 菲涅尔近似等式：



其中，bias、scale和power是控制项。

Shader "Unlit/Fresnel"

{

Properties

{

\_Color ("Color Tint", Color) = (1.0, 1.0, 1.0, 1.0)

\_Fresnel ("Fresnel Scale", Range(0.0, 1.0)) = 0.5

\_Gloss ("Gloss", Range(8.0, 256.0)) = 20.0

\_Cubemap ("Cubemap", Cube) = "\_SkyBox" {}

}

SubShader

{

Tags { "LightMode" = "ForwardBase" }

pass

{

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

#include "Lighting.cginc"

struct a2v

{

float4 vertex : POSITION;

float3 normal : NORMAL;

};

struct v2f

{

float4 pos : SV\_POSITION;

float4 worldPosition : TEXCOORD0;

float3 worldNormal : TEXCOORD1;

float3 worldLightDir : TEXCOORD2;

float3 worldViewDir : TEXCOORD3;

float3 worldReflectDir : TEXCOORD4;

};

fixed4 \_Color;

float \_Fresnel;

float \_Gloss;

samplerCUBE \_Cubemap;

v2f vert(a2v v)

{

v2f o;

o.pos = UnityObjectToClipPos(v.vertex);

o.worldPosition = mul(unity\_ObjectToWorld, v.vertex);

o.worldNormal = UnityObjectToWorldNormal(v.normal);

o.worldLightDir = UnityWorldSpaceLightDir(o.worldPosition);

o.worldViewDir = UnityWorldSpaceViewDir(o.worldPosition);

o.worldReflectDir = reflect(-o.worldViewDir, o.worldNormal);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

fixed3 worldNormal = normalize(o.worldNormal);

fixed3 worldLightDir = normalize(o.worldLightDir);

fixed3 worldViewDir = normalize(o.worldViewDir);

// ambient

fixed3 ambient = \_Color.rgb \* UNITY\_LIGHTMODEL\_AMBIENT.rgb;

// diffuse

fixed3 diffuse = \_Color.rgb \* \_LightColor0.rgb \* saturate(dot(worldNormal, worldLightDir));

// specular

//fixed3 halfDir = normalize(worldLightDir + worldViewDir);

//fixed3 specular = \_Color.rgb \* \_LightColor0.rgb \* pow(saturate(dot(worldNormal, halfDir)), \_Gloss);

float3 reflect = texCUBE(\_Cubemap, o.worldReflectDir).rgb;

fixed fresnel = \_Fresnel + (1 - \_Fresnel) \* pow(1 - dot(worldViewDir, worldNormal), 5);

return fixed4(ambient + lerp(diffuse, reflect, saturate(fresnel)), 1.0);

}

ENDCG

}

}

FallBack "Diffuse"

}

\_Fresnel=0.48



\_Fresnel=0



\_Fresnel=1



**渲染纹理**

Unity为渲染目标纹理定义了一种专门的纹理类型---渲染纹理（Render Texture）。在Unity中使用渲染纹理通常有两种方式：

1. 在Project目录下创建一个渲染纹理，然后把某个这相机的渲染目标设置成该渲染纹理，这样一来该摄像机的渲染结果就会实时更新到渲染纹理中，而不会显示在屏幕上。使用这种方法，我们还可以选择渲染纹理的分辨率、滤波模式等纹理属性。
2. 在屏幕后处理时使用GrabPass命令或OnRenderImage函数来获取当前屏幕图像，Unity会把这个屏幕图像放到一张和屏幕分辨率等同的渲染纹理中，我们可以在自定义的Pass中把它们当成普通的纹理来处理，从而实现各种屏幕特效。

**镜子效果**

原理：另外取一个camera,创建一个RenderTexture，将这个Camera的场景渲染到RenderTexture中，然后将这个RenderTexture给到镜子的采样纹理中即可，注意镜子的左右颠倒

Shader "Unlit/Mirror"

{

Properties

{

\_MainTex ("Main Tex", 2D) = "white" {}

}

SubShader

{

Tags { "LightMode" = "ForwardBase" }

Pass

{

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

#include "Lighting.cginc"

struct a2v

{

float4 vertex : POSITION;

float4 texcoord : TEXCOORD0;

};

struct v2f

{

float4 pos : SV\_POSITION;

float4 uv : TEXCOORD0;

};

sampler2D \_MainTex;

v2f vert(a2v v)

{

v2f o;

o.pos = UnityObjectToClipPos(v.vertex);

o.uv = v.texcoord;

o.uv.x = 1 - o.uv.x;

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

return tex2D(\_MainTex, o.uv);

}


ENDCG

}

}

FallBack "Diffuse"

}




**玻璃效果**

在Unity中，我们还可以在Unity Shader中使用一种特殊的Pass来完成获取屏幕图像的目的，这就是GrabPass。

**让画面动起来**

Unity提供了一些内置的时间变量



**纹理动画**

Shader "Unlit/ImageSequenceAnimation"

{

Properties

{

\_Color ("Color Tint", Color) = (1.0, 1.0, 1.0, 1.0)

\_MainTex ("Image Sequence", 2D) = "white" {}

\_HorizontalAmount ("Horizontal Amount", Float) = 4

\_VerticalAmount ("Vertical Amount", Float) = 4

\_Speed ("Speed", Range(1.0, 100.0)) = 30.0

}

SubShader

{

Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }

Pass

{

Tags { "LightMode" = "ForwardBase" }

ZWrite Off

Blend SrcAlpha OneMinusSrcAlpha

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

struct a2v

{

float4 vertex : POSITION;

float4 texcoord : TEXCOORD0;

};

struct v2f

{

float4 pos : SV\_POSITION;

float2 uv : TEXCOORD0;

};

fixed4 \_Color;

sampler2D \_MainTex;

float4 \_MainTex\_ST;

float \_HorizontalAmount;

float \_VerticalAmount;

float \_Speed;

v2f vert(a2v v)

{

v2f o;

o.pos = UnityObjectToClipPos(v.vertex);

o.uv = TRANSFORM\_TEX(v.texcoord, \_MainTex);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

float time = floor(\_Time.y \* \_Speed);

float row = floor(time / \_HorizontalAmount);

float column = time - row \* \_VerticalAmount;

half2 uv = o.uv + half2(column, -row);

uv.x /= \_HorizontalAmount;

uv.y /= \_VerticalAmount;

fixed4 c = tex2D(\_MainTex, uv);

c.rgba \*= \_Color;

return c;

}

ENDCG

}

}

FallBack "Transparent/VertexLit"

}

由于是透明纹理，因此需要勾选该纹理的Alpha Is Transparency属性



**滚动背景**

Shader "Unlit/ScrollingBackground"

{

Properties

{

\_MainTex ("Base Layer (RGB)", 2D) = "white" {}

\_DetailTex ("2nd Layer (RGB)", 2D) = "white" {}

\_ScrollX ("Base Layer Scroll Speed", Range(0.1, 1.0)) = 1.0

\_Scroll2X ("2nd Layer Scroll Speed", Range(0.1, 1.0)) = 1.0

\_Multiplier ("Layer Multiplier", Range(0.1, 1.0)) = 1.0

}

SubShader

{

Pass

{

Tags { "LightMode" = "ForwardBase" }

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

struct a2v

{

float4 vertex : POSITION;

float4 texcoord : TEXCOORD0;

};

struct v2f

{

float4 pos : SV\_POSITION;

float4 uv : TEXCOORD0;

};

sampler2D \_MainTex;

float4 \_MainTex\_ST;

sampler2D \_DetailTex;

float4 \_DetailTex\_ST;

float \_ScrollX;

float \_Scroll2X;

float \_Multiplier;

v2f vert(a2v v)

{

v2f o;

o.pos = UnityObjectToClipPos(v.vertex);

o.uv.xy = TRANSFORM\_TEX(v.texcoord, \_MainTex) + fixed2(frac(\_ScrollX \* \_Time.y), 0.0);

o.uv.zw = TRANSFORM\_TEX(v.texcoord, \_DetailTex) + fixed2(frac(\_Scroll2X \* \_Time.y), 0.0);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

fixed4 firstLayer = tex2D(\_MainTex, o.uv.xy);

fixed4 secondLayer = tex2D(\_DetailTex, o.uv.zw);

fixed4 c = lerp(firstLayer, secondLayer, secondLayer.a);

c.rgb \*= \_Multiplier;

return c;

}

ENDCG

}

}

FallBack "Diffuse"

}



上面的例子有几个地方需要注意：

1. frac函数是用于截取小数部分
2. lerp(firstLayer, secondLayer, secondLayer.a)这里实际上是实现了混合
3. 图片的Wrap Mode必须为Repeat

**顶点动画**

流动的河流

Shader "Unlit/Water"

{

Properties

{

\_MainTex ("Main Tex", 2D) = "white" {}

\_Color ("Color Tint", Color) = (1.0, 1.0, 1.0, 1.0)

\_Magnitude ("Distortion Magnitude", Range(0.0, 10.0)) = 1

\_Frequency ("Distortion Frequency", Range(0.0, 10.0)) = 1.0

\_InvWaveLength ("Distortion Inverse Wave Length", Range(0.0, 100.0)) = 10

\_Speed ("Speed", Float) = 0.5

}

SubShader

{

Tags { "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" "DisableBatching" = "True" }

Pass

{

Tags { "LightMode" = "ForwardBase" }

ZWrite Off

Blend SrcAlpha OneMinusSrcAlpha

Cull Off

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

struct a2v

{

float4 vertex : POSITION;

float4 texcoord : TEXCOORD0;

};

struct v2f

{

float4 pos : SV\_POSITION;

float2 uv : TEXCOORD0;

};

sampler2D \_MainTex;

float4 \_MainTex\_ST;

fixed4 \_Color;

float \_Magnitude;

float \_Frequency;

float \_InvWaveLength;

float \_Speed;

v2f vert(a2v v)

{

v2f o;

UNITY\_INITIALIZE\_OUTPUT(v2f, o);

float4 offset;

offset.yzw = float3(0.0, 0.0, 0.0);

offset.x = \_Magnitude \* sin(\_Frequency \* \_Time.y + v.vertex.x \* \_InvWaveLength +

v.vertex.y \* \_InvWaveLength + v.vertex.z \* \_InvWaveLength);

o.pos = UnityObjectToClipPos(v.vertex + offset);

o.uv = TRANSFORM\_TEX(v.texcoord, \_MainTex);

o.uv += float2(0.0, \_Time.y \* \_Speed);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

fixed4 c = tex2D(\_MainTex, o.uv);

c.rgb \*= \_Color.rgb;

return c;

}

ENDCG

}

}


FallBack "Transparent/VertexLit"

}

其中\_MainTex是河流的纹理，\_Color用于控制整体颜色，\_Magnitude用于控制水流波动的幅度，\_Frequency用于控制波动频率，\_InvWaveLength用于控制波长的倒数（\_InvWaveLength越大，波长越小），\_Speed用于控制河流纹理的移动速度

在上面的例子中，我们设置了一个新的标签---DisableBatching。一些SubShader在使用Unity的批处理功能时会出现纹理，这时可以通过该标签来直接指明是否对该SubShader使用批处理。而这些需要特殊处理的Shader通常就是包含了模型空间的顶点动画的Shader。这时因为，批处理会合并所有相关的模型，而这些模型各自的模型空间就会丢失，在本例中，我们需要在物体的模型空间下对顶点位置进行偏移。因此，在这里需要取消对该Shader的批处理操作。

在上面的例子中，我们使用Cull Off，如果不使用，背面就看不见了（已证实）



广告牌

注意事项：

首先，如果我们在模型空间下进行了一些顶点动画，那么批处理往往就会破坏这种动画效果。这时我们可以通过SubShader的DisableBatching标签来强制取消对该Unity Shader的批处理。然而，取消批处理会带来一定的性能下降，增加了Draw Call，因此我们应该尽量避免使用模型空间下的一些绝对位置和方向来进行计算。

**屏幕后处理效果**

想要实现屏幕后处理的基础在于得到渲染后的屏幕图像，即抓取屏幕，而Unity为我们提供了这样一个方便的接口—OnRenderImage函数，它的函数声明如下：

MonoBehaviour.OnRenderImage(RenderTexture src, RenderTexture dest)

当我们在脚本中声明此函数后，Unity会把当前渲染得到的图像存储在第一个参数对应的源渲染纹理中，通过函数中一系列操作后，再把目标渲染纹理，即第二个参数对应的额渲染纹理显示到屏幕上。在OnRenderImage函数中，我们通常是利用Graphics.Blit函数来完成对渲染纹理的处理，它有3中函数声明：

Public static void Blit(Texture src, RenderTexture dest)

Public static void Blit(Texture src, RenderTexture dest, Material mat, int pass = -1)

Public static void Blit(Texture src, Material mat, int pass = -1)

其中，参数src对应了源纹理，在屏幕后处理技术中，这个参数通常就是当前屏幕的渲染纹理或是上一步处理后得到的渲染纹理。参数dest是目标渲染纹理，如果它的值为null就会直接将结果显示在屏幕上。参数mat是我们使用的材质，这个材质使用的Unity Shader将会进行各种屏幕后处理操作，，而src纹理将会被传递给Shader中名为\_MainTex的纹理属性。参数pass的默认值为-1，表示将会一次调用Shader内的所有Pass。否则，只会调用给定索引的Pass

在默认情况下，OnRenderImage函数会在所有的不透明和透明的Pass执行完毕后被调用，以便对场景中所有游戏对象都产生影响。但有时，我们希望在不透明的Pass（即渲染队列小于等于2500的Pass，内置的Background、Geometry和AlphaTest渲染队列均在此范围内）执行完毕后立即调用OnRenderImage函数，从而不对透明物体产生任何影响。此时我们可以在OnRenderImage函数前添加ImageEffectOpaque属性来实现这样的目的。

因此，要在Unity中实现屏幕后处理效果，过程通常如下：我们首先需要在摄像中添加一个用于屏幕后处理的脚本。在这个脚本中，我们会实现OnRenderImage函数来获取当前屏幕的渲染纹理。然后，再调用Graphics.Blit函数使用特定的Unity Shader来对当前图像进行处理，再把返回的渲染纹理显示到屏幕上。对于一些复杂的屏幕特效，我们可能需要多次调用Graphics.Blit函数来对上一步的输出结果进行下一步处理。

但是，在进行屏幕后处理之前，我们需要检查一系列条件是否满足，例如当前平台是否支持渲染纹理和屏幕特效，是否支持当前使用的Unity Shader。为此，我们创建了一个用于屏幕后处理效果的基类，在实现各种屏幕特效时，我们只需要继承自该基类，再实现派生类种不同的操作即可。

1）调整屏幕的亮度与饱和度

我们可以将一张纹理的Texture Type设置为Sprite(2D and UI)格式，就产生了一个Sprite，可以直接拖入到场景中

饱和度是指彩色的鲜艳程度。饱和度取决于该色中含色成分和消色成分（灰色）的比例。含色成分越大，饱和度越大，否则越小。

首先添加一个基类脚本:

**[ExecuteInEditMode]**

**[RequireComponent (typeof(Camera))]**

public class PostEffectsBase : MonoBehaviour {

protected bool CheckSupport()

{

if (!SystemInfo.supportsImageEffects || !SystemInfo.supportsRenderTextures)

{

Debug.LogWarning("This platform does not support image effects or render textures.");

return false;

}

return true;

}

protected void CheckResources()

{

bool supported = CheckSupport();

if (!supported) this.enabled = false;

}

void Start () { **// 这里在Start的时候会检查平台是否支持Image Effect与RenderTexture，如果不支持则不执行该脚本，也就不会执行后面的OnRenderImage**

Debug.Log("post effects base start.");

CheckResources();

}

protected Material CheckShaderAndCreateMaterial(Shader shader, Material material)

{

if (shader == null) return null;

if (shader.isSupported && material && material.shader == shader) return material;

if (shader.isSupported)

{

material = new Material(shader);

material.hideFlags = HideFlags.DontSave;

if (material) return material;

}

return null;

}

}

然后添加挂在Camera上的脚本（继承于上面的脚本）

public class BrightnessSaturationAndContrast : PostEffectsBase {

public Shader briSatConShader;

private Material briSatConMaterial;

public Material material

{

get

{

briSatConMaterial = CheckShaderAndCreateMaterial(briSatConShader, briSatConMaterial);

return briSatConMaterial;

}

}

[Range(0.0f, 3.0f)]

public float brightness = 1.0f;

[Range(0.0f, 3.0f)]

public float saturation = 1.0f;

[Range(0.0f, 3.0f)]

public float contrast = 1.0f;

void OnRenderImage(RenderTexture src, RenderTexture dest)

{

if (material) // 这里会检查材质是否可用

{

material.SetFloat("\_Brightness", brightness);

material.SetFloat("\_Saturation", saturation);

material.SetFloat("\_Contrast", contrast);

Graphics.Blit(src, dest, material);

}

else // 没有材质则直接将原图显示到屏幕上行

{

Graphics.Blit(src, dest);

}

}

}

**Graphics.Blit会将第一个参数传递给Shader中名为\_MainTex的属性**

真正的修改实现在下面的shader：

Shader "Unlit/BrightnessSaturationAndContrast"

{

Properties

{

\_MainTex ("Base (RGB)", 2D) = "white" {}

\_Brightness ("Brightness", Float) = 1.0

\_Saturation ("Saturation", Float) = 1.0

\_Contrast ("Contrast", Float) = 1.0

}

SubShader

{

ZTest Always

Cull Off

ZWrite Off

Pass

{

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

struct a2v

{

float4 vertex : POSITION;

float2 texcoord : TEXCOORD0;

};

struct v2f

{

float4 pos : SV\_POSITION;

float2 uv : TEXCOORD0;

};

sampler2D \_MainTex;

float4 \_MainTex\_ST;

half \_Brightness;

half \_Saturation;

half \_Contrast;

v2f vert(a2v v)

{

v2f o;

UNITY\_INITIALIZE\_OUTPUT(v2f, o);

o.pos = UnityObjectToClipPos(v.vertex);

o.uv = TRANSFORM\_TEX(v.texcoord, \_MainTex);

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

fixed4 renderTex = tex2D(\_MainTex, o.uv);

// 亮度

fixed3 finalColor = renderTex.rgb \* \_Brightness;

// 饱和度（为0就表示灰度图）

fixed luminance = 0.2125 \* renderTex.r + 0.7154 \* renderTex.g + 0.0721 \* renderTex.b;

fixed3 luminanceColor = fixed3(luminance, luminance, luminance);

finalColor = lerp(luminanceColor, finalColor, \_Saturation);

// 对比度

fixed3 avgColor = fixed3(0.5, 0.5, 0.5);

finalColor = lerp(avgColor, finalColor, \_Contrast);

return fixed4(finalColor, renderTex.a);

}

ENDCG

}

}

}



OnRenderImage在OnGUI之后执行，并且该GameObject上必须有Camera组件

ZTest Always

Cull Off


ZWrite Off

屏幕后处理实际上是在场景中绘制了一个与屏幕同宽同高的四边形面片，为了防止它对其他物体产生影响，我们需要设置相关的渲染状态。在这里，我们关闭了深度写入，是为了防止它“挡住”在其后面被渲染的物体。例如，如果当前的OnRenderImage函数在所有不透明的Pass执行完毕后立即被调用，不关闭深度写入就会影响后面透明的Pass的渲染。这些状态设置可以认为是用于屏幕后处理的Shader的“标配”

2）边缘检测

卷积

在图像处理中，卷积操作指的就是使用一个卷积核（kernel）对一张图像中的每个像素进行一个系列操作。卷积核通常是一个四方形网格结构（例如2x2、3x3的方形区域），该区域内每个方格都有一个权重值。当对图像中某个像素进行卷积时，我们会把卷积核的中心放置于该像素上，翻转核之后再一次计算核中每个元素和其覆盖的图像像素值的乘积并求和，得到的结果就是该位置的新像素值。卷积操作的神奇之处就在于选择的卷积核。



上面的三种常见的边缘检测算子都包含了两个方向的卷积核，分别用于检测水平方向和数值方向上的边缘信息。在进行边缘检测时，我们需要对每个像素分别进行一次卷积计算，得到两个方向上的梯度值Gx和Gy，而整体的梯度可以按下面的公式计算而得：



由于上面的计算包含了开根号操作，处于性能考虑，我们有时会使用绝对值操作来代替开根号操作：



当得到梯度G后，我们就可以根据此来判断哪些像素对应了边缘（梯度值越大，越有可能是边缘点）

Shader "Unlit/EdgeDetect"

{

Properties

{

\_MainTex ("Base (RGB)", 2D) = "white" {}

\_EdgeOnly ("Edge Only", Float) = 1.0

\_EdgeColor ("Edge Color", Color) = (0.0, 0.0, 0.0, 1.0)

\_BackgroundColor ("Background Color", Color) = (1.0, 1.0, 1.0, 1.0)

}

SubShader

{

Pass

{

ZTest Always

Cull Off

ZWrite Off

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

#include "UnityCG.cginc"

sampler2D \_MainTex;

float4 \_MainTex\_ST;

half4 \_MainTex\_TexelSize; // 纹理对应的每个纹素大小

float \_EdgeOnly;

fixed4 \_EdgeColor;

fixed4 \_BackgroundColor;

struct v2f

{

float4 pos : SV\_POSITION;

half2 uv[9] : TEXCOORD0;

};

v2f vert(appdata\_img v)

{

v2f o;

UNITY\_INITIALIZE\_OUTPUT(v2f, o);

o.pos = UnityObjectToClipPos(v.vertex);

half2 uv = v.texcoord;

o.uv[0] = uv + \_MainTex\_TexelSize.xy \* half2(-1, -1);

o.uv[1] = uv + \_MainTex\_TexelSize.xy \* half2(0, -1);

o.uv[2] = uv + \_MainTex\_TexelSize.xy \* half2(1, -1);

o.uv[3] = uv + \_MainTex\_TexelSize.xy \* half2(-1, 0);

o.uv[4] = uv + \_MainTex\_TexelSize.xy \* half2(0, 0);

o.uv[5] = uv + \_MainTex\_TexelSize.xy \* half2(1, 0);

o.uv[6] = uv + \_MainTex\_TexelSize.xy \* half2(-1, 1);

o.uv[7] = uv + \_MainTex\_TexelSize.xy \* half2(0, 1);

o.uv[8] = uv + \_MainTex\_TexelSize.xy \* half2(1, 1);

return o;

}

fixed luminance(fixed4 color)

{

return 0.2125 \* color.r + 0.7154 \* color.g + 0.0721 \* color.b;

}

half Sobel(v2f o)

{

const half Gx[9] = { -1, -2, -1, 0, 0, 0, 1, 2, 1};

const half Gy[9] = { -1, 0, 1, -2, 0, 2, -1, 0, 1};

half texColor;

half edgeX = 0;

half edgeY = 0;

for (int i = 0; i < 9; i++)

{

texColor = luminance(tex2D(\_MainTex, o.uv[i])); // 先转换为灰度图，取9个纹素能消除噪声污染

edgeX += texColor \* Gx[i];

edgeY += texColor \* Gy[i];

}

half edge = 1 - abs(edgeX) - abs(edgeY); // 如果edgeX+edgeY比较大，则可能为0，就表示为边缘

return edge;

}

fixed4 frag(v2f o) : SV\_Target

{

half edge = Sobel(o);

fixed4 withEdgeColor = lerp(\_EdgeColor, tex2D(\_MainTex, o.uv[4]), edge);

fixed4 onlyEdgeColor = lerp(\_EdgeColor, \_BackgroundColor, edge);

return lerp(withEdgeColor, onlyEdgeColor, \_EdgeOnly);


}


ENDCG

}

}

}





3）均值模糊

所谓模糊，也就是不清楚，各个像素之间会有明显的过渡，而如果像素之间的差距不是很大，那么图像就会模糊了，极端一点的情况，当一张图片所有的像素之间颜色都差不多时，那么这张图片就是一张纯色的图片了。模糊操作就是让像素间的颜色差距变小。

影响模糊程度的重要因素是模糊半径，模糊半径越大，模糊程度越大

void OnRenderImage(RenderTexture src, RenderTexture dest)

{

if (material)

{

material.SetFloat("\_BlurRadius", blurRadius);

Graphics.Blit(src, dest, material, -1);

}

else

{

Graphics.Blit(src, dest);

}

}

Shader "Unlit/SimpleBlur"

{

Properties

{

\_MainTex ("Texture Tint", 2D) = "white" {}

\_BlurRadius ("Blur Raidus", Float) = 1.0

}

CGINCLUDE

#include "UnityCG.cginc"

struct v2f

{

float4 pos : SV\_POSITION;

float2 uv[9] : TEXCOORD0;

};

sampler2D \_MainTex;

half4 \_MainTex\_TexelSize;

float \_BlurRadius;

v2f vert(appdata\_img v)

{

v2f o;

half2 texcoordOffset = half2(\_MainTex\_TexelSize.x, \_MainTex\_TexelSize.y);

o.pos = UnityObjectToClipPos(v.vertex);

o.uv[0] = v.texcoord + \_BlurRadius \* texcoordOffset \* half2(1, 1);

o.uv[1] = v.texcoord + \_BlurRadius \* texcoordOffset \* half2(-1, 1);

o.uv[2] = v.texcoord + \_BlurRadius \* texcoordOffset \* half2(-1, -1);

o.uv[3] = v.texcoord + \_BlurRadius \* texcoordOffset \* half2(1, -1);

o.uv[4] = v.texcoord + \_BlurRadius \* texcoordOffset \* half2(0, 1);

o.uv[5] = v.texcoord + \_BlurRadius \* texcoordOffset \* half2(0, -1);

o.uv[6] = v.texcoord + \_BlurRadius \* texcoordOffset \* half2(-1, 0);

o.uv[7] = v.texcoord + \_BlurRadius \* texcoordOffset \* half2(1, 0);

o.uv[8] = v.texcoord;

return o;

}

fixed4 frag(v2f o) : SV\_Target

{

fixed3 finalColor = fixed3(0.0, 0.0, 0.0);

for (int i = 0; i < 9; i++)

{

fixed3 color0 = tex2D(\_MainTex, o.uv[i]);

finalColor += color0 \* 0.111;

}

return fixed4(finalColor, 1.0);

}

ENDCG

SubShader

{

ZTest Always

ZWrite Off

Cull Off

Pass

{

CGPROGRAM

#pragma vertex vert

#pragma fragment frag

ENDCG

}


}

}

注意上面的CGINCLUDE与ENDCG标签，它实际上定义了一段CG代码段，下面可以引用上面的代码段

half4 \_MainTex\_TexelSize;

这个存储了相邻坐标的纹理偏移量






**均值模糊会出现方块化的效果，并不是很好**

4）高斯模糊

模糊的实现有很多方法，例如均值模糊和中值模糊。均值模糊同样适用了卷积操作，它使用的卷积核中的各个元素值都相等，且相加等于1，也就是说，卷积后得到的像素值是其领域内各个像素值的平均值。而中值模糊则是选择领域内对所有像素排序后的中值替换掉原颜色，一个更高级的模糊方法是高斯模糊。高斯模糊同样利用了卷积计算，它使用的卷积核名为高斯核。高斯核是一个正方形大小的滤波核，其中每个元素的计算都是基于下面的高斯方程：




其中是标准方差（一般取值为1），x和y分别对应了当前位置到卷积核重心的整数距离。为了构建一个高斯核，我们只需要计算高斯核中各个位置对应的高斯值。为了保证滤波后的图像不会变暗，我们需要对高斯核中的权重归一化，即让每个权重除以所有权重的和，这样可以保证所有权重的和为1。高斯方程很好地模拟了领域每个像素对当前处理像素的影响程度—-距离越近，影响越大。高斯的维数越高，模糊程度越大。



高斯方程很好地模拟了领域每个像素对当前处理像素的影响程度—距离越近，影响越大。高斯核的维数越高，模糊程度越大。使用一个N\*N的高斯核对图像进行卷积滤波，就需要N\*N\*W\*H（W和H分别是图像的宽和高）次纹理采样。当N的大小不断增大时，采样次数就会变得非常巨大。幸运的是，我们可以把这个二维高斯函数拆分成两个一维函数。也就是说，我们可以使用两个一维的高斯核先后对图像进行滤波，他们得到的结果和直接使用二维高斯和是一样的，但采样次数只需要2\*N\*W\*H。

再游戏中的模糊通常都是近似高斯模糊，只要保证权重采样是一条类似高斯模糊的钟形曲线就行，即从中心到边缘是平滑渐变的，一般来说游戏中对高斯模糊的优化有几点：

1. 降低阶数：降低采样的阶数，比如5阶的滤波器就比7阶的滤波器效率高，实际上一般不超过7阶
2. 迭代计算：采用低阶采样的同时，可以进行迭代计算，就是把上一次的模糊结果，再进行同样的采样模糊，以达到更好的效果
3. 固定权重：权重预先计算好，并且归一化固定下来，不在游戏过程中实时计算
4. 降维计算：因为高斯模糊在二维图像上是线性可分的，可以二维计算拆分成两次一维计算。具体就是先在水平方向做一维高斯矩阵变换后，将其结果再进行垂直方向的一维高斯矩阵变换。如下图来看对于一个9阶的二维运算来说，需要9\*9=81次采样，但是如果拆分成以为运算的话，只需要9+9=18次采样，只不过需要缓存第一次计算的结果，以空间换时间还是划算的，也可以得出阶数越高，效率相差也越大的结论。



Shader代码：

Shader "Unlit/GaussianBlur"

{

Properties

{

\_MainTex ("Texture", 2D) = "white" {}

\_BlurSize ("Blur Size", Float) = 1.0

}

SubShader

{

ZTest Always

Cull Off

ZWrite Off

CGINCLUDE

#include "UnityCG.cginc"

sampler2D \_MainTex;

float4 \_MainTex\_ST;

float4 \_MainTex\_TexelSize;

float \_BlurSize;

struct v2f

{

float4 pos : SV\_POSITION;

half2 uv[5] : TEXCOORD0;

};

v2f vertBlurVertical(appdata\_img v)

{

v2f o;

UNITY\_INITIALIZE\_OUTPUT(v2f, o);

o.pos = UnityObjectToClipPos(v.vertex);

half2 uv = v.texcoord;

o.uv[0] = uv;

o.uv[1] = uv + float2(0.0, \_MainTex\_TexelSize.y \* 1.0) \* \_BlurSize;

o.uv[2] = uv - float2(0.0, \_MainTex\_TexelSize.y \* 1.0) \* \_BlurSize;

o.uv[3] = uv + float2(0.0, \_MainTex\_TexelSize.y \* 2.0) \* \_BlurSize;

o.uv[4] = uv - float2(0.0, \_MainTex\_TexelSize.y \* 2.0) \* \_BlurSize;

return o;

}

v2f vertBlurHorizontal(appdata\_img v)

{

v2f o;

UNITY\_INITIALIZE\_OUTPUT(v2f, o);

o.pos = UnityObjectToClipPos(v.vertex);

half2 uv = v.texcoord;

o.uv[0] = uv;

o.uv[1] = uv + float2(\_MainTex\_TexelSize.x \* 1.0, 0.0) \* \_BlurSize;

o.uv[2] = uv - float2(\_MainTex\_TexelSize.x \* 1.0, 0.0) \* \_BlurSize;

o.uv[3] = uv + float2(\_MainTex\_TexelSize.x \* 2.0, 0.0) \* \_BlurSize;

o.uv[4] = uv - float2(\_MainTex\_TexelSize.x \* 2.0, 0.0) \* \_BlurSize;

return o;

}

fixed4 fragBlur(v2f o) : SV\_Target

{

float weight[3] = { 0.4026, 0.2442, 0.0545 };

fixed3 sum = tex2D(\_MainTex, o.uv[0]).rgb \* weight[0];

for (int i = 1; i < 3; i++)

{

sum += tex2D(\_MainTex, o.uv[i]).rgb \* weight[i];

sum += tex2D(\_MainTex, o.uv[2 \* i]).rgb \* weight[i];

}

return fixed4(sum, 1.0);

}

ENDCG

Pass

{

NAME "GAUSSIAN\_BLUR\_VERTICAL"

CGPROGRAM

#pragma vertex vertBlurVertical

#pragma fragment fragBlur

ENDCG

}

Pass

{

NAME "GAUSSIAN\_BLUR\_HORIZONTAL"

CGPROGRAM

#pragma vertex vertBlurHorizontal

#pragma fragment fragBlur

ENDCG

}

}

}

1）简单的c#代码

void OnRenderImage(RenderTexture src, RenderTexture dest)

{

if (material)

{

material.SetFloat("\_BlurSize", blurSpread);

int rtW = src.width;

int rtH = src.height;

RenderTexture buffer = RenderTexture.GetTemporary(rtW, rtH, 0);

// Render the vertical pass (采用第一个pass)

Graphics.Blit(src, buffer, material, 0);

// Render the horizontal pass (采用第二个pass)

Graphics.Blit(buffer, dest, material, 1);

RenderTexture.ReleaseTemporary(buffer);

}

else

{

Graphics.Blit(src, dest);

}

}





2）降采样

void OnRenderImage(RenderTexture src, RenderTexture dest)

{

if (material)

{

material.SetFloat("\_BlurSize", blurSpread);

int rtW = src.width / downSample;

int rtH = src.height / downSample;

RenderTexture buffer = RenderTexture.GetTemporary(rtW, rtH, 0);

buffer.filterMode = FilterMode.Bilinear;

// Render the vertical pass (采用第一个pass，渲染到了buffer中)

Graphics.Blit(src, buffer, material, 0);

// Render the horizontal pass (采用第二个pass)

Graphics.Blit(buffer, dest, material, 1);

RenderTexture.ReleaseTemporary(buffer);

}

else

{

Graphics.Blit(src, dest);

}

}



3）多次迭代

void OnRenderImage(RenderTexture src, RenderTexture dest)

{

if (material)

{

int rtW = src.width / downSample;

int rtH = src.height / downSample;

RenderTexture buffer0 = RenderTexture.GetTemporary(rtW, rtH, 0);

buffer0.filterMode = FilterMode.Bilinear;

Graphics.Blit(src, buffer0); // 直接将采样，在迭代的过程中处理的是降采样的纹理

for (int i = 0; i < iterations; i++)

{

material.SetFloat("\_BlurSize", 1.0f + i \* blurSpread);

// 处理垂直模糊

RenderTexture buffer1 = RenderTexture.GetTemporary(rtW, rtH, 0);

Graphics.Blit(buffer0, buffer1, material, 0);

RenderTexture.ReleaseTemporary(buffer0);

buffer0 = buffer1;

// 处理水平模糊

buffer1 = RenderTexture.GetTemporary(rtW, rtH, 0);

Graphics.Blit(buffer0, buffer1, material, 1);

RenderTexture.ReleaseTemporary(buffer0);

buffer0 = buffer1;

}

Graphics.Blit(buffer0, dest);

RenderTexture.ReleaseTemporary(buffer0);

}

else

{

Graphics.Blit(src, dest);

}

}



在高斯核维数不变的情况下，\_BlurSize越大，模糊程度越高，但采样数却不会收到影响。但过大的\_BlurSize值会造成虚影，这可能并不是我们希望的，所以应该将这个值设置为一个合理值。

5）bloom效果

Bloom特效时游戏中常见的一种屏幕特效。这种特效可以模糊真实摄像机的一种图像效果，它让画面中较亮的区域“扩散”到周围的区域中，造成一种朦胧效果。

Bloom的实现原理非常简单：我们首先根据一个阈值提取出图像中较亮区域，把他们存储在一张渲染纹理中，再利用高斯模糊对这张渲染纹理进行模糊处理，模拟光线扩散的效果，最后再将其和原图像进行混合，得到最终的效果。

Shader "Unlit/Bloom"

{

Properties

{

\_MainTex ("Texture", 2D) = "white" {}

\_Bloom ("Bloom", 2D) = "black" {}

\_LuminanceThreshold ("Luminance Threshold", Float) = 0.5

\_BlurSize ("Blur Size", Float) = 1.0

}

SubShader

{

ZTest Always

Cull Off

ZWrite Off

CGINCLUDE

#include "UnityCG.cginc"

sampler2D \_MainTex;

float4 \_MainTex\_TexelSize;

sampler2D \_Bloom;

float \_LuminanceThreshold;

float \_BlurSize;

struct v2f

{

float4 pos : SV\_POSITION;

half2 uv : TEXCOORD0;

};

v2f vertExtractBright(appdata\_img v)

{

v2f o;

UNITY\_INITIALIZE\_OUTPUT(v2f, o);

o.pos = UnityObjectToClipPos(v.vertex);

o.uv = v.texcoord;

return o;

}

fixed luminance(fixed4 color)

{

return 0.2125 \* color.r + 0.7154 \* color.g + 0.0721 \* color.b;

}

fixed4 fragExtractBright(v2f o) : SV\_Target

{

fixed4 c = tex2D(\_MainTex, o.uv);

fixed4 val = clamp(luminance(c) - \_LuminanceThreshold, 0.0, 1.0);

return c \* val;

}

struct v2fBloom

{

float4 pos : SV\_POSITION;

half4 uv : TEXCOORD0;

};

v2fBloom vertBloom(appdata\_img v)

{

v2fBloom o;

UNITY\_INITIALIZE\_OUTPUT(v2fBloom, o);

o.pos = UnityObjectToClipPos(v.vertex);

o.uv.xy = v.texcoord;

o.uv.zw = v.texcoord;

#if UNITY\_UV\_STARTS\_AT\_TOP

if (\_MainTex\_TexelSize.y < 0.0)

o.uv.w = 1.0 - o.uv.w;

#endif

return o;

}

fixed4 fragBloom(v2fBloom o) : SV\_Target

{

return tex2D(\_MainTex, o.uv.xy) + tex2D(\_Bloom, o.uv.zw);

}

ENDCG

Pass

{

CGPROGRAM

#pragma vertex vertExtractBright

#pragma fragment fragExtractBright

ENDCG

}

UsePass "Unlit/GaussianBlur/GAUSSIAN\_BLUR\_VERTICAL"

UsePass "Unlit/GaussianBlur/GAUSSIAN\_BLUR\_HORIZONTAL"

Pass

{

CGPROGRAM

#pragma vertex vertBloom

#pragma fragment fragBloom

ENDCG

}

}

}

C#代码：

void OnRenderImage(RenderTexture src, RenderTexture dest)

{

if (material)

{

material.SetFloat("\_LuminanceThreshold", luminanThreshold);

int rtW = src.width / downSample;

int rtH = src.height / downSample;

RenderTexture buffer0 = RenderTexture.GetTemporary(src.width, src.height, 0);

buffer0.filterMode = FilterMode.Bilinear;

Graphics.Blit(src, buffer0, material, 0); // 第一个pass，提取较亮区域

for (int i = 0; i < iterations; i++)

{

material.SetFloat("\_BlurSize", 1.0f + blurSpread);

RenderTexture buffer1 = RenderTexture.GetTemporary(rtW, rtH, 0);

Graphics.Blit(buffer0, buffer1, material, 1); // 第二个pass

RenderTexture.ReleaseTemporary(buffer0);

buffer0 = buffer1;

buffer1 = RenderTexture.GetTemporary(rtW, rtH, 0);

Graphics.Blit(buffer0, buffer1, material, 2); // 第三个pass

RenderTexture.ReleaseTemporary(buffer0);

buffer0 = buffer1;

}

material.SetTexture("\_Bloom", buffer0);

Graphics.Blit(src, dest, material, 3); // 第四个pass

RenderTexture.ReleaseTemporary(buffer0);

}

else

{


Graphics.Blit(src, dest);

}

}



**渲染纹理的坐标差异**



需要注意的是，我们不仅可以把渲染结果输出到屏幕上，还可以输出到不同的渲染目标（Render Texture）中。这时，我们需要使用渲染纹理（Render Texture）来保存这些渲染结果。大多数情况下，这样的差异并不会对我们造成任何影响。但当我们要使用渲染到纹理技术，把屏幕图像渲染到一张渲染纹理中时，如果不采取任何措施的话，就会出现纹理翻转的情况。

UNITY\_UV\_STARTS\_AT\_TOP用于判断当前平台是否是DirectX类型的平台，而当在这样的平台下开启了抗锯齿后，主纹理的纹素大小在竖直方向上会变成负数，以方便我们队主纹理进行正确的采样。因此我们可以通过判断\_MainTex\_TexelSize.y是否小于0来检验是否开启了抗锯齿，如果是，我们就需要对除主纹理外的其他纹理的采样坐标进行竖直方向上的翻转。

UNITY\_UV\_STARTS\_AT\_TOP 总是用1或0定义；   
当纹理的V坐标系原点在纹理顶部的平台上值是1。   
Direct3D类似平台使用1；OpenGL类似平台使用0。

在Direct3D平台下，如果我们开启了抗锯齿，则xxx\_TexelSize.y 会变成负值，好让我们能够正确的进行采样。   
所以if (\_MainTex\_TexelSize.y < 0)的作用就是判断我们当前是否开启了抗锯齿。

**UNITY\_UV\_STARTS\_AT\_TOP用于判断是否是Direct3D平台**

**if (\_MainTex\_TexelSize.y < 0)判断是否开启了抗锯齿**

如果我们做的屏幕后期特效简单（一次处理一个纹理），这无关紧要，因为 Graphics.Blit 方法会自动进行处理。

然而，如果在屏幕后期特效中同时处理一个以上的 RenderTexture，它们很可能会在不同的垂直方向出现（仅在类似 Direct3D 的平台上，并且仅在使用抗锯齿选项时）。您需要在顶点着色器中手动“翻转”屏幕纹理。

6）运动模糊

运动模糊的实现有多重方法。一种实现方法是利用一块累积缓存区来混合多张连续的图像。当物体快速移动产生多张图像后，我们取它们之间的平均值作为最后的运动模糊图像，然而，这种暴力的方法对性能的消耗很大，因此想要获取多张帧图像往往意味着我们需要在同一帧里渲染多次场景。另一种应用广泛的方法是创建和使用速度缓存，这个缓存中存储了各个像素当前的运动速度，然后利用该值来决定模糊的方向和大小