
Homework Week 3

Professor Data Science

Solve problem 3.4-15 using OPL in CPLEX Optimization Studio. Here is the mathematical formulation of the linear programming problem (students aren’t required to submit this part):

Here is a model file for solving this problem in OPL:

// Initialize data from file

{string} Workers = ...;

{string} Days = ...;

float wageRates[Workers] = ...;

float minHours[Workers] = ...;

float hoursOpen[Days] = ...;

tuple workerAssignType {

string w;

string d;

float availHrs;

}

{workerAssignType} WorkAssigns = ...;

tuple connection {

string w;

string d;

}

// every possible assignment of a worker to a day is a "connection"

{connection} Connections = { <w,d> | <w,d,availHrs> in WorkAssigns};

float Availability[Connections] = [ <t.w,t.d>:t.availHrs | t in WorkAssigns];

dvar float+ Hours[Connections];

minimize sum(c in Connections) wageRates[c.w]\*Hours[c];

constraint ctSupply[Workers];

constraint ctDemand[Days];

constraint ctAvail[Connections];

subject to {

forall( w in Workers)

ctSupply[w]: // each worker gets at least minimum Hours

sum( <w,d> in Connections)

Hours[<w,d>] >= minHours[w];

forall( d in Days)

ctDemand[d]: // total hours supplied by workers each day equals demand

sum( <w,d> in Connections)

Hours[<w,d>] == 14;

forall (c in Connections)

ctAvail[c]: // each worker gets assigned no more than their available hours

Hours[c] <= Availability[c];

}

execute{

for( var c in Connections ) {

writeln(c, Hours[c]);

}

}

Here is a model file for solving this problem in OPL:

Workers = {KC DH HB SC KS NK};

Days = {Monday Tuesday Wednesday Thursday Friday};

wageRates = #[

KC:25

DH:26

HB:24

SC:23

KS:28

NK:30

]#;

minHours = #[

KC:8

DH:8

HB:8

SC:8

KS:7

NK:7

]#;

hoursOpen = #[

Monday:14

Tuesday:14

Wednesday:14

Thursday:14

Friday:14

]#;

WorkAssigns = {

<KC,Monday,6>

<KC,Wednesday,6>

<KC,Friday,6>

<DH,Tuesday,6>

<DH,Thursday,6>

<HB,Monday,4>

<HB,Tuesday,8>

<HB,Wednesday,4>

<HB,Friday,4>

<SC,Monday,5>

<SC,Tuesday,5>

<SC,Wednesday,5>

<SC,Friday,5>

<KS,Monday,3>

<KS,Wednesday,3>

<KS,Thursday,8>

<NK,Thursday,6>

<NK,Friday,2>

};

Here are the results:

// solution (optimal) with objective 1755

<"KC" "Monday">3

<"KC" "Wednesday">2

<"KC" "Friday">4

<"DH" "Tuesday">2

<"DH" "Thursday">6

<"HB" "Monday">4

<"HB" "Tuesday">7

<"HB" "Wednesday">4

<"HB" "Friday">4

<"SC" "Monday">5

<"SC" "Tuesday">5

<"SC" "Wednesday">5

<"SC" "Friday">5

<"KS" "Monday">2

<"KS" "Wednesday">3

<"KS" "Thursday">2

<"NK" "Thursday">6

<"NK" "Friday">1

The total labor cost for the week is $1755.

KC gets 9 hours.

DH gets 8 hours.

HB gets 20 hours.

SC gets 15 hours.

KS gets 7 hours.

NK gets 7 hours.

Each day is staffed efficiently with exactly 14 hours.