Permalink
Browse files

Add newer mythtv patch set.

  • Loading branch information...
1 parent 605c248 commit 1fdaeb418603363628794a39e128eddd78f30a34 @rich0 committed Dec 22, 2012
Showing with 349 additions and 3 deletions.
  1. +2 −3 media-tv/mythtv/Manifest
  2. +347 −0 media-tv/mythtv/mythtv-0.26.0_p20121221.ebuild
@@ -7,7 +7,6 @@ AUX mythfrontend.wrapper 794 SHA256 db90ac5ff3bec3f2a81f376cc94c553d2cce026fd921
AUX mythtv.logrotate.d-r2 1127 SHA256 bd7b8bfbd116ba5cbe97ad2651d58ac9bce2afc7bb976eec6f035928361882a5 SHA512 3e4a7777a02c0945729286b02a42ef6bbd5a6507ebd22735a3abfdb2f722b2a94f347f1ef9aed3a8e213e860f980021d94985218d0930617dbb1563b781cc729 WHIRLPOOL 774d4dce5baaadef73eba004a2f808863eaa295a767eda89890969aa4d0ba1b8978353e86ccc5d1915cc4668048f717428aa68dc1d98390f3c0b31f6455bb75f
AUX mythtv.logrotate.d-r3 573 SHA256 07c97a5f83274061eafd371e03f55f9a526fae672f4f1bd6bc47a67317465888 SHA512 515f3fa9064fa97c99872b195b09fe67736194e544d7a348c0ebd3bd04336e7e921bfb72313d9004fad610cd09a94d3dc3cfeff144880d59747bf2c17b8c6458 WHIRLPOOL 12f56707552ab13ef2de6c219d486599b0fa86f93ffe720d012fc5a40ed70d1a7affaf94d4bb6a696163cb0457a108ac58f5ac74f4aaf00a482ede81e9e4d200
AUX xinitrc-r1 234 SHA256 0b335cc6d1e22d71f61bacfdcfed6cc450fecf7ff10bdb4bad50fd085bd7b2db SHA512 885adfe395fe553f6d5cf518856be7be9a6bf6073888f8e055271ed7c3d9ad85a162e9e9ff95a68e54047948ac280796c69ef55d0b4e549eb0beabbf0fec1188 WHIRLPOOL 6796d4d83ff200bd36cc02e3765222efd77dd7baa69ed9d6845b7ecb836fcd0b110f7ce644af1e2c4af3f76c4c924f7e69499b0b4f9f511ace31f3f9cc804240
-DIST mythtv-0.26.0-cd2e061f999d336a87fad9c3eace6fd3c0d01dd4.tar.xz 17856 SHA256 6128bb8ed8344d7e33e5c6bc91423e71ac6a8cf3dec8f8582e9db8cf13e61d4e SHA512 a952fdc26f3d8a0186452b25164c42cd91ff9653e4596fbd3fd10d50f63db9203b64cfe468eb6885893e2d2f6a8f315e5f14d3d75b79c847e72f6997847f8bc7 WHIRLPOOL 6ab3a3027d085d37bd93fb1003a21f33ac795d1b304f4f6e0d62f8a0ad79c2b6bda0455107a2ee69678563087d8ed4c101a6a865609bd0b15dfe815e80138200
+DIST mythtv-0.26.0-637d6d87d20aa8b17247fedf87b6c78ef091f08c.tar.xz 35064 SHA256 8451fb058751f4cda6cf81da80dd047218819ff3f63d0dc015024cfbddf79c1a SHA512 bc1aa616ce2f912119535348ade64a1a95e5952a006864f5997b174a175f825b9f46350c038ef9b53137f0d7b0e979dcb016294e1d6d3851eb21adaa81beb1fb WHIRLPOOL 75f56b9c902c44b0119e0cc1da58f6fe0e1b22bf445b8dd245d7e0ca49015b781a225124ce11b6f6c24e043c8df611afdad072800d40a6104cacd924b7a4c032
DIST mythtv-0.26.0.tar.bz2 40887666 SHA256 2f158962ca3009db563dabc32827c47788a688bd67a25abd76f4baa9c3cfe306 SHA512 8c8766542b6a1a877d400fd99343e8149d9c6cc4ab1e425db358bdbdc10b6cb7422bb4bdcf984ce64b2cf02b0ad0725606b266558afcadff9ec9c9bb95bb49c0 WHIRLPOOL c737a1dbdfafe65ae5ee3bde8d0b3a9ad50ebfccec784d6907c78d03f9732637cfbf8b82ecfca80af0b049c65d70c608a81ac3bf27a8070ba3f32d657f5137bb
-EBUILD mythtv-0.26.0_p20121006.ebuild 9364 SHA256 8abd6db75a99094292a300569a0de7b32120c92a5b28f32a509b38702e58dd1a SHA512 2b8f36554ab7c2a1abe507e9d49baac8d72c0be7c68531a0d6967a1bb400806fedef1420df6aea726a5e636f4bac3c401daef6f61caa7c4f73027cb995c8023b WHIRLPOOL 92fb715f614eb2ba0ab9c23cb7f878645951233e535171fe73f8b4155c4e84fe7f6e26ce6c07d73d87235fadc64b7fc98aa67a8b4abb295e5a0442395aa19d60
-EBUILD mythtv-0.26.0_p20121107.ebuild 9393 SHA256 cdd1a4e5c51d84e72a2537cb05883e9833c23263b048de382d57baf54dbd8eeb SHA512 1fb85ff3280b311e725384b1a7c6acd3b9d4493ff90fc9a90827f8da6e44939e767a5d3531e1ec470353bcdb9278fa43861574b0d93e433f34c763307658432a WHIRLPOOL e7acabceea08d2c05c6c1371120bf97f8403c66e81171aa1b0e429b462a8d95e5b683b073224754551198eb2859cf2953ce2c56f07478a918df9573b677935ba
+EBUILD mythtv-0.26.0_p20121221.ebuild 9391 SHA256 8c997b3847054937656694a138b0cce2cd824fc19f8be7d6e9737435551465fb SHA512 5d746d69f0aca2bb2d7fcdba753bcff67ea4946a7d67338509aef9eb13834a1d502e7826090718c20dab5da3dc722cc2b878d44ba0f1eefb5aacb5b5536a0a97 WHIRLPOOL 7faa17afb944df04305811bb2ce3ec6f031af5f8c907300103203ed41d57784da56d800fb690072be3ed57f1a583c19425e5bdcf2de97acb8aa4a0679d621e7a
@@ -0,0 +1,347 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/mythtv/mythtv-0.26.0_p20121107.ebuild,v 1.1 2012/11/23 01:24:11 rich0 Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="python? 2:2.6"
+BACKPORTS="637d6d87d20aa8b17247fedf87b6c78ef091f08c"
+MY_P=${P%_p*}
+
+inherit flag-o-matic multilib eutils python user
+
+MYTHTV_VERSION="v0.26.0"
+MYTHTV_BRANCH="fixes/0.26"
+
+DESCRIPTION="Homebrew PVR project"
+HOMEPAGE="http://www.mythtv.org"
+SRC_URI="ftp://ftp.osuosl.org/pub/mythtv/${MY_P}.tar.bz2
+ ${BACKPORTS:+http://dev.gentoo.org/~rich0/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+IUSE_INPUT_DEVICES="input_devices_joystick"
+IUSE="alsa altivec libass autostart bluray cec crystalhd debug dvb dvd \
+egl fftw +hls ieee1394 jack lcd lirc perl pulseaudio python raop +theora \
+vaapi vdpau +vorbis +xml xmltv +xvid ${IUSE_INPUT_DEVICES}"
+
+REQUIRED_USE="
+ bluray? ( xml )
+ theora? ( vorbis )"
+
+COMMON="
+ >=media-libs/freetype-2.0
+ sys-libs/zlib
+ x11-libs/libX11
+ x11-libs/libXext
+ x11-libs/libXinerama
+ x11-libs/libXv
+ x11-libs/libXrandr
+ x11-libs/libXxf86vm
+ >=x11-libs/qt-core-4.7.2:4
+ >=x11-libs/qt-dbus-4.7.2:4
+ >=x11-libs/qt-gui-4.7.2:4
+ >=x11-libs/qt-script-4.7.2:4
+ >=x11-libs/qt-sql-4.7.2:4[mysql]
+ >=x11-libs/qt-opengl-4.7.2:4[egl?]
+ >=x11-libs/qt-webkit-4.7.2:4
+ x11-misc/wmctrl
+ virtual/mysql
+ virtual/opengl
+ alsa? ( >=media-libs/alsa-lib-1.0.24 )
+ bluray? (
+ dev-libs/libcdio
+ media-libs/libbluray
+ )
+ cec? ( dev-libs/libcec )
+ dvb? (
+ media-libs/libdvb
+ virtual/linuxtv-dvb-headers
+ )
+ dvd? ( dev-libs/libcdio )
+ egl? ( media-libs/mesa[egl] )
+ fftw? ( sci-libs/fftw:3.0 )
+ hls? (
+ media-libs/faac
+ media-libs/libvpx
+ >=media-libs/x264-0.0.20111220
+ >=media-sound/lame-3.93.1
+ )
+ ieee1394? (
+ >=sys-libs/libraw1394-1.2.0
+ >=sys-libs/libavc1394-0.5.3
+ >=media-libs/libiec61883-1.0.0
+ )
+ jack? ( media-sound/jack-audio-connection-kit )
+ lcd? ( app-misc/lcdproc )
+ libass? ( >=media-libs/libass-0.9.11 )
+ lirc? ( app-misc/lirc )
+ perl? (
+ dev-perl/DBD-mysql
+ dev-perl/Net-UPnP
+ dev-perl/LWP-Protocol-https
+ dev-perl/HTTP-Message
+ dev-perl/IO-Socket-INET6
+ >=dev-perl/libwww-perl-5
+ )
+ pulseaudio? ( media-sound/pulseaudio )
+ python? (
+ dev-python/mysql-python
+ dev-python/lxml
+ dev-python/urlgrabber
+ )
+ raop? (
+ dev-libs/openssl
+ net-dns/avahi[mdnsresponder-compat]
+ )
+ theora? ( media-libs/libtheora )
+ vaapi? ( x11-libs/libva )
+ vdpau? ( x11-libs/libvdpau )
+ vorbis? ( >=media-libs/libvorbis-1.0 )
+ xml? ( >=dev-libs/libxml2-2.6.0 )
+ xvid? ( >=media-libs/xvid-1.1.0 )
+ !media-tv/mythtv-bindings
+ !x11-themes/mythtv-themes
+ "
+
+RDEPEND="${COMMON}
+ media-fonts/corefonts
+ media-fonts/dejavu
+ media-fonts/liberation-fonts
+ x11-apps/xinit
+ autostart? (
+ net-dialup/mingetty
+ x11-wm/evilwm
+ x11-apps/xset
+ )
+ dvd? ( media-libs/libdvdcss )
+ xmltv? ( >=media-tv/xmltv-0.5.43 )
+ "
+
+DEPEND="${COMMON}
+ dev-lang/yasm
+ x11-proto/xineramaproto
+ x11-proto/xf86vidmodeproto
+ "
+
+S="${WORKDIR}/${MY_P}"
+
+MYTHTV_GROUPS="video,audio,tty,uucp"
+
+pkg_setup() {
+ python_set_active_version 2
+ python_pkg_setup
+ enewuser mythtv -1 /bin/bash /home/mythtv ${MYTHTV_GROUPS}
+ usermod -a -G ${MYTHTV_GROUPS} mythtv
+}
+
+src_prepare() {
+ [[ -n ${BACKPORTS} ]] && \
+ EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
+ epatch
+
+ # Perl bits need to go into vender_perl and not site_perl
+ sed -e "s:pure_install:pure_install INSTALLDIRS=vendor:" \
+ -i "${S}"/bindings/perl/Makefile
+
+ # Fix up the version info since we are using the fixes/${PV} branch
+ echo "SOURCE_VERSION=\"${MYTHTV_VERSION}\"" > "${S}"/VERSION
+ echo "BRANCH=\"${MYTHTV_BRANCH}\"" >> "${S}"/VERSION
+
+ echo "setting.extra -= -ldconfig" >> "${S}"/programs/mythfrontend/mythfrontend.pro
+
+ epatch "${FILESDIR}/libdir.patch"
+
+ epatch_user
+}
+
+src_configure() {
+ local myconf=
+
+ # Setup paths
+ myconf="${myconf} --prefix=${EPREFIX}/usr"
+ myconf="${myconf} --libdir=${EPREFIX}/usr/$(get_libdir)"
+ myconf="${myconf} --libdir-name=$(get_libdir)"
+ myconf="${myconf} --mandir=${EPREFIX}/usr/share/man"
+
+ # Audio
+ myconf="${myconf} $(use_enable alsa audio-alsa)"
+ myconf="${myconf} $(use_enable jack audio-jack)"
+ use pulseaudio || myconf="${myconf} --disable-audio-pulseoutput"
+
+ use altivec || myconf="${myconf} --disable-altivec"
+ myconf="${myconf} $(use_enable dvb)"
+ myconf="${myconf} $(use_enable ieee1394 firewire)"
+ myconf="${myconf} $(use_enable lirc)"
+ myconf="${myconf} $(use_enable xvid libxvid)"
+ myconf="${myconf} --dvb-path=/usr/include"
+ myconf="${myconf} --enable-xrandr"
+ myconf="${myconf} --enable-xv"
+ myconf="${myconf} --enable-x11"
+ myconf="${myconf} --enable-nonfree"
+ use cec || myconf="${myconf} --disable-libcec"
+ use raop || myconf="${myconf} --disable-libdns-sd"
+ myconf="${myconf} $(use_enable theora libtheora)"
+ myconf="${myconf} $(use_enable vorbis libvorbis)"
+
+ if use hls; then
+ myconf="${myconf} --enable-libmp3lame"
+ myconf="${myconf} --enable-libx264"
+ myconf="${myconf} --enable-libvpx"
+ myconf="${myconf} --enable-libfaac"
+ fi
+
+ if use perl && use python; then
+ myconf="${myconf} --with-bindings=perl,python"
+ elif use perl; then
+ myconf="${myconf} --without-bindings=python"
+ myconf="${myconf} --with-bindings=perl"
+ elif use python; then
+ myconf="${myconf} --without-bindings=perl"
+ myconf="${myconf} --with-bindings=python"
+ else
+ myconf="${myconf} --without-bindings=perl,python"
+ fi
+
+ use python && myconf="${myconf} --python=$(PYTHON)"
+
+ if use debug; then
+ myconf="${myconf} --compile-type=debug"
+ else
+ myconf="${myconf} --compile-type=profile"
+ #myconf="${myconf} --enable-debug" does nothing per sphery
+ #myconf="${myconf} --disable-stripping" does nothing per sphery
+ fi
+
+ # Video
+ use vdpau && myconf="${myconf} --enable-vdpau"
+ use vaapi && myconf="${myconf} --enable-vaapi"
+ use crystalhd && myconf="${myconf} --enable-crystalhd"
+
+ # Input
+ use input_devices_joystick || myconf="${myconf} --disable-joystick-menu"
+
+ # Clean up DSO load times and other compiler bits
+ myconf="${myconf} --enable-symbol-visibility"
+ myconf="${myconf} --enable-pic"
+
+ # CPU settings
+ for i in $(get-flag march) $(get-flag mcpu) $(get-flag mtune) ; do
+ [ "${i}" = "native" ] && i="host"
+ myconf="${myconf} --cpu=${i}"
+ break
+ done
+
+ if tc-is-cross-compiler ; then
+ myconf="${myconf} --enable-cross-compile --arch=$(tc-arch-kernel)"
+ myconf="${myconf} --cross-prefix=${CHOST}-"
+ fi
+
+ # Build boosters
+ has distcc ${FEATURES} || myconf="${myconf} --disable-distcc"
+ has ccache ${FEATURES} || myconf="${myconf} --disable-ccache"
+
+ chmod +x ./external/FFmpeg/version.sh
+
+ einfo "Running ./configure ${myconf}"
+ ./configure \
+ --cc="$(tc-getCC)" \
+ --cxx="$(tc-getCXX)" \
+ --ar="$(tc-getAR)" \
+ --extra-cflags="${CFLAGS}" \
+ --extra-cxxflags="${CXXFLAGS}" \
+ --extra-ldflags="${LDFLAGS}" \
+ ${myconf} || die "configure died"
+}
+
+src_install() {
+ emake INSTALL_ROOT="${D}" install || die "install failed"
+ dodoc AUTHORS UPGRADING README
+
+ insinto /usr/share/mythtv/database
+ doins database/*
+
+ newinitd "${FILESDIR}"/mythbackend.init mythbackend
+ newconfd "${FILESDIR}"/mythbackend.conf mythbackend
+
+ dodoc keys.txt
+
+ keepdir /etc/mythtv
+ chown -R mythtv "${ED}"/etc/mythtv
+ keepdir /var/log/mythtv
+ chown -R mythtv "${ED}"/var/log/mythtv
+ dodir /var/log/mythtv/old
+
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}"/mythtv.logrotate.d-r3 mythtv
+
+ insinto /usr/share/mythtv/contrib
+ doins -r contrib/*
+
+ # Install our mythfrontend wrapper which is similar to Mythbuntu's
+ mv "${ED}/usr/bin/mythfrontend" "${ED}/usr/bin/mythfrontend.real"
+ newbin "${FILESDIR}"/mythfrontend.wrapper mythfrontend
+ newconfd "${FILESDIR}"/mythfrontend.conf mythfrontend
+
+ if use autostart; then
+ dodir /etc/env.d/
+ echo 'CONFIG_PROTECT="/home/mythtv/"' > "${ED}"/etc/env.d/95mythtv
+
+ insinto /home/mythtv
+ newins "${FILESDIR}"/bash_profile .bash_profile
+ newins "${FILESDIR}"/xinitrc-r1 .xinitrc
+ fi
+
+ # Make Python files executable
+ find "${ED}/usr/share/mythtv" -type f -name '*.py' | while read file; do
+ if [[ ! "${file##*/}" = "__init__.py" ]]; then
+ chmod a+x "${file}"
+ fi
+ done
+
+ # Ensure that Python scripts are executed by Python 2
+ python_convert_shebangs -q -r 2 "${ED}/usr/share/mythtv"
+
+ # Make shell & perl scripts executable
+ find "${ED}" -type f -name '*.sh' -o -type f -name '*.pl' | \
+ while read file; do
+ chmod a+x "${file}"
+ done
+}
+
+pkg_preinst() {
+ export CONFIG_PROTECT="${CONFIG_PROTECT} ${EROOT}/home/mythtv/"
+}
+
+pkg_postinst() {
+ use python && python_mod_optimize MythTV
+
+ elog "To have this machine operate as recording host for MythTV, "
+ elog "mythbackend must be running. Run the following:"
+ elog "rc-update add mythbackend default"
+ elog
+ elog "Your recordings folder must be owned 'mythtv'. e.g."
+ elog "chown -R mythtv /var/lib/mythtv"
+
+ elog "Want mythfrontend to start automatically?"
+ elog "Set USE=autostart. Details can be found at:"
+ elog "http://dev.gentoo.org/~cardoe/mythtv/autostart.html"
+}
+
+pkg_postrm() {
+ use python && python_mod_cleanup MythTV
+}
+
+pkg_info() {
+ if [[ -f "${EROOT}"/usr/bin/mythfrontend ]]; then
+ "${EROOT}"/usr/bin/mythfrontend --version
+ fi
+}
+
+pkg_config() {
+ echo "Creating mythtv MySQL user and mythconverg database if it does not"
+ echo "already exist. You will be prompted for your MySQL root password."
+ "${EROOT}"/usr/bin/mysql -u root -p < "${EROOT}"/usr/share/mythtv/database/mc.sql
+}

0 comments on commit 1fdaeb4

Please sign in to comment.