# 练习七

1．宏录制

1)使用“录制新宏”记录一段宏：设置单元格的颜色，底色，字体大小。

2)改变宏代码，使该宏运行时，其单元格的值改为0

2．练习查找Abs 函数。

3．在VBA 中输入以下代码，练习掌握Range, Cell, Worksheet, Workbook等对象和属性的基本操作。

Range属性：

Sub RngSelect()

  Sheet1.Range("A3:F6, B1:C5").Select

End Sub

Cell属性：

Sub Cell()

  Dim icell As Integer

  For icell = 1 To 100

      Sheet2.Cells(icell, 1).Value = icell

  Next

End Sub

快捷键访问：

Sub Fastmark()

  [A1：A5] = 2

  [Fast] = 4

End Sub

Offset属性

Sub Offset()

  Sheet3.Range("A1:C3").Offset(3, 3).Select

End Sub

Resize属性

Sub Resize()

  Sheet4.Range("A1").Resize(3, 3).Select

End Sub

Union属性

Sub UnSelect()

  Union(Sheet5.Range("A1:D4"), Sheet5.Range("E5:H8")).Select

End Sub

CurrentRegion属性

Sub CurrentSelect()

  Sheet7.Range("A5").CurrentRegion.Select

End Sub

使用Insert方法，在Worksheet工作表的中插入多行空行：

Sub InSertRows\_1()

  Dim i As Integer

  For i = 1 To 3

      Sheet1.Rows(3).Insert

  Next

End Sub

使用Add方法，新建WorkBook工作簿对象：

Sub AddNowbook()

  Dim Nowbook As Workbook

  Dim ShName As Variant

  Dim Arr As Variant

  Dim i As Integer

  Dim myNewWorkbook As Integer

  myNewWorkbook = Application.SheetsInNewWorkbook

  ShName = Array("余额", "单价", "数量", "金额")

  Arr = Array("01月", "02月", "03月", "04月", "05月", "06月", "07月", "08月", "09月", "10月", "11月", "12月")

  Application.SheetsInNewWorkbook = 4

  Set Nowbook = Workbooks.Add

  With Nowbook

      For i = 1 To 4

          With .Sheets(i)

              .Name = ShName(i - 1)

              .Range("B1").Resize(1, UBound(Arr) + 1) = Arr

              .Range("A2") = "品名"

          End With

      Next

      .SaveAs Filename:=ThisWorkbook.Path & "\" & "存货明细.xls"

      .Close Savechanges:=True

  End With

  Set Nowbook = Nothing

  Application.SheetsInNewWorkbook = myNewWorkbook

End Sub

使用Save方法保存WorkBook工作簿：

Sub SaveWork()

  ThisWorkbook.Save

End Sub

使用Workbook对象的SaveAs方法，将工作簿另存为另一个文件名：

Sub SaveAsWork()

  ThisWorkbook.SaveAs Filename:=ThisWorkbook.Path & "\123.xls"

End Sub

工作表中的图片的移动、旋转：

Sub MoveShape()

  Dim i As Long

  Dim j As Long

  With Sheet1.Shapes(1)

      For i = 1 To 3000 Step 5

         .Top = Sin(i \* (3.1416 / 180)) \* 100 + 100

         .Left = Cos(i \* (3.1416 / 180)) \* 100 + 100

         .Fill.ForeColor.RGB = i \* 100

          For j = 1 To 10

              .IncrementRotation -2

              DoEvents

          Next

      Next

  End With

End Sub

在工作表中自动生成图表：

Sub ChartAdd()

  Dim myRange As Range

  Dim myChart As ChartObject

  Dim R As Integer

  With Sheet1

      .ChartObjects.Delete

      R = .Range("A65536").End(xlUp).Row

      Set myRange = .Range("A" & 1 & ":B" & R)

      Set myChart = .ChartObjects.Add(120, 40, 400, 250)

      With myChart.Chart

          .ChartType = xlColumnClustered

          .SetSourceData Source:=myRange, PlotBy:=xlColumns

          .ApplyDataLabels ShowValue:=True

          .HasTitle = True

          .ChartTitle.Text = "图表制作示例"

          With .ChartTitle.Font

              .Size = 20

              .ColorIndex = 3

              .Name = "华文新魏"

          End With

          With .ChartArea.Interior

              .ColorIndex = 8

              .PatternColorIndex = 1

              .Pattern = xlSolid

          End With

          With .PlotArea.Interior

              .ColorIndex = 35

              .PatternColorIndex = 1

              .Pattern = xlSolid

          End With

          .SeriesCollection(1).DataLabels.Delete

          With .SeriesCollection(2).DataLabels.Font

              .Size = 10

              .ColorIndex = 5

          End With

      End With

  End With

  Set myRange = Nothing

  Set myChart = Nothing

End Sub

使用Export方法，以图形文件格式导出图表：

Sub ExportChart()

  Dim myChart As Chart

  Dim myFileName As String

  Set myChart = Sheet1.ChartObjects(1).Chart

  myFileName = "myChart.jpg"

  On Error Resume Next

  Kill ThisWorkbook.Path & "\" & myFileName

  myChart.Export Filename:=ThisWorkbook.Path \_

      & "\" & myFileName, Filtername:="JPG"

  MsgBox "图表已保存在[" & ThisWorkbook.Path & "]文件夹中!"

  Set myChart = Nothing

End Sub

将工作表中嵌入的图表显示在独立的窗口中：

Sub ChartShow()

  With Sheet1.ChartObjects(1)

      .Activate

      .Chart.ShowWindow = True

  End With

  With ActiveWindow

      .Top = 50

      .Left = 50

      .Width = 400

      .Height = 280

      .Caption = ThisWorkbook.Name

  End With

End Sub